configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_PROG_CC
   5 AC_CANONICAL_HOST
   6
   7 # Checks for programs.
   8 AC_PROG_CPP
   9 AC_PROG_RANLIB
  10 AC_PROG_INSTALL
  11 AC_CHECK_PROG(AR, ar, ar)
  12 AC_PATH_PROG(PERL, perl)
  13 AC_SUBST(PERL)
  14 AC_PATH_PROG(ENT, ent)
  15 AC_SUBST(ENT)
  16 AC_PATH_PROGS(FILEPRIV, filepriv, true, /sbin:/usr/sbin)
  17
  18 if test -z "$AR" ; then
  19         AC_MSG_ERROR([*** 'ar' missing, please install or fix your \$PATH ***])
  20 fi
  21
  22 # Use LOGIN_PROGRAM from environment if possible
  23 if test ! -z "$LOGIN_PROGRAM" ; then
  24         AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM")
  25 else
  26         # Search for login
  27         AC_PATH_PROG(LOGIN_PROGRAM_FALLBACK, login)
  28         if test ! -z "$LOGIN_PROGRAM_FALLBACK" ; then
  29                 AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM_FALLBACK")
  30         fi
  31 fi
  32
  33 if test -z "$LD" ; then
  34         LD=$CC
  35 fi
  36 AC_SUBST(LD)
  37
  38 # C Compiler features
  39 AC_C_INLINE
  40 if test "$GCC" = "yes"; then
  41         CFLAGS="$CFLAGS -Wall"
  42 fi
  43
  44 # Check for some target-specific stuff
  45 case "$host" in
  46 *-*-aix*)
  47         AFS_LIBS="-lld"
  48         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
  49         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  50         if (test "$LD" != "gcc" && test -z "$blibpath"); then
  51                 blibpath="/usr/lib:/lib:/usr/local/lib"
  52         fi
  53         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)])
  54         AC_DEFINE(BROKEN_GETADDRINFO)
  55         MANTYPE='$(CATMAN)'
  56         mansubdir=cat
  57         dnl AIX handles lastlog as part of its login message
  58         AC_DEFINE(DISABLE_LASTLOG)
  59         MANTYPE='$(CATMAN)'
  60         mansubdir=cat
  61         ;;
  62 *-*-cygwin*)
  63         LIBS="$LIBS -lregex /usr/lib/textmode.o"
  64         AC_DEFINE(HAVE_CYGWIN)
  65         AC_DEFINE(DISABLE_PAM)
  66         AC_DEFINE(DISABLE_SHADOW)
  67         AC_DEFINE(IPV4_DEFAULT)
  68         AC_DEFINE(IP_TOS_IS_BROKEN)
  69         AC_DEFINE(BROKEN_VHANGUP)
  70         no_pam=1
  71         no_libsocket=1
  72         no_libnsl=1
  73         ;;
  74 *-*-hpux10*)
  75         if test -z "$GCC"; then
  76                 CFLAGS="$CFLAGS -Ae"
  77         fi
  78         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE"
  79         IPADDR_IN_DISPLAY=yes
  80         AC_DEFINE(USE_PIPES)
  81         AC_DEFINE(DISABLE_SHADOW)
  82         AC_DEFINE(DISABLE_UTMP)
  83         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
  84         LIBS="$LIBS -lsec"
  85         MANTYPE='$(CATMAN)'
  86         mansubdir=cat
  87         ;;
  88 *-*-hpux11*)
  89         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE"
  90         IPADDR_IN_DISPLAY=yes
  91         AC_DEFINE(PAM_SUN_CODEBASE)
  92         AC_DEFINE(USE_PIPES)
  93         AC_DEFINE(DISABLE_SHADOW)
  94         AC_DEFINE(DISABLE_UTMP)
  95         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
  96         LIBS="$LIBS -lsec"
  97         MANTYPE='$(CATMAN)'
  98         mansubdir=cat
  99         ;;
 100 *-*-irix5*)
 101         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 102         LDFLAGS="$LDFLAGS"
 103         PATH="$PATH:/usr/etc"
 104         MANTYPE='$(CATMAN)'
 105         no_libsocket=1
 106         no_libnsl=1
 107         AC_DEFINE(BROKEN_INET_NTOA)
 108         ;;
 109 *-*-irix6*)
 110         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 111         LDFLAGS="$LDFLAGS"
 112         PATH="$PATH:/usr/etc"
 113         MANTYPE='$(CATMAN)'
 114         AC_DEFINE(WITH_IRIX_ARRAY)
 115         AC_DEFINE(WITH_IRIX_PROJECT)
 116         AC_DEFINE(WITH_IRIX_AUDIT)
 117         AC_CHECK_FUNC(jlimit_startjob, [AC_DEFINE(WITH_IRIX_JOBS)])
 118         no_libsocket=1
 119         no_libnsl=1
 120         AC_DEFINE(BROKEN_INET_NTOA)
 121         mansubdir=man
 122         ;;
 123 *-*-linux*)
 124         no_dev_ptmx=1
 125         AC_DEFINE(DONT_TRY_OTHER_AF)
 126         AC_DEFINE(PAM_TTY_KLUDGE)
 127         inet6_default_4in6=yes
 128         ;;
 129 mips-sony-bsd|mips-sony-newsos4)
 130         AC_DEFINE(HAVE_NEWS4)
 131         SONY=1
 132         AC_CHECK_LIB(iberty, xatexit, AC_DEFINE(HAVE_XATEXIT),
 133                 AC_MSG_ERROR([*** libiberty missing - please install first ***])
 134         )
 135         ;;
 136 *-*-netbsd*)
 137         need_dash_r=1
 138         ;;
 139 *-next-*)
 140         conf_lastlog_location="/usr/adm/lastlog"
 141         conf_utmp_location=/etc/utmp
 142         conf_wtmp_location=/usr/adm/wtmp
 143         MAIL=/usr/spool/mail
 144         AC_DEFINE(HAVE_NEXT)
 145         AC_DEFINE(BROKEN_REALPATH)
 146         AC_DEFINE(USE_PIPES)
 147         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 148         CFLAGS="$CFLAGS"
 149         ;;
 150 *-*-solaris*)
 151         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 152         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib -L/usr/ucblib -R/usr/ucblib"
 153         need_dash_r=1
 154         AC_DEFINE(PAM_SUN_CODEBASE)
 155         # hardwire lastlog location (can't detect it on some versions)
 156         conf_lastlog_location="/var/adm/lastlog"
 157         AC_MSG_CHECKING(for obsolete utmp and wtmp in solaris2.x)
 158         sol2ver=`echo "$host"| sed -e 's/.*[[0-9]]\.//'`
 159         if test "$sol2ver" -ge 8; then
 160                 AC_MSG_RESULT(yes)
 161                 AC_DEFINE(DISABLE_UTMP)
 162                 AC_DEFINE(DISABLE_WTMP)
 163         else
 164                 AC_MSG_RESULT(no)
 165         fi
 166         ;;
 167 *-*-sunos4*)
 168         CPPFLAGS="$CPPFLAGS -DSUNOS4"
 169         AC_CHECK_FUNCS(getpwanam)
 170         AC_DEFINE(PAM_SUN_CODEBASE)
 171         conf_utmp_location=/etc/utmp
 172         conf_wtmp_location=/var/adm/wtmp
 173         conf_lastlog_location=/var/adm/lastlog
 174         AC_DEFINE(USE_PIPES)
 175         MANTYPE='$(CATMAN)'
 176         mansubdir=cat
 177         ;;
 178 *-sni-sysv*)
 179         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 180         LDFLAGS="$LDFLAGS -L/usr/local/lib -L/usr/ucblib"
 181         MANTYPE='$(CATMAN)'
 182         AC_DEFINE(IP_TOS_IS_BROKEN)
 183         mansubdir=cat
 184         LIBS="$LIBS -lgen -lnsl -lucb"
 185         ;;
 186 *-*-sysv4.2*)
 187         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 188         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 189         MANTYPE='$(CATMAN)'
 190         mansubdir=cat
 191         enable_suid_ssh=no
 192         ;;
 193 *-*-sysv5*)
 194         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 195         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 196         MANTYPE='$(CATMAN)'
 197         mansubdir=cat
 198         enable_suid_ssh=no
 199         ;;
 200 *-*-sysv*)
 201         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 202         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 203         MANTYPE='$(CATMAN)'
 204         mansubdir=cat
 205         LIBS="$LIBS -lgen -lsocket"
 206         ;;
 207 *-*-sco3.2v4*)
 208         AC_DEFINE(USE_PIPES)
 209         CPPFLAGS="$CPPFLAGS -Dftruncate=chsize -I/usr/local/include"
 210         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 211         MANTYPE='$(CATMAN)'
 212         mansubdir=cat
 213         LIBS="$LIBS -lgen -lsocket -los -lprot -lx -ltinfo -lm"
 214         no_dev_ptmx=1
 215         RANLIB=true
 216         AC_DEFINE(BROKEN_SYS_TERMIO_H)
 217         rsh_path="/usr/bin/rcmd"
 218         AC_DEFINE(HAVE_SCO_PROTECTED_PW)
 219         AC_DEFINE(DISABLE_SHADOW)
 220         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 221         ;;
 222 *-*-sco3.2v5*)
 223         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 224         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 225         MANTYPE='$(CATMAN)'
 226         mansubdir=cat
 227         LIBS="$LIBS -lprot -lx -ltinfo -lm"
 228         no_dev_ptmx=1
 229         rsh_path="/usr/bin/rcmd"
 230         AC_DEFINE(HAVE_SCO_PROTECTED_PW)
 231         AC_DEFINE(DISABLE_SHADOW)
 232         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 233         ;;
 234 *-dec-osf*)
 235 # This is untested
 236         if test ! -z "USE_SIA" ; then
 237                 AC_MSG_CHECKING(for Digital Unix Security Integration Architecture)
 238                 if test -f /etc/sia/matrix.conf; then
 239                         AC_MSG_RESULT(yes)
 240                         AC_DEFINE(HAVE_OSF_SIA)
 241                         AC_DEFINE(DISABLE_LOGIN)
 242                         LIBS="$LIBS -lsecurity -ldb -lm -laud"
 243                 else
 244                         AC_MSG_RESULT(no)
 245                 fi
 246         fi
 247         ;;
 248 esac
 249
 250 # Allow user to specify flags
 251 AC_ARG_WITH(cflags,
 252         [  --with-cflags           Specify additional flags to pass to compiler],
 253         [
 254                 if test "x$withval" != "xno" ; then
 255                         CFLAGS="$CFLAGS $withval"
 256                 fi
 257         ]
 258 )
 259 AC_ARG_WITH(cppflags,
 260         [  --with-cppflags         Specify additional flags to pass to preprocessor] ,
 261         [
 262                 if test "x$withval" != "xno"; then
 263                         CPPFLAGS="$CPPFLAGS $withval"
 264                 fi
 265         ]
 266 )
 267 AC_ARG_WITH(ldflags,
 268         [  --with-ldflags          Specify additional flags to pass to linker],
 269         [
 270                 if test "x$withval" != "xno" ; then
 271                         LDFLAGS="$LDFLAGS $withval"
 272                 fi
 273         ]
 274 )
 275 AC_ARG_WITH(libs,
 276         [  --with-libs             Specify additional libraries to link with],
 277         [
 278                 if test "x$withval" != "xno" ; then
 279                         LIBS="$LIBS $withval"
 280                 fi
 281         ]
 282 )
 283
 284
 285 # Checks for libraries.
 286 if test -z "$no_libsocket" ; then
 287         AC_CHECK_LIB(nsl, yp_match, , )
 288 fi
 289 if test -z "$no_libnsl" ; then
 290         AC_CHECK_LIB(socket, main, , )
 291 fi
 292
 293 AC_CHECK_LIB(gen, getspnam, LIBS="$LIBS -lgen")
 294 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
 295 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
 296
 297 AC_CHECK_FUNC(regcomp,
 298         [],
 299         [
 300                 AC_CHECK_LIB(pcre, pcre_info,
 301                         AC_DEFINE(HAVE_LIBPCRE) LIBS="$LIBS -lpcreposix -lpcre")
 302         ]
 303 )
 304
 305 dnl UnixWare 2.x
 306 AC_CHECK_FUNC(strcasecmp,
 307         [], [ AC_CHECK_LIB(resolv, strcasecmp, LIBS="$LIBS -lresolv") ]
 308 )
 309 AC_CHECK_FUNC(utimes,
 310         [], [ AC_CHECK_LIB(c89, utimes, LIBS="$LIBS -lc89") ]
 311 )
 312
 313 # Checks for header files.
 314 AC_CHECK_HEADERS(bstring.h endian.h floatingpoint.h getopt.h lastlog.h limits.h login.h login_cap.h maillock.h netdb.h netgroup.h netinet/in_systm.h paths.h poll.h pty.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/queue.h sys/select.h sys/stat.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h sys/un.h stddef.h time.h ttyent.h usersec.h util.h utmp.h utmpx.h vis.h)
 315
 316 dnl    Checks for library functions.
 317 AC_CHECK_FUNCS(arc4random atexit b64_ntop bcopy bindresvport_af clock fchmod freeaddrinfo futimes gai_strerror getcwd getaddrinfo getnameinfo getrlimit getrusage getttyent inet_aton inet_ntoa innetgr login_getcapbool md5_crypt memmove mkdtemp on_exit openpty realpath rresvport_af setdtablesize setenv seteuid setlogin setproctitle setreuid setrlimit setsid sigaction sigvec snprintf strerror strlcat strlcpy strsep strtok_r sysconf vsnprintf vhangup vis waitpid _getpty __b64_ntop)
 318 dnl    Checks for time functions
 319 AC_CHECK_FUNCS(gettimeofday time)
 320 dnl    Checks for libutil functions
 321 AC_CHECK_HEADERS(libutil.h)
 322 AC_CHECK_FUNCS(login logout updwtmp logwtmp)
 323 dnl    Checks for utmp functions
 324 AC_CHECK_FUNCS(endutent getutent getutid getutline pututline setutent)
 325 AC_CHECK_FUNCS(utmpname)
 326 dnl    Checks for utmpx functions
 327 AC_CHECK_FUNCS(endutxent getutxent getutxid getutxline pututxline )
 328 AC_CHECK_FUNCS(setutxent utmpxname)
 329
 330 AC_CHECK_FUNC(getuserattr,
 331         [AC_DEFINE(HAVE_GETUSERATTR)],
 332         [AC_CHECK_LIB(s, getuserattr, [LIBS="$LIBS -ls"; AC_DEFINE(HAVE_GETUSERATTR)])]
 333 )
 334
 335 AC_CHECK_FUNC(login,
 336         [AC_DEFINE(HAVE_LOGIN)],
 337         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 338 )
 339
 340 AC_CHECK_FUNC(daemon,
 341         [AC_DEFINE(HAVE_DAEMON)],
 342         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 343 )
 344
 345 AC_CHECK_FUNC(getpagesize,
 346         [AC_DEFINE(HAVE_GETPAGESIZE)],
 347         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 348 )
 349
 350 # Check for broken snprintf
 351 if test "x$ac_cv_func_snprintf" = "xyes" ; then
 352         AC_MSG_CHECKING([whether snprintf correctly terminates long strings])
 353         AC_TRY_RUN(
 354                 [
 355 #include <stdio.h>
 356 int main(void){char b[5];snprintf(b,5,"123456789");return(b[4]!='\0');}
 357                 ],
 358                 [AC_MSG_RESULT(yes)],
 359                 [
 360                         AC_MSG_RESULT(no)
 361                         AC_DEFINE(BROKEN_SNPRINTF)
 362                         AC_MSG_WARN([****** Your snprintf() function is broken, complain to your vendor])
 363                 ]
 364         )
 365 fi
 366
 367 AC_FUNC_GETPGRP
 368
 369 PAM_MSG="no"
 370 AC_ARG_WITH(pam,
 371         [  --without-pam           Disable PAM support ],
 372         [
 373                 if test "x$withval" = "xno" ; then
 374                         no_pam=1
 375                         AC_DEFINE(DISABLE_PAM)
 376                         PAM_MSG="disabled"
 377                 fi
 378         ]
 379 )
 380 if (test -z "$no_pam" && test "x$ac_cv_header_security_pam_appl_h" = "xyes") ; then
 381         AC_CHECK_LIB(dl, dlopen, , )
 382         LIBS="$LIBS -lpam"
 383
 384         AC_CHECK_FUNCS(pam_getenvlist)
 385
 386         disable_shadow=yes
 387
 388         PAM_MSG="yes"
 389
 390         # Check PAM strerror arguments (old PAM)
 391         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 392         AC_TRY_COMPILE(
 393                 [
 394 #include <stdlib.h>
 395 #include <security/pam_appl.h>
 396                 ],
 397                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 398                 [AC_MSG_RESULT(no)],
 399                 [
 400                         AC_DEFINE(HAVE_OLD_PAM)
 401                         AC_MSG_RESULT(yes)
 402                         PAM_MSG="yes (old library)"
 403                 ]
 404         )
 405 fi
 406
 407 # The big search for OpenSSL
 408 AC_ARG_WITH(ssl-dir,
 409         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 410         [
 411                 if test "x$withval" != "xno" ; then
 412                         tryssldir=$withval
 413                 fi
 414         ]
 415 )
 416
 417 saved_LIBS="$LIBS"
 418 saved_LDFLAGS="$LDFLAGS"
 419 saved_CPPFLAGS="$CPPFLAGS"
 420 if test "x$prefix" != "xNONE" ; then
 421         tryssldir="$tryssldir $prefix"
 422 fi
 423 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 424
 425         for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 426                 if test ! -z "$ssldir" ; then
 427                         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 428                         CPPFLAGS="$saved_CPPFLAGS -I$ssldir/include"
 429                         if test ! -z "$need_dash_r" ; then
 430                                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 431                         fi
 432                 else
 433                         LDFLAGS="$saved_LDFLAGS"
 434                 fi
 435
 436                 LIBS="$saved_LIBS -lcrypto"
 437
 438                 # Basic test to check for compatible version and correct linking
 439                 # *does not* test for RSA - that comes later.
 440                 AC_TRY_RUN(
 441                         [
 442 #include <string.h>
 443 #include <openssl/rand.h>
 444 int main(void)
 445 {
 446         char a[2048];
 447         memset(a, 0, sizeof(a));
 448         RAND_add(a, sizeof(a), sizeof(a));
 449         return(RAND_status() <= 0);
 450 }
 451                         ],
 452                         [
 453                                 found_crypto=1
 454                                 break;
 455                         ], []
 456                 )
 457
 458                 if test ! -z "$found_crypto" ; then
 459                         break;
 460                 fi
 461         done
 462
 463         if test -z "$found_crypto" ; then
 464                 AC_MSG_ERROR([Could not find working SSLeay / OpenSSL libraries, please install])
 465         fi
 466         if test -z "$ssldir" ; then
 467                 ssldir="(system)"
 468         fi
 469
 470         ac_cv_openssldir=$ssldir
 471 ])
 472
 473 if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ; then
 474         AC_DEFINE(HAVE_OPENSSL)
 475         dnl Need to recover ssldir - test above runs in subshell
 476         ssldir=$ac_cv_openssldir
 477         CPPFLAGS="$saved_CPPFLAGS -I$ssldir/include"
 478         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 479         if test ! -z "$need_dash_r" ; then
 480                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 481         fi
 482         if test ! -z "$blibpath" ; then
 483                 blibpath="$blibpath:$ssldir:$ssldir/lib"
 484         fi
 485 fi
 486 LIBS="$saved_LIBS -lcrypto"
 487
 488 # Now test RSA support
 489 saved_LIBS="$LIBS"
 490 AC_MSG_CHECKING([for RSA support])
 491 for WANTS_RSAREF in "" 1 ; do
 492         if test -z "$WANTS_RSAREF" ; then
 493                 LIBS="$saved_LIBS"
 494         else
 495                 LIBS="$saved_LIBS -lRSAglue -lrsaref"
 496         fi
 497         AC_TRY_RUN([
 498 #include <string.h>
 499 #include <openssl/rand.h>
 500 #include <openssl/rsa.h>
 501 #include <openssl/bn.h>
 502 #include <openssl/sha.h>
 503 int main(void)
 504 {
 505         int num; RSA *key; static unsigned char p_in[] = "blahblah";
 506         unsigned char c[256], p[256];
 507         memset(c, 0, sizeof(c)); RAND_add(c, sizeof(c), sizeof(c));
 508         if ((key=RSA_generate_key(512, 3, NULL, NULL))==NULL) return(1);
 509         num = RSA_public_encrypt(sizeof(p_in) - 1, p_in, c, key, RSA_PKCS1_PADDING);
 510         return(-1 == RSA_private_decrypt(num, c, p, key, RSA_PKCS1_PADDING));
 511 }
 512         ],
 513         [
 514                 rsa_works=1
 515                 break;
 516         ], [])
 517 done
 518
 519 if test ! -z "$no_rsa" ; then
 520         AC_MSG_RESULT(disabled)
 521         RSA_MSG="disabled"
 522 else
 523         if test -z "$rsa_works" ; then
 524                 AC_MSG_WARN([*** No RSA support found *** ])
 525                 RSA_MSG="no"
 526         else
 527                 if test -z "$WANTS_RSAREF" ; then
 528                         AC_MSG_RESULT(yes)
 529                         RSA_MSG="yes"
 530                 else
 531                         RSA_MSG="yes (using RSAref)"
 532                         AC_MSG_RESULT(using RSAref)
 533                         LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 534                 fi
 535         fi
 536 fi
 537
 538 # Cheap hack to ensure NEWS-OS libraries are arranged right.
 539 if test ! -z "$SONY" ; then
 540   LIBS="$LIBS -liberty";
 541 fi
 542
 543 # Checks for data types
 544 AC_CHECK_SIZEOF(char, 1)
 545 AC_CHECK_SIZEOF(short int, 2)
 546 AC_CHECK_SIZEOF(int, 4)
 547 AC_CHECK_SIZEOF(long int, 4)
 548 AC_CHECK_SIZEOF(long long int, 8)
 549
 550 # More checks for data types
 551 AC_CACHE_CHECK([for u_int type], ac_cv_have_u_int, [
 552         AC_TRY_COMPILE(
 553                 [ #include <sys/types.h> ],
 554                 [ u_int a; a = 1;],
 555                 [ ac_cv_have_u_int="yes" ],
 556                 [ ac_cv_have_u_int="no" ]
 557         )
 558 ])
 559 if test "x$ac_cv_have_u_int" = "xyes" ; then
 560         AC_DEFINE(HAVE_U_INT)
 561         have_u_int=1
 562 fi
 563
 564 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
 565         AC_TRY_COMPILE(
 566                 [ #include <sys/types.h> ],
 567                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
 568                 [ ac_cv_have_intxx_t="yes" ],
 569                 [ ac_cv_have_intxx_t="no" ]
 570         )
 571 ])
 572 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
 573         AC_DEFINE(HAVE_INTXX_T)
 574         have_intxx_t=1
 575 fi
 576
 577 AC_CACHE_CHECK([for int64_t type], ac_cv_have_int64_t, [
 578         AC_TRY_COMPILE(
 579                 [ #include <sys/types.h> ],
 580                 [ int64_t a; a = 1;],
 581                 [ ac_cv_have_int64_t="yes" ],
 582                 [ ac_cv_have_int64_t="no" ]
 583         )
 584 ])
 585 if test "x$ac_cv_have_int64_t" = "xyes" ; then
 586         AC_DEFINE(HAVE_INT64_T)
 587         have_int64_t=1
 588 fi
 589
 590 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
 591         AC_TRY_COMPILE(
 592                 [ #include <sys/types.h> ],
 593                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
 594                 [ ac_cv_have_u_intxx_t="yes" ],
 595                 [ ac_cv_have_u_intxx_t="no" ]
 596         )
 597 ])
 598 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
 599         AC_DEFINE(HAVE_U_INTXX_T)
 600         have_u_intxx_t=1
 601 fi
 602
 603 AC_CACHE_CHECK([for u_int64_t types], ac_cv_have_u_int64_t, [
 604         AC_TRY_COMPILE(
 605                 [ #include <sys/types.h> ],
 606                 [ u_int64_t a; a = 1;],
 607                 [ ac_cv_have_u_int64_t="yes" ],
 608                 [ ac_cv_have_u_int64_t="no" ]
 609         )
 610 ])
 611 if test "x$ac_cv_have_u_int64_t" = "xyes" ; then
 612         AC_DEFINE(HAVE_U_INT64_T)
 613         have_u_int64_t=1
 614 fi
 615
 616 if (test -z "$have_u_intxx_t" || test -z "$have_intxx_t" && \
 617            test "x$ac_cv_header_sys_bitypes_h" = "xyes")
 618 then
 619         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 620         AC_TRY_COMPILE(
 621                 [
 622 #include <sys/bitypes.h>
 623                 ],
 624                 [
 625                         int8_t a; int16_t b; int32_t c;
 626                         u_int8_t e; u_int16_t f; u_int32_t g;
 627                         a = b = c = e = f = g = 1;
 628                 ],
 629                 [
 630                         AC_DEFINE(HAVE_U_INTXX_T)
 631                         AC_DEFINE(HAVE_INTXX_T)
 632                         AC_MSG_RESULT(yes)
 633                 ],
 634                 [AC_MSG_RESULT(no)]
 635         )
 636 fi
 637
 638 if test -z "$have_u_intxx_t" ; then
 639         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
 640                 AC_TRY_COMPILE(
 641                         [
 642 #include <sys/types.h>
 643                         ],
 644                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
 645                         [ ac_cv_have_uintxx_t="yes" ],
 646                         [ ac_cv_have_uintxx_t="no" ]
 647                 )
 648         ])
 649         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
 650                 AC_DEFINE(HAVE_UINTXX_T)
 651         fi
 652 fi
 653
 654 AC_CACHE_CHECK([for socklen_t], ac_cv_have_socklen_t, [
 655         AC_TRY_COMPILE(
 656                 [
 657 #include <sys/types.h>
 658 #include <sys/socket.h>
 659                 ],
 660                 [socklen_t foo; foo = 1235;],
 661                 [ ac_cv_have_socklen_t="yes" ],
 662                 [ ac_cv_have_socklen_t="no" ]
 663         )
 664 ])
 665 if test "x$ac_cv_have_socklen_t" = "xyes" ; then
 666         AC_DEFINE(HAVE_SOCKLEN_T)
 667 fi
 668
 669 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
 670         AC_TRY_COMPILE(
 671                 [
 672 #include <sys/types.h>
 673                 ],
 674                 [ size_t foo; foo = 1235; ],
 675                 [ ac_cv_have_size_t="yes" ],
 676                 [ ac_cv_have_size_t="no" ]
 677         )
 678 ])
 679 if test "x$ac_cv_have_size_t" = "xyes" ; then
 680         AC_DEFINE(HAVE_SIZE_T)
 681 fi
 682
 683 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
 684         AC_TRY_COMPILE(
 685                 [
 686 #include <sys/types.h>
 687                 ],
 688                 [ ssize_t foo; foo = 1235; ],
 689                 [ ac_cv_have_ssize_t="yes" ],
 690                 [ ac_cv_have_ssize_t="no" ]
 691         )
 692 ])
 693 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
 694         AC_DEFINE(HAVE_SSIZE_T)
 695 fi
 696
 697 AC_CACHE_CHECK([for clock_t], ac_cv_have_clock_t, [
 698         AC_TRY_COMPILE(
 699                 [
 700 #include <time.h>
 701                 ],
 702                 [ clock_t foo; foo = 1235; ],
 703                 [ ac_cv_have_clock_t="yes" ],
 704                 [ ac_cv_have_clock_t="no" ]
 705         )
 706 ])
 707 if test "x$ac_cv_have_clock_t" = "xyes" ; then
 708         AC_DEFINE(HAVE_CLOCK_T)
 709 fi
 710
 711 AC_CACHE_CHECK([for sa_family_t], ac_cv_have_sa_family_t, [
 712         AC_TRY_COMPILE(
 713                 [
 714 #include <sys/types.h>
 715 #include <sys/socket.h>
 716                 ],
 717                 [ sa_family_t foo; foo = 1235; ],
 718                 [ ac_cv_have_sa_family_t="yes" ],
 719                 [ AC_TRY_COMPILE(
 720                   [
 721 #include <sys/types.h>
 722 #include <sys/socket.h>
 723 #include <netinet/in.h>
 724                 ],
 725                 [ sa_family_t foo; foo = 1235; ],
 726                 [ ac_cv_have_sa_family_t="yes" ],
 727
 728                 [ ac_cv_have_sa_family_t="no" ]
 729         )]
 730         )
 731 ])
 732 if test "x$ac_cv_have_sa_family_t" = "xyes" ; then
 733         AC_DEFINE(HAVE_SA_FAMILY_T)
 734 fi
 735
 736 AC_CACHE_CHECK([for pid_t], ac_cv_have_pid_t, [
 737         AC_TRY_COMPILE(
 738                 [
 739 #include <sys/types.h>
 740                 ],
 741                 [ pid_t foo; foo = 1235; ],
 742                 [ ac_cv_have_pid_t="yes" ],
 743                 [ ac_cv_have_pid_t="no" ]
 744         )
 745 ])
 746 if test "x$ac_cv_have_pid_t" = "xyes" ; then
 747         AC_DEFINE(HAVE_PID_T)
 748 fi
 749
 750 AC_CACHE_CHECK([for mode_t], ac_cv_have_mode_t, [
 751         AC_TRY_COMPILE(
 752                 [
 753 #include <sys/types.h>
 754                 ],
 755                 [ mode_t foo; foo = 1235; ],
 756                 [ ac_cv_have_mode_t="yes" ],
 757                 [ ac_cv_have_mode_t="no" ]
 758         )
 759 ])
 760 if test "x$ac_cv_have_mode_t" = "xyes" ; then
 761         AC_DEFINE(HAVE_MODE_T)
 762 fi
 763
 764
 765 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
 766         AC_TRY_COMPILE(
 767                 [
 768 #include <sys/types.h>
 769 #include <sys/socket.h>
 770                 ],
 771                 [ struct sockaddr_storage s; ],
 772                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
 773                 [ ac_cv_have_struct_sockaddr_storage="no" ]
 774         )
 775 ])
 776 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
 777         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 778 fi
 779
 780 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
 781         AC_TRY_COMPILE(
 782                 [
 783 #include <sys/types.h>
 784 #include <netinet/in.h>
 785                 ],
 786                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
 787                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
 788                 [ ac_cv_have_struct_sockaddr_in6="no" ]
 789         )
 790 ])
 791 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
 792         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 793 fi
 794
 795 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
 796         AC_TRY_COMPILE(
 797                 [
 798 #include <sys/types.h>
 799 #include <netinet/in.h>
 800                 ],
 801                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
 802                 [ ac_cv_have_struct_in6_addr="yes" ],
 803                 [ ac_cv_have_struct_in6_addr="no" ]
 804         )
 805 ])
 806 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
 807         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 808 fi
 809
 810 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
 811         AC_TRY_COMPILE(
 812                 [
 813 #include <sys/types.h>
 814 #include <sys/socket.h>
 815 #include <netdb.h>
 816                 ],
 817                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
 818                 [ ac_cv_have_struct_addrinfo="yes" ],
 819                 [ ac_cv_have_struct_addrinfo="no" ]
 820         )
 821 ])
 822 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
 823         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 824 fi
 825
 826 # If we don't have int64_t then we can't compile sftp-server.  So don't
 827 # even attempt to do it.
 828 if test "x$ac_cv_have_int64_t" = "xno" -a \
 829         "x$ac_cv_sizeof_long_int" != "x8" -a \
 830         "x$ac_cv_sizeof_long_long_int" = "x0" ; then
 831         NO_SFTP='#'
 832         AC_SUBST(NO_SFTP)
 833 fi
 834
 835 dnl Checks for structure members
 836 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
 837 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
 838 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
 839 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
 840 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
 841 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
 842 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
 843 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
 844 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmpx.h, HAVE_ID_IN_UTMPX)
 845 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
 846 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
 847 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
 848 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
 849 OSSH_CHECK_HEADER_FOR_FIELD(ut_exit, utmp.h, HAVE_EXIT_IN_UTMP)
 850 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmp.h, HAVE_TIME_IN_UTMP)
 851 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmpx.h, HAVE_TIME_IN_UTMPX)
 852 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmpx.h, HAVE_TV_IN_UTMPX)
 853 AC_STRUCT_ST_BLKSIZE
 854
 855 AC_CACHE_CHECK([for sun_len field in struct sockaddr_un],
 856                 ac_cv_have_sun_len_in_struct_sockaddr_un, [
 857         AC_TRY_COMPILE(
 858                 [
 859 #include <sys/types.h>
 860 #include <sys/socket.h>
 861                 ],
 862                 [ struct sockaddr_un s; s.sun_len = 1; ],
 863                 [ ac_cv_have_sun_len_in_struct_sockaddr_un="yes" ],
 864                 [ ac_cv_have_sun_len_in_struct_sockaddr_un="no" ],
 865         )
 866 ])
 867 if test "x$ac_cv_have_sun_len_in_struct_sockaddr_un" = "xyes" ; then
 868         AC_DEFINE(HAVE_SUN_LEN_IN_SOCKADDR_UN)
 869 fi
 870
 871 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
 872                 ac_cv_have_ss_family_in_struct_ss, [
 873         AC_TRY_COMPILE(
 874                 [
 875 #include <sys/types.h>
 876 #include <sys/socket.h>
 877                 ],
 878                 [ struct sockaddr_storage s; s.ss_family = 1; ],
 879                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
 880                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
 881         )
 882 ])
 883 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
 884         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 885 fi
 886
 887 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
 888                 ac_cv_have___ss_family_in_struct_ss, [
 889         AC_TRY_COMPILE(
 890                 [
 891 #include <sys/types.h>
 892 #include <sys/socket.h>
 893                 ],
 894                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
 895                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
 896                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
 897         )
 898 ])
 899 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
 900         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 901 fi
 902
 903 AC_CACHE_CHECK([for pw_class field in struct passwd],
 904                 ac_cv_have_pw_class_in_struct_passwd, [
 905         AC_TRY_COMPILE(
 906                 [
 907 #include <pwd.h>
 908                 ],
 909                 [ struct passwd p; p.pw_class = 0; ],
 910                 [ ac_cv_have_pw_class_in_struct_passwd="yes" ],
 911                 [ ac_cv_have_pw_class_in_struct_passwd="no" ]
 912         )
 913 ])
 914 if test "x$ac_cv_have_pw_class_in_struct_passwd" = "xyes" ; then
 915         AC_DEFINE(HAVE_PW_CLASS_IN_PASSWD)
 916 fi
 917
 918
 919 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
 920         AC_TRY_LINK([],
 921                 [ extern char *__progname; printf("%s", __progname); ],
 922                 [ ac_cv_libc_defines___progname="yes" ],
 923                 [ ac_cv_libc_defines___progname="no" ]
 924         )
 925 ])
 926 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
 927         AC_DEFINE(HAVE___PROGNAME)
 928 fi
 929
 930
 931 AC_CACHE_CHECK([if libc defines sys_errlist], ac_cv_libc_defines_sys_errlist, [
 932         AC_TRY_LINK([],
 933                 [ extern const char *const sys_errlist[]; printf("%s", sys_errlist[0]);],
 934                 [ ac_cv_libc_defines_sys_errlist="yes" ],
 935                 [ ac_cv_libc_defines_sys_errlist="no" ]
 936         )
 937 ])
 938 if test "x$ac_cv_libc_defines_sys_errlist" = "xyes" ; then
 939         AC_DEFINE(HAVE_SYS_ERRLIST)
 940 fi
 941
 942
 943 AC_CACHE_CHECK([if libc defines sys_nerr], ac_cv_libc_defines_sys_nerr, [
 944         AC_TRY_LINK([],
 945                 [ extern int sys_nerr; printf("%i", sys_nerr);],
 946                 [ ac_cv_libc_defines_sys_nerr="yes" ],
 947                 [ ac_cv_libc_defines_sys_nerr="no" ]
 948         )
 949 ])
 950 if test "x$ac_cv_libc_defines_sys_nerr" = "xyes" ; then
 951         AC_DEFINE(HAVE_SYS_NERR)
 952 fi
 953
 954
 955 # Looking for programs, paths and files
 956 AC_ARG_WITH(rsh,
 957         [  --with-rsh=PATH         Specify path to remote shell program ],
 958         [
 959                 if test "x$withval" != "$no" ; then
 960                         rsh_path=$withval
 961                 fi
 962         ],
 963         [
 964                 AC_PATH_PROG(rsh_path, rsh)
 965         ]
 966 )
 967
 968 AC_ARG_WITH(xauth,
 969         [  --with-xauth=PATH       Specify path to xauth program ],
 970         [
 971                 if test "x$withval" != "xno" ; then
 972                         xauth_path=$withval
 973                 fi
 974         ],
 975         [
 976                 AC_PATH_PROG(xauth_path, xauth,,$PATH:/usr/X/bin:/usr/bin/X11:/usr/X11R6/bin:/usr/openwin/bin)
 977                 if (test ! -z "$xauth_path" && test -x "/usr/openwin/bin/xauth") ; then
 978                         xauth_path="/usr/openwin/bin/xauth"
 979                 fi
 980         ]
 981 )
 982
 983 if test -z "$xauth_path" ; then
 984         XAUTH_PATH="undefined"
 985         AC_SUBST(XAUTH_PATH)
 986 else
 987         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
 988         XAUTH_PATH=$xauth_path
 989         AC_SUBST(XAUTH_PATH)
 990 fi
 991 if test ! -z "$rsh_path" ; then
 992         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
 993 fi
 994
 995 # Check for mail directory (last resort if we cannot get it from headers)
 996 if test ! -z "$MAIL" ; then
 997         maildir=`dirname $MAIL`
 998         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
 999 fi
1000
1001 if test -z "$no_dev_ptmx" ; then
1002         AC_CHECK_FILE("/dev/ptmx",
1003                 [
1004                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
1005                         have_dev_ptmx=1
1006                 ]
1007         )
1008 fi
1009 AC_CHECK_FILE("/dev/ptc",
1010         [
1011                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
1012                 have_dev_ptc=1
1013         ]
1014 )
1015
1016 # Options from here on. Some of these are preset by platform above
1017
1018 # Check for user-specified random device, otherwise check /dev/urandom
1019 AC_ARG_WITH(random,
1020         [  --with-random=FILE      read randomness from FILE (default=/dev/urandom)],
1021         [
1022                 if test "x$withval" != "xno" ; then
1023                         RANDOM_POOL="$withval";
1024                         AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
1025                 fi
1026         ],
1027         [
1028                 # Check for random device
1029                 AC_CHECK_FILE("/dev/urandom",
1030                         [
1031                                 RANDOM_POOL="/dev/urandom";
1032                                 AC_SUBST(RANDOM_POOL)
1033                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
1034                         ]
1035                 )
1036         ]
1037 )
1038
1039 # Check for EGD pool file
1040 AC_ARG_WITH(egd-pool,
1041         [  --with-egd-pool=FILE    read randomness from EGD pool FILE (default none)],
1042         [
1043                 if test "x$withval" != "xno" ; then
1044                         EGD_SOCKET="$withval";
1045                         AC_DEFINE_UNQUOTED(EGD_SOCKET, "$EGD_SOCKET")
1046                 fi
1047         ]
1048 )
1049
1050 # detect pathnames for entropy gathering commands, if we need them
1051 INSTALL_SSH_PRNG_CMDS=""
1052 rm -f prng_commands
1053 if (test -z "$RANDOM_POOL" && test -z "$EGD_SOCKET") ; then
1054         # Use these commands to collect entropy
1055         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1056         OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
1057         OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
1058         OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
1059         OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
1060         OSSH_PATH_ENTROPY_PROG(PROG_W, w)
1061         OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
1062         OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
1063         OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
1064         OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
1065         OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
1066         OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
1067         OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
1068         OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
1069         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1070
1071         INSTALL_SSH_PRNG_CMDS="yes"
1072 fi
1073 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
1074
1075
1076 AC_ARG_WITH(catman,
1077         [  --with-catman=man|cat   Install preformatted manpages[no]],
1078         [
1079                 MANTYPE='$(CATMAN)'
1080                 if test x"$withval" != x"yes" ; then
1081                    mansubdir=$withval
1082                 else
1083                    mansubdir=cat
1084                 fi
1085         ], [
1086                 if test -z "$MANTYPE" ; then
1087                         MANTYPE='$(TROFFMAN)'
1088                         mansubdir=man
1089                 fi
1090         ]
1091 )
1092 AC_SUBST(MANTYPE)
1093 AC_SUBST(mansubdir)
1094
1095 # Check whether user wants Kerberos support
1096 KRB4_MSG="no"
1097 AC_ARG_WITH(kerberos4,
1098         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
1099         [
1100                 if test "x$withval" != "xno" ; then
1101
1102                         if test "x$withval" != "xyes" ; then
1103                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1104                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1105                                 if test ! -z "$need_dash_r" ; then
1106                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
1107                                 fi
1108                                 if test ! -z "$blibpath" ; then
1109                                         blibpath="$blibpath:${withval}/lib"
1110                                 fi
1111                         else
1112                                 if test -d /usr/include/kerberosIV ; then
1113                                         CPPFLAGS="$CPPFLAGS -I/usr/include/kerberosIV"
1114                                 fi
1115                         fi
1116
1117                         AC_CHECK_HEADERS(krb.h)
1118                         AC_CHECK_LIB(krb, main)
1119                         if test "$ac_cv_header_krb_h" != yes; then
1120                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
1121                         fi
1122                         if test "$ac_cv_lib_krb_main" != yes; then
1123                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
1124                         fi
1125
1126                         KLIBS="-lkrb -ldes"
1127                         AC_CHECK_LIB(resolv, dn_expand, , )
1128                         KRB4=yes
1129                         KRB4_MSG="yes"
1130                         AC_DEFINE(KRB4)
1131                 fi
1132         ]
1133 )
1134
1135 # Check whether user wants AFS support
1136 AFS_MSG="no"
1137 AC_ARG_WITH(afs,
1138         [  --with-afs=PATH         Enable AFS support],
1139         [
1140                 if test "x$withval" != "xno" ; then
1141
1142                         if test "x$withval" != "xyes" ; then
1143                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1144                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1145                         fi
1146
1147                         if test -z "$KRB4" ; then
1148                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
1149                         fi
1150
1151                         LIBS="$LIBS -lkafs"
1152                         if test ! -z "$AFS_LIBS" ; then
1153                                 LIBS="$LIBS $AFS_LIBS"
1154                         fi
1155                         AC_DEFINE(AFS)
1156                         AFS_MSG="yes"
1157                 fi
1158         ]
1159 )
1160 LIBS="$LIBS $KLIBS"
1161
1162 # Check whether user wants S/Key support
1163 SKEY_MSG="no"
1164 AC_ARG_WITH(skey,
1165         [  --with-skey=PATH         Enable S/Key support],
1166         [
1167                 if test "x$withval" != "xno" ; then
1168
1169                         if test "x$withval" != "xyes" ; then
1170                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1171                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1172                         fi
1173
1174                         AC_DEFINE(SKEY)
1175                         LIBS="$LIBS -lskey"
1176                         SKEY_MSG="yes"
1177
1178                         AC_CHECK_FUNC(skey_keyinfo,
1179                                 [],
1180                                 [
1181                                         AC_MSG_ERROR([** Incomplete or missing s/key libraries.])
1182                                 ])
1183                 fi
1184         ]
1185 )
1186
1187 # Check whether user wants TCP wrappers support
1188 TCPW_MSG="no"
1189 AC_ARG_WITH(tcp-wrappers,
1190         [  --with-tcp-wrappers     Enable tcpwrappers support],
1191         [
1192                 if test "x$withval" != "xno" ; then
1193                         saved_LIBS="$LIBS"
1194                         LIBS="$LIBS -lwrap"
1195                         AC_MSG_CHECKING(for libwrap)
1196                         AC_TRY_LINK(
1197                                 [
1198 #include <tcpd.h>
1199                                         int deny_severity = 0, allow_severity = 0;
1200                                 ],
1201                                 [hosts_access(0);],
1202                                 [
1203                                         AC_MSG_RESULT(yes)
1204                                         AC_DEFINE(LIBWRAP)
1205                                         TCPW_MSG="yes"
1206                                 ],
1207                                 [
1208                                         AC_MSG_ERROR([*** libwrap missing])
1209                                 ]
1210                         )
1211                 fi
1212         ]
1213 )
1214
1215 # Check whether to enable MD5 passwords
1216 MD5_MSG="no"
1217 AC_ARG_WITH(md5-passwords,
1218         [  --with-md5-passwords    Enable use of MD5 passwords],
1219         [
1220                 if test "x$withval" != "xno" ; then
1221                         AC_DEFINE(HAVE_MD5_PASSWORDS)
1222                         MD5_MSG="yes"
1223                 fi
1224         ]
1225 )
1226
1227 # Whether to disable shadow password support
1228 AC_ARG_WITH(shadow,
1229         [  --without-shadow        Disable shadow password support],
1230         [
1231                 if test "x$withval" = "xno" ; then
1232                         AC_DEFINE(DISABLE_SHADOW)
1233                         disable_shadow=yes
1234                 fi
1235         ]
1236 )
1237
1238 if test -z "$disable_shadow" ; then
1239         AC_MSG_CHECKING([if the systems has expire shadow information])
1240         AC_TRY_COMPILE(
1241         [
1242 #include <sys/types.h>
1243 #include <shadow.h>
1244         struct spwd sp;
1245         ],[ sp.sp_expire = sp.sp_lstchg = sp.sp_inact = 0; ],
1246         [ sp_expire_available=yes ], []
1247         )
1248
1249         if test "x$sp_expire_available" = "xyes" ; then
1250                 AC_MSG_RESULT(yes)
1251                 AC_DEFINE(HAS_SHADOW_EXPIRE)
1252         else
1253                 AC_MSG_RESULT(no)
1254         fi
1255 fi
1256
1257 # Use ip address instead of hostname in $DISPLAY
1258 if test ! -z "$IPADDR_IN_DISPLAY" ; then
1259         DISPLAY_HACK_MSG="yes"
1260         AC_DEFINE(IPADDR_IN_DISPLAY)
1261 else
1262         DISPLAY_HACK_MSG="no"
1263         AC_ARG_WITH(ipaddr-display,
1264                 [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
1265                 [
1266                         if test "x$withval" != "xno" ; then
1267                                 AC_DEFINE(IPADDR_IN_DISPLAY)
1268                                 DISPLAY_HACK_MSG="yes"
1269                         fi
1270                 ]
1271         )
1272 fi
1273
1274 # Whether to mess with the default path
1275 SERVER_PATH_MSG="(default)"
1276 AC_ARG_WITH(default-path,
1277         [  --with-default-path=PATH Specify default \$PATH environment for server],
1278         [
1279                 if test "x$withval" != "xno" ; then
1280                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
1281                         SERVER_PATH_MSG="$withval"
1282                 fi
1283         ]
1284 )
1285
1286 # Whether to force IPv4 by default (needed on broken glibc Linux)
1287 IPV4_HACK_MSG="no"
1288 AC_ARG_WITH(ipv4-default,
1289         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
1290         [
1291                 if test "x$withval" != "xno" ; then
1292                         AC_DEFINE(IPV4_DEFAULT)
1293                         IPV4_HACK_MSG="yes"
1294                 fi
1295         ]
1296 )
1297
1298 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
1299 IPV4_IN6_HACK_MSG="no"
1300 AC_ARG_WITH(4in6,
1301         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
1302         [
1303                 if test "x$withval" != "xno" ; then
1304                         AC_MSG_RESULT(yes)
1305                         AC_DEFINE(IPV4_IN_IPV6)
1306                         IPV4_IN6_HACK_MSG="yes"
1307                 else
1308                         AC_MSG_RESULT(no)
1309                 fi
1310         ],[
1311                 if test "x$inet6_default_4in6" = "xyes"; then
1312                         AC_MSG_RESULT([yes (default)])
1313                         AC_DEFINE(IPV4_IN_IPV6)
1314                         IPV4_IN6_HACK_MSG="yes"
1315                 else
1316                         AC_MSG_RESULT([no (default)])
1317                 fi
1318         ]
1319 )
1320
1321 AC_MSG_CHECKING(whether to install ssh as suid root)
1322 AC_ARG_ENABLE(suid-ssh,
1323 [  --enable-suid-ssh       Install ssh as suid root (default)
1324   --disable-suid-ssh      Install ssh without suid bit],
1325 [ case "$enableval" in
1326   no)
1327        AC_MSG_RESULT(no)
1328        SSHMODE=0711
1329        ;;
1330   *)   AC_MSG_RESULT(yes)
1331        SSHMODE=04711
1332        ;;
1333   esac ],
1334   AC_MSG_RESULT(yes)
1335   SSHMODE=04711
1336 )
1337 AC_SUBST(SSHMODE)
1338
1339
1340 # Where to place sshd.pid
1341 piddir=/var/run
1342 AC_ARG_WITH(pid-dir,
1343         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
1344         [
1345                 if test "x$withval" != "xno" ; then
1346                         piddir=$withval
1347                 fi
1348         ]
1349 )
1350
1351 # make sure the directory exists
1352 if test ! -d $piddir ; then
1353         piddir=`eval echo ${sysconfdir}`
1354         case $piddir in
1355                 NONE/*) piddir=`echo $piddir | sed "s~NONE~$ac_default_prefix~"` ;;
1356         esac
1357 fi
1358
1359 AC_DEFINE_UNQUOTED(PIDDIR, "$piddir")
1360 AC_SUBST(piddir)
1361
1362 dnl allow user to disable some login recording features
1363 AC_ARG_ENABLE(lastlog,
1364         [  --disable-lastlog       disable use of lastlog even if detected [no]],
1365         [ AC_DEFINE(DISABLE_LASTLOG) ]
1366 )
1367 AC_ARG_ENABLE(utmp,
1368         [  --disable-utmp          disable use of utmp even if detected [no]],
1369         [ AC_DEFINE(DISABLE_UTMP) ]
1370 )
1371 AC_ARG_ENABLE(utmpx,
1372         [  --disable-utmpx         disable use of utmpx even if detected [no]],
1373         [ AC_DEFINE(DISABLE_UTMPX) ]
1374 )
1375 AC_ARG_ENABLE(wtmp,
1376         [  --disable-wtmp          disable use of wtmp even if detected [no]],
1377         [ AC_DEFINE(DISABLE_WTMP) ]
1378 )
1379 AC_ARG_ENABLE(wtmpx,
1380         [  --disable-wtmpx         disable use of wtmpx even if detected [no]],
1381         [ AC_DEFINE(DISABLE_WTMPX) ]
1382 )
1383 AC_ARG_ENABLE(libutil,
1384         [  --disable-libutil       disable use of libutil (login() etc.) [no]],
1385         [ AC_DEFINE(DISABLE_LOGIN) ]
1386 )
1387 AC_ARG_ENABLE(pututline,
1388         [  --disable-pututline     disable use of pututline() etc. ([uw]tmp) [no]],
1389         [ AC_DEFINE(DISABLE_PUTUTLINE) ]
1390 )
1391 AC_ARG_ENABLE(pututxline,
1392         [  --disable-pututxline    disable use of pututxline() etc. ([uw]tmpx) [no]],
1393         [ AC_DEFINE(DISABLE_PUTUTXLINE) ]
1394 )
1395 AC_ARG_WITH(lastlog,
1396   [  --with-lastlog=FILE|DIR specify lastlog location [common locations]],
1397   [ conf_lastlog_location="$withval";  ],)
1398
1399 dnl lastlog, [uw]tmpx? detection
1400 dnl  NOTE: set the paths in the platform section to avoid the
1401 dnl   need for command-line parameters
1402 dnl lastlog and [uw]tmp are subject to a file search if all else fails
1403
1404 dnl lastlog detection
1405 dnl  NOTE: the code itself will detect if lastlog is a directory
1406 AC_MSG_CHECKING([if your system defines LASTLOG_FILE])
1407 AC_TRY_COMPILE([
1408 #include <sys/types.h>
1409 #include <utmp.h>
1410 #ifdef HAVE_LASTLOG_H
1411 #  include <lastlog.h>
1412 #endif
1413 #ifdef HAVE_PATHS_H
1414 #  include <paths.h>
1415 #endif
1416         ],
1417         [ char *lastlog = LASTLOG_FILE; ],
1418         [ AC_MSG_RESULT(yes) ],
1419         [
1420                 AC_MSG_RESULT(no)
1421                 AC_MSG_CHECKING([if your system defines _PATH_LASTLOG])
1422                 AC_TRY_COMPILE([
1423 #include <sys/types.h>
1424 #include <utmp.h>
1425 #ifdef HAVE_LASTLOG_H
1426 #  include <lastlog.h>
1427 #endif
1428 #ifdef HAVE_PATHS_H
1429 #  include <paths.h>
1430 #endif
1431                 ],
1432                 [ char *lastlog = _PATH_LASTLOG; ],
1433                 [ AC_MSG_RESULT(yes) ],
1434                 [
1435                         AC_MSG_RESULT(no)
1436                         system_lastlog_path=no
1437                 ])
1438         ]
1439 )
1440
1441 if test -z "$conf_lastlog_location"; then
1442         if test x"$system_lastlog_path" = x"no" ; then
1443                 for f in /var/log/lastlog /usr/adm/lastlog /var/adm/lastlog /etc/security/lastlog ; do
1444                                 if (test -d "$f" || test -f "$f") ; then
1445                                         conf_lastlog_location=$f
1446                                 fi
1447                 done
1448                 if test -z "$conf_lastlog_location"; then
1449                         AC_MSG_WARN([** Cannot find lastlog **])
1450                         dnl Don't define DISABLE_LASTLOG - that means we don't try wtmp/wtmpx
1451                 fi
1452         fi
1453 fi
1454
1455 if test -n "$conf_lastlog_location"; then
1456         AC_DEFINE_UNQUOTED(CONF_LASTLOG_FILE, "$conf_lastlog_location")
1457 fi
1458
1459 dnl utmp detection
1460 AC_MSG_CHECKING([if your system defines UTMP_FILE])
1461 AC_TRY_COMPILE([
1462 #include <sys/types.h>
1463 #include <utmp.h>
1464 #ifdef HAVE_PATHS_H
1465 #  include <paths.h>
1466 #endif
1467         ],
1468         [ char *utmp = UTMP_FILE; ],
1469         [ AC_MSG_RESULT(yes) ],
1470         [ AC_MSG_RESULT(no)
1471           system_utmp_path=no ]
1472 )
1473 if test -z "$conf_utmp_location"; then
1474         if test x"$system_utmp_path" = x"no" ; then
1475                 for f in /etc/utmp /usr/adm/utmp /var/run/utmp; do
1476                         if test -f $f ; then
1477                                 conf_utmp_location=$f
1478                         fi
1479                 done
1480                 if test -z "$conf_utmp_location"; then
1481                         AC_DEFINE(DISABLE_UTMP)
1482                 fi
1483         fi
1484 fi
1485 if test -n "$conf_utmp_location"; then
1486         AC_DEFINE_UNQUOTED(CONF_UTMP_FILE, "$conf_utmp_location")
1487 fi
1488
1489 dnl wtmp detection
1490 AC_MSG_CHECKING([if your system defines WTMP_FILE])
1491 AC_TRY_COMPILE([
1492 #include <sys/types.h>
1493 #include <utmp.h>
1494 #ifdef HAVE_PATHS_H
1495 #  include <paths.h>
1496 #endif
1497         ],
1498         [ char *wtmp = WTMP_FILE; ],
1499         [ AC_MSG_RESULT(yes) ],
1500         [ AC_MSG_RESULT(no)
1501           system_wtmp_path=no ]
1502 )
1503 if test -z "$conf_wtmp_location"; then
1504         if test x"$system_wtmp_path" = x"no" ; then
1505                 for f in /usr/adm/wtmp /var/log/wtmp; do
1506                         if test -f $f ; then
1507                                 conf_wtmp_location=$f
1508                         fi
1509                 done
1510                 if test -z "$conf_wtmp_location"; then
1511                         AC_DEFINE(DISABLE_WTMP)
1512                 fi
1513         fi
1514 fi
1515 if test -n "$conf_wtmp_location"; then
1516         AC_DEFINE_UNQUOTED(CONF_WTMP_FILE, "$conf_wtmp_location")
1517 fi
1518
1519
1520 dnl utmpx detection - I don't know any system so perverse as to require
1521 dnl  utmpx, but not define UTMPX_FILE (ditto wtmpx.) No doubt it's out
1522 dnl  there, though.
1523 AC_MSG_CHECKING([if your system defines UTMPX_FILE])
1524 AC_TRY_COMPILE([
1525 #include <sys/types.h>
1526 #include <utmp.h>
1527 #ifdef HAVE_UTMPX_H
1528 #include <utmpx.h>
1529 #endif
1530 #ifdef HAVE_PATHS_H
1531 #  include <paths.h>
1532 #endif
1533         ],
1534         [ char *utmpx = UTMPX_FILE; ],
1535         [ AC_MSG_RESULT(yes) ],
1536         [ AC_MSG_RESULT(no)
1537           system_utmpx_path=no ]
1538 )
1539 if test -z "$conf_utmpx_location"; then
1540         if test x"$system_utmpx_path" = x"no" ; then
1541                 AC_DEFINE(DISABLE_UTMPX)
1542         fi
1543 else
1544         AC_DEFINE_UNQUOTED(CONF_UTMPX_FILE, "$conf_utmpx_location")
1545 fi
1546
1547 dnl wtmpx detection
1548 AC_MSG_CHECKING([if your system defines WTMPX_FILE])
1549 AC_TRY_COMPILE([
1550 #include <sys/types.h>
1551 #include <utmp.h>
1552 #ifdef HAVE_UTMPX_H
1553 #include <utmpx.h>
1554 #endif
1555 #ifdef HAVE_PATHS_H
1556 #  include <paths.h>
1557 #endif
1558         ],
1559         [ char *wtmpx = WTMPX_FILE; ],
1560         [ AC_MSG_RESULT(yes) ],
1561         [ AC_MSG_RESULT(no)
1562           system_wtmpx_path=no ]
1563 )
1564 if test -z "$conf_wtmpx_location"; then
1565         if test x"$system_wtmpx_path" = x"no" ; then
1566                 AC_DEFINE(DISABLE_WTMPX)
1567         fi
1568 else
1569         AC_DEFINE_UNQUOTED(CONF_WTMPX_FILE, "$conf_wtmpx_location")
1570 fi
1571
1572
1573 # Change default command timeout for builtin PRNG
1574 entropy_timeout=200
1575 AC_ARG_WITH(entropy-timeout,
1576         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
1577         [
1578                 if test "x$withval" != "xno" ; then
1579                         entropy_timeout=$withval
1580                 fi
1581         ]
1582 )
1583 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
1584
1585
1586 if test ! -z "$blibpath" ; then
1587         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
1588         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
1589 fi
1590
1591 AC_EXEEXT
1592
1593 AC_OUTPUT(Makefile ssh_prng_cmds)
1594
1595 # Print summary of options
1596
1597 if test x$MANTYPE = x'$(CATMAN)' ; then
1598         MAN_MSG=cat
1599 else
1600         MAN_MSG=man
1601 fi
1602 if test ! -z "$RANDOM_POOL" ; then
1603         RAND_MSG="Device ($RANDOM_POOL)"
1604 else
1605         if test ! -z "$EGD_SOCKET" ; then
1606                 RAND_MSG="EGD ($EGD_SOCKET)"
1607         else
1608                 RAND_MSG="Builtin (timeout $entropy_timeout)"
1609                 BUILTIN_RNG=1
1610         fi
1611 fi
1612
1613 # Someone please show me a better way :)
1614 A=`eval echo ${prefix}` ; A=`eval echo ${A}`
1615 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
1616 C=`eval echo ${sbindir}` ; C=`eval echo ${C}`
1617 D=`eval echo ${sysconfdir}` ; D=`eval echo ${D}`
1618 E=`eval echo ${libexecdir}/ssh-askpass` ; E=`eval echo ${E}`
1619 F=`eval echo ${mandir}/${mansubdir}X` ; F=`eval echo ${F}`
1620 G=`eval echo ${piddir}` ; G=`eval echo ${G}`
1621
1622 echo ""
1623 echo "OpenSSH configured has been configured with the following options."
1624 echo "                 User binaries: $B"
1625 echo "                 User binaries: $B"
1626 echo "               System binaries: $C"
1627 echo "           Configuration files: $D"
1628 echo "               Askpass program: $E"
1629 echo "                  Manual pages: $F"
1630 echo "                      PID file: $G"
1631 echo "      Random number collection: $RAND_MSG"
1632 echo "                Manpage format: $MAN_MSG"
1633 echo "                   PAM support: ${PAM_MSG}"
1634 echo "            KerberosIV support: $KRB4_MSG"
1635 echo "                   AFS support: $AFS_MSG"
1636 echo "                 S/KEY support: $SKEY_MSG"
1637 echo "          TCP Wrappers support: $TCPW_MSG"
1638 echo "          MD5 password support: $MD5_MSG"
1639 echo "   IP address in \$DISPLAY hack: $DISPLAY_HACK_MSG"
1640 echo "      Use IPv4 by default hack: $IPV4_HACK_MSG"
1641 echo "       Translate v4 in v6 hack: $IPV4_IN6_HACK_MSG"
1642
1643 echo ""
1644
1645 echo "              Host: ${host}"
1646 echo "          Compiler: ${CC}"
1647 echo "    Compiler flags: ${CFLAGS}"
1648 echo "Preprocessor flags: ${CPPFLAGS}"
1649 echo "      Linker flags: ${LDFLAGS}"
1650 echo "         Libraries: ${LIBS}"
1651
1652 echo ""
1653
1654 if test "x$PAM_MSG" = "xyes" ; then
1655         echo "PAM is enabled. You may need to install a PAM control file for sshd,"
1656         echo "otherwise password authentication may fail. Example PAM control files"
1657         echo "can be found in the contrib/ subdirectory"
1658         echo ""
1659 fi
1660
1661 if test ! -z "$BUILTIN_RNG" ; then
1662         echo "WARNING: you are using the builtin random number collection service."
1663         echo "Please read WARNING.RNG and request that your OS vendor includes"
1664         echo "/dev/random in future versions of their OS."
1665         echo ""
1666 fi
1667
1668 if test ! -z "$NO_SFTP"; then
1669         echo "sftp-server will be disabled.  Your compiler does not support"
1670         echo "64bit integers."
1671         echo ""
1672 fi