[moira.git] / configure.in

AC_INIT(patchlevel.h)

dnl On Athena at least, many of the packages (krb, zephyr, hesiod, etc)
dnl will all be in /usr/athena... this hack lets us not end up with 10
dnl copies of -I/usr/athena/include -L/usr/athena/lib in our command lines
AC_DEFUN(MR_EXTEND, [
    case $$1 in
	*$2*) ;;
	*) $1=$2\ $$1 ;;
    esac
])

dnl Define for both C and Pro*C
AC_DEFUN(MR_DEFINE, [
    AC_DEFINE($1)
    MR_EXTEND(PRO_C_DEFS, DEFINE=$1)
])

dnl Add to include path for both C and Pro*C
AC_DEFUN(MR_INCLUDE, [
    MR_EXTEND(CPPFLAGS, -I$1)
    MR_EXTEND(PRO_C_INCLUDES, INCLUDE=$1)
]) 

dnl Add to lib path
AC_DEFUN(MR_LIBS, [MR_EXTEND(LIBPATH, -L$1)])

AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_PROG_MAKE_SET

if test "$athena" = true; then
    enable_athena=yes
    prefix=/afs/athena.mit.edu/system/moira
    bindir=$prefix/arch/$ATHENA_SYS/bin
    sbindir=$bindir
    MR_INCLUDE(/usr/athena/include)
    MR_INCLUDE(/usr/athena/include/kerberosIV)
    MR_LIBS(/usr/athena/lib)
fi

# We currently just don't support changing this
mrbindir=/moira/bin
AC_SUBST(mrbindir)

# Athena-local policy decisions
AC_MSG_CHECKING(for Athena)
AC_ARG_ENABLE(athena,
    [  --enable-athena         Enable Athena-specific policy decisions],
    , [if test "$athena" = true; then
           enableval=yes
       else
	   enableval=no
       fi])
AC_MSG_RESULT($enableval)
if test "$enableval" = yes; then
    MR_DEFINE(ATHENA)
fi

# Networking libraries
AC_CHECKING(network libraries...)
AC_CHECK_FUNC(gethostbyname, :,
	      AC_CHECK_LIB(nsl, gethostbyname, ,
			   AC_CHECK_LIB(resolv, gethostbyname)))
AC_CHECK_FUNC(socket, :,
	      AC_CHECK_LIB(socket, socket, ,
			   AC_CHECK_LIB(socket, socket,
					LIBS="-lsocket -lnsl $LIBS", :,
					-lnsl)))

# com_err (required, but can be built)
AC_MSG_CHECKING(for com_err)
AC_ARG_WITH(com_err,
    [  --with-com_err=PREFIX   Specify location of com_err],
    [AC_MSG_RESULT($withval)
     if test $withval = "no"; then
         AC_MSG_ERROR(com_err is required for Moira)
     fi
     if test $withval != "yes"; then
	 MR_INCLUDE($withval/include)
	 MR_LIBS($withval/lib)
     fi
     COMPILE_ET=compile_et],
    [AC_MSG_RESULT(util/et)
     COM_ERR_SUBDIR=util/et;
     MR_INCLUDE(`pwd`/util/et)
     MR_LIBS(`pwd`/util/et)
     COMPILE_ET=`pwd`/util/et/compile_et
     AC_CONFIG_SUBDIRS($COM_ERR_SUBDIR)])
AC_SUBST(COM_ERR_SUBDIR)
AC_SUBST(COMPILE_ET)

# Kerberos (Kerberos 4 required, Kerberos 5 optional for reg_svr)
AC_MSG_CHECKING(for Kerberos 4)
AC_ARG_WITH(krb4,
    [  --with-krb4=PREFIX      Specify location of krb4],
    [krb4="$withval"], [krb4=no])
AC_MSG_RESULT($krb4)
if test $krb4 = "no"; then
    AC_MSG_ERROR(Kerberos is required for Moira)
fi
if test "$krb4" != yes; then
    MR_INCLUDE($krb4/include)
    if test -d "$krb4/include/kerberosIV"; then
	MR_INCLUDE($krb4/include/kerberosIV)
    fi
    MR_LIBS($krb4/lib)
elif test -d /usr/include/kerberosIV; then
    MR_INCLUDE(/usr/include/kerberosIV)
fi
AC_CHECK_LIB(krb4, krb_rd_req,
	     [KRB4_LIBS="-lkrb4 -ldes425 -lkrb5 -lcrypto"],
	     [AC_CHECK_LIB(krb, krb_rd_req,
			   [KRB4_LIBS="-lkrb -ldes"],
			   [AC_MSG_ERROR(Kerberos 4 libraries not found)],
			   $LIBPATH -ldes)],
	     $LIBPATH -ldes425 -lkrb5 -lcrypto -lcom_err)

AC_MSG_CHECKING(for Kerberos 5)
AC_ARG_WITH(krb5,
    [  --with-krb5=PREFIX      Specify location of krb5 (for reg_svr)],
    [krb5="$withval"], [krb5=no])
AC_MSG_RESULT($krb5)
if test "$krb5" != no; then
    REG_SVR_DEFS=-DKRB5
    if test "$krb5" != yes; then
	REG_SVR_INCLUDES=-I$krb5/include
	REG_SVR_LIBS=-L$krb5/lib
    fi
    REG_SVR_LIBS="$REG_SVR_LIBS -lkadm5clnt -lgssapi_krb5 -lgssrpc -ldyn -lkrb4 -ldes425 -lkrb5 -lcrypto"
else
    REG_SVR_DEFS=-DKRB4
    REG_SVR_LIBS=-lkadm
fi
AC_SUBST(REG_SVR_DEFS)
AC_SUBST(REG_SVR_INCLUDES)
AC_SUBST(REG_SVR_LIBS)

# Hesiod support
AC_MSG_CHECKING(for Hesiod)
AC_ARG_WITH(hesiod,
    [  --with-hesiod=PREFIX    Specify location of Hesiod],
    [hesiod="$withval"], [hesiod=no])
AC_MSG_RESULT($hesiod)
if test "$hesiod" != no; then
    if test "$hesiod" != yes; then
	MR_INCLUDE($hesiod/include)
	MR_LIBS($hesiod/lib)
    fi
    AC_CHECK_FUNC(res_send, :,
		  AC_CHECK_LIB(resolv, res_send))
    AC_CHECK_LIB(hesiod, hes_resolve, :,
		 [AC_MSG_ERROR(Hesiod library not found)],
		 $LIBPATH $LIBS)
    MR_DEFINE(HAVE_HESIOD)
fi

# Zephyr support
AC_MSG_CHECKING(for Zephyr)
AC_ARG_WITH(zephyr,
    [  --with-zephyr=PREFIX    Specify location of Zephyr],
    [zephyr="$withval"], [zephyr=no])
AC_MSG_RESULT($zephyr)
if test "$zephyr" != no; then
    if test "$zephyr" != yes; then
	MR_INCLUDE($zephyr/include)
	MR_LIBS($zephyr/lib)
    fi
    AC_CHECK_LIB(zephyr, ZInitialize, :,
		 [AC_MSG_ERROR(Zephyr library not found)],
		 $LIBPATH $KRB4_LIBS -lcom_err)
    MR_DEFINE(HAVE_ZEPHYR)
fi

# GDSS support (default: build util/gdss if present)
AC_MSG_CHECKING(for GDSS)
AC_ARG_WITH(gdss,
    [  --with-gdss=PREFIX      Specify location of GDSS],
    [gdss="$withval"
     if test "$gdss" != no; then
       MR_INCLUDE("$gdss/include")
       GDSS_LIBS="-L$gdss/lib -lgdss"
     fi],
    [if test -d $srcdir/util/gdss; then
         gdss=$srcdir/util/gdss
	 GDSS_SUBDIR=util/gdss
	 GDSS_OUTPUT_FILES="util/gdss/Makefile util/gdss/lib/Makefile \
	     util/gdss/lib/crypto/Makefile util/gdss/lib/crypto/bignum/Makefile \
	     util/gdss/lib/crypto/algorithm/Makefile"
	 # autoconf can't deal with creating util/gdss if util doesn't exist
	 if test ! -d util; then
	     mkdir util
	 fi
	 MR_INCLUDE('$(SRCTOP)/util/gdss/include')
	 GDSS_LIBS='-L$(BUILDTOP)/util/gdss/lib -lgdss'
	 GDSS_LIBDEP='$(BUILDTOP)/util/gdss/lib/libgdss.a'
     else
         gdss=no
     fi])
AC_MSG_RESULT($gdss)
if test "$gdss" != no; then
    GDSS_OBJS='$(GDSS_OBJS)'
    GDSS_CFILES='$(GDSS_CFILES)'
    GDSS_TARGET='$(GDSS_TARGET)'
    MR_DEFINE(HAVE_GDSS)
fi
AC_SUBST(GDSS_CPPFLAGS)
AC_SUBST(GDSS_LIBS)
AC_SUBST(GDSS_SUBDIR)
AC_SUBST(GDSS_OBJS)
AC_SUBST(GDSS_CFILES)
AC_SUBST(GDSS_TARGET)
AC_SUBST(GDSS_LIBDEP)

# RSAREF support (default: build util/rsaref if present)
AC_MSG_CHECKING(for RSAREF)
AC_ARG_WITH(rsaref,
    [  --with-rsaref=PREFIX      Specify location of RSAREF],
    [rsaref="$withval"
     RSAREF_CPPFLAGS="-I$rsaref/include"
     RSAREF_LIBS="$rsaref/lib/rsaref.a"],
     RSAREF_SUBDIRS=reg_svr
    [if test -d $srcdir/util/rsaref; then
         rsaref=$srcdir/util/rsaref
	 RSAREF_SUBDIRS="util/rsaref reg_svr"
	 RSAREF_OUTPUT_FILES="util/rsaref/Makefile"
	 # autoconf can't deal with creating util/rsaref if util doesn't exist
	 if test ! -d util; then
	     mkdir util
	 fi
	 RSAREF_CPPFLAGS='-I$(SRCTOP)/util/rsaref'
	 RSAREF_LIBS='$(BUILDTOP)/util/rsaref/rsaref.a'
	 RSAREF_LIBDEP='$(BUILDTOP)/util/rsaref/rsaref.a'
     else
         rsaref=no
     fi])
AC_MSG_RESULT($rsaref)
if test "$rsaref" != no; then
    MR_DEFINE(HAVE_RSAREF)
fi
AC_SUBST(RSAREF_CPPFLAGS)
AC_SUBST(RSAREF_LIBS)
AC_SUBST(RSAREF_SUBDIRS)
AC_SUBST(RSAREF_LIBDEP)

# Oracle (default: yes, if $ORACLE_HOME is set)
AC_MSG_CHECKING(for Oracle)
AC_ARG_WITH(oracle,
    [  --with-oracle=PREFIX    Specify location of Oracle (for server)],
    [oracle="$withval"],
    [if test -n "$ORACLE_HOME" -a -d "$ORACLE_HOME"; then
         oracle=$ORACLE_HOME
     else
	 oracle=no
     fi])
AC_MSG_RESULT($oracle)
if test "$oracle" != no; then
    AC_MSG_CHECKING(Pro*C version)
    ORACLE_HOME=$oracle release=`$ORACLE_HOME/bin/proc | awk '/Release/ {print $3;}'`
    AC_MSG_RESULT($release)
    case $release in
	2.0.6.0.0)
	    SQL_LIBS="-L$oracle/lib -lsql $oracle/lib/osntab.o -lsqlnet -lora -lsqlnet -lnlsrtl -lcv6 -lcore -lnlsrtl -lcore -lm"
	    ;;
	*)
	    SQL_LIBS="-L$oracle/lib -lclntsh -lxa -lsql -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric   -lepc -lnlsrtl3 -lc3v6 -lcore3 -lnlsrtl3 -lcore3 -lnlsrtl3 `cat $oracle/rdbms/lib/sysliblist` -lm -lthread"
	    ;;
    esac
    SVRSUBDIRS='$(SVRDIRS)'
    SERVER_OUTPUT_FILES="db/Makefile server/Makefile backup/Makefile dbck/Makefile dcm/Makefile gen/Makefile reg_svr/Makefile regtape/Makefile"
    PRO_C=$oracle/bin/proc
    PRO_C_OPTS=CODE=ANSI_C
    PRO_C_DEFS="DEFINE=_PROC_ $PRO_C_DEFS"
fi
AC_SUBST(PRO_C)
AC_SUBST(PRO_C_DEFS)
AC_SUBST(PRO_C_INCLUDES)
AC_SUBST(PRO_C_OPTS)
AC_SUBST(SQL_LIBS)
AC_SUBST(SVRSUBDIRS)

# AFS support
AC_MSG_CHECKING(for AFS)
AC_ARG_WITH(afs,
    [  --with-afs=PREFIX       Specify location of AFS libs (for server)],
    [afs="$withval"], [afs=no])
AC_MSG_RESULT($afs)
if test "$afs" != no -a "$oracle" != no; then
    if test "$afs" != yes; then
	AFS_CPPFLAGS="-I$afs/include -I$afs/include/afs -I$afs/include/rx"
	AFS_PRO_C_INCLUDES="INCLUDE=$afs/include INCLUDE=$afs/include/afs INCLUDE=$afs/include/rx"
	AFS_LIBS="-L$afs/lib -L$afs/lib/afs"
	AFS_DIR=$afs
    fi
    AC_CHECK_FUNC(insque, :, AC_CHECK_LIB(compat, insque,
					  AFS_EXTRA_LIBS="-lcompat",
					  AC_MSG_ERROR(insque not found)))
    AC_CHECK_FUNC(sigvec, :, AC_CHECK_LIB(ucb, sigvec,
					  AFS_EXTRA_LIBS="$AFS_EXTRA_LIBS -L/usr/ucblib -lc -lucb",
					  :, -L/usr/ucblib))
    AC_CHECK_LIB(sys, pioctl, :,
		 [AC_MSG_ERROR(AFS libraries not found)],
		 $AFS_LIBS -lrx -llwp -lsys $AFS_EXTRA_LIBS)
    MR_DEFINE(HAVE_AFS)

    AFS_SUBDIRS="incremental"
    AFS_OUTPUT_FILES="incremental/Makefile"
    if test -d $srcdir/afssync; then
	AFS_SUBDIRS="$AFS_SUBDIRS afssync"
	AFS_OUTPUT_FILES="$AFS_OUTPUT_FILES afssync/Makefile"
    fi
fi
AC_SUBST(AFS_CPPFLAGS)
AC_SUBST(AFS_PRO_C_INCLUDES)
AC_SUBST(AFS_LIBS)
AC_SUBST(AFS_EXTRA_LIBS)
AC_SUBST(AFS_DIR)
AC_SUBST(AFS_SUBDIRS)

# GNU readline
AC_CHECKING(for GNU readline...)
AC_ARG_WITH(readline,
    [  --with-readline=PREFIX  Specify location of GNU readline],
    [readline="$withval"; AC_MSG_RESULT($withval)],
    [AC_CHECK_LIB(readline, readline, [readline=yes],
	[if test "$athena" = true; then
	     unset ac_cv_lib_readline_readline
	     AC_CHECK_LIB(readline, readline, [readline=/mit/gnu], :,
	         -L/mit/gnu/lib -ltermcap)
	 fi],
	-ltermcap)])
if test "$readline" != no; then
    if test "$readline" != yes; then
	READLINE_CPPFLAGS="-I$readline/include -I$readline/include/readline"
	READLINE_LIBS="-L$readline/lib"
    else
	READLINE_CPPFLAGS="-I/usr/include/readline"
    fi
    READLINE_CPPFLAGS="$READLINE_CPPFLAGS -DHAVE_READLINE"
    READLINE_LIBS="$READLINE_LIBS -lreadline -ltermcap"
fi
AC_SUBST(READLINE_CPPFLAGS)
AC_SUBST(READLINE_LIBS)

# Curses
curses=curses
AC_CHECKING(for curses)
AC_CHECK_LIB(curses, main, :, AC_CHECK_LIB(ncurses, main, curses=ncurses))
if test -n "$curses"; then
    OLDLIBS=$LIBS
    LIBS=-l$curses
    AC_CHECKING(if curses needs termcap)
    dnl we need to use AC_TRY_RUN because under NetBSD, the program will
    dnl link with just -lcurses, but then fail with a runtime linker error
    dnl because you didn't use -ltermcap
    AC_TRY_RUN([#include <curses.h>
		main(int argc, char **argv)
		{
		    initscr();
		    endwin();
		    return 0;
		}], [CURSES_LIBS="-l$curses"],
		LIBS="-l$curses -ltermcap"
		AC_TRY_RUN([#include <curses.h>
			    main(int argc, char **argv)
			    {
				initscr();
				endwin();
				return 0;
			    }], [CURSES_LIBS="-l$curses -ltermcap"],
			    :, :),
		:)
    LIBS=$OLDLIBS
fi
if test -n "$CURSES_LIBS"; then
    OLDLIBS=$LIBS
    LIBS=$CURSES_LIBS
    AC_TRY_LINK([#include <curses.h>],[WINDOW *w; getmaxx(w);],
		:,
		AC_TRY_COMPILE([#include <curses.h>],[WINDOW *w; w->_maxx;],
			       [CURSES_CPPFLAGS="-D'getmaxx(w)=w->_maxx'"],
			       [CURSES_CPPFLAGS="-D'getmaxx(w)=w->maxx'"]))
    AC_TRY_LINK([#include <curses.h>],[newterm(NULL, NULL, NULL);],
		[CURSES_CPPFLAGS="$CURSES_CPPFLAGS -DCURSES_HAS_NEWTERM"])
    LIBS=$OLDLIBS
    CURSES_CPPFLAGS="-DHAVE_CURSES $CURSES_CPPFLAGS"
    CURSES_SUBDIRS='$(CURSES_SUBDIRS)'
else
    AC_MSG_WARN(Couldn't find -lcurses)
fi
AC_SUBST(CURSES_CPPFLAGS)
AC_SUBST(CURSES_LIBS)
AC_SUBST(CURSES_SUBDIRS)


AC_CHECK_FUNCS(getusershell)

MR_EXTEND(PRO_C_INCLUDES, INCLUDE='$(srcdir)')
MR_INCLUDE('$(SRCTOP)/include')
MR_INCLUDE('$(SRCTOP)/lib')
MR_INCLUDE('$(BUILDTOP)/lib')
MR_INCLUDE('$(BUILDTOP)/db')
MR_INCLUDE('$(srcdir)')
LDFLAGS="$LDFLAGS -L\$(BUILDTOP)/lib $LIBPATH"
KLIBS="-lzephyr $KRB4_LIBS -lcom_err -lhesiod $LIBS"
LIBS="-lmoira $KLIBS"
AC_SUBST(KLIBS)

MR_LIBDEP='$(BUILDTOP)/lib/libmoira.a'
AC_SUBST(MR_LIBDEP)

AC_OUTPUT(Makefile lib/Makefile include/Makefile clients/Makefile \
	  clients/lib/Makefile clients/addusr/Makefile \
	  clients/blanche/Makefile clients/mailmaint/Makefile
	  clients/moira/Makefile clients/mrcheck/Makefile
	  clients/mrtest/Makefile clients/passwd/Makefile
	  update/Makefile man/Makefile \
	  $SERVER_OUTPUT_FILES $AFS_OUTPUT_FILES \
	  $GDSS_OUTPUT_FILES $RSAREF_OUTPUT_FILES)
Commit	Line	Data
ea0caf4a	1	AC_INIT(patchlevel.h)
	2
	3	dnl On Athena at least, many of the packages (krb, zephyr, hesiod, etc)
	4	dnl will all be in /usr/athena... this hack lets us not end up with 10
	5	dnl copies of -I/usr/athena/include -L/usr/athena/lib in our command lines
	6	AC_DEFUN(MR_EXTEND, [
	7	case $$1 in
	8	$2) ;;
	9	*) $1=$2\ $$1 ;;
	10	esac
	11	])
	12
	13	dnl Define for both C and Pro*C
	14	AC_DEFUN(MR_DEFINE, [
	15	AC_DEFINE($1)
	16	MR_EXTEND(PRO_C_DEFS, DEFINE=$1)
	17	])
	18
	19	dnl Add to include path for both C and Pro*C
	20	AC_DEFUN(MR_INCLUDE, [
	21	MR_EXTEND(CPPFLAGS, -I$1)
	22	MR_EXTEND(PRO_C_INCLUDES, INCLUDE=$1)
	23	])
	24
	25	dnl Add to lib path
	26	AC_DEFUN(MR_LIBS, [MR_EXTEND(LIBPATH, -L$1)])
	27
	28	AC_PROG_CC
	29	AC_PROG_INSTALL
	30	AC_PROG_RANLIB
	31	AC_PROG_MAKE_SET
	32
	33	if test "$athena" = true; then
	34	enable_athena=yes
ea0caf4a	35	prefix=/afs/athena.mit.edu/system/moira
	36	bindir=$prefix/arch/$ATHENA_SYS/bin
	37	sbindir=$bindir
618b3834	38	MR_INCLUDE(/usr/athena/include)
	39	MR_INCLUDE(/usr/athena/include/kerberosIV)
	40	MR_LIBS(/usr/athena/lib)
ea0caf4a	41	fi
	42
	43	# We currently just don't support changing this
	44	mrbindir=/moira/bin
	45	AC_SUBST(mrbindir)
	46
	47	# Athena-local policy decisions
	48	AC_MSG_CHECKING(for Athena)
	49	AC_ARG_ENABLE(athena,
	50	[ --enable-athena Enable Athena-specific policy decisions],
	51	, [if test "$athena" = true; then
	52	enableval=yes
	53	else
	54	enableval=no
	55	fi])
	56	AC_MSG_RESULT($enableval)
	57	if test "$enableval" = yes; then
	58	MR_DEFINE(ATHENA)
	59	fi
	60
	61	# Networking libraries
	62	AC_CHECKING(network libraries...)
	63	AC_CHECK_FUNC(gethostbyname, :,
	64	AC_CHECK_LIB(nsl, gethostbyname, ,
	65	AC_CHECK_LIB(resolv, gethostbyname)))
	66	AC_CHECK_FUNC(socket, :,
	67	AC_CHECK_LIB(socket, socket, ,
	68	AC_CHECK_LIB(socket, socket,
	69	LIBS="-lsocket -lnsl $LIBS", :,
	70	-lnsl)))
	71
7f7f279f	72	# com_err (required, but can be built)
	73	AC_MSG_CHECKING(for com_err)
	74	AC_ARG_WITH(com_err,
	75	[ --with-com_err=PREFIX Specify location of com_err],
	76	[AC_MSG_RESULT($withval)
	77	if test $withval = "no"; then
	78	AC_MSG_ERROR(com_err is required for Moira)
	79	fi
	80	if test $withval != "yes"; then
	81	MR_INCLUDE($withval/include)
	82	MR_LIBS($withval/lib)
	83	fi
	84	COMPILE_ET=compile_et],
	85	[AC_MSG_RESULT(util/et)
	86	COM_ERR_SUBDIR=util/et;
	87	MR_INCLUDE(`pwd`/util/et)
	88	MR_LIBS(`pwd`/util/et)
	89	COMPILE_ET=`pwd`/util/et/compile_et
	90	AC_CONFIG_SUBDIRS($COM_ERR_SUBDIR)])
	91	AC_SUBST(COM_ERR_SUBDIR)
	92	AC_SUBST(COMPILE_ET)
	93
	94	# Kerberos (Kerberos 4 required, Kerberos 5 optional for reg_svr)
ea0caf4a	95	AC_MSG_CHECKING(for Kerberos 4)
	96	AC_ARG_WITH(krb4,
	97	[ --with-krb4=PREFIX Specify location of krb4],
	98	[krb4="$withval"], [krb4=no])
	99	AC_MSG_RESULT($krb4)
	100	if test $krb4 = "no"; then
	101	AC_MSG_ERROR(Kerberos is required for Moira)
	102	fi
	103	if test "$krb4" != yes; then
	104	MR_INCLUDE($krb4/include)
	105	if test -d "$krb4/include/kerberosIV"; then
	106	MR_INCLUDE($krb4/include/kerberosIV)
	107	fi
	108	MR_LIBS($krb4/lib)
	109	elif test -d /usr/include/kerberosIV; then
	110	MR_INCLUDE(/usr/include/kerberosIV)
	111	fi
	112	AC_CHECK_LIB(krb4, krb_rd_req,
	113	[KRB4_LIBS="-lkrb4 -ldes425 -lkrb5 -lcrypto"],
	114	[AC_CHECK_LIB(krb, krb_rd_req,
	115	[KRB4_LIBS="-lkrb -ldes"],
	116	[AC_MSG_ERROR(Kerberos 4 libraries not found)],
	117	$LIBPATH -ldes)],
7f7f279f	118	$LIBPATH -ldes425 -lkrb5 -lcrypto -lcom_err)
ea0caf4a	119
7f7f279f	120	AC_MSG_CHECKING(for Kerberos 5)
	121	AC_ARG_WITH(krb5,
	122	[ --with-krb5=PREFIX Specify location of krb5 (for reg_svr)],
	123	[krb5="$withval"], [krb5=no])
	124	AC_MSG_RESULT($krb5)
	125	if test "$krb5" != no; then
	126	REG_SVR_DEFS=-DKRB5
	127	if test "$krb5" != yes; then
	128	REG_SVR_INCLUDES=-I$krb5/include
	129	REG_SVR_LIBS=-L$krb5/lib
	130	fi
	131	REG_SVR_LIBS="$REG_SVR_LIBS -lkadm5clnt -lgssapi_krb5 -lgssrpc -ldyn -lkrb4 -ldes425 -lkrb5 -lcrypto"
	132	else
	133	REG_SVR_DEFS=-DKRB4
	134	REG_SVR_LIBS=-lkadm
	135	fi
	136	AC_SUBST(REG_SVR_DEFS)
	137	AC_SUBST(REG_SVR_INCLUDES)
	138	AC_SUBST(REG_SVR_LIBS)
33567bea	139
ea0caf4a	140	# Hesiod support
	141	AC_MSG_CHECKING(for Hesiod)
	142	AC_ARG_WITH(hesiod,
	143	[ --with-hesiod=PREFIX Specify location of Hesiod],
	144	[hesiod="$withval"], [hesiod=no])
	145	AC_MSG_RESULT($hesiod)
	146	if test "$hesiod" != no; then
	147	if test "$hesiod" != yes; then
	148	MR_INCLUDE($hesiod/include)
	149	MR_LIBS($hesiod/lib)
	150	fi
	151	AC_CHECK_FUNC(res_send, :,
	152	AC_CHECK_LIB(resolv, res_send))
	153	AC_CHECK_LIB(hesiod, hes_resolve, :,
	154	[AC_MSG_ERROR(Hesiod library not found)],
	155	$LIBPATH $LIBS)
	156	MR_DEFINE(HAVE_HESIOD)
	157	fi
	158
	159	# Zephyr support
	160	AC_MSG_CHECKING(for Zephyr)
	161	AC_ARG_WITH(zephyr,
	162	[ --with-zephyr=PREFIX Specify location of Zephyr],
	163	[zephyr="$withval"], [zephyr=no])
	164	AC_MSG_RESULT($zephyr)
	165	if test "$zephyr" != no; then
	166	if test "$zephyr" != yes; then
	167	MR_INCLUDE($zephyr/include)
	168	MR_LIBS($zephyr/lib)
	169	fi
	170	AC_CHECK_LIB(zephyr, ZInitialize, :,
	171	[AC_MSG_ERROR(Zephyr library not found)],
	172	$LIBPATH $KRB4_LIBS -lcom_err)
	173	MR_DEFINE(HAVE_ZEPHYR)
	174	fi
	175
	176	# GDSS support (default: build util/gdss if present)
	177	AC_MSG_CHECKING(for GDSS)
	178	AC_ARG_WITH(gdss,
	179	[ --with-gdss=PREFIX Specify location of GDSS],
	180	[gdss="$withval"
71b838ed	181	if test "$gdss" != no; then
	182	MR_INCLUDE("$gdss/include")
	183	GDSS_LIBS="-L$gdss/lib -lgdss"
	184	fi],
ea0caf4a	185	[if test -d $srcdir/util/gdss; then
	186	gdss=$srcdir/util/gdss
	187	GDSS_SUBDIR=util/gdss
	188	GDSS_OUTPUT_FILES="util/gdss/Makefile util/gdss/lib/Makefile \
	189	util/gdss/lib/crypto/Makefile util/gdss/lib/crypto/bignum/Makefile \
	190	util/gdss/lib/crypto/algorithm/Makefile"
	191	# autoconf can't deal with creating util/gdss if util doesn't exist
	192	if test ! -d util; then
	193	mkdir util
	194	fi
cd357ef5	195	MR_INCLUDE('$(SRCTOP)/util/gdss/include')
ea0caf4a	196	GDSS_LIBS='-L$(BUILDTOP)/util/gdss/lib -lgdss'
3fb6166b	197	GDSS_LIBDEP='$(BUILDTOP)/util/gdss/lib/libgdss.a'
ea0caf4a	198	else
	199	gdss=no
	200	fi])
	201	AC_MSG_RESULT($gdss)
	202	if test "$gdss" != no; then
	203	GDSS_OBJS='$(GDSS_OBJS)'
	204	GDSS_CFILES='$(GDSS_CFILES)'
	205	GDSS_TARGET='$(GDSS_TARGET)'
	206	MR_DEFINE(HAVE_GDSS)
	207	fi
	208	AC_SUBST(GDSS_CPPFLAGS)
	209	AC_SUBST(GDSS_LIBS)
	210	AC_SUBST(GDSS_SUBDIR)
	211	AC_SUBST(GDSS_OBJS)
	212	AC_SUBST(GDSS_CFILES)
	213	AC_SUBST(GDSS_TARGET)
3fb6166b	214	AC_SUBST(GDSS_LIBDEP)
ea0caf4a	215
33567bea	216	# RSAREF support (default: build util/rsaref if present)
	217	AC_MSG_CHECKING(for RSAREF)
	218	AC_ARG_WITH(rsaref,
	219	[ --with-rsaref=PREFIX Specify location of RSAREF],
	220	[rsaref="$withval"
	221	RSAREF_CPPFLAGS="-I$rsaref/include"
	222	RSAREF_LIBS="$rsaref/lib/rsaref.a"],
	223	RSAREF_SUBDIRS=reg_svr
	224	[if test -d $srcdir/util/rsaref; then
	225	rsaref=$srcdir/util/rsaref
	226	RSAREF_SUBDIRS="util/rsaref reg_svr"
	227	RSAREF_OUTPUT_FILES="util/rsaref/Makefile"
	228	# autoconf can't deal with creating util/rsaref if util doesn't exist
	229	if test ! -d util; then
	230	mkdir util
	231	fi
46fa38eb	232	RSAREF_CPPFLAGS='-I$(SRCTOP)/util/rsaref'
33567bea	233	RSAREF_LIBS='$(BUILDTOP)/util/rsaref/rsaref.a'
3fb6166b	234	RSAREF_LIBDEP='$(BUILDTOP)/util/rsaref/rsaref.a'
33567bea	235	else
	236	rsaref=no
	237	fi])
	238	AC_MSG_RESULT($rsaref)
	239	if test "$rsaref" != no; then
	240	MR_DEFINE(HAVE_RSAREF)
	241	fi
	242	AC_SUBST(RSAREF_CPPFLAGS)
	243	AC_SUBST(RSAREF_LIBS)
	244	AC_SUBST(RSAREF_SUBDIRS)
3fb6166b	245	AC_SUBST(RSAREF_LIBDEP)
33567bea	246
ea0caf4a	247	# Oracle (default: yes, if $ORACLE_HOME is set)
	248	AC_MSG_CHECKING(for Oracle)
	249	AC_ARG_WITH(oracle,
	250	[ --with-oracle=PREFIX Specify location of Oracle (for server)],
	251	[oracle="$withval"],
	252	[if test -n "$ORACLE_HOME" -a -d "$ORACLE_HOME"; then
	253	oracle=$ORACLE_HOME
	254	else
	255	oracle=no
	256	fi])
	257	AC_MSG_RESULT($oracle)
	258	if test "$oracle" != no; then
cd357ef5	259	AC_MSG_CHECKING(Pro*C version)
	260	ORACLE_HOME=$oracle release=`$ORACLE_HOME/bin/proc \| awk '/Release/ {print $3;}'`
	261	AC_MSG_RESULT($release)
	262	case $release in
	263	2.0.6.0.0)
	264	SQL_LIBS="-L$oracle/lib -lsql $oracle/lib/osntab.o -lsqlnet -lora -lsqlnet -lnlsrtl -lcv6 -lcore -lnlsrtl -lcore -lm"
	265	;;
	266	*)
	267	SQL_LIBS="-L$oracle/lib -lclntsh -lxa -lsql -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric -lepc -lnlsrtl3 -lc3v6 -lcore3 -lnlsrtl3 -lcore3 -lnlsrtl3 `cat $oracle/rdbms/lib/sysliblist` -lm -lthread"
	268	;;
	269	esac
ea0caf4a	270	SVRSUBDIRS='$(SVRDIRS)'
9ed720ef	271	SERVER_OUTPUT_FILES="db/Makefile server/Makefile backup/Makefile dbck/Makefile dcm/Makefile gen/Makefile reg_svr/Makefile regtape/Makefile"
ea0caf4a	272	PRO_C=$oracle/bin/proc
ea0caf4a	273	PRO_C_OPTS=CODE=ANSI_C
cd357ef5	274	PRO_C_DEFS="DEFINE=_PROC_ $PRO_C_DEFS"
ea0caf4a	275	fi
	276	AC_SUBST(PRO_C)
	277	AC_SUBST(PRO_C_DEFS)
	278	AC_SUBST(PRO_C_INCLUDES)
	279	AC_SUBST(PRO_C_OPTS)
	280	AC_SUBST(SQL_LIBS)
	281	AC_SUBST(SVRSUBDIRS)
	282
	283	# AFS support
	284	AC_MSG_CHECKING(for AFS)
	285	AC_ARG_WITH(afs,
	286	[ --with-afs=PREFIX Specify location of AFS libs (for server)],
	287	[afs="$withval"], [afs=no])
	288	AC_MSG_RESULT($afs)
	289	if test "$afs" != no -a "$oracle" != no; then
	290	if test "$afs" != yes; then
	291	AFS_CPPFLAGS="-I$afs/include -I$afs/include/afs -I$afs/include/rx"
	292	AFS_PRO_C_INCLUDES="INCLUDE=$afs/include INCLUDE=$afs/include/afs INCLUDE=$afs/include/rx"
	293	AFS_LIBS="-L$afs/lib -L$afs/lib/afs"
	294	AFS_DIR=$afs
	295	fi
	296	AC_CHECK_FUNC(insque, :, AC_CHECK_LIB(compat, insque,
	297	AFS_EXTRA_LIBS="-lcompat",
	298	AC_MSG_ERROR(insque not found)))
	299	AC_CHECK_FUNC(sigvec, :, AC_CHECK_LIB(ucb, sigvec,
	300	AFS_EXTRA_LIBS="$AFS_EXTRA_LIBS -L/usr/ucblib -lc -lucb",
	301	:, -L/usr/ucblib))
	302	AC_CHECK_LIB(sys, pioctl, :,
	303	[AC_MSG_ERROR(AFS libraries not found)],
	304	$AFS_LIBS -lrx -llwp -lsys $AFS_EXTRA_LIBS)
	305	MR_DEFINE(HAVE_AFS)
9ed720ef	306
	307	AFS_SUBDIRS="incremental"
	308	AFS_OUTPUT_FILES="incremental/Makefile"
	309	if test -d $srcdir/afssync; then
	310	AFS_SUBDIRS="$AFS_SUBDIRS afssync"
	311	AFS_OUTPUT_FILES="$AFS_OUTPUT_FILES afssync/Makefile"
	312	fi
ea0caf4a	313	fi
	314	AC_SUBST(AFS_CPPFLAGS)
	315	AC_SUBST(AFS_PRO_C_INCLUDES)
	316	AC_SUBST(AFS_LIBS)
	317	AC_SUBST(AFS_EXTRA_LIBS)
	318	AC_SUBST(AFS_DIR)
9ed720ef	319	AC_SUBST(AFS_SUBDIRS)
ea0caf4a	320
	321	# GNU readline
	322	AC_CHECKING(for GNU readline...)
	323	AC_ARG_WITH(readline,
	324	[ --with-readline=PREFIX Specify location of GNU readline],
ee85084d	325	[readline="$withval"; AC_MSG_RESULT($withval)],
	326	[AC_CHECK_LIB(readline, readline, [readline=yes],
	327	[if test "$athena" = true; then
	328	unset ac_cv_lib_readline_readline
	329	AC_CHECK_LIB(readline, readline, [readline=/mit/gnu], :,
	330	-L/mit/gnu/lib -ltermcap)
	331	fi],
	332	-ltermcap)])
ea0caf4a	333	if test "$readline" != no; then
ea0caf4a	334	if test "$readline" != yes; then
ee85084d	335	READLINE_CPPFLAGS="-I$readline/include -I$readline/include/readline"
	336	READLINE_LIBS="-L$readline/lib"
	337	else
	338	READLINE_CPPFLAGS="-I/usr/include/readline"
ea0caf4a	339	fi
ee85084d	340	READLINE_CPPFLAGS="$READLINE_CPPFLAGS -DHAVE_READLINE"
ee85084d	341	READLINE_LIBS="$READLINE_LIBS -lreadline -ltermcap"
ea0caf4a	342	fi
	343	AC_SUBST(READLINE_CPPFLAGS)
	344	AC_SUBST(READLINE_LIBS)
	345
	346	# Curses
	347	curses=curses
	348	AC_CHECKING(for curses)
	349	AC_CHECK_LIB(curses, main, :, AC_CHECK_LIB(ncurses, main, curses=ncurses))
	350	if test -n "$curses"; then
	351	OLDLIBS=$LIBS
	352	LIBS=-l$curses
	353	AC_CHECKING(if curses needs termcap)
	354	dnl we need to use AC_TRY_RUN because under NetBSD, the program will
	355	dnl link with just -lcurses, but then fail with a runtime linker error
	356	dnl because you didn't use -ltermcap
	357	AC_TRY_RUN([#include <curses.h>
	358	main(int argc, char **argv)
	359	{
	360	initscr();
	361	endwin();
	362	return 0;
	363	}], [CURSES_LIBS="-l$curses"],
	364	LIBS="-l$curses -ltermcap"
	365	AC_TRY_RUN([#include <curses.h>
	366	main(int argc, char **argv)
	367	{
	368	initscr();
	369	endwin();
	370	return 0;
	371	}], [CURSES_LIBS="-l$curses -ltermcap"],
	372	:, :),
	373	:)
	374	LIBS=$OLDLIBS
	375	fi
	376	if test -n "$CURSES_LIBS"; then
	377	OLDLIBS=$LIBS
	378	LIBS=$CURSES_LIBS
	379	AC_TRY_LINK([#include <curses.h>],[WINDOW *w; getmaxx(w);],
	380	:,
	381	AC_TRY_COMPILE([#include <curses.h>],[WINDOW *w; w->_maxx;],
	382	[CURSES_CPPFLAGS="-D'getmaxx(w)=w->_maxx'"],
	383	[CURSES_CPPFLAGS="-D'getmaxx(w)=w->maxx'"]))
4753fa79	384	AC_TRY_LINK([#include <curses.h>],[newterm(NULL, NULL, NULL);],
4753fa79	385	[CURSES_CPPFLAGS="$CURSES_CPPFLAGS -DCURSES_HAS_NEWTERM"])
ea0caf4a	386	LIBS=$OLDLIBS
	387	CURSES_CPPFLAGS="-DHAVE_CURSES $CURSES_CPPFLAGS"
	388	CURSES_SUBDIRS='$(CURSES_SUBDIRS)'
	389	else
	390	AC_MSG_WARN(Couldn't find -lcurses)
	391	fi
	392	AC_SUBST(CURSES_CPPFLAGS)
	393	AC_SUBST(CURSES_LIBS)
	394	AC_SUBST(CURSES_SUBDIRS)
	395
	396
	397	AC_CHECK_FUNCS(getusershell)
	398
25f58600	399	MR_EXTEND(PRO_C_INCLUDES, INCLUDE='$(srcdir)')
ea0caf4a	400	MR_INCLUDE('$(SRCTOP)/include')
25f58600	401	MR_INCLUDE('$(SRCTOP)/lib')
ea0caf4a	402	MR_INCLUDE('$(BUILDTOP)/lib')
ea0caf4a	403	MR_INCLUDE('$(BUILDTOP)/db')
f4036eed	404	MR_INCLUDE('$(srcdir)')
ea0caf4a	405	LDFLAGS="$LDFLAGS -L\$(BUILDTOP)/lib $LIBPATH"
	406	KLIBS="-lzephyr $KRB4_LIBS -lcom_err -lhesiod $LIBS"
	407	LIBS="-lmoira $KLIBS"
	408	AC_SUBST(KLIBS)
	409
3fb6166b	410	MR_LIBDEP='$(BUILDTOP)/lib/libmoira.a'
	411	AC_SUBST(MR_LIBDEP)
	412
ea0caf4a	413	AC_OUTPUT(Makefile lib/Makefile include/Makefile clients/Makefile \
ee85084d	414	clients/lib/Makefile clients/addusr/Makefile \
	415	clients/blanche/Makefile clients/mailmaint/Makefile
	416	clients/moira/Makefile clients/mrcheck/Makefile
	417	clients/mrtest/Makefile clients/passwd/Makefile
	418	update/Makefile man/Makefile \
9ed720ef	419	$SERVER_OUTPUT_FILES $AFS_OUTPUT_FILES \
9ed720ef	420	$GDSS_OUTPUT_FILES $RSAREF_OUTPUT_FILES)