configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_PROG_CC
   5 AC_CANONICAL_HOST
   6
   7 # Checks for programs.
   8 AC_PROG_CPP
   9 AC_PROG_RANLIB
  10 AC_PROG_INSTALL
  11 AC_CHECK_PROG(AR, ar, ar)
  12 AC_PATH_PROG(PERL, perl)
  13 AC_SUBST(PERL)
  14
  15 if test -z "$LD" ; then
  16         LD=$CC
  17 fi
  18 AC_SUBST(LD)
  19
  20 # C Compiler features
  21 AC_C_INLINE
  22 if test "$GCC" = "yes"; then
  23         CFLAGS="$CFLAGS -Wall"
  24 fi
  25
  26 # Check for some target-specific stuff
  27 case "$host" in
  28 *-*-aix*)
  29         AFS_LIBS="-lld"
  30         CFLAGS="$CFLAGS -I/usr/local/include"
  31         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  32         if test "$LD" != "gcc" -a -z "$blibpath"; then
  33                 blibpath="/usr/lib:/lib:/usr/local/lib"
  34         fi
  35         AC_DEFINE(BROKEN_GETADDRINFO)
  36         ;;
  37 *-*-hpux10*)
  38         if test -z "$GCC"; then
  39                 CFLAGS="$CFLAGS -Aa"
  40         fi
  41         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  42         CFLAGS="$CFLAGS -I/usr/local/include"
  43         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  44         AC_DEFINE(IPADDR_IN_DISPLAY)
  45         AC_DEFINE(USE_UTMPX)
  46         AC_MSG_CHECKING(for HPUX trusted system password database)
  47         if test -f /tcb/files/auth/system/default; then
  48                 AC_MSG_RESULT(yes)
  49                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  50                 LIBS="$LIBS -lsec"
  51                 AC_MSG_WARN([This configuration is untested])
  52         else
  53                 AC_MSG_RESULT(no)
  54                 AC_DEFINE(DISABLE_SHADOW)
  55         fi
  56         MANTYPE='$(CATMAN)'
  57         mansubdir=cat
  58         ;;
  59 *-*-hpux11*)
  60         if test -z "$GCC"; then
  61                 CFLAGS="$CFLAGS -Ae"
  62         fi
  63         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  64         CFLAGS="$CFLAGS -I/usr/local/include"
  65         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  66         AC_DEFINE(IPADDR_IN_DISPLAY)
  67         AC_DEFINE(USE_UTMPX)
  68         AC_MSG_CHECKING(for HPUX trusted system password database)
  69         if test -f /tcb/files/auth/system/default; then
  70                 AC_MSG_RESULT(yes)
  71                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  72                 LIBS="$LIBS -lsec"
  73                 AC_MSG_WARN([This configuration is untested])
  74         else
  75                 AC_MSG_RESULT(no)
  76                 AC_DEFINE(DISABLE_SHADOW)
  77         fi
  78         MANTYPE='$(CATMAN)'
  79         mansubdir=cat
  80         ;;
  81 *-*-irix5*)
  82         CFLAGS="$CFLAGS -I/usr/local/include"
  83         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  84         MANTYPE='$(CATMAN)'
  85         no_libsocket=1
  86         no_libnsl=1
  87         ;;
  88 *-*-irix6*)
  89         CFLAGS="$CFLAGS -I/usr/local/include"
  90         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  91         MANTYPE='$(CATMAN)'
  92         AC_MSG_WARN([*** Irix 6.x is not tested, please report you experiences *** ])
  93         no_libsocket=1
  94         no_libnsl=1
  95         ;;
  96 *-*-linux*)
  97         no_dev_ptmx=1
  98         AC_DEFINE(DONT_TRY_OTHER_AF)
  99         inet6_default_4in6=yes
 100         ;;
 101 *-*-netbsd*)
 102         need_dash_r=1
 103         ;;
 104 *-*-solaris*)
 105         CFLAGS="$CFLAGS -I/usr/local/include"
 106         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib -L/usr/ucblib -R/usr/ucblib"
 107         need_dash_r=1
 108         AC_DEFINE(USE_UTMPX)
 109         ;;
 110 *-*-sysv*)
 111         CFLAGS="$CFLAGS -I/usr/local/include"
 112         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 113         AC_DEFINE(USE_UTMPX)
 114         MANTYPE='$(CATMAN)'
 115         mansubdir=cat
 116         LIBS="$LIBS -lgen -lsocket"
 117         ;;
 118 esac
 119
 120 # Checks for libraries.
 121 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
 122 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
 123
 124 if test -z "$no_libsocket" ; then
 125         AC_CHECK_LIB(nsl, yp_match, , )
 126 fi
 127 if test -z "$no_libnsl" ; then
 128         AC_CHECK_LIB(socket, main, , )
 129 fi
 130
 131 # Checks for header files.
 132 AC_CHECK_HEADERS(bstring.h endian.h lastlog.h login.h maillock.h netdb.h netgroup.h netinet/in_systm.h paths.h poll.h pty.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/select.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h stddef.h util.h utmp.h utmpx.h)
 133
 134 # Checks for library functions.
 135 AC_CHECK_FUNCS(arc4random b64_ntop bindresvport_af clock freeaddrinfo gai_strerror getaddrinfo getnameinfo getrusage innetgr md5_crypt mkdtemp openpty rresvport_af setenv seteuid setlogin setproctitle setreuid snprintf strlcat strlcpy updwtmpx vsnprintf vhangup _getpty __b64_ntop)
 136
 137 AC_CHECK_FUNC(login,
 138         [AC_DEFINE(HAVE_LOGIN)],
 139         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 140 )
 141
 142 AC_CHECK_FUNC(daemon,
 143         [AC_DEFINE(HAVE_DAEMON)],
 144         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 145 )
 146
 147 AC_CHECK_FUNC(getpagesize,
 148         [AC_DEFINE(HAVE_GETPAGESIZE)],
 149         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 150 )
 151
 152 AC_ARG_WITH(pam,
 153         [  --without-pam           Disable PAM support ],
 154         [
 155                 if test "x$withval" = "xno" ; then
 156                         no_pam=1
 157                         AC_DEFINE(DISABLE_PAM)
 158                 fi
 159         ]
 160 )
 161 if test -z "$no_pam" -a "x$ac_cv_header_security_pam_appl_h" = "xyes" ; then
 162         AC_CHECK_LIB(dl, dlopen, , )
 163         LIBS="$LIBS -lpam"
 164
 165         AC_CHECK_FUNC(pam_getenvlist)
 166
 167         # Check PAM strerror arguments (old PAM)
 168         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 169         AC_TRY_COMPILE(
 170                 [
 171 #include <stdlib.h>
 172 #include <security/pam_appl.h>
 173                 ],
 174                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 175                 [AC_MSG_RESULT(no)],
 176                 [
 177                         AC_DEFINE(HAVE_OLD_PAM)
 178                         AC_MSG_RESULT(yes)
 179                 ]
 180         )
 181 fi
 182
 183 # The big search for OpenSSL
 184 AC_ARG_WITH(ssl-dir,
 185         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 186         [
 187                 if test "x$withval" != "$xno" ; then
 188                         tryssldir=$withval
 189                 fi
 190         ]
 191 )
 192
 193 saved_LIBS="$LIBS"
 194 saved_LDFLAGS="$LDFLAGS"
 195 saved_CFLAGS="$CFLAGS"
 196 if test "x$prefix" != "xNONE" ; then
 197         tryssldir="$tryssldir $prefix"
 198 fi
 199 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 200
 201         for ssldir in "" $tryssldir /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 202                 if test ! -z "$ssldir" ; then
 203                         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 204                         CFLAGS="$saved_CFLAGS -I$ssldir/include"
 205                         if test ! -z "$need_dash_r" ; then
 206                                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 207                         fi
 208                 else
 209                         LDFLAGS="$saved_LDFLAGS"
 210                 fi
 211
 212                 for WANTS_RSAREF in "" 1 ; do
 213
 214                         if test -z "$WANTS_RSAREF" ; then
 215                                 LIBS="$saved_LIBS -lcrypto"
 216                         else
 217                                 LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 218                         fi
 219
 220                         AC_TRY_RUN(
 221                                 [
 222 #include <string.h>
 223 #include <openssl/rand.h>
 224 #include <openssl/rsa.h>
 225 #include <openssl/bn.h>
 226 #include <openssl/sha.h>
 227 int main(void)
 228 {
 229         RSA *key; char a[2048],b[2048];;
 230         memset(a, 0, sizeof(a));memset(b, 0, sizeof(b));
 231         RAND_add(a, sizeof(a), sizeof(a));
 232         key=RSA_generate_key(32,3,NULL,NULL);
 233         if (key==NULL) return(1);
 234         return(-1==RSA_private_decrypt(RSA_size(key),a,b,key,RSA_NO_PADDING));
 235 }
 236                                 ],
 237                                 [
 238                                         found_crypto=1
 239                                         break;
 240                                 ], []
 241                         )
 242                 done
 243
 244                 if test ! -z "$found_crypto" ; then
 245                         break;
 246                 fi
 247         done
 248
 249         if test -z "$found_crypto" ; then
 250                 AC_MSG_ERROR([Could not find working SSLeay / OpenSSL libraries, please install])
 251         fi
 252         if test -z "$ssldir" ; then
 253                 ssldir="(system)"
 254         fi
 255
 256         ac_cv_openssldir=$ssldir
 257 ])
 258
 259 if test ! -z "$ac_cv_openssldir" -a ! "x$ac_cv_openssldir" = "x(system)" ; then
 260         AC_DEFINE(HAVE_OPENSSL)
 261         dnl Need to recover ssldir - test above runs in subshell
 262         ssldir=$ac_cv_openssldir
 263         CFLAGS="$saved_CFLAGS -I$ssldir/include"
 264         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 265         if test ! -z "$need_dash_r" ; then
 266                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 267         fi
 268         if test ! -z "$blibpath" ; then
 269                 blibpath="$blibpath:$ssldir:$ssldir/lib"
 270         fi
 271 fi
 272 if test -z "$WANTS_RSAREF" ; then
 273         LIBS="$saved_LIBS -lcrypto"
 274 else
 275         LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 276 fi
 277
 278
 279 # Checks for data types
 280 AC_CHECK_SIZEOF(char, 1)
 281 AC_CHECK_SIZEOF(short int, 2)
 282 AC_CHECK_SIZEOF(int, 4)
 283 AC_CHECK_SIZEOF(long int, 4)
 284 AC_CHECK_SIZEOF(long long int, 8)
 285
 286 # More checks for data types
 287 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
 288         AC_TRY_COMPILE(
 289                 [ #include <sys/types.h> ],
 290                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
 291                 [ ac_cv_have_intxx_t="yes" ],
 292                 [ ac_cv_have_intxx_t="no" ]
 293         )
 294 ])
 295 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
 296         AC_DEFINE(HAVE_INTXX_T)
 297         have_intxx_t=1
 298 fi
 299
 300 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
 301         AC_TRY_COMPILE(
 302                 [ #include <sys/types.h> ],
 303                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
 304                 [ ac_cv_have_u_intxx_t="yes" ],
 305                 [ ac_cv_have_u_intxx_t="no" ]
 306         )
 307 ])
 308 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
 309         AC_DEFINE(HAVE_U_INTXX_T)
 310         have_u_intxx_t=1
 311 fi
 312
 313
 314 if test -z "$have_u_intxx_t" -o -z "$have_intxx_t" -a \
 315            "x$ac_cv_header_sys_bitypes_h" = "xyes"
 316 then
 317         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 318         AC_TRY_COMPILE(
 319                 [
 320 #include <sys/bitypes.h>
 321                 ],
 322                 [
 323                         int8_t a; int16_t b; int32_t c;
 324                         u_int8_t e; u_int16_t f; u_int32_t g;
 325                         a = b = c = e = f = g = 1;
 326                 ],
 327                 [
 328                         AC_DEFINE(HAVE_U_INTXX_T)
 329                         AC_DEFINE(HAVE_INTXX_T)
 330                         AC_MSG_RESULT(yes)
 331                 ],
 332                 [AC_MSG_RESULT(no)]
 333         )
 334 fi
 335
 336 if test -z "$have_u_intxx_t" ; then
 337         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
 338                 AC_TRY_COMPILE(
 339                         [
 340 #include <sys/types.h>
 341                         ],
 342                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
 343                         [ ac_cv_have_uintxx_t="yes" ],
 344                         [ ac_cv_have_uintxx_t="no" ]
 345                 )
 346         ])
 347         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
 348                 AC_DEFINE(HAVE_UINTXX_T)
 349         fi
 350 fi
 351
 352 AC_CACHE_CHECK([for socklen_t], ac_cv_have_socklen_t, [
 353         AC_TRY_COMPILE(
 354                 [
 355 #include <sys/types.h>
 356 #include <sys/socket.h>
 357                 ],
 358                 [socklen_t foo; foo = 1235;],
 359                 [ ac_cv_have_socklen_t="yes" ],
 360                 [ ac_cv_have_socklen_t="no" ]
 361         )
 362 ])
 363 if test "x$ac_cv_have_socklen_t" = "xyes" ; then
 364         AC_DEFINE(HAVE_SOCKLEN_T)
 365 fi
 366
 367 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
 368         AC_TRY_COMPILE(
 369                 [
 370 #include <sys/types.h>
 371                 ],
 372                 [ size_t foo; foo = 1235; ],
 373                 [ ac_cv_have_size_t="yes" ],
 374                 [ ac_cv_have_size_t="no" ]
 375         )
 376 ])
 377 if test "x$ac_cv_have_size_t" = "xyes" ; then
 378         AC_DEFINE(HAVE_SIZE_T)
 379 fi
 380
 381
 382 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
 383         AC_TRY_COMPILE(
 384                 [
 385 #include <sys/types.h>
 386 #include <sys/socket.h>
 387                 ],
 388                 [ struct sockaddr_storage s; ],
 389                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
 390                 [ ac_cv_have_struct_sockaddr_storage="no" ]
 391         )
 392 ])
 393 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
 394         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 395 fi
 396
 397 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
 398         AC_TRY_COMPILE(
 399                 [
 400 #include <netinet/in.h>
 401                 ],
 402                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
 403                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
 404                 [ ac_cv_have_struct_sockaddr_in6="no" ]
 405         )
 406 ])
 407 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
 408         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 409 fi
 410
 411 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
 412         AC_TRY_COMPILE(
 413                 [
 414 #include <netinet/in.h>
 415                 ],
 416                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
 417                 [ ac_cv_have_struct_in6_addr="yes" ],
 418                 [ ac_cv_have_struct_in6_addr="no" ]
 419         )
 420 ])
 421 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
 422         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 423 fi
 424
 425 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
 426         AC_TRY_COMPILE(
 427                 [
 428 #include <sys/types.h>
 429 #include <sys/socket.h>
 430 #include <netdb.h>
 431                 ],
 432                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
 433                 [ ac_cv_have_struct_addrinfo="yes" ],
 434                 [ ac_cv_have_struct_addrinfo="no" ]
 435         )
 436 ])
 437 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
 438         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 439 fi
 440
 441
 442 # Checks for structure members
 443
 444 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
 445 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
 446 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
 447 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
 448 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
 449 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
 450 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
 451 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
 452 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
 453 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
 454 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
 455
 456
 457 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
 458                 ac_cv_have_ss_family_in_struct_ss, [
 459         AC_TRY_COMPILE(
 460                 [
 461 #include <sys/types.h>
 462 #include <sys/socket.h>
 463                 ],
 464                 [ struct sockaddr_storage s; s.ss_family = 1; ],
 465                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
 466                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
 467         )
 468 ])
 469 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
 470         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 471 fi
 472
 473
 474 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
 475                 ac_cv_have___ss_family_in_struct_ss, [
 476         AC_TRY_COMPILE(
 477                 [
 478 #include <sys/types.h>
 479 #include <sys/socket.h>
 480                 ],
 481                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
 482                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
 483                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
 484         )
 485 ])
 486 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
 487         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 488 fi
 489
 490
 491 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
 492         AC_TRY_LINK([],
 493                 [ extern char *__progname; printf("%s", __progname); ],
 494                 [ ac_cv_libc_defines___progname="yes" ],
 495                 [ ac_cv_libc_defines___progname="no" ]
 496         )
 497 ])
 498 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
 499         AC_DEFINE(HAVE___PROGNAME)
 500 fi
 501
 502
 503 # Looking for programs, paths and files
 504 AC_ARG_WITH(rsh,
 505         [  --with-rsh=PATH         Specify path to remote shell program ],
 506         [
 507                 if test "x$withval" != "$no" ; then
 508                         AC_DEFINE_UNQUOTED(RSH_PATH, "$withval")
 509                 fi
 510         ],
 511         [
 512                 AC_PATH_PROG(rsh_path, rsh)
 513         ]
 514 )
 515
 516 AC_ARG_WITH(xauth,
 517         [  --with-xauth=PATH       Specify path to xauth program ],
 518         [
 519                 if test "x$withval" != "$xno" ; then
 520                         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$withval")
 521                 fi
 522         ],
 523         [
 524                 AC_PATH_PROG(xauth_path, xauth)
 525                 if test ! -z "$xauth_path" -a -x "/usr/openwin/bin/xauth" ; then
 526                         xauth_path="/usr/openwin/bin/xauth"
 527                 fi
 528         ]
 529 )
 530
 531 if test ! -z "$xauth_path" ; then
 532         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
 533 fi
 534 if test ! -z "$rsh_path" ; then
 535         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
 536 fi
 537
 538 # Check for mail directory (last resort if we cannot get it from headers)
 539 if test ! -z "$MAIL" ; then
 540         maildir=`dirname $MAIL`
 541         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
 542 fi
 543
 544 # Look for lastlog location
 545 AC_ARG_WITH(lastlog,
 546         [  --with-lastlog=FILE     Location of lastlog file],
 547         [
 548                 if test "x$withval" = "xno" ; then
 549                         AC_DEFINE(DISABLE_LASTLOG)
 550                 else
 551                         AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$withval")
 552                 fi
 553         ],
 554         [
 555                 AC_MSG_CHECKING([location of lastlog file])
 556                 for lastlog in /var/log/lastlog /var/adm/lastlog /usr/adm/lastlog  /etc/security/lastlog ; do
 557                         if test -f $lastlog ; then
 558                                 gotlastlog="file"
 559                                 break
 560                         fi
 561                         if test -d $lastlog ; then
 562                                 gotlastlog="dir"
 563                                 break
 564                         fi
 565                 done
 566                 if test -z "$gotlastlog" ; then
 567                         AC_MSG_RESULT(not found)
 568                         nolastlog=1
 569                 else
 570                         if test "x$gotlastlog" = "xdir" ; then
 571                                 AC_MSG_RESULT(${lastlog}/)
 572                                 AC_DEFINE(LASTLOG_IS_DIR)
 573                         else
 574                                 AC_MSG_RESULT($lastlog)
 575                                 AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$lastlog")
 576                         fi
 577                 fi
 578         ]
 579 )
 580
 581 if test ! -z "$nolastlog" ; then
 582         AC_MSG_WARN([*** Disabling lastlog support *** ])
 583         AC_DEFINE(DISABLE_LASTLOG)
 584 fi
 585
 586 if test -z "$no_dev_ptmx" ; then
 587         AC_CHECK_FILE("/dev/ptmx",
 588                 [
 589                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
 590                         have_dev_ptmx=1
 591                 ]
 592         )
 593 fi
 594 AC_CHECK_FILE("/dev/ptc",
 595         [
 596                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
 597                 have_dev_ptc=1
 598         ]
 599 )
 600
 601 # Options from here on. Some of these are preset by platform above
 602
 603 # Check for user-specified random device, otherwise check /dev/urandom
 604 AC_ARG_WITH(random,
 605         [  --with-random=FILE      read randomness from FILE (default=/dev/urandom)],
 606         [
 607                 if test "x$withval" != "xno" ; then
 608                         RANDOM_POOL="$withval";
 609                         AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 610                 fi
 611         ],
 612         [
 613                 # Check for random device
 614                 AC_CHECK_FILE("/dev/urandom",
 615                         [
 616                                 RANDOM_POOL="/dev/urandom";
 617                                 AC_SUBST(RANDOM_POOL)
 618                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 619                         ]
 620                 )
 621         ]
 622 )
 623
 624 # Check for EGD pool file
 625 AC_ARG_WITH(egd-pool,
 626         [  --with-egd-pool=FILE    read randomness from EGD pool FILE (default none)],
 627         [
 628                 if test "x$withval" != "xno" ; then
 629                         EGD_SOCKET="$withval";
 630                         AC_DEFINE_UNQUOTED(EGD_SOCKET, "$EGD_SOCKET")
 631                 fi
 632         ]
 633 )
 634
 635 # detect pathnames for entropy gathering commands, if we need them
 636 INSTALL_SSH_PRNG_CMDS=""
 637 rm -f prng_commands
 638 if test -z "$RANDOM_POOL" -a -z "$EGD_SOCKET" ; then
 639         # Use these commands to collect entropy
 640         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
 641         OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
 642         OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
 643         OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
 644         OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
 645         OSSH_PATH_ENTROPY_PROG(PROG_W, w)
 646         OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
 647         OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
 648         OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
 649         OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
 650         OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
 651         OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
 652         OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
 653         OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
 654         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
 655
 656         INSTALL_SSH_PRNG_CMDS="yes"
 657 fi
 658 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
 659
 660
 661 AC_ARG_WITH(catman,
 662         [  --with-catman=man|cat   Install preformatted manpages[no]],
 663         [
 664                 MANTYPE='$(CATMAN)'
 665                 if test x"$withval" != x"yes" ; then
 666                    mansubdir=$withval
 667                 else
 668                    mansubdir=cat
 669                 fi
 670         ], [
 671                 if test -z "$MANTYPE" ; then
 672                         MANTYPE='$(TROFFMAN)'
 673                         mansubdir=man
 674                 fi
 675         ]
 676 )
 677 AC_SUBST(MANTYPE)
 678 AC_SUBST(mansubdir)
 679
 680 # Check whether user wants Kerberos support
 681 AC_ARG_WITH(kerberos4,
 682         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
 683         [
 684                 if test "x$withval" != "xno" ; then
 685
 686                         if test "x$withval" != "$xyes" ; then
 687                                 CFLAGS="$CFLAGS -I${withval}/include"
 688                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 689                                 if test ! -z "$need_dash_r" ; then
 690                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
 691                                 fi
 692                                 if test ! -z "$blibpath" ; then
 693                                         blibpath="$blibpath:${withval}/lib"
 694                                 fi
 695                         else
 696                                 if test -d /usr/include/kerberosIV ; then
 697                                         CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 698                                 fi
 699                         fi
 700
 701                         AC_CHECK_HEADERS(krb.h)
 702                         AC_CHECK_LIB(krb, main)
 703                         if test "$ac_cv_header_krb_h" != yes; then
 704                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
 705                         fi
 706                         if test "$ac_cv_lib_krb_main" != yes; then
 707                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
 708                         fi
 709
 710                         KLIBS="-lkrb -ldes"
 711                         AC_CHECK_LIB(resolv, dn_expand, , )
 712                         KRB4=yes
 713                         AC_DEFINE(KRB4)
 714                 fi
 715         ]
 716 )
 717
 718 # Check whether user wants AFS support
 719 AC_ARG_WITH(afs,
 720         [  --with-afs=PATH         Enable AFS support],
 721         [
 722                 if test "x$withval" != "xno" ; then
 723
 724                         if test "x$withval" != "$xyes" ; then
 725                                 CFLAGS="$CFLAGS -I${withval}/include"
 726                                 LFLAGS="$LFLAGS -L${withval}/lib"
 727                         fi
 728
 729                         if test -z "$KRB4" ; then
 730                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
 731                         fi
 732
 733                         LIBS="$LIBS -lkafs"
 734                         if test ! -z "$AFS_LIBS" ; then
 735                                 LIBS="$LIBS $AFS_LIBS"
 736                         fi
 737                         AC_DEFINE(AFS)
 738                 fi
 739         ]
 740 )
 741 LIBS="$LIBS $KLIBS"
 742
 743 # Check whether user wants S/Key support
 744 AC_ARG_WITH(skey,
 745         [  --with-skey             Enable S/Key support],
 746         [
 747                 if test "x$withval" != "xno" ; then
 748                         AC_DEFINE(SKEY)
 749                         LIBS="$LIBS -lskey"
 750                 fi
 751         ]
 752 )
 753
 754 # Check whether user wants TCP wrappers support
 755 AC_ARG_WITH(tcp-wrappers,
 756         [  --with-tcp-wrappers     Enable tcpwrappers support],
 757         [
 758                 if test "x$withval" != "xno" ; then
 759                         saved_LIBS="$LIBS"
 760                         LIBS="$LIBS -lwrap"
 761                         AC_MSG_CHECKING(for libwrap)
 762                         AC_TRY_LINK(
 763                                 [
 764 #include <tcpd.h>
 765                                         int deny_severity = 0, allow_severity = 0;
 766                                 ],
 767                                 [hosts_access(0);],
 768                                 [
 769                                         AC_MSG_RESULT(yes)
 770                                         AC_DEFINE(LIBWRAP)
 771                                 ],
 772                                 [
 773                                         AC_MSG_RESULT(no)
 774                                         AC_MSG_WARN([*** libwrap missing - tcpwrapper support disabled ***])
 775                                         LIBS="$saved_LIBS"
 776                                 ]
 777                         )
 778                 fi
 779         ]
 780 )
 781
 782 # Check whether to enable MD5 passwords
 783 AC_ARG_WITH(md5-passwords,
 784         [  --with-md5-passwords    Enable use of MD5 passwords],
 785         [
 786                 if test "x$withval" != "xno" ; then
 787                         AC_DEFINE(HAVE_MD5_PASSWORDS)
 788                 fi
 789         ]
 790 )
 791
 792 # Check whether to enable utmpx support
 793 AC_ARG_WITH(utmpx,
 794         [  --with-utmpx            Enable utmpx support],
 795         [
 796                 if test "x$withval" != "xno" ; then
 797                         AC_DEFINE(USE_UTMPX)
 798                 fi
 799         ]
 800 )
 801
 802 # Whether to disable shadow password support
 803 AC_ARG_WITH(shadow,
 804         [  --without-shadow        Disable shadow password support],
 805         [
 806                 if test "x$withval" = "xno" ; then
 807                         AC_DEFINE(DISABLE_SHADOW)
 808                 fi
 809         ]
 810 )
 811
 812 # Use ip address instead of hostname in $DISPLAY
 813 AC_ARG_WITH(ipaddr-display,
 814         [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
 815         [
 816                 if test "x$withval" = "xno" ; then
 817                         AC_DEFINE(IPADDR_IN_DISPLAY)
 818                 fi
 819         ]
 820 )
 821
 822 # Whether to mess with the default path
 823 AC_ARG_WITH(default-path,
 824         [  --with-default-path=PATH Specify default \$PATH environment for server],
 825         [
 826                 if test "x$withval" != "xno" ; then
 827                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
 828                 fi
 829         ]
 830 )
 831
 832 # Whether to force IPv4 by default (needed on broken glibc Linux)
 833 AC_ARG_WITH(ipv4-default,
 834         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
 835         [
 836                 if test "x$withval" != "xno" ; then
 837                         AC_DEFINE(IPV4_DEFAULT)
 838                 fi
 839         ]
 840 )
 841
 842 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
 843 AC_ARG_WITH(4in6,
 844         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
 845         [
 846                 if test "x$withval" != "xno" ; then
 847                         AC_MSG_RESULT(yes)
 848                         AC_DEFINE(IPV4_IN_IPV6)
 849                 else
 850                         AC_MSG_RESULT(no)
 851                 fi
 852         ],[
 853                 if test "x$inet6_default_4in6" = "xyes"; then
 854                         AC_MSG_RESULT([yes (default)])
 855                         AC_DEFINE(IPV4_IN_IPV6)
 856                 else
 857                         AC_MSG_RESULT([no (default)])
 858                 fi
 859         ]
 860 )
 861
 862 # Where to place sshd.pid
 863 piddir=/var/run
 864 AC_ARG_WITH(pid-dir,
 865         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
 866         [
 867                 if test "x$withval" != "xno" ; then
 868                         piddir=$withval
 869                 fi
 870         ]
 871 )
 872
 873 AC_DEFINE_UNQUOTED(PIDDIR, "$piddir")
 874 AC_SUBST(piddir)
 875
 876
 877 # Change default command timeout for builtin PRNG
 878 entropy_timeout=100
 879 AC_ARG_WITH(entropy-timeout,
 880         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
 881         [
 882                 if test "x$withval" != "xno" ; then
 883                         entropy_timeout=$withval
 884                 fi
 885         ]
 886 )
 887 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
 888
 889
 890 if test ! -z "$blibpath" ; then
 891         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
 892         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
 893 fi
 894
 895 AC_OUTPUT(Makefile ssh_prng_cmds)
 896
 897