src/cgrammar.y

   1 /*;-*-C-*-;
   2 ** Splint - annotation-assisted static program checker
   3 ** Copyright (C) 1994-2002 University of Virginia,
   4 **         Massachusetts Institute of Technology
   5 **
   6 ** This program is free software; you can redistribute it and/or modify it
   7 ** under the terms of the GNU General Public License as published by the
   8 ** Free Software Foundation; either version 2 of the License, or (at your
   9 ** option) any later version.
  10 **
  11 ** This program is distributed in the hope that it will be useful, but
  12 ** WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ** MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 ** General Public License for more details.
  15 **
  16 ** The GNU General Public License is available from http://www.gnu.org/ or
  17 ** the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  18 ** MA 02111-1307, USA.
  19 **
  20 ** For information on splint: info@splint.org
  21 ** To report a bug: splint-bug@splint.org
  22 ** For more information: http://www.splint.org
  23 */
  24 %{
  25 /*
  26 **
  27 ** cgrammar.y
  28 **
  29 ** Yacc/Bison grammar for extended ANSI C used by Splint.
  30 **
  31 ** original grammar by Nate Osgood ---
  32 **    hacrat@catfish.lcs.mit.edu Mon Jun 14 13:06:32 1993
  33 **
  34 ** changes for Splint --- handle typedef names correctly
  35 ** fix struct/union parsing bug (empty struct is accepted)
  36 ** add productions to handle macros --- require
  37 ** error correction --- main source of conflicts in grammar.
  38 ** need to process initializations sequentially, L->R
  39 **
  40 ** production names are cryptic, so more productions fit on one line
  41 **
  42 ** conflicts:  87 shift/reduce, 18 reduce/reduce
  43 ** most of these are due to handling macros
  44 ** a few are due to handling type expressions
  45 */
  46
  47 /*@=allmacros@*/
  48
  49 extern int yylex ();
  50 extern void swallowMacro (void);
  51 extern void yyerror (char *);
  52
  53 # include "splintMacros.nf"
  54 # include "basic.h"
  55 # include "cscanner.h"
  56 # include "cgrammar.h"
  57 # include "exprChecks.h"
  58
  59 /*@-allmacros@*/
  60 /*@-matchfields@*/
  61
  62 # define SHOWCSYM FALSE
  63
  64 /*
  65 ** This is necessary, or else when the bison-generated code #include's malloc.h,
  66 ** there will be a parse error.
  67 **
  68 ** Unfortunately, it means the error checking on malloc, etc. is lost for allocations
  69 ** in bison-generated files under Win32.
  70 */
  71
  72 # ifdef WIN32
  73 # undef malloc
  74 # undef calloc
  75 # undef realloc
  76 # endif
  77
  78 %}
  79
  80 %union
  81 {
  82   lltok tok;
  83   int count;
  84   qual typequal;
  85   qualList tquallist;
  86   ctype ctyp;
  87   /*@dependent@*/ sRef sr;
  88   /*@only@*/ sRef osr;
  89
  90   /*@only@*/ functionClauseList funcclauselist;
  91   /*@only@*/ functionClause funcclause;
  92   /*@only@*/ flagSpec flagspec;
  93   /*@only@*/ globalsClause globsclause;
  94   /*@only@*/ modifiesClause modsclause;
  95   /*@only@*/ warnClause warnclause;
  96   /*@only@*/ stateClause stateclause;
  97
  98   /*@only@*/ functionConstraint fcnconstraint;
  99
 100   /*@only@*/ metaStateConstraint msconstraint;
 101   /*@only@*/ metaStateSpecifier msspec;
 102   /*@only@*/ metaStateExpression msexpr;
 103   /*@observer@*/ metaStateInfo msinfo;
 104
 105   /*@only@*/ sRefList srlist;
 106   /*@only@*/ globSet globset;
 107   /*@only@*/ qtype qtyp;
 108   /*@only@*/ cstring cname;
 109   /*@observer@*/ annotationInfo annotation;
 110   /*@only@*/ idDecl ntyp;
 111   /*@only@*/ idDeclList ntyplist;
 112   /*@only@*/ uentryList flist;
 113   /*@owned@*/ uentryList entrylist;
 114   /*@observer@*/ /*@dependent@*/ uentry entry;
 115   /*@only@*/ uentry oentry;
 116   /*@only@*/ exprNode expr;
 117   /*@only@*/ enumNameList enumnamelist;
 118   /*@only@*/ exprNodeList exprlist;
 119   /*@only@*/ sRefSet srset;
 120   /*@only@*/ cstringList cstringlist;
 121
 122   /*drl
 123     added 1/19/2001
 124   */
 125   constraint con;
 126   constraintList conL;
 127   constraintExpr conE;
 128   /* drl */
 129 }
 130
 131 /* standard C tokens */
 132
 133 %token <tok> BADTOK SKIPTOK
 134 %token <tok> CTOK_ELIPSIS CASE DEFAULT CIF CELSE SWITCH WHILE DO CFOR
 135 %token <tok> GOTO CONTINUE BREAK RETURN
 136 %token <tok> TSEMI TLBRACE TRBRACE TCOMMA TCOLON TASSIGN TLPAREN
 137 %token <tok> TRPAREN TLSQBR TRSQBR TDOT TAMPERSAND TEXCL TTILDE
 138 %token <tok> TMINUS TPLUS TMULT TDIV TPERCENT TLT TGT TCIRC TBAR TQUEST
 139 %token <tok> CSIZEOF CALIGNOF CTYPEOF ARROW_OP CTYPEDEF COFFSETOF
 140 %token <tok> INC_OP DEC_OP LEFT_OP RIGHT_OP
 141 %token <tok> LE_OP GE_OP EQ_OP NE_OP AND_OP OR_OP
 142 %token <tok> MUL_ASSIGN DIV_ASSIGN MOD_ASSIGN ADD_ASSIGN SUB_ASSIGN
 143 %token <tok> LEFT_ASSIGN RIGHT_ASSIGN AND_ASSIGN XOR_ASSIGN OR_ASSIGN
 144 %token <tok> CSTRUCT CUNION CENUM
 145 %token <tok> VA_ARG VA_DCL
 146 %token <tok> QWARN
 147 %token <tok> QGLOBALS
 148 %token <tok> QMODIFIES
 149 %token <tok> QNOMODS
 150 %token <tok> QCONSTANT
 151 %token <tok> QFUNCTION
 152 %token <tok> QITER
 153 %token <tok> QDEFINES
 154 %token <tok> QUSES
 155 %token <tok> QALLOCATES
 156 %token <tok> QSETS
 157 %token <tok> QRELEASES
 158 %token <tok> QPRECLAUSE
 159 %token <tok> QPOSTCLAUSE
 160 %token <tok> QINVARIANT
 161 %token <tok> QALT
 162 %token <tok> QUNDEF QKILLED
 163 %token <tok> QENDMACRO
 164
 165 /* additional tokens introduced by splint pre-processor. */
 166 %token <tok> LLMACRO LLMACROITER LLMACROEND TENDMACRO
 167
 168 /* break comments: */
 169 %token <tok> QSWITCHBREAK QLOOPBREAK QINNERBREAK QSAFEBREAK
 170 %token <tok> QINNERCONTINUE
 171
 172 /* case fall-through marker: */
 173 %token <tok> QFALLTHROUGH
 174
 175 /* used in scanner only */
 176 %token <tok> QLINTNOTREACHED
 177 %token <tok> QLINTFALLTHROUGH
 178 %token <tok> QLINTFALLTHRU
 179 %token <tok> QARGSUSED
 180 %token <tok> QPRINTFLIKE QLINTPRINTFLIKE QSCANFLIKE QMESSAGELIKE
 181
 182 /* not-reached marker: (used like a label) */
 183 %token <tok> QNOTREACHED
 184
 185 /* type qualifiers: */
 186 %token <tok> QCONST QVOLATILE QINLINE QEXTENSION QEXTERN QSTATIC QAUTO QREGISTER
 187 %token <tok> QOUT QIN QYIELD QONLY QTEMP QSHARED QREF QUNIQUE
 188 %token <tok> QCHECKED QUNCHECKED QCHECKEDSTRICT QCHECKMOD
 189 %token <tok> QKEEP QKEPT QPARTIAL QSPECIAL QOWNED QDEPENDENT
 190 %token <tok> QRETURNED QEXPOSED QNULL QOBSERVER QISNULL
 191 %token <tok> QEXITS QMAYEXIT QNEVEREXIT QTRUEEXIT QFALSEEXIT
 192 %token <tok> QLONG QSIGNED QUNSIGNED QSHORT QUNUSED QSEF QNOTNULL QRELNULL
 193 %token <tok> QABSTRACT QCONCRETE QMUTABLE QIMMUTABLE
 194 %token <tok> QTRUENULL QFALSENULL QEXTERNAL
 195 %token <tok> QREFCOUNTED QREFS QNEWREF QTEMPREF QKILLREF QRELDEF
 196 %token <ctyp> CGCHAR CBOOL CINT CGFLOAT CDOUBLE CVOID
 197 %token <tok> QANYTYPE QINTEGRALTYPE QUNSIGNEDINTEGRALTYPE QSIGNEDINTEGRALTYPE
 198
 199 %token <tok> QNULLTERMINATED
 200 %token <tok> QSETBUFFERSIZE
 201 %token <tok> QSETSTRINGLENGTH
 202 %token <tok> QMAXSET
 203 %token <tok> QMAXREAD
 204 %token <tok> QTESTINRANGE
 205
 206 %token <tok> TCAND
 207
 208
 209 /* identifiers, literals */
 210 %token <entry> IDENTIFIER
 211 %token <cname> NEW_IDENTIFIER TYPE_NAME_OR_ID
 212 %token <annotation> CANNOTATION
 213 %token <expr> CCONSTANT
 214 %type <cname> flagId
 215 %type <flagspec> flagSpec
 216 %type <expr> cconstantExpr
 217 %token <entry> ITER_NAME ITER_ENDNAME
 218 %type <entry> endIter
 219
 220 %type <funcclauselist> functionClauses functionClausesPlain
 221 %type <funcclause> functionClause functionClause functionClausePlain
 222
 223 %type <globsclause> globalsClause globalsClausePlain
 224 %type <modsclause> modifiesClause modifiesClausePlain nomodsClause
 225 %type <warnclause> warnClause warnClausePlain optWarnClause
 226 %type <funcclause> conditionClause conditionClausePlain
 227 %type <stateclause> stateClause stateClausePlain
 228 %type <msconstraint> metaStateConstraint
 229 %type <fcnconstraint> functionConstraint
 230 %type <msspec> metaStateSpecifier
 231 %type <msexpr> metaStateExpression
 232
 233 %type <sr> globId globIdListExpr
 234 %type <globset> globIdList
 235
 236 %token <ctyp>  TYPE_NAME
 237 %token <msinfo> METASTATE_NAME
 238 %type <msinfo> metaStateName
 239 %type <cname> enumerator newId  /*@-varuse@*/ /* yacc declares yytranslate here */
 240 %type <count> pointers /*@=varuse@*/
 241
 242 %type <tok> doHeader stateTag conditionTag startConditionClause
 243 %type <typequal> exitsQualifier checkQualifier stateQualifier
 244                  paramQualifier returnQualifier visibilityQualifier
 245                  typedefQualifier refcountQualifier definedQualifier
 246
 247 /* type construction */
 248 %type <ctyp> abstractDecl abstractDeclBase optAbstractDeclBase
 249 %type <ctyp> suSpc enumSpc typeName typeSpecifier
 250
 251 %type <ntyp> namedDecl namedDeclBase optNamedDecl
 252 %type <ntyp> plainNamedDecl plainNamedDeclBase
 253 %type <ntyp> structNamedDecl
 254 %type <ntyp> fcnDefHdrAux plainFcn
 255
 256 %type <oentry> paramDecl
 257 %type <entry> id
 258
 259 %type <ntyplist> structNamedDeclList
 260
 261 %type <entrylist> genericParamList paramTypeList paramList idList paramIdList
 262 %type <exprlist> argumentExprList iterArgList
 263 %type <exprlist> initList namedInitializerList namedInitializerListAux
 264 %type <flist> structDeclList structDecl
 265 %type <srset> locModifies modList specClauseList optSpecClauseList
 266 %type <sr>    mExpr modListExpr specClauseListExpr
 267
 268 /*drl*/
 269 %type <con> BufConstraint
 270 %type <tok> relationalOp
 271 %type <tok> BufBinaryOp
 272 %type <tok> bufferModifier
 273
 274 %type <conE> BufConstraintExpr
 275
 276 %type <conE> BufConstraintTerm
 277 %type <sr> BufConstraintSrefExpr
 278
 279 %type <conL> BufConstraintList
 280
 281 %type <conL> optStructInvariant
 282
 283 %type <tok>  BufUnaryOp
 284
 285 /*drl 1/6/2002 either /\ or && */
 286 %type <tok> constraintSeperator
 287
 288 %type <enumnamelist> enumeratorList
 289 %type <cstringlist> fieldDesignator
 290
 291 %type <expr> sizeofExpr sizeofExprAux offsetofExpr
 292 %type <expr> openScope closeScope
 293 %type <expr> instanceDecl namedInitializer optDeclarators
 294 %type <expr> primaryExpr postfixExpr primaryIterExpr postfixIterExpr
 295 %type <expr> unaryExpr castExpr timesExpr plusExpr
 296 %type <expr> unaryIterExpr castIterExpr timesIterExpr plusIterExpr
 297 %type <expr> shiftExpr relationalExpr equalityExpr bitandExpr
 298 %type <expr> xorExpr bitorExpr andExpr
 299 %type <expr> orExpr conditionalExpr assignExpr
 300 %type <expr> shiftIterExpr relationalIterExpr equalityIterExpr bitandIterExpr
 301 %type <expr> xorIterExpr bitorIterExpr andIterExpr
 302 %type <expr> orIterExpr conditionalIterExpr assignIterExpr iterArgExpr
 303 %type <expr> expr optExpr constantExpr
 304 %type <expr> init macroBody iterBody endBody partialIterStmt iterSelectionStmt
 305 %type <expr> stmt stmtList fcnBody iterStmt iterDefStmt iterDefStmtList
 306 %type <expr> labeledStmt caseStmt defaultStmt
 307 %type <expr> compoundStmt compoundStmtAux compoundStmtRest compoundStmtAuxErr
 308 %type <expr> expressionStmt selectionStmt iterationStmt jumpStmt iterDefIterationStmt
 309 %type <expr> stmtErr stmtListErr compoundStmtErr expressionStmtErr
 310 %type <expr> iterationStmtErr initializerList typeInitializerList initializer
 311 %type <expr> ifPred whilePred forPred iterWhilePred typeInitializer
 312
 313 %type <expr> designator designatorList designation
 314
 315 %type <typequal> storageSpecifier typeQualifier typeModifier globQual
 316 %type <tquallist> optGlobQuals
 317 %type <qtyp> completeType completeTypeSpecifier optCompleteType
 318 %type <qtyp> completeTypeSpecifierAux altType typeExpression
 319
 320 %start file
 321
 322 %%
 323
 324 file
 325  :
 326  | externalDefs
 327
 328 externalDefs
 329  : externalDef { context_checkGlobalScope (); }
 330  | externalDefs externalDef { context_checkGlobalScope (); }
 331
 332 externalDef
 333  : fcnDef optSemi { uentry_clearDecl (); }
 334  | constantDecl   { uentry_clearDecl (); }
 335  | fcnDecl        { uentry_clearDecl (); }
 336  | iterDecl       { uentry_clearDecl (); }
 337  | macroDef       { uentry_clearDecl (); }
 338  | initializer    { uentry_checkDecl (); exprNode_free ($1); }
 339  | TSEMI          { uentry_clearDecl (); /* evans 2002-02-08: okay to have a null statement */ }
 340  | error          { uentry_clearDecl (); }
 341
 342 constantDecl
 343  : QCONSTANT completeTypeSpecifier NotType namedDecl NotType optSemi IsType QENDMACRO
 344    { checkConstant ($2, $4); }
 345  | QCONSTANT completeTypeSpecifier NotType namedDecl NotType TASSIGN IsType init optDeclarators optSemi QENDMACRO
 346    { checkValueConstant ($2, $4, $8) ; }
 347
 348 fcnDecl
 349  : QFUNCTION { context_enterFunctionHeader (); } plainFcn optSemi QENDMACRO
 350    {
 351      declareStaticFunction ($3); context_quietExitFunction ();
 352      context_exitFunctionHeader ();
 353    }
 354
 355 plainFcn
 356  : plainNamedDecl
 357    {
 358      qtype qint = qtype_create (ctype_int);
 359      $$ = idDecl_fixBase ($1, qint);
 360      qtype_free (qint);
 361    }
 362  | completeTypeSpecifier NotType plainNamedDecl
 363    { $$ = idDecl_fixBase ($3, $1); }
 364
 365 plainNamedDecl
 366  : plainNamedDeclBase
 367  | pointers plainNamedDeclBase
 368    { $$ = $2; qtype_adjustPointers ($1, idDecl_getTyp ($$)); }
 369
 370 namedDeclBase
 371  : newId { $$ = idDecl_create ($1, qtype_unknown ()); }
 372  | IsType TLPAREN NotType namedDecl IsType TRPAREN
 373    { $$ = idDecl_expectFunction ($4); }
 374  | namedDeclBase TLSQBR TRSQBR
 375    { $$ = idDecl_replaceCtype ($1, ctype_makeInnerArray (idDecl_getCtype ($1))); }
 376  | namedDeclBase TLSQBR IsType constantExpr TRSQBR NotType
 377    {
 378      exprNode_findValue ($4);
 379      idDecl_notExpectingFunction ($1);
 380
 381      if (exprNode_hasValue ($4))
 382        {
 383          $$ = idDecl_replaceCtype ($1, ctype_makeInnerFixedArray (idDecl_getCtype ($1),
 384                                                                   exprNode_getLongValue ($4)));
 385        }
 386      else
 387        {
 388          $$ = idDecl_replaceCtype ($1, ctype_makeInnerArray (idDecl_getCtype ($1)));
 389        }
 390    }
 391  | namedDeclBase PushType TLPAREN TRPAREN
 392    { setCurrentParams (uentryList_missingParams); }
 393    functionClauses
 394    { /* need to support globals and modifies here! */
 395      ctype ct = ctype_makeFunction (idDecl_getCtype ($1),
 396                                     uentryList_makeMissingParams ());
 397
 398      $$ = idDecl_replaceCtype ($1, ct);
 399      idDecl_addClauses ($$, $6);
 400      context_popLoc ();
 401      /*drl 7/25/01 added*/
 402      setImplictfcnConstraints();
 403    }
 404  | namedDeclBase PushType TLPAREN genericParamList TRPAREN
 405    { setCurrentParams ($4); }
 406    functionClauses
 407    { setImplictfcnConstraints ();
 408      clearCurrentParams ();
 409      $$ = idDecl_replaceCtype ($1, ctype_makeFunction (idDecl_getCtype ($1), $4));
 410      idDecl_addClauses ($$, $7);
 411      context_popLoc ();
 412    }
 413
 414 plainNamedDeclBase
 415  : newId { $$ = idDecl_create ($1, qtype_unknown ()); }
 416  | IsType TLPAREN NotType plainNamedDecl IsType TRPAREN
 417    { $$ = idDecl_expectFunction ($4); }
 418  | plainNamedDeclBase TLSQBR TRSQBR
 419    { $$ = idDecl_replaceCtype ($1, ctype_makeInnerArray (idDecl_getCtype ($1))); }
 420  | plainNamedDeclBase TLSQBR IsType constantExpr TRSQBR NotType
 421    {
 422      int value;
 423
 424      if (exprNode_hasValue ($4)
 425          && multiVal_isInt (exprNode_getValue ($4)))
 426        {
 427          value = (int) multiVal_forceInt (exprNode_getValue ($4));
 428        }
 429      else
 430        {
 431          value = 0;
 432        }
 433
 434      $$ = idDecl_replaceCtype ($1, ctype_makeInnerFixedArray (idDecl_getCtype ($1), value));
 435    }
 436  | plainNamedDeclBase PushType TLPAREN TRPAREN
 437    { setCurrentParams (uentryList_missingParams); }
 438    functionClausesPlain
 439    {
 440      ctype ct = ctype_makeFunction (idDecl_getCtype ($1),
 441                                     uentryList_makeMissingParams ());
 442
 443      $$ = idDecl_replaceCtype ($1, ct);
 444      idDecl_addClauses ($$, $6);
 445      context_popLoc ();
 446    }
 447  | plainNamedDeclBase PushType TLPAREN genericParamList TRPAREN
 448    { setCurrentParams ($4); }
 449    functionClausesPlain
 450    {
 451      clearCurrentParams ();
 452      $$ = idDecl_replaceCtype ($1, ctype_makeFunction (idDecl_getCtype ($1), $4));
 453      idDecl_addClauses ($$, $7);
 454      context_popLoc ();
 455    }
 456
 457 iterDecl
 458  : QITER newId TLPAREN genericParamList TRPAREN
 459    { setCurrentParams ($4); } functionClausesPlain
 460    { clearCurrentParams (); } optSemi QENDMACRO
 461    { declareCIter ($2, $4); }
 462
 463 macroDef
 464  : LLMACRO macroBody TENDMACRO     { exprNode_checkMacroBody ($2); }
 465  | LLMACROITER iterBody TENDMACRO  { exprNode_checkIterBody ($2); }
 466  | LLMACROEND endBody TENDMACRO    { exprNode_checkIterEnd ($2); }
 467  | LLMACRO TENDMACRO /* no stmt */ { exprChecks_checkEmptyMacroBody (); }
 468
 469 fcnDefHdr
 470  : fcnDefHdrAux { clabstract_declareFunction ($1); }
 471
 472 metaStateConstraint
 473  : metaStateSpecifier TASSIGN metaStateExpression
 474    { $$ = metaStateConstraint_create ($1, $3); }
 475
 476 metaStateSpecifier
 477   : BufConstraintSrefExpr { cscanner_expectingMetaStateName (); } TCOLON metaStateName
 478     { cscanner_clearExpectingMetaStateName ();
 479       $$ = metaStateSpecifier_create ($1, $4); }
 480   | CTOK_ELIPSIS { cscanner_expectingMetaStateName (); } TCOLON metaStateName
 481     { cscanner_clearExpectingMetaStateName ();
 482       $$ = metaStateSpecifier_createElipsis ($4); }
 483
 484 metaStateExpression
 485 : metaStateSpecifier { $$ = metaStateExpression_create ($1); }
 486 | metaStateSpecifier TBAR metaStateExpression { $$ = metaStateExpression_createMerge ($1, $3); }
 487
 488 metaStateName
 489 : METASTATE_NAME
 490
 491 /*drl*/
 492
 493 constraintSeperator
 494 : TCAND
 495 | AND_OP
 496
 497 BufConstraintList
 498 : BufConstraint constraintSeperator BufConstraintList { $$ = constraintList_add ($3, $1); }
 499 | BufConstraint { $$ = constraintList_single ($1); }
 500
 501 BufConstraint
 502 :  BufConstraintExpr relationalOp BufConstraintExpr {
 503  $$ = makeConstraintParse3 ($1, $2, $3);
 504  DPRINTF(("Done BufConstraint1\n")); }
 505
 506 bufferModifier
 507  : QMAXSET
 508  | QMAXREAD
 509
 510 relationalOp
 511  : GE_OP
 512  | LE_OP
 513  | EQ_OP
 514
 515 BufConstraintExpr
 516  : BufConstraintTerm
 517  | BufUnaryOp TLPAREN BufConstraintExpr TRPAREN {$$ = constraintExpr_parseMakeUnaryOp ($1, $3);  DPRINTF( ("Got BufConstraintExpr UNary Op ") ); }
 518  | TLPAREN BufConstraintExpr BufBinaryOp BufConstraintExpr TRPAREN {
 519    DPRINTF( ("Got BufConstraintExpr BINary Op ") );
 520    $$ = constraintExpr_parseMakeBinaryOp ($2, $3, $4); }
 521
 522 BufConstraintTerm
 523  : BufConstraintSrefExpr { $$ =  constraintExpr_makeTermsRef ($1);}
 524  | CCONSTANT { $$ = constraintExpr_makeIntLiteral (exprNode_getLongValue ($1)); }
 525
 526 BufConstraintSrefExpr
 527 : id
 528   { /*@-onlytrans@*/ $$ = checkbufferConstraintClausesId ($1); /*@=onlytrans@*/ /*@i523@*/ }
 529 | NEW_IDENTIFIER
 530   { $$ = fixStateClausesId ($1); }
 531 | BufConstraintSrefExpr TLSQBR TRSQBR
 532   { $$ = sRef_makeAnyArrayFetch ($1); }
 533 | BufConstraintSrefExpr  TLSQBR CCONSTANT TRSQBR
 534   {
 535     /*
 536     char *t; int c;
 537     t =  cstring_toCharsSafe (exprNode_unparse($3));
 538     c = atoi( t );
 539     */
 540     $$ = sRef_makeArrayFetchKnown ($1, exprNode_getLongValue ($3));
 541   }
 542 | TMULT  BufConstraintSrefExpr
 543   { $$ = sRef_constructPointer ($2); }
 544 | TLPAREN BufConstraintSrefExpr TRPAREN
 545   { $$ = $2; }
 546 | BufConstraintSrefExpr TDOT newId
 547   { cstring_markOwned ($3); $$ = sRef_buildField ($1, $3); }
 548 | BufConstraintSrefExpr ARROW_OP newId
 549   { cstring_markOwned ($3); $$ = sRef_makeArrow ($1, $3); }
 550
 551 /*
 552 | BufConstraintTerm TLSQBR TRSQBR       { $$ = sRef_makeAnyArrayFetch ($1); }
 553  | specClauseListExpr TLSQBR mExpr TRSQBR { $$ = sRef_makeAnyArrayFetch ($1); }
 554  | TLPAREN specClauseListExpr TRPAREN     { $$ = $2; }
 555  | specClauseListExpr TDOT newId          { cstring_markOwned ($3);
 556                                             $$ = sRef_buildField ($1, $3); }
 557 */
 558
 559 /*BufConstraintExpr
 560 : BufConstraintTerm
 561 */
 562
 563 BufUnaryOp
 564 : bufferModifier
 565 ;
 566
 567 BufBinaryOp
 568  : TPLUS
 569 | TMINUS
 570 ;
 571 /*
 572 ** Function clauses can appear in any order.
 573 */
 574
 575 functionClauses
 576  : { $$ = functionClauseList_new (); }
 577  | functionClause functionClauses
 578    { $$ = functionClauseList_prepend ($2, $1); }
 579
 580 /*
 581 ** Inside macro definitions, there are no end macros.
 582 */
 583
 584 functionClausesPlain
 585  :
 586    { $$ = functionClauseList_new (); }
 587  | functionClausePlain functionClausesPlain
 588    { $$ = functionClauseList_prepend ($2, $1); }
 589
 590 functionClause
 591  : globalsClause   { $$ = functionClause_createGlobals ($1); }
 592  | modifiesClause  { $$ = functionClause_createModifies ($1); }
 593  | nomodsClause    { $$ = functionClause_createModifies ($1); }
 594  | stateClause     { $$ = functionClause_createState ($1); }
 595  | conditionClause { $$ = $1; }
 596  | warnClause      { $$ = functionClause_createWarn ($1); }
 597
 598 functionClausePlain
 599  : globalsClausePlain   { $$ = functionClause_createGlobals ($1); }
 600  | modifiesClausePlain  { $$ = functionClause_createModifies ($1); }
 601  | nomodsClause         { $$ = functionClause_createModifies ($1); }
 602  | stateClausePlain     { $$ = functionClause_createState ($1); }
 603  | conditionClausePlain { $$ = $1; }
 604  | warnClausePlain      { $$ = functionClause_createWarn ($1); }
 605
 606 globalsClause
 607  : globalsClausePlain QENDMACRO { $$ = $1; }
 608
 609 globalsClausePlain
 610  : QGLOBALS { setProcessingGlobalsList (); }
 611    globIdList optSemi
 612    {
 613      unsetProcessingGlobals ();
 614      $$ = globalsClause_create ($1, $3);
 615    }
 616
 617 nomodsClause
 618  : QNOMODS { $$ = modifiesClause_createNoMods ($1); }
 619
 620 modifiesClause
 621  : modifiesClausePlain QENDMACRO { $$ = $1; }
 622
 623 modifiesClausePlain
 624  : QMODIFIES
 625    {
 626      context_setProtectVars (); enterParamsTemp ();
 627      sRef_setGlobalScopeSafe ();
 628    }
 629    locModifies
 630    {
 631      exitParamsTemp ();
 632      sRef_clearGlobalScopeSafe ();
 633      context_releaseVars ();
 634      $$ = modifiesClause_create ($1, $3);
 635    }
 636
 637 flagSpec
 638  : flagId
 639    { $$ = flagSpec_createPlain ($1); }
 640  | flagId TBAR flagSpec
 641    { $$ = flagSpec_createOr ($1, $3); }
 642
 643 flagId
 644  : NEW_IDENTIFIER
 645
 646 optWarnClause
 647  : warnClause
 648  | /* empty */ { $$ = warnClause_undefined; }
 649
 650 warnClause
 651  : warnClausePlain QENDMACRO { $$ = $1; }
 652
 653 warnClausePlain
 654  : QWARN flagSpec cconstantExpr
 655    {
 656      llassert (exprNode_knownStringValue ($3));
 657      $$ = warnClause_create ($1, $2, cstring_copy (multiVal_forceString (exprNode_getValue ($3))));
 658      exprNode_free ($3);
 659    }
 660  | QWARN flagSpec
 661    { $$ = warnClause_create ($1, $2, cstring_undefined); }
 662
 663 globIdList
 664  : globIdListExpr                     { $$ = globSet_single ($1); }
 665  | globIdList TCOMMA globIdListExpr   { $$ = globSet_insert ($1, $3); }
 666
 667 globIdListExpr
 668  : optGlobQuals globId { $$ = clabstract_createGlobal ($2, $1); }
 669
 670 optGlobQuals
 671  : /* empty */           { $$ = qualList_undefined; }
 672  | globQual optGlobQuals { $$ = qualList_add ($2, $1); }
 673
 674 globId
 675  : id             { $$ = uentry_getSref ($1); }
 676  | NEW_IDENTIFIER { $$ = clabstract_unrecognizedGlobal ($1); }
 677  | initializer    { $$ = clabstract_checkGlobal ($1); }
 678
 679 globQual
 680  : QUNDEF   { $$ = qual_createUndef (); }
 681  | QKILLED  { $$ = qual_createKilled (); }
 682  | QOUT     { $$ = qual_createOut (); }
 683  | QIN      { $$ = qual_createIn (); }
 684  | QPARTIAL { $$ = qual_createPartial (); }
 685
 686 stateTag
 687  : QDEFINES
 688  | QUSES
 689  | QALLOCATES
 690  | QSETS
 691  | QRELEASES
 692
 693 conditionTag
 694  : QPRECLAUSE
 695  | QPOSTCLAUSE
 696
 697 fcnDefHdrAux
 698  : namedDecl
 699    {
 700      /**!!! deal with fred; fred (int); declarations! **/
 701      qtype qint = qtype_create (ctype_int);
 702      $$ = idDecl_fixBase ($1, qint);
 703      qtype_free (qint);
 704    }
 705  | completeTypeSpecifier NotType namedDecl
 706    { $$ = idDecl_fixBase ($3, $1); }
 707
 708 fcnBody
 709  : TLBRACE { checkDoneParams (); context_enterInnerContext (); }
 710    compoundStmtRest
 711    {
 712      exprNode_checkFunctionBody ($3); $$ = $3;
 713      context_exitInner ($3);
 714    }
 715  | { context_enterOldStyleScope (); } initializerList
 716    { oldStyleDoneParams (); context_enterInnerContext (); }
 717    compoundStmt
 718    {
 719      exprNode_checkFunctionBody ($4);
 720      $$ = $4; /* oldstyle */
 721      context_exitInner ($4);
 722    }
 723
 724 fcnDef
 725  : fcnDefHdr fcnBody
 726    {
 727      context_setFunctionDefined (exprNode_loc ($2));
 728      exprNode_checkFunction (context_getHeader (),  $2);
 729      /* DRL 8 8 2000 */
 730
 731      context_exitFunction ();
 732    }
 733
 734 locModifies
 735  : modList optSemi           { $$ = $1; }
 736  | optSemi                   { $$ = sRefSet_new (); }
 737
 738 modListExpr
 739  : id                              { $$ = uentry_getSref ($1); checkModifiesId ($1); }
 740  | NEW_IDENTIFIER                  { $$ = fixModifiesId ($1); }
 741  | modListExpr TLSQBR TRSQBR       { $$ = modListArrayFetch ($1, sRef_undefined); }
 742  | modListExpr TLSQBR mExpr TRSQBR { $$ = modListArrayFetch ($1, $3); }
 743  | TMULT modListExpr               { $$ = modListPointer ($2); }
 744  | TLPAREN modListExpr TRPAREN     { $$ = $2; }
 745  | modListExpr TDOT newId          { $$ = modListFieldAccess ($1, $3); }
 746  | modListExpr ARROW_OP newId      { $$ = modListArrowAccess ($1, $3); }
 747
 748
 749 mExpr
 750   : modListExpr     { $$ = $1; }
 751   | cconstantExpr   { $$ = sRef_makeUnknown (); /* sRef_makeConstant ($1); ? */ }
 752     /* arithmetic? */
 753
 754 modList
 755   : modListExpr                { $$ = sRefSet_single ($1); }
 756   | modList TCOMMA modListExpr { $$ = sRefSet_insert ($1, $3); }
 757
 758 specClauseListExpr
 759  : id
 760    { $$ = checkStateClausesId ($1); }
 761  | NEW_IDENTIFIER
 762    { $$ = fixStateClausesId ($1); }
 763  | specClauseListExpr TLSQBR TRSQBR       { $$ = sRef_makeAnyArrayFetch ($1); }
 764  | specClauseListExpr TLSQBR mExpr TRSQBR { $$ = sRef_makeAnyArrayFetch ($1); }
 765  | TMULT specClauseListExpr               { $$ = sRef_constructPointer ($2); }
 766  | TLPAREN specClauseListExpr TRPAREN     { $$ = $2; }
 767  | specClauseListExpr TDOT newId          { cstring_markOwned ($3);
 768                                             $$ = sRef_buildField ($1, $3); }
 769  | specClauseListExpr ARROW_OP newId      { cstring_markOwned ($3);
 770                                             $$ = sRef_makeArrow ($1, $3); }
 771
 772 optSpecClauseList
 773  : /* empty */ { $$ = sRefSet_undefined }
 774  | specClauseList
 775
 776 specClauseList
 777   : specClauseListExpr
 778     { if (sRef_isValid ($1)) { $$ = sRefSet_single ($1); }
 779       else { $$ = sRefSet_undefined; }
 780     }
 781   | specClauseList TCOMMA specClauseListExpr
 782     { if (sRef_isValid ($3))
 783         {
 784           $$ = sRefSet_insert ($1, $3);
 785         }
 786       else
 787         {
 788           $$ = $1;
 789         }
 790     }
 791
 792 primaryExpr
 793  : id { $$ = exprNode_fromIdentifier ($1); }
 794  | NEW_IDENTIFIER { $$ = exprNode_fromUIO ($1); }
 795  | cconstantExpr
 796  | TLPAREN expr TRPAREN { $$ = exprNode_addParens ($1, $2); }
 797  | TYPE_NAME_OR_ID { $$ = exprNode_fromIdentifier (coerceId ($1)); }
 798  | QEXTENSION { $$ = exprNode_makeError (); }
 799  | TLPAREN { exprChecks_inCompoundStatementExpression (); }
 800    compoundStmt TRPAREN
 801    { exprChecks_leaveCompoundStatementExpression (); $$ = exprNode_compoundStatementExpression ($1, $3); }
 802
 803 postfixExpr
 804  : primaryExpr
 805  | postfixExpr TLSQBR expr TRSQBR { $$ = exprNode_arrayFetch ($1, $3); }
 806  | postfixExpr TLPAREN TRPAREN { $$ = exprNode_functionCall ($1, exprNodeList_new ()); }
 807  | postfixExpr TLPAREN argumentExprList TRPAREN { $$ = exprNode_functionCall ($1, $3); }
 808  | VA_ARG TLPAREN assignExpr TCOMMA typeExpression TRPAREN { $$ = exprNode_vaArg ($1, $3, $5); }
 809  | postfixExpr NotType TDOT newId IsType { $$ = exprNode_fieldAccess ($1, $3, $4); }
 810  | postfixExpr NotType ARROW_OP newId IsType { $$ = exprNode_arrowAccess ($1, $3, $4); }
 811  | postfixExpr INC_OP { $$ = exprNode_postOp ($1, $2); }
 812  | postfixExpr DEC_OP { $$ = exprNode_postOp ($1, $2); }
 813  | TLPAREN typeExpression TRPAREN TLBRACE typeInitializerList optComma TRBRACE
 814    { /* added for C99 */ $$ = exprNode_undefined; /*@i87 no checking */ }
 815
 816 argumentExprList
 817  : assignExpr { $$ = exprNodeList_singleton ($1); }
 818  | argumentExprList TCOMMA assignExpr { $$ = exprNodeList_push ($1, $3); }
 819
 820 unaryExpr
 821  : postfixExpr
 822  | INC_OP unaryExpr { $$ = exprNode_preOp ($2, $1); }
 823  | DEC_OP unaryExpr { $$ = exprNode_preOp ($2, $1); }
 824  | TAMPERSAND castExpr { $$ = exprNode_preOp ($2, $1); }
 825  | TMULT castExpr  { $$ = exprNode_preOp ($2, $1); }
 826  | TPLUS castExpr  { $$ = exprNode_preOp ($2, $1); }
 827  | TMINUS castExpr { $$ = exprNode_preOp ($2, $1); }
 828  | TTILDE castExpr { $$ = exprNode_preOp ($2, $1); }
 829  | TEXCL castExpr  { $$ = exprNode_preOp ($2, $1); }
 830  | sizeofExpr      { $$ = $1; }
 831  | offsetofExpr    { $$ = $1; }
 832
 833 fieldDesignator
 834  : fieldDesignator TDOT newId { $$ = cstringList_add ($1, $3); }
 835  | newId                      { $$ = cstringList_single ($1); }
 836
 837 offsetofExpr
 838  : COFFSETOF IsType TLPAREN typeExpression NotType TCOMMA fieldDesignator TRPAREN IsType
 839    { $$ = exprNode_offsetof ($4, $7); }
 840
 841 sizeofExpr
 842  : IsType { context_setProtectVars (); }
 843    sizeofExprAux { context_sizeofReleaseVars (); $$ = $3; }
 844
 845 sizeofExprAux
 846  : CSIZEOF TLPAREN typeExpression TRPAREN { $$ = exprNode_sizeofType ($3); }
 847  | CSIZEOF unaryExpr                      { $$ = exprNode_sizeofExpr ($2); }
 848  | CALIGNOF TLPAREN typeExpression TRPAREN { $$ = exprNode_alignofType ($3); }
 849  | CALIGNOF unaryExpr                      { $$ = exprNode_alignofExpr ($2); }
 850
 851 castExpr
 852  : unaryExpr
 853  | TLPAREN typeExpression TRPAREN castExpr
 854    { $$ = exprNode_cast ($1, $4, $2); }
 855
 856 timesExpr
 857  : castExpr
 858  | timesExpr TMULT castExpr { $$ = exprNode_op ($1, $3, $2); }
 859  | timesExpr TDIV castExpr { $$ = exprNode_op ($1, $3, $2); }
 860  | timesExpr TPERCENT castExpr { $$ = exprNode_op ($1, $3, $2); }
 861
 862 plusExpr
 863  : timesExpr
 864  | plusExpr TPLUS timesExpr { $$ = exprNode_op ($1, $3, $2); }
 865  | plusExpr TMINUS timesExpr { $$ = exprNode_op ($1, $3, $2); }
 866
 867 shiftExpr
 868  : plusExpr
 869  | shiftExpr LEFT_OP plusExpr { $$ = exprNode_op ($1, $3, $2); }
 870  | shiftExpr RIGHT_OP plusExpr { $$ = exprNode_op ($1, $3, $2); }
 871
 872 relationalExpr
 873  : shiftExpr
 874  | relationalExpr TLT shiftExpr { $$ = exprNode_op ($1, $3, $2); }
 875  | relationalExpr TGT shiftExpr { $$ = exprNode_op ($1, $3, $2); }
 876  | relationalExpr LE_OP shiftExpr { $$ = exprNode_op ($1, $3, $2); }
 877  | relationalExpr GE_OP shiftExpr { $$ = exprNode_op ($1, $3, $2); }
 878
 879 equalityExpr
 880  : relationalExpr
 881  | equalityExpr EQ_OP relationalExpr { $$ = exprNode_op ($1, $3, $2); }
 882  | equalityExpr NE_OP relationalExpr { $$ = exprNode_op ($1, $3, $2); }
 883
 884 bitandExpr
 885  : equalityExpr
 886  | bitandExpr TAMPERSAND equalityExpr { $$ = exprNode_op ($1, $3, $2); }
 887
 888 xorExpr
 889  : bitandExpr
 890  | xorExpr TCIRC bitandExpr { $$ = exprNode_op ($1, $3, $2); }
 891 ;
 892
 893 bitorExpr
 894  : xorExpr
 895  | bitorExpr TBAR xorExpr { $$ = exprNode_op ($1, $3, $2); }
 896
 897 andExpr
 898  : bitorExpr
 899  | andExpr AND_OP
 900    { exprNode_produceGuards ($1);
 901      context_enterAndClause ($1);
 902    }
 903    bitorExpr
 904    {
 905      $$ = exprNode_op ($1, $4, $2);
 906      context_exitAndClause ($$, $4);
 907    }
 908
 909 orExpr
 910  : andExpr
 911  | orExpr OR_OP
 912    {
 913      exprNode_produceGuards ($1);
 914      context_enterOrClause ($1);
 915    }
 916    andExpr
 917    {
 918      $$ = exprNode_op ($1, $4, $2);
 919      context_exitOrClause ($$, $4);
 920    }
 921
 922 conditionalExpr
 923  : orExpr
 924  | orExpr TQUEST { exprNode_produceGuards ($1); context_enterTrueClause ($1); } expr TCOLON
 925    { context_enterFalseClause ($1); } conditionalExpr
 926    { $$ = exprNode_cond ($1, $4, $7); context_exitClause ($1, $4, $7); }
 927
 928 assignExpr
 929  : conditionalExpr
 930  | unaryExpr TASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 931  | unaryExpr MUL_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 932  | unaryExpr DIV_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 933  | unaryExpr MOD_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 934  | unaryExpr ADD_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 935  | unaryExpr SUB_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 936  | unaryExpr LEFT_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 937  | unaryExpr RIGHT_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 938  | unaryExpr AND_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 939  | unaryExpr XOR_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 940  | unaryExpr OR_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
 941
 942 expr
 943  : assignExpr
 944  | expr TCOMMA assignExpr { $$ = exprNode_comma ($1, $3); }
 945
 946 optExpr
 947  : /* empty */ { $$ = exprNode_undefined; }
 948  | expr
 949
 950 constantExpr
 951  : conditionalExpr
 952
 953 /* instance_orTypeDecl_and_possible_initialization */
 954
 955 initializer
 956  : instanceDecl { $$ = $1; }
 957  | VA_DCL       { doVaDcl (); $$ = exprNode_makeError (); }
 958  | typeDecl     { $$ = exprNode_makeError (); }
 959
 960 instanceDecl
 961  : completeTypeSpecifier IsType TSEMI
 962    { $$ = exprNode_makeError (); }
 963     /*
 964      ** This causes r/r conflicts with function definitions.
 965      ** Instead we need to snarf one first. (gack)
 966      **
 967      ** | completeTypeSpecifier { setProcessingVars ($1); }
 968      ** NotType
 969      ** namedInitializerList IsType TSEMI
 970      ** { unsetProcessingVars (); }
 971      **;
 972      **
 973      ** the solution is pretty ugly:
 974      */
 975  | completeTypeSpecifier NotType namedDecl NotType
 976    {
 977      setProcessingVars ($1);
 978      processNamedDecl ($3);
 979    }
 980    IsType optDeclarators TSEMI IsType
 981    {
 982      unsetProcessingVars ();
 983      $$ = exprNode_makeEmptyInitialization ($3);
 984      DPRINTF (("Empty initialization: %s", exprNode_unparse ($$)));
 985    }
 986  | completeTypeSpecifier NotType namedDecl NotType TASSIGN
 987    { setProcessingVars ($1); processNamedDecl ($3); }
 988    IsType init optDeclarators TSEMI IsType
 989    { $$ = exprNode_concat ($9, exprNode_makeInitialization ($3, $8));
 990      unsetProcessingVars ();
 991    }
 992
 993 namedInitializer
 994  : namedDecl NotType
 995    {
 996      processNamedDecl ($1);
 997      $$ = exprNode_makeEmptyInitialization ($1);
 998    }
 999  | namedDecl NotType TASSIGN { processNamedDecl ($1); } IsType init
1000    { $$ = exprNode_makeInitialization ($1, $6); }
1001
1002 typeDecl
1003  : CTYPEDEF completeTypeSpecifier { setProcessingTypedef ($2); }
1004    NotType namedInitializerList IsType optWarnClause TSEMI
1005    { clabstract_declareType ($5, $7); }
1006  | CTYPEDEF completeTypeSpecifier IsType TSEMI { /* in the ANSI grammar, semantics unclear */ }
1007  | CTYPEDEF namedInitializerList IsType TSEMI { /* in the ANSI grammar, semantics unclear */ }
1008
1009 IsType
1010  : { g_expectingTypeName = TRUE; }
1011
1012 PushType
1013  : { g_expectingTypeName = TRUE; context_pushLoc (); }
1014
1015 namedInitializerList
1016  :  namedInitializerListAux IsType { $$ = $1; }
1017
1018 namedInitializerListAux
1019  : namedInitializer { $$ = exprNodeList_singleton ($1); }
1020  | namedInitializerList TCOMMA NotType namedInitializer { $$ = exprNodeList_push ($1, $4); }
1021
1022 optDeclarators
1023  : /* empty */      { $$ = exprNode_makeError (); }
1024  | optDeclarators TCOMMA NotType namedInitializer { $$ = exprNode_concat ($1, $4); }
1025
1026 init
1027  : assignExpr
1028  | TLBRACE initList TRBRACE        { $$ = exprNode_makeInitBlock ($1, $2); }
1029  | TLBRACE initList TCOMMA TRBRACE { $$ = exprNode_makeInitBlock ($1, $2); }
1030  | designation init                { $$ = exprNode_undefined; }
1031
1032 /*
1033 ** Splint parses these (added in ISO C99), but no checking yet...
1034 */
1035
1036 designation
1037  : designatorList TASSIGN          { $$ = $1; }
1038  | newId TCOLON                    { $$ = exprNode_undefined;
1039                                      /* gcc extension, obsolete since 2.5 */ }
1040
1041 designatorList
1042  : designator                      { $$ = exprNode_undefined; }
1043  | designatorList designator       { $$ = exprNode_undefined; }
1044
1045 designator
1046  : TLSQBR constantExpr TRSQBR      { $$ = exprNode_undefined; }
1047  | TDOT newId                      { $$ = exprNode_undefined; }
1048
1049 initList
1050  : init
1051    { $$ = exprNodeList_singleton ($1); }
1052  | initList TCOMMA init
1053    { $$ = exprNodeList_push ($1, $3); }
1054
1055 /*
1056 ** need to do the storage class global hack so tags are
1057 ** declared with the right storage class.
1058 */
1059
1060 storageSpecifier
1061  : QEXTERN   { setStorageClass (SCEXTERN); $$ = qual_createExtern (); }
1062  | QINLINE   { $$ = qual_createInline (); }
1063  | QSTATIC   { setStorageClass (SCSTATIC); $$ = qual_createStatic (); }
1064  | QAUTO     { $$ = qual_createAuto (); }
1065  | QREGISTER { $$ = qual_createRegister (); }
1066
1067 stateClause
1068  : stateClausePlain QENDMACRO { $$ = $1; }
1069
1070 stateClausePlain
1071  : stateTag NotType
1072    {
1073      context_setProtectVars ();
1074      enterParamsTemp ();
1075      sRef_setGlobalScopeSafe ();
1076    }
1077    specClauseList optSemi IsType
1078    {
1079      exitParamsTemp ();
1080      sRef_clearGlobalScopeSafe ();
1081      context_releaseVars ();
1082      $$ = stateClause_createPlain ($1, $4);
1083    }
1084
1085 conditionClause
1086  : conditionClausePlain QENDMACRO { $$ = $1; }
1087
1088 startConditionClause
1089 : conditionTag NotType { $$ = $1; context_enterFunctionHeader (); }
1090
1091 conditionClausePlain
1092  : startConditionClause stateQualifier
1093    {
1094      context_exitFunctionHeader ();
1095      context_setProtectVars ();
1096      enterParamsTemp ();
1097      sRef_setGlobalScopeSafe ();
1098    }
1099    optSpecClauseList optSemi IsType
1100    {
1101      exitParamsTemp ();
1102      sRef_clearGlobalScopeSafe ();
1103      context_releaseVars ();
1104      $$ = functionClause_createState (stateClause_create ($1, $2, $4));
1105    }
1106  | startConditionClause
1107    {
1108      context_setProtectVars ();
1109      enterParamsTemp ();
1110      sRef_setGlobalScopeSafe ();
1111    }
1112    functionConstraint optSemi IsType
1113    {
1114      context_exitFunctionHeader ();
1115      exitParamsTemp ();
1116      sRef_clearGlobalScopeSafe ();
1117      context_releaseVars ();
1118      DPRINTF (("done optGlobBufConstraintsAux\n"));
1119
1120      if (lltok_isEnsures ($1))
1121        {
1122          $$ = functionClause_createEnsures ($3);
1123        }
1124      else if (lltok_isRequires ($1))
1125        {
1126          $$ = functionClause_createRequires ($3);
1127        }
1128      else
1129        {
1130          BADBRANCH;
1131        }
1132
1133      DPRINTF (("FunctionclauseS: %s", functionClause_unparse ($$)));
1134    }
1135
1136 functionConstraint
1137  : BufConstraintList   { $$ = functionConstraint_createBufferConstraint ($1); }
1138  | metaStateConstraint { $$ = functionConstraint_createMetaStateConstraint ($1); DPRINTF (("Made constraint: %s", functionConstraint_unparse ($$))); }
1139
1140 exitsQualifier
1141  : QEXITS        { $$ = qual_createExits (); }
1142  | QMAYEXIT      { $$ = qual_createMayExit (); }
1143  | QTRUEEXIT     { $$ = qual_createTrueExit (); }
1144  | QFALSEEXIT    { $$ = qual_createFalseExit (); }
1145  | QNEVEREXIT    { $$ = qual_createNeverExit (); }
1146
1147 checkQualifier
1148  : QCHECKED        { $$ = qual_createChecked (); }
1149  | QCHECKMOD       { $$ = qual_createCheckMod (); }
1150  | QUNCHECKED      { $$ = qual_createUnchecked (); }
1151  | QCHECKEDSTRICT  { $$ = qual_createCheckedStrict (); }
1152
1153 stateQualifier
1154  : QOWNED        { $$ = qual_createOwned (); }
1155  | QDEPENDENT    { $$ = qual_createDependent (); }
1156  | QYIELD        { $$ = qual_createYield (); }
1157  | QTEMP         { $$ = qual_createTemp (); }
1158  | QONLY         { $$ = qual_createOnly (); }
1159  | QKEEP         { $$ = qual_createKeep (); }
1160  | QKEPT         { $$ = qual_createKept (); }
1161  | QSHARED       { $$ = qual_createShared (); }
1162  | QUNIQUE       { $$ = qual_createUnique (); }
1163  | QNULL         { $$ = qual_createNull (); }
1164  | QISNULL       { $$ = qual_createIsNull (); }
1165  | QRELNULL      { $$ = qual_createRelNull (); }
1166  | QNOTNULL      { $$ = qual_createNotNull (); }
1167  | QEXPOSED      { $$ = qual_createExposed (); }
1168  | QOBSERVER     { $$ = qual_createObserver (); }
1169  | QNULLTERMINATED { $$ = qual_createNullTerminated (); }
1170  | CANNOTATION   { $$ = qual_createMetaState ($1); }
1171
1172
1173 paramQualifier
1174  : QRETURNED     { $$ = qual_createReturned (); }
1175  | QSEF          { $$ = qual_createSef (); }
1176
1177 visibilityQualifier
1178  : QUNUSED       { $$ = qual_createUnused (); }
1179  | QEXTERNAL     { $$ = qual_createExternal (); }
1180
1181 returnQualifier
1182  : QTRUENULL     { $$ = qual_createTrueNull (); }
1183  | QFALSENULL    { $$ = qual_createFalseNull (); }
1184
1185 typedefQualifier
1186  : QABSTRACT     { $$ = qual_createAbstract (); }
1187  | QCONCRETE     { $$ = qual_createConcrete (); }
1188  | QMUTABLE      { $$ = qual_createMutable (); }
1189  | QIMMUTABLE    { $$ = qual_createImmutable (); }
1190
1191 refcountQualifier
1192  : QREFCOUNTED   { $$ = qual_createRefCounted (); }
1193  | QREFS         { $$ = qual_createRefs (); }
1194  | QKILLREF      { $$ = qual_createKillRef (); }
1195  | QRELDEF       { $$ = qual_createRelDef (); }
1196  | QNEWREF       { $$ = qual_createNewRef (); }
1197  | QTEMPREF      { $$ = qual_createTempRef (); }
1198
1199 typeModifier
1200  : QSHORT            { $$ = qual_createShort (); }
1201  | QLONG             { $$ = qual_createLong (); }
1202  | QSIGNED           { $$ = qual_createSigned (); }
1203  | QUNSIGNED         { $$ = qual_createUnsigned (); }
1204
1205 definedQualifier
1206  : QOUT              { $$ = qual_createOut (); }
1207  | QIN               { $$ = qual_createIn (); }
1208  | QPARTIAL          { $$ = qual_createPartial (); }
1209  | QSPECIAL          { $$ = qual_createSpecial (); }
1210
1211 typeQualifier
1212  : QCONST IsType       { $$ = qual_createConst (); }
1213  | QVOLATILE IsType    { $$ = qual_createVolatile (); }
1214  | definedQualifier IsType { $$ = $1; }
1215  | stateQualifier IsType { $$ = $1; }
1216  | exitsQualifier IsType { $$ = $1; }
1217  | paramQualifier IsType { $$ = $1; }
1218  | checkQualifier IsType { $$ = $1; }
1219  | returnQualifier IsType { $$ = $1; }
1220  | visibilityQualifier IsType { $$ = $1; }
1221  | typedefQualifier IsType { $$ = $1; }
1222  | refcountQualifier IsType { $$ = $1; }
1223
1224 /*
1225 ** This is copied into the mtgrammar!
1226 */
1227
1228 typeSpecifier
1229  : CGCHAR NotType
1230  | CINT NotType
1231  | CBOOL NotType
1232  | CGFLOAT NotType
1233  | CDOUBLE NotType
1234  | CVOID NotType
1235  | QANYTYPE NotType              { $$ = ctype_makeAnytype (); }
1236  | QINTEGRALTYPE NotType         { $$ = ctype_anyintegral; }
1237  | QUNSIGNEDINTEGRALTYPE NotType { $$ = ctype_unsignedintegral; }
1238  | QSIGNEDINTEGRALTYPE NotType   { $$ = ctype_signedintegral; }
1239  | typeName NotType
1240  | suSpc NotType
1241  | enumSpc NotType
1242  | typeModifier NotType           { $$ = ctype_fromQual ($1); }
1243
1244 completeType
1245  : IsType completeTypeSpecifier IsType
1246    { $$ = qtype_resolve ($2); }
1247
1248 completeTypeSpecifier
1249  : completeTypeSpecifierAux { $$ = $1; }
1250  | completeTypeSpecifierAux QALT altType QENDMACRO
1251    { $$ = qtype_mergeAlt ($1, $3); }
1252
1253 altType
1254  : typeExpression
1255  | typeExpression TCOMMA altType
1256    { $$ = qtype_mergeAlt ($1, $3); }
1257
1258 completeTypeSpecifierAux
1259  : storageSpecifier optCompleteType        { $$ = qtype_addQual ($2, $1); }
1260  | typeQualifier optCompleteType           { $$ = qtype_addQual ($2, $1); }
1261  | typeSpecifier optCompleteType           { $$ = qtype_combine ($2, $1); }
1262
1263 optCompleteType
1264  : /* empty */                             { $$ = qtype_unknown (); }
1265  | completeTypeSpecifier                   { $$ = $1; }
1266
1267
1268 optStructInvariant
1269 : /* empty */ { $$ = constraintList_undefined; }
1270 /* don't want to have support for structure invariant until we're
1271    sure it's stable
1272    |  QINVARIANT BufConstraintList QENDMACRO { $$ = $2 }
1273 */
1274
1275 suSpc
1276  : NotType CSTRUCT newId IsType TLBRACE { sRef_setGlobalScopeSafe (); }
1277    CreateStructInnerScope
1278    structDeclList  DeleteStructInnerScope { sRef_clearGlobalScopeSafe (); }
1279    TRBRACE
1280    optStructInvariant
1281    { ctype ct; ct = declareStruct ($3, $8); /* setGlobalStructInfo(ct, $12);*/ $$ = ct; }
1282  | NotType CUNION  newId IsType TLBRACE { sRef_setGlobalScopeSafe (); }
1283    CreateStructInnerScope
1284    structDeclList DeleteStructInnerScope { sRef_clearGlobalScopeSafe (); }
1285    TRBRACE
1286    { $$ = declareUnion ($3, $8); }
1287  | NotType CSTRUCT newId IsType TLBRACE TRBRACE
1288    { $$ = declareStruct ($3, uentryList_new ()); }
1289  | NotType CUNION  newId IsType TLBRACE TRBRACE
1290    { $$ = declareUnion ($3, uentryList_new ()); }
1291  | NotType CSTRUCT IsType TLBRACE { sRef_setGlobalScopeSafe (); }
1292    CreateStructInnerScope
1293    structDeclList DeleteStructInnerScope { sRef_clearGlobalScopeSafe (); }
1294    TRBRACE
1295    { $$ = declareUnnamedStruct ($7); }
1296  | NotType CUNION IsType TLBRACE { sRef_setGlobalScopeSafe (); }
1297    CreateStructInnerScope structDeclList DeleteStructInnerScope
1298    { sRef_clearGlobalScopeSafe (); }
1299    TRBRACE
1300    { $$ = declareUnnamedUnion ($7); }
1301  | NotType CSTRUCT IsType TLBRACE TRBRACE
1302    { $$ = ctype_createUnnamedStruct (uentryList_new ()); }
1303  | NotType CUNION IsType TLBRACE TRBRACE
1304    { $$ = ctype_createUnnamedUnion (uentryList_new ()); }
1305  | NotType CSTRUCT newId NotType { $$ = handleStruct ($3); }
1306  | NotType CUNION newId NotType { $$ = handleUnion ($3); }
1307
1308 NotType
1309  : { g_expectingTypeName = FALSE; }
1310
1311 structDeclList
1312  : structDecl
1313  | macroDef { $$ = uentryList_undefined; /* bogus! */ }
1314  | structDeclList structDecl { $$ = uentryList_mergeFields ($1, $2); }
1315
1316 structDecl
1317  : completeTypeSpecifier NotType structNamedDeclList IsType TSEMI
1318    { $$ = fixUentryList ($3, $1); }
1319  | completeTypeSpecifier IsType TSEMI
1320    { $$ = fixUnnamedDecl ($1); }
1321
1322 structNamedDeclList
1323  : structNamedDecl NotType
1324    { $$ = idDeclList_singleton ($1); }
1325  | structNamedDeclList TCOMMA structNamedDecl NotType
1326    { $$ = idDeclList_add ($1, $3); }
1327
1328 structNamedDecl  /* hack to get around namespace problems */
1329  : namedDecl                            { $$ = $1; }
1330  | TCOLON IsType constantExpr           { $$ = idDecl_undefined; }
1331  | namedDecl TCOLON IsType constantExpr { $$ = $1; }
1332    /* Need the IsType in case there is a cast in the constant expression. */
1333
1334 enumSpc
1335  : NotType CENUM TLBRACE enumeratorList TRBRACE IsType
1336    { $$ = declareUnnamedEnum ($4); }
1337  | NotType CENUM newId TLBRACE { context_pushLoc (); } enumeratorList TRBRACE IsType
1338    { context_popLoc (); $$ = declareEnum ($3, $6); }
1339  | NotType CENUM newId IsType { $$ = handleEnum ($3); }
1340
1341 enumeratorList
1342  : enumerator
1343    { $$ = enumNameList_single ($1); }
1344  | enumeratorList TCOMMA enumerator
1345    { $$ = enumNameList_push ($1, $3); }
1346  | enumeratorList TCOMMA
1347
1348 enumerator
1349  : newId
1350    { uentry ue = uentry_makeEnumConstant ($1, ctype_unknown);
1351      usymtab_supGlobalEntry (ue);
1352      $$ = $1;
1353    }
1354  | newId TASSIGN IsType constantExpr
1355    { uentry ue = uentry_makeEnumInitializedConstant ($1, ctype_unknown, $4);
1356      usymtab_supGlobalEntry (ue);
1357      $$ = $1;
1358    }
1359
1360 optNamedDecl
1361  : namedDeclBase
1362  | optAbstractDeclBase   { $$ = idDecl_create (cstring_undefined, qtype_create ($1)); }
1363  | pointers TYPE_NAME
1364    {
1365      qtype qt = qtype_unknown ();
1366
1367      qtype_adjustPointers ($1, qt);
1368      $$ = idDecl_create (cstring_copy (LastIdentifier ()), qt);
1369    }
1370  | pointers optNamedDecl
1371    { $$ = $2; qtype_adjustPointers ($1, idDecl_getTyp ($$)); }
1372
1373 namedDecl
1374  : namedDeclBase
1375  | pointers namedDeclBase
1376    { $$ = $2; qtype_adjustPointers ($1, idDecl_getTyp ($$)); }
1377
1378 genericParamList
1379  : paramTypeList       { $$ = handleParamTypeList ($1); }
1380  | NotType paramIdList { $$ = handleParamIdList ($2); }
1381
1382 innerMods
1383  : QCONST    { /* ignored for now */; }
1384  | QVOLATILE { ; }
1385
1386 innerModsList
1387  : innerMods { ; }
1388  | innerModsList innerMods { ; }
1389
1390 pointers
1391  : TMULT { $$ = 1; }
1392  | TMULT innerModsList { $$ = 1; }
1393  | TMULT pointers { $$ = 1 + $2; }
1394  | TMULT innerModsList pointers { $$ = 1 + $3; }
1395
1396 paramIdList
1397  : idList
1398  | idList TCOMMA CTOK_ELIPSIS { $$ = uentryList_add ($1, uentry_makeElipsisMarker ()); }
1399
1400 idList
1401  : newId { $$ = uentryList_single (uentry_makeVariableLoc ($1, ctype_int)); }
1402  | idList TCOMMA newId { $$ = uentryList_add ($1, uentry_makeVariableLoc ($3, ctype_int)); }
1403
1404 paramTypeList
1405  : CTOK_ELIPSIS { $$ = uentryList_single (uentry_makeElipsisMarker ()); }
1406  | paramList
1407  | paramList TCOMMA CTOK_ELIPSIS { $$ = uentryList_add ($1, uentry_makeElipsisMarker ()); }
1408
1409 paramList
1410  : { storeLoc (); } paramDecl { $$ = uentryList_single ($2); }
1411  | paramList TCOMMA { storeLoc (); } paramDecl
1412    { $$ = uentryList_add ($1, $4); }
1413
1414 paramDecl
1415  : IsType completeTypeSpecifier optNamedDecl IsType
1416    {
1417      if (isFlipOldStyle ())
1418        {
1419          llparseerror (cstring_makeLiteral ("Inconsistent function parameter syntax (mixing old and new style declaration)"));
1420        }
1421      else
1422        {
1423          setNewStyle ();
1424        }
1425      $$ = makeCurrentParam (idDecl_fixParamBase ($3, $2));
1426    }
1427  | newId /* its an old-style declaration */
1428    {
1429      idDecl tparam = idDecl_create ($1, qtype_unknown ());
1430
1431      if (isNewStyle ())
1432        {
1433          llparseerror (message ("Inconsistent function parameter syntax: %q",
1434                                 idDecl_unparse (tparam)));
1435        }
1436
1437      setFlipOldStyle ();
1438      $$ = makeCurrentParam (tparam);
1439      idDecl_free (tparam);
1440    }
1441
1442 typeExpression
1443  : completeType
1444  | completeType abstractDecl  { $$ = qtype_newBase ($1, $2); }
1445
1446 abstractDecl
1447  : pointers { $$ = ctype_adjustPointers ($1, ctype_unknown); }
1448  | abstractDeclBase
1449  | pointers abstractDeclBase { $$ = ctype_adjustPointers ($1, $2); }
1450
1451 optAbstractDeclBase
1452  : /* empty */ { $$ = ctype_unknown; }
1453  | abstractDeclBase
1454
1455 abstractDeclBase
1456  : IsType TLPAREN NotType abstractDecl TRPAREN
1457    { $$ = ctype_expectFunction ($4); }
1458  | TLSQBR TRSQBR { $$ = ctype_makeArray (ctype_unknown); }
1459  | TLSQBR constantExpr TRSQBR
1460    { $$ = ctype_makeFixedArray (ctype_unknown, exprNode_getLongValue ($2)); }
1461  | abstractDeclBase TLSQBR TRSQBR { $$ = ctype_makeInnerArray ($1); }
1462  | abstractDeclBase TLSQBR constantExpr TRSQBR
1463    { $$ = ctype_makeInnerFixedArray ($1, exprNode_getLongValue ($3)); }
1464  | IsType TLPAREN TRPAREN
1465    { $$ = ctype_makeFunction (ctype_unknown, uentryList_makeMissingParams ()); }
1466  | IsType TLPAREN paramTypeList TRPAREN
1467    { $$ = ctype_makeParamsFunction (ctype_unknown, $3); }
1468  | abstractDeclBase IsType TLPAREN TRPAREN
1469    { $$ = ctype_makeFunction ($1, uentryList_makeMissingParams ()); }
1470  | abstractDeclBase IsType TLPAREN paramTypeList TRPAREN
1471    { $$ = ctype_makeParamsFunction ($1, $4); }
1472
1473 /* statement */
1474
1475 stmt
1476  : labeledStmt
1477  | caseStmt
1478  | defaultStmt
1479  | compoundStmt
1480  | expressionStmt
1481  | selectionStmt
1482  | iterationStmt
1483  | iterStmt
1484  | jumpStmt
1485
1486
1487 iterBody
1488  : iterDefStmtList { $$ = $1; }
1489
1490 endBody
1491  : iterBody
1492
1493 iterDefStmtList
1494  : iterDefStmt
1495  | iterDefStmtList iterDefStmt
1496    { $$ = exprNode_concat ($1, $2); }
1497
1498 iterDefIterationStmt
1499  : iterWhilePred iterDefStmtList
1500    { $$ = exprNode_while ($1, $2); }
1501  | doHeader stmtErr WHILE TLPAREN expr TRPAREN TSEMI
1502    { $$ = exprNode_doWhile ($2, $5); }
1503  | doHeader stmtErr WHILE TLPAREN expr TRPAREN
1504    { $$ = exprNode_doWhile ($2, $5); }
1505  | forPred iterDefStmt
1506    { $$ = exprNode_for ($1, $2); }
1507
1508 forPred
1509  : CFOR TLPAREN optExpr TSEMI optExpr TSEMI
1510    { context_setProtectVars (); } optExpr { context_sizeofReleaseVars (); }
1511    TRPAREN
1512    { $$ = exprNode_forPred ($3, $5, $8);
1513      context_enterForClause ($5); }
1514
1515 partialIterStmt
1516  : ITER_NAME CreateInnerScope TLPAREN
1517    { setProcessingIterVars ($1); }
1518    iterArgList TRPAREN
1519    { $$ = exprNode_iterStart ($1, $5); }
1520  | ITER_ENDNAME { $$ = exprNode_createId ($1); }
1521
1522 iterDefStmt
1523  : labeledStmt
1524  | caseStmt
1525  | defaultStmt
1526  | openScope initializerList { $$ = $1; DPRINTF (("def stmt: %s", exprNode_unparse ($$))); }
1527  | openScope
1528  | closeScope
1529  | expressionStmt
1530  | iterSelectionStmt
1531  | iterDefIterationStmt
1532  | partialIterStmt
1533  | jumpStmt
1534  | TLPAREN iterDefStmt TRPAREN { $$ = $2; }
1535  | error { $$ = exprNode_makeError (); }
1536
1537 iterSelectionStmt
1538  : ifPred { exprNode_checkIfPred ($1); } iterDefStmt
1539    { /* don't: context_exitTrueClause ($1, $2); */
1540      $$ = exprNode_if ($1, $3);
1541    }
1542
1543 openScope
1544  : CreateInnerScope TLBRACE { $$ = exprNode_createTok ($2); }
1545
1546 closeScope
1547  : DeleteInnerScopeSafe TRBRACE { $$ = exprNode_createTok ($2); }
1548
1549 macroBody
1550  : stmtErr
1551  | stmtListErr
1552
1553 stmtErr
1554  : labeledStmt
1555  | caseStmt
1556  | defaultStmt
1557  | compoundStmtErr
1558  | expressionStmtErr
1559  | selectionStmt
1560  | iterStmt
1561  | iterationStmtErr
1562  | TLPAREN stmtErr TRPAREN { $$ = exprNode_addParens ($1, $2); }
1563  | jumpStmt
1564  | error { $$ = exprNode_makeError (); }
1565
1566 labeledStmt
1567  : newId TCOLON      { $$ = exprNode_labelMarker ($1); }
1568  | QNOTREACHED stmt  { $$ = exprNode_notReached ($2); }
1569
1570 /*
1571 ** We allow more than one QFALLTHROUGH token to support mixed lint/splint markers.
1572 */
1573
1574 optExtraFallThroughs
1575  : /* empty */ { ; }
1576  | QFALLTHROUGH optExtraFallThroughs { ; }
1577
1578 /* Note that we can semantically check that the object to the case is
1579  indeed constant. In this case, we may not want to go through this effort */
1580
1581 caseStmt
1582  : CASE constantExpr { context_enterCaseClause ($2); }
1583    TCOLON            { $$ = exprNode_caseMarker ($2, FALSE); }
1584  | QFALLTHROUGH optExtraFallThroughs CASE constantExpr { context_enterCaseClause ($4); }
1585    TCOLON            { $$ = exprNode_caseMarker ($4, TRUE); }
1586
1587 defaultStmt
1588  : DEFAULT { context_enterCaseClause (exprNode_undefined); }
1589    TCOLON { $$ = exprNode_defaultMarker ($1, FALSE); }
1590  | QFALLTHROUGH optExtraFallThroughs DEFAULT { context_enterCaseClause (exprNode_undefined); }
1591    TCOLON { $$ = exprNode_defaultMarker ($3, TRUE); }
1592
1593 compoundStmt
1594  : TLPAREN compoundStmt TRPAREN { $$ = $2; }
1595  | CreateInnerScope compoundStmtAux
1596    { $$ = $2; context_exitInner ($2); }
1597
1598 compoundStmtErr
1599  : CreateInnerScope compoundStmtAuxErr DeleteInnerScope { $$ = $2; }
1600
1601 CreateInnerScope
1602  : { context_enterInnerContext (); }
1603
1604 DeleteInnerScope
1605  : { context_exitInnerPlain (); }
1606
1607 CreateStructInnerScope
1608  : { context_enterStructInnerContext (); }
1609
1610 DeleteStructInnerScope
1611  : { context_exitStructInnerContext (); }
1612
1613 DeleteInnerScopeSafe
1614  : { context_exitInnerSafe (); }
1615
1616 compoundStmtRest
1617  : TRBRACE { $$ = exprNode_createTok ($1); }
1618  | QNOTREACHED TRBRACE { $$ = exprNode_notReached (exprNode_createTok ($2)); }
1619  | stmtList TRBRACE { $$ = exprNode_updateLocation ($1, lltok_getLoc ($2)); }
1620  | stmtList QNOTREACHED TRBRACE
1621    { $$ = exprNode_notReached (exprNode_updateLocation ($1, lltok_getLoc ($3))); }
1622  | initializerList TRBRACE { $$ = exprNode_updateLocation ($1, lltok_getLoc ($2)); }
1623  | initializerList QNOTREACHED TRBRACE
1624    { $$ = exprNode_notReached (exprNode_updateLocation ($1, lltok_getLoc ($3))); }
1625  | initializerList stmtList TRBRACE
1626    { $$ = exprNode_updateLocation (exprNode_concat ($1, $2), lltok_getLoc ($3)); }
1627  | initializerList stmtList QNOTREACHED TRBRACE
1628    { $$ = exprNode_notReached (exprNode_updateLocation (exprNode_concat ($1, $2),
1629                                                         lltok_getLoc ($3)));
1630    }
1631
1632 compoundStmtAux
1633  : TLBRACE compoundStmtRest
1634    { $$ = exprNode_makeBlock ($2); }
1635
1636 compoundStmtAuxErr
1637  : TLBRACE TRBRACE
1638    { $$ = exprNode_createTok ($2); }
1639  | TLBRACE stmtListErr TRBRACE
1640    { $$ = exprNode_updateLocation ($2, lltok_getLoc ($3)); }
1641  | TLBRACE initializerList TRBRACE
1642    { $$ = exprNode_updateLocation ($2, lltok_getLoc ($3)); }
1643  | TLBRACE initializerList stmtList TRBRACE
1644    { $$ = exprNode_updateLocation (exprNode_concat ($2, $3), lltok_getLoc ($4)); }
1645
1646 stmtListErr
1647  : stmtErr
1648  | stmtListErr stmtErr { $$ = exprNode_concat ($1, $2); }
1649
1650 initializerList
1651  : initializer { $$ = $1; }
1652  | initializerList initializer { $$ = exprNode_concat ($1, $2); }
1653
1654 typeInitializerList
1655  : typeInitializer { $$ = $1; }
1656  | typeInitializerList TCOMMA typeInitializer { $$ = exprNode_concat ($1, $3); }
1657
1658 typeInitializer
1659  : assignExpr { $$ = $1; }
1660  | TLBRACE typeInitializerList optComma TRBRACE { $$ = $2; }
1661
1662 stmtList
1663  : stmt { $$ = $1; }
1664  | stmtList stmt { $$ = exprNode_concat ($1, $2); }
1665
1666 expressionStmt
1667  : TSEMI { $$ = exprNode_createTok ($1); }
1668  | expr TSEMI { $$ = exprNode_statement ($1, $2); }
1669
1670 expressionStmtErr
1671  : TSEMI { $$ = exprNode_createTok ($1); }
1672  | expr TSEMI { $$ = exprNode_statement ($1, $2); }
1673  | expr { $$ = exprNode_checkExpr ($1); }
1674
1675 ifPred
1676  : CIF TLPAREN expr TRPAREN
1677    {
1678      exprNode_produceGuards ($3); context_enterTrueClause ($3);
1679      exprNode_checkIfPred ($3);
1680      $$ = $3;
1681    }
1682
1683  /*
1684  ** not ANSI: | CIF TLPAREN compoundStmt TRPAREN
1685  **             { $$ = $3; context_enterTrueClause (); }
1686  */
1687
1688 selectionStmt
1689  : ifPred stmt
1690    {
1691      context_exitTrueClause ($1, $2);
1692      $$ = exprNode_if ($1, $2);
1693    }
1694  | ifPred stmt CELSE  { context_enterFalseClause ($1); } stmt
1695    {
1696      context_exitClause ($1, $2, $5);
1697      $$ = exprNode_ifelse ($1, $2, $5);
1698    }
1699  | SWITCH TLPAREN expr { context_enterSwitch ($3); }
1700    TRPAREN stmt        { $$ = exprNode_switch ($3, $6); }
1701
1702 whilePred
1703  : WHILE TLPAREN expr TRPAREN
1704    { $$ = exprNode_whilePred ($3); context_enterWhileClause ($3); }
1705    /* not ANSI: | WHILE TLPAREN compoundStmt TRPAREN stmt { $$ = exprNode_while ($3, $5); } */
1706
1707 iterWhilePred
1708  : WHILE TLPAREN expr TRPAREN { $$ = exprNode_whilePred($3); }
1709
1710 iterStmt
1711  : ITER_NAME { context_enterIterClause (); }
1712    CreateInnerScope TLPAREN { setProcessingIterVars ($1); }
1713    iterArgList TRPAREN
1714    compoundStmt endIter DeleteInnerScope
1715    {
1716      $$ = exprNode_iter ($1, $6, $8, $9);
1717
1718    }
1719
1720 iterArgList
1721  : iterArgExpr { $$ = exprNodeList_singleton ($1); }
1722  | iterArgList { nextIterParam (); } TCOMMA iterArgExpr
1723    { $$ = exprNodeList_push ($1, $4); }
1724
1725 iterArgExpr
1726   : assignIterExpr  { $$ = exprNode_iterExpr ($1); }
1727   | id              { $$ = exprNode_iterId ($1); }
1728   | TYPE_NAME_OR_ID { uentry ue = coerceIterId ($1);
1729
1730                       if (uentry_isValid (ue))
1731                         {
1732                           $$ = exprNode_iterId (ue);
1733                         }
1734                       else
1735                         {
1736                           $$ = exprNode_iterNewId (cstring_copy (LastIdentifier ()));
1737                         }
1738                     }
1739   | NEW_IDENTIFIER  { $$ = exprNode_iterNewId ($1); }
1740
1741 /*
1742 ** everything is the same, EXCEPT it cannot be a NEW_IDENTIFIER
1743 */
1744
1745 cconstantExpr
1746  : CCONSTANT
1747  | cconstantExpr CCONSTANT { $$ = exprNode_combineLiterals ($1, $2); }
1748
1749 primaryIterExpr
1750  : cconstantExpr
1751  | TLPAREN expr TRPAREN { $$ = exprNode_addParens ($1, $2); }
1752
1753 postfixIterExpr
1754  : primaryIterExpr
1755  | postfixExpr TLSQBR expr TRSQBR { $$ = exprNode_arrayFetch ($1, $3); }
1756  | postfixExpr TLPAREN TRPAREN { $$ = exprNode_functionCall ($1, exprNodeList_new ()); }
1757  | postfixExpr TLPAREN argumentExprList TRPAREN { $$ = exprNode_functionCall ($1, $3); }
1758  | VA_ARG TLPAREN assignExpr TCOMMA typeExpression TRPAREN
1759        { $$ = exprNode_vaArg ($1, $3, $5); }
1760  | postfixExpr NotType TDOT newId IsType { $$ = exprNode_fieldAccess ($1, $3, $4); }
1761  | postfixExpr NotType ARROW_OP newId IsType { $$ = exprNode_arrowAccess ($1, $3, $4); }
1762  | postfixExpr INC_OP { $$ = exprNode_postOp ($1, $2); }
1763  | postfixExpr DEC_OP { $$ = exprNode_postOp ($1, $2); }
1764
1765 unaryIterExpr
1766  : postfixIterExpr
1767  | INC_OP unaryExpr    { $$ = exprNode_preOp ($2, $1); }
1768  | DEC_OP unaryExpr    { $$ = exprNode_preOp ($2, $1); }
1769  | TAMPERSAND castExpr { $$ = exprNode_preOp ($2, $1); }
1770  | TMULT castExpr      { $$ = exprNode_preOp ($2, $1); }
1771  | TPLUS castExpr      { $$ = exprNode_preOp ($2, $1); }
1772  | TMINUS castExpr     { $$ = exprNode_preOp ($2, $1); }
1773  | TTILDE castExpr     { $$ = exprNode_preOp ($2, $1); }
1774  | TEXCL castExpr      { $$ = exprNode_preOp ($2, $1); }
1775  | sizeofExpr          { $$ = $1; }
1776
1777 castIterExpr
1778  : unaryIterExpr
1779  | TLPAREN typeExpression TRPAREN castExpr { $$ = exprNode_cast ($1, $4, $2); }
1780
1781 timesIterExpr
1782  : castIterExpr
1783  | timesExpr TMULT castExpr { $$ = exprNode_op ($1, $3, $2); }
1784  | timesExpr TDIV castExpr { $$ = exprNode_op ($1, $3, $2); }
1785  | timesExpr TPERCENT castExpr { $$ = exprNode_op ($1, $3, $2); }
1786
1787 plusIterExpr
1788  : timesIterExpr
1789  | plusExpr TPLUS timesExpr { $$ = exprNode_op ($1, $3, $2); }
1790  | plusExpr TMINUS timesExpr { $$ = exprNode_op ($1, $3, $2); }
1791
1792 shiftIterExpr
1793  : plusIterExpr
1794  | shiftExpr LEFT_OP plusExpr { $$ = exprNode_op ($1, $3, $2); }
1795  | shiftExpr RIGHT_OP plusExpr { $$ = exprNode_op ($1, $3, $2); }
1796
1797 relationalIterExpr
1798  : shiftIterExpr
1799  | relationalExpr TLT shiftExpr { $$ = exprNode_op ($1, $3, $2); }
1800  | relationalExpr TGT shiftExpr { $$ = exprNode_op ($1, $3, $2); }
1801  | relationalExpr LE_OP shiftExpr { $$ = exprNode_op ($1, $3, $2); }
1802  | relationalExpr GE_OP shiftExpr { $$ = exprNode_op ($1, $3, $2); }
1803
1804 equalityIterExpr
1805  : relationalIterExpr
1806  | equalityExpr EQ_OP relationalExpr { $$ = exprNode_op ($1, $3, $2); }
1807  | equalityExpr NE_OP relationalExpr { $$ = exprNode_op ($1, $3, $2); }
1808
1809 bitandIterExpr
1810  : equalityIterExpr
1811  | bitandExpr TAMPERSAND equalityExpr { $$ = exprNode_op ($1, $3, $2); }
1812
1813 xorIterExpr
1814  : bitandIterExpr
1815  | xorExpr TCIRC bitandExpr { $$ = exprNode_op ($1, $3, $2); }
1816 ;
1817
1818 bitorIterExpr
1819  : xorIterExpr
1820  | bitorExpr TBAR xorExpr { $$ = exprNode_op ($1, $3, $2); }
1821
1822 andIterExpr
1823  : bitorIterExpr
1824  | andExpr AND_OP bitorExpr { $$ = exprNode_op ($1, $3, $2); }
1825
1826 orIterExpr
1827  : andIterExpr
1828  | orExpr OR_OP andExpr { $$ = exprNode_op ($1, $3, $2); }
1829
1830 conditionalIterExpr
1831  : orIterExpr
1832  | orExpr TQUEST { context_enterTrueClause ($1); }
1833    expr TCOLON { context_enterFalseClause ($1); } conditionalExpr
1834    { $$ = exprNode_cond ($1, $4, $7); }
1835
1836 assignIterExpr
1837  : conditionalIterExpr
1838  | unaryExpr TASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1839  | unaryExpr MUL_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1840  | unaryExpr DIV_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1841  | unaryExpr MOD_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1842  | unaryExpr ADD_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1843  | unaryExpr SUB_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1844  | unaryExpr LEFT_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1845  | unaryExpr RIGHT_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1846  | unaryExpr AND_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1847  | unaryExpr XOR_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1848  | unaryExpr OR_ASSIGN assignExpr { $$ = exprNode_assign ($1, $3, $2); }
1849
1850 endIter
1851  : ITER_ENDNAME { $$ = $1; }
1852  | /* empty */  { $$ = uentry_undefined; }
1853
1854 doHeader
1855  : DO { context_enterDoWhileClause (); $$ = $1; }
1856
1857 iterationStmt
1858  : whilePred stmt
1859    { $$ = exprNode_while ($1, $2); context_exitWhileClause ($1, $2); }
1860  | doHeader stmt WHILE TLPAREN expr TRPAREN TSEMI
1861    { $$ = exprNode_statement (exprNode_doWhile ($2, $5), $7); }
1862  | forPred stmt
1863    { $$ = exprNode_for ($1, $2); context_exitForClause ($1, $2); }
1864
1865 iterationStmtErr
1866  : whilePred stmtErr { $$ = exprNode_while ($1, $2); context_exitWhileClause ($1, $2); }
1867  | doHeader stmtErr WHILE TLPAREN expr TRPAREN TSEMI
1868    { $$ = exprNode_statement (exprNode_doWhile ($2, $5), $7); }
1869  | doHeader stmtErr WHILE TLPAREN expr TRPAREN
1870    { $$ = exprNode_doWhile ($2, $5); }
1871  | forPred stmtErr { $$ = exprNode_for ($1, $2); context_exitForClause ($1, $2); }
1872
1873 jumpStmt
1874  : GOTO newId TSEMI         { $$ = exprNode_goto ($2); }
1875  | CONTINUE TSEMI           { $$ = exprNode_continue ($1, BADTOK); }
1876  | QINNERCONTINUE CONTINUE TSEMI
1877                             { $$ = exprNode_continue ($1, QINNERCONTINUE); }
1878  | BREAK TSEMI              { $$ = exprNode_break ($1, BADTOK); }
1879  | QSWITCHBREAK BREAK TSEMI { $$ = exprNode_break ($2, QSWITCHBREAK); }
1880  | QLOOPBREAK BREAK TSEMI   { $$ = exprNode_break ($2, QLOOPBREAK); }
1881  | QINNERBREAK BREAK TSEMI  { $$ = exprNode_break ($2, QINNERBREAK); }
1882  | QSAFEBREAK BREAK TSEMI   { $$ = exprNode_break ($2, QSAFEBREAK); }
1883  | RETURN TSEMI             { $$ = exprNode_nullReturn ($1); }
1884  | RETURN expr TSEMI        { $$ = exprNode_return ($2); }
1885
1886 optSemi
1887  :
1888  | TSEMI { ; }
1889
1890 optComma
1891  :
1892  | TCOMMA { ; }
1893
1894 id
1895  : IDENTIFIER
1896
1897 newId
1898  : NEW_IDENTIFIER
1899  | ITER_NAME       { $$ = uentry_getName ($1); }
1900  | ITER_ENDNAME    { $$ = uentry_getName ($1); }
1901  | id              { $$ = uentry_getName ($1); }
1902  | TYPE_NAME_OR_ID { $$ = $1; }
1903
1904 typeName
1905  : TYPE_NAME
1906  | TYPE_NAME_OR_ID { $$ = ctype_unknown; }
1907  | CTYPEOF TLPAREN expr TRPAREN { $$ = exprNode_getType ($3); exprNode_free ($3); }
1908  | CTYPEOF TLPAREN typeExpression TRPAREN { $$ = qtype_getType ($3); }
1909
1910 %%
1911
1912 /*@-redecl@*/ /*@-namechecks@*/
1913 extern char *yytext;
1914 /*@=redecl@*/ /*@=namechecks@*/
1915
1916 # include "bison.reset"
1917
1918 void yyerror (/*@unused@*/ char *s)
1919 {
1920   static bool givehint = FALSE;
1921
1922   if (context_inIterDef ())
1923     {
1924       llerror (FLG_SYNTAX, message ("Iter syntax not parseable: %s",
1925                                     context_inFunctionName ()));
1926     }
1927   else if (context_inIterEnd ())
1928     {
1929       llerror (FLG_SYNTAX, message ("Iter finalizer syntax not parseable: %s",
1930                                     context_inFunctionName ()));
1931     }
1932   else if (context_inMacro ())
1933     {
1934       llerror (FLG_SYNTAX, message ("Macro syntax not parseable: %s",
1935                                     context_inFunctionName ()));
1936
1937       if (context_inUnknownMacro ())
1938         {
1939           if (!givehint)
1940             {
1941               llhint (cstring_makeLiteral
1942                      ("Precede macro definition with /*@notfunction@*/ "
1943                       "to suppress checking and force expansion"));
1944               givehint = TRUE;
1945             }
1946         }
1947
1948       swallowMacro ();
1949       context_exitAllClausesQuiet ();
1950     }
1951   else
1952     {
1953       llparseerror (cstring_undefined);
1954     }
1955 }
1956
1957
1958
1959
1960
1961
1962
1963
1964
1965
1966
1967