configure.in

   1 AC_INIT(patchlevel.h)
   2
   3 dnl On Athena at least, many of the packages (krb, zephyr, hesiod, etc)
   4 dnl will all be in /usr/athena... this hack lets us not end up with 10
   5 dnl copies of -I/usr/athena/include -L/usr/athena/lib in our command lines
   6 AC_DEFUN(MR_EXTEND, [
   7     case $$1 in
   8         *$2*) ;;
   9         *) $1=$2\ $$1 ;;
  10     esac
  11 ])
  12
  13 dnl Define for both C and Pro*C
  14 AC_DEFUN(MR_DEFINE, [
  15     AC_DEFINE($1)
  16     MR_EXTEND(PRO_C_DEFS, DEFINE=$1)
  17 ])
  18
  19 dnl Add to include path for both C and Pro*C
  20 AC_DEFUN(MR_INCLUDE, [
  21     MR_EXTEND(CPPFLAGS, -I$1)
  22     MR_EXTEND(PRO_C_INCLUDES, INCLUDE=$1)
  23 ])
  24
  25 dnl Add to lib path
  26 AC_DEFUN(MR_LIBS, [MR_EXTEND(LIBPATH, -L$1)])
  27
  28 AC_PROG_CC
  29 AC_PROG_INSTALL
  30 AC_PROG_RANLIB
  31 AC_PROG_MAKE_SET
  32
  33 if test "$athena" = true; then
  34     enable_athena=yes
  35     prefix=/afs/athena.mit.edu/system/moira
  36     bindir=$prefix/arch/$ATHENA_SYS/bin
  37     sbindir=$bindir
  38     MR_INCLUDE(/usr/athena/include)
  39     MR_INCLUDE(/usr/athena/include/kerberosIV)
  40     MR_LIBS(/usr/athena/lib)
  41 fi
  42
  43 # We currently just don't support changing this
  44 mrbindir=/moira/bin
  45 AC_SUBST(mrbindir)
  46
  47 # Athena-local policy decisions
  48 AC_MSG_CHECKING(for Athena)
  49 AC_ARG_ENABLE(athena,
  50     [  --enable-athena         Enable Athena-specific policy decisions],
  51     , [if test "$athena" = true; then
  52            enableval=yes
  53        else
  54            enableval=no
  55        fi])
  56 AC_MSG_RESULT($enableval)
  57 if test "$enableval" = yes; then
  58     MR_DEFINE(ATHENA)
  59 fi
  60
  61 # Networking libraries
  62 AC_CHECKING(network libraries...)
  63 AC_CHECK_FUNC(gethostbyname, :,
  64               AC_CHECK_LIB(nsl, gethostbyname, ,
  65                            AC_CHECK_LIB(resolv, gethostbyname)))
  66 AC_CHECK_FUNC(socket, :,
  67               AC_CHECK_LIB(socket, socket, ,
  68                            AC_CHECK_LIB(socket, socket,
  69                                         LIBS="-lsocket -lnsl $LIBS", :,
  70                                         -lnsl)))
  71
  72 # com_err (required, but can be built)
  73 AC_MSG_CHECKING(for com_err)
  74 AC_ARG_WITH(com_err,
  75     [  --with-com_err=PREFIX   Specify location of com_err],
  76     [AC_MSG_RESULT($withval)
  77      if test $withval = "no"; then
  78          AC_MSG_ERROR(com_err is required for Moira)
  79      fi
  80      if test $withval != "yes"; then
  81          MR_INCLUDE($withval/include)
  82          MR_LIBS($withval/lib)
  83      fi
  84      COMPILE_ET=compile_et],
  85     [AC_MSG_RESULT(util/et)
  86      COM_ERR_SUBDIR=util/et;
  87      MR_INCLUDE(`pwd`/util/et)
  88      MR_LIBS(`pwd`/util/et)
  89      COMPILE_ET=`pwd`/util/et/compile_et
  90      AC_CONFIG_SUBDIRS($COM_ERR_SUBDIR)])
  91 AC_SUBST(COM_ERR_SUBDIR)
  92 AC_SUBST(COMPILE_ET)
  93
  94 # Kerberos (Kerberos 4 required, Kerberos 5 optional for reg_svr)
  95 AC_MSG_CHECKING(for Kerberos 4)
  96 AC_ARG_WITH(krb4,
  97     [  --with-krb4=PREFIX      Specify location of krb4],
  98     [krb4="$withval"], [krb4=no])
  99 AC_MSG_RESULT($krb4)
 100 if test $krb4 = "no"; then
 101     AC_MSG_ERROR(Kerberos is required for Moira)
 102 fi
 103 if test "$krb4" != yes; then
 104     MR_INCLUDE($krb4/include)
 105     if test -d "$krb4/include/kerberosIV"; then
 106         MR_INCLUDE($krb4/include/kerberosIV)
 107     fi
 108     MR_LIBS($krb4/lib)
 109 elif test -d /usr/include/kerberosIV; then
 110     MR_INCLUDE(/usr/include/kerberosIV)
 111 fi
 112 AC_CHECK_LIB(krb4, krb_rd_req,
 113              [KRB4_LIBS="-lkrb4 -ldes425 -lkrb5 -lcrypto"],
 114              [AC_CHECK_LIB(krb, krb_rd_req,
 115                            [KRB4_LIBS="-lkrb -ldes"],
 116                            [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 117                            $LIBPATH -ldes)],
 118              $LIBPATH -ldes425 -lkrb5 -lcrypto -lcom_err)
 119
 120 AC_MSG_CHECKING(for Kerberos 5)
 121 AC_ARG_WITH(krb5,
 122     [  --with-krb5=PREFIX      Specify location of krb5 (for reg_svr)],
 123     [krb5="$withval"], [krb5=no])
 124 AC_MSG_RESULT($krb5)
 125 if test "$krb5" != no; then
 126     REG_SVR_DEFS=-DKRB5
 127     if test "$krb5" != yes; then
 128         REG_SVR_INCLUDES=-I$krb5/include
 129         REG_SVR_LIBS=-L$krb5/lib
 130     fi
 131     REG_SVR_LIBS="$REG_SVR_LIBS -lkadm5clnt -lgssapi_krb5 -lgssrpc -ldyn -lkrb4 -ldes425 -lkrb5 -lcrypto"
 132 else
 133     REG_SVR_DEFS=-DKRB4
 134     REG_SVR_LIBS=-lkadm
 135 fi
 136 AC_SUBST(REG_SVR_DEFS)
 137 AC_SUBST(REG_SVR_INCLUDES)
 138 AC_SUBST(REG_SVR_LIBS)
 139
 140 # Hesiod support
 141 AC_MSG_CHECKING(for Hesiod)
 142 AC_ARG_WITH(hesiod,
 143     [  --with-hesiod=PREFIX    Specify location of Hesiod],
 144     [hesiod="$withval"], [hesiod=no])
 145 AC_MSG_RESULT($hesiod)
 146 if test "$hesiod" != no; then
 147     if test "$hesiod" != yes; then
 148         MR_INCLUDE($hesiod/include)
 149         MR_LIBS($hesiod/lib)
 150     fi
 151     AC_CHECK_FUNC(res_send, :,
 152                   AC_CHECK_LIB(resolv, res_send))
 153     AC_CHECK_LIB(hesiod, hes_resolve, :,
 154                  [AC_MSG_ERROR(Hesiod library not found)],
 155                  $LIBPATH $LIBS)
 156     MR_DEFINE(HAVE_HESIOD)
 157 fi
 158
 159 # Zephyr support
 160 AC_MSG_CHECKING(for Zephyr)
 161 AC_ARG_WITH(zephyr,
 162     [  --with-zephyr=PREFIX    Specify location of Zephyr],
 163     [zephyr="$withval"], [zephyr=no])
 164 AC_MSG_RESULT($zephyr)
 165 if test "$zephyr" != no; then
 166     if test "$zephyr" != yes; then
 167         MR_INCLUDE($zephyr/include)
 168         MR_LIBS($zephyr/lib)
 169     fi
 170     AC_CHECK_LIB(zephyr, ZInitialize, :,
 171                  [AC_MSG_ERROR(Zephyr library not found)],
 172                  $LIBPATH $KRB4_LIBS -lcom_err)
 173     MR_DEFINE(HAVE_ZEPHYR)
 174 fi
 175
 176 # GDSS support (default: build util/gdss if present)
 177 AC_MSG_CHECKING(for GDSS)
 178 AC_ARG_WITH(gdss,
 179     [  --with-gdss=PREFIX      Specify location of GDSS],
 180     [gdss="$withval"
 181      if test "$gdss" != no; then
 182        MR_INCLUDE("$gdss/include")
 183        GDSS_LIBS="-L$gdss/lib -lgdss"
 184      fi],
 185     [if test -d $srcdir/util/gdss; then
 186          gdss=$srcdir/util/gdss
 187          GDSS_SUBDIR=util/gdss
 188          GDSS_OUTPUT_FILES="util/gdss/Makefile util/gdss/lib/Makefile \
 189              util/gdss/lib/crypto/Makefile util/gdss/lib/crypto/bignum/Makefile \
 190              util/gdss/lib/crypto/algorithm/Makefile"
 191          # autoconf can't deal with creating util/gdss if util doesn't exist
 192          if test ! -d util; then
 193              mkdir util
 194          fi
 195          MR_INCLUDE('$(SRCTOP)/util/gdss/include')
 196          GDSS_LIBS='-L$(BUILDTOP)/util/gdss/lib -lgdss'
 197          GDSS_LIBDEP='$(BUILDTOP)/util/gdss/lib/libgdss.a'
 198      else
 199          gdss=no
 200      fi])
 201 AC_MSG_RESULT($gdss)
 202 if test "$gdss" != no; then
 203     GDSS_OBJS='$(GDSS_OBJS)'
 204     GDSS_CFILES='$(GDSS_CFILES)'
 205     GDSS_TARGET='$(GDSS_TARGET)'
 206     MR_DEFINE(HAVE_GDSS)
 207 fi
 208 AC_SUBST(GDSS_CPPFLAGS)
 209 AC_SUBST(GDSS_LIBS)
 210 AC_SUBST(GDSS_SUBDIR)
 211 AC_SUBST(GDSS_OBJS)
 212 AC_SUBST(GDSS_CFILES)
 213 AC_SUBST(GDSS_TARGET)
 214 AC_SUBST(GDSS_LIBDEP)
 215
 216 # RSAREF support (default: build util/rsaref if present)
 217 AC_MSG_CHECKING(for RSAREF)
 218 AC_ARG_WITH(rsaref,
 219     [  --with-rsaref=PREFIX      Specify location of RSAREF],
 220     [rsaref="$withval"
 221      RSAREF_CPPFLAGS="-I$rsaref/include"
 222      RSAREF_LIBS="$rsaref/lib/rsaref.a"],
 223      RSAREF_SUBDIRS=reg_svr
 224     [if test -d $srcdir/util/rsaref; then
 225          rsaref=$srcdir/util/rsaref
 226          RSAREF_SUBDIRS="util/rsaref reg_svr"
 227          RSAREF_OUTPUT_FILES="util/rsaref/Makefile"
 228          # autoconf can't deal with creating util/rsaref if util doesn't exist
 229          if test ! -d util; then
 230              mkdir util
 231          fi
 232          RSAREF_CPPFLAGS='-I$(SRCTOP)/util/rsaref'
 233          RSAREF_LIBS='$(BUILDTOP)/util/rsaref/rsaref.a'
 234          RSAREF_LIBDEP='$(BUILDTOP)/util/rsaref/rsaref.a'
 235      else
 236          rsaref=no
 237      fi])
 238 AC_MSG_RESULT($rsaref)
 239 if test "$rsaref" != no; then
 240     MR_DEFINE(HAVE_RSAREF)
 241 fi
 242 AC_SUBST(RSAREF_CPPFLAGS)
 243 AC_SUBST(RSAREF_LIBS)
 244 AC_SUBST(RSAREF_SUBDIRS)
 245 AC_SUBST(RSAREF_LIBDEP)
 246
 247 # Oracle (default: yes, if $ORACLE_HOME is set)
 248 AC_MSG_CHECKING(for Oracle)
 249 AC_ARG_WITH(oracle,
 250     [  --with-oracle=PREFIX    Specify location of Oracle (for server)],
 251     [oracle="$withval"],
 252     [if test -n "$ORACLE_HOME" -a -d "$ORACLE_HOME"; then
 253          oracle=$ORACLE_HOME
 254      else
 255          oracle=no
 256      fi])
 257 AC_MSG_RESULT($oracle)
 258 if test "$oracle" != no; then
 259     AC_MSG_CHECKING(Pro*C version)
 260     ORACLE_HOME=$oracle release=`$ORACLE_HOME/bin/proc | awk '/Release/ {print $3;}'`
 261     AC_MSG_RESULT($release)
 262     case $release in
 263         2.0.6.0.0)
 264             SQL_LIBS="-L$oracle/lib -lsql $oracle/lib/osntab.o -lsqlnet -lora -lsqlnet -lnlsrtl -lcv6 -lcore -lnlsrtl -lcore -lm"
 265             ;;
 266         *)
 267             SQL_LIBS="-L$oracle/lib -lclntsh -lxa -lsql -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric   -lepc -lnlsrtl3 -lc3v6 -lcore3 -lnlsrtl3 -lcore3 -lnlsrtl3 `cat $oracle/rdbms/lib/sysliblist` -lm -lthread"
 268             ;;
 269     esac
 270     SVRSUBDIRS='$(SVRDIRS)'
 271     SERVER_OUTPUT_FILES="db/Makefile server/Makefile backup/Makefile dbck/Makefile dcm/Makefile gen/Makefile reg_svr/Makefile regtape/Makefile"
 272     PRO_C=$oracle/bin/proc
 273     PRO_C_OPTS=CODE=ANSI_C
 274     PRO_C_DEFS="DEFINE=_PROC_ $PRO_C_DEFS"
 275 fi
 276 AC_SUBST(PRO_C)
 277 AC_SUBST(PRO_C_DEFS)
 278 AC_SUBST(PRO_C_INCLUDES)
 279 AC_SUBST(PRO_C_OPTS)
 280 AC_SUBST(SQL_LIBS)
 281 AC_SUBST(SVRSUBDIRS)
 282
 283 # AFS support
 284 AC_MSG_CHECKING(for AFS)
 285 AC_ARG_WITH(afs,
 286     [  --with-afs=PREFIX       Specify location of AFS libs (for server)],
 287     [afs="$withval"], [afs=no])
 288 AC_MSG_RESULT($afs)
 289 if test "$afs" != no -a "$oracle" != no; then
 290     if test "$afs" != yes; then
 291         AFS_CPPFLAGS="-I$afs/include -I$afs/include/afs -I$afs/include/rx"
 292         AFS_PRO_C_INCLUDES="INCLUDE=$afs/include INCLUDE=$afs/include/afs INCLUDE=$afs/include/rx"
 293         AFS_LIBS="-L$afs/lib -L$afs/lib/afs"
 294         AFS_DIR=$afs
 295     fi
 296     AC_CHECK_FUNC(insque, :, AC_CHECK_LIB(compat, insque,
 297                                           AFS_EXTRA_LIBS="-lcompat",
 298                                           AC_MSG_ERROR(insque not found)))
 299     AC_CHECK_FUNC(sigvec, :, AC_CHECK_LIB(ucb, sigvec,
 300                                           AFS_EXTRA_LIBS="$AFS_EXTRA_LIBS -L/usr/ucblib -lc -lucb",
 301                                           :, -L/usr/ucblib))
 302     AC_CHECK_LIB(sys, pioctl, :,
 303                  [AC_MSG_ERROR(AFS libraries not found)],
 304                  $AFS_LIBS -lrx -llwp -lsys $AFS_EXTRA_LIBS)
 305     MR_DEFINE(HAVE_AFS)
 306
 307     AFS_SUBDIRS="incremental"
 308     AFS_OUTPUT_FILES="incremental/Makefile"
 309     if test -d $srcdir/afssync; then
 310         AFS_SUBDIRS="$AFS_SUBDIRS afssync"
 311         AFS_OUTPUT_FILES="$AFS_OUTPUT_FILES afssync/Makefile"
 312     fi
 313 fi
 314 AC_SUBST(AFS_CPPFLAGS)
 315 AC_SUBST(AFS_PRO_C_INCLUDES)
 316 AC_SUBST(AFS_LIBS)
 317 AC_SUBST(AFS_EXTRA_LIBS)
 318 AC_SUBST(AFS_DIR)
 319 AC_SUBST(AFS_SUBDIRS)
 320
 321 # GNU readline
 322 AC_CHECKING(for GNU readline...)
 323 AC_ARG_WITH(readline,
 324     [  --with-readline=PREFIX  Specify location of GNU readline],
 325     [readline="$withval"; AC_MSG_RESULT($withval)],
 326     [AC_CHECK_LIB(readline, readline, [readline=yes],
 327         [if test "$athena" = true; then
 328              unset ac_cv_lib_readline_readline
 329              AC_CHECK_LIB(readline, readline, [readline=/mit/gnu], :,
 330                  -L/mit/gnu/lib -ltermcap)
 331          fi],
 332         -ltermcap)])
 333 if test "$readline" != no; then
 334     if test "$readline" != yes; then
 335         READLINE_CPPFLAGS="-I$readline/include -I$readline/include/readline"
 336         READLINE_LIBS="-L$readline/lib"
 337     else
 338         READLINE_CPPFLAGS="-I/usr/include/readline"
 339     fi
 340     READLINE_CPPFLAGS="$READLINE_CPPFLAGS -DHAVE_READLINE"
 341     READLINE_LIBS="$READLINE_LIBS -lreadline -ltermcap"
 342 fi
 343 AC_SUBST(READLINE_CPPFLAGS)
 344 AC_SUBST(READLINE_LIBS)
 345
 346 # Curses
 347 curses=curses
 348 AC_CHECKING(for curses)
 349 AC_CHECK_LIB(curses, main, :, AC_CHECK_LIB(ncurses, main, curses=ncurses))
 350 if test -n "$curses"; then
 351     OLDLIBS=$LIBS
 352     LIBS=-l$curses
 353     AC_CHECKING(if curses needs termcap)
 354     dnl we need to use AC_TRY_RUN because under NetBSD, the program will
 355     dnl link with just -lcurses, but then fail with a runtime linker error
 356     dnl because you didn't use -ltermcap
 357     AC_TRY_RUN([#include <curses.h>
 358                 main(int argc, char **argv)
 359                 {
 360                     initscr();
 361                     endwin();
 362                     return 0;
 363                 }], [CURSES_LIBS="-l$curses"],
 364                 LIBS="-l$curses -ltermcap"
 365                 AC_TRY_RUN([#include <curses.h>
 366                             main(int argc, char **argv)
 367                             {
 368                                 initscr();
 369                                 endwin();
 370                                 return 0;
 371                             }], [CURSES_LIBS="-l$curses -ltermcap"],
 372                             :, :),
 373                 :)
 374     LIBS=$OLDLIBS
 375 fi
 376 if test -n "$CURSES_LIBS"; then
 377     OLDLIBS=$LIBS
 378     LIBS=$CURSES_LIBS
 379     AC_TRY_LINK([#include <curses.h>],[WINDOW *w; getmaxx(w);],
 380                 :,
 381                 AC_TRY_COMPILE([#include <curses.h>],[WINDOW *w; w->_maxx;],
 382                                [CURSES_CPPFLAGS="-D'getmaxx(w)=w->_maxx'"],
 383                                [CURSES_CPPFLAGS="-D'getmaxx(w)=w->maxx'"]))
 384     AC_TRY_LINK([#include <curses.h>],[newterm(NULL, NULL, NULL);],
 385                 [CURSES_CPPFLAGS="$CURSES_CPPFLAGS -DCURSES_HAS_NEWTERM"])
 386     LIBS=$OLDLIBS
 387     CURSES_CPPFLAGS="-DHAVE_CURSES $CURSES_CPPFLAGS"
 388     CURSES_SUBDIRS='$(CURSES_SUBDIRS)'
 389 else
 390     AC_MSG_WARN(Couldn't find -lcurses)
 391 fi
 392 AC_SUBST(CURSES_CPPFLAGS)
 393 AC_SUBST(CURSES_LIBS)
 394 AC_SUBST(CURSES_SUBDIRS)
 395
 396
 397 AC_CHECK_FUNCS(getusershell)
 398
 399 MR_EXTEND(PRO_C_INCLUDES, INCLUDE='$(srcdir)')
 400 MR_INCLUDE('$(SRCTOP)/include')
 401 MR_INCLUDE('$(SRCTOP)/lib')
 402 MR_INCLUDE('$(BUILDTOP)/lib')
 403 MR_INCLUDE('$(BUILDTOP)/db')
 404 MR_INCLUDE('$(srcdir)')
 405 LDFLAGS="$LDFLAGS -L\$(BUILDTOP)/lib $LIBPATH"
 406 KLIBS="-lzephyr $KRB4_LIBS -lcom_err -lhesiod $LIBS"
 407 LIBS="-lmoira $KLIBS"
 408 AC_SUBST(KLIBS)
 409
 410 MR_LIBDEP='$(BUILDTOP)/lib/libmoira.a'
 411 AC_SUBST(MR_LIBDEP)
 412
 413 AC_OUTPUT(Makefile lib/Makefile include/Makefile clients/Makefile \
 414           clients/lib/Makefile clients/addusr/Makefile \
 415           clients/blanche/Makefile clients/mailmaint/Makefile
 416           clients/moira/Makefile clients/mrcheck/Makefile
 417           clients/mrtest/Makefile clients/passwd/Makefile
 418           update/Makefile man/Makefile \
 419           $SERVER_OUTPUT_FILES $AFS_OUTPUT_FILES \
 420           $GDSS_OUTPUT_FILES $RSAREF_OUTPUT_FILES)