configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_PROG_CC
   5 AC_CANONICAL_HOST
   6
   7 # Checks for programs.
   8 AC_PROG_CPP
   9 AC_PROG_RANLIB
  10 AC_PROG_INSTALL
  11 AC_CHECK_PROG(AR, ar, ar)
  12 AC_PATH_PROG(PERL, perl)
  13 AC_SUBST(PERL)
  14 AC_PATH_PROG(ENT, ent)
  15 AC_SUBST(ENT)
  16 AC_PATH_PROGS(FILEPRIV, filepriv, true, /sbin:/usr/sbin)
  17
  18 if test -z "$AR" ; then
  19         AC_MSG_ERROR([*** 'ar' missing, please install or fix your \$PATH ***])
  20 fi
  21
  22 # Use LOGIN_PROGRAM from environment if possible
  23 if test ! -z "$LOGIN_PROGRAM" ; then
  24         AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM")
  25 else
  26         # Search for login
  27         AC_PATH_PROG(LOGIN_PROGRAM_FALLBACK, login)
  28         if test ! -z "$LOGIN_PROGRAM_FALLBACK" ; then
  29                 AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM_FALLBACK")
  30         fi
  31 fi
  32
  33 if test -z "$LD" ; then
  34         LD=$CC
  35 fi
  36 AC_SUBST(LD)
  37
  38 # C Compiler features
  39 AC_C_INLINE
  40 if test "$GCC" = "yes"; then
  41         CFLAGS="$CFLAGS -Wall"
  42 fi
  43
  44 # Check for some target-specific stuff
  45 case "$host" in
  46 *-*-aix*)
  47         AFS_LIBS="-lld"
  48         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
  49         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  50         if (test "$LD" != "gcc" && test -z "$blibpath"); then
  51                 blibpath="/usr/lib:/lib:/usr/local/lib"
  52         fi
  53         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)])
  54         AC_DEFINE(BROKEN_GETADDRINFO)
  55         MANTYPE='$(CATMAN)'
  56         mansubdir=cat
  57         dnl AIX handles lastlog as part of its login message
  58         AC_DEFINE(DISABLE_LASTLOG)
  59         MANTYPE='$(CATMAN)'
  60         mansubdir=cat
  61         ;;
  62 *-*-cygwin*)
  63         LIBS="$LIBS -lregex /usr/lib/textmode.o"
  64         AC_DEFINE(HAVE_CYGWIN)
  65         AC_DEFINE(DISABLE_SHADOW)
  66         AC_DEFINE(IPV4_DEFAULT)
  67         AC_DEFINE(IP_TOS_IS_BROKEN)
  68         AC_DEFINE(BROKEN_VHANGUP)
  69         no_libsocket=1
  70         no_libnsl=1
  71         ;;
  72 *-*-hpux10*)
  73         if test -z "$GCC"; then
  74                 CFLAGS="$CFLAGS -Ae"
  75         fi
  76         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE"
  77         IPADDR_IN_DISPLAY=yes
  78         AC_DEFINE(USE_PIPES)
  79         AC_DEFINE(DISABLE_SHADOW)
  80         AC_DEFINE(DISABLE_UTMP)
  81         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
  82         LIBS="$LIBS -lsec"
  83         MANTYPE='$(CATMAN)'
  84         mansubdir=cat
  85         ;;
  86 *-*-hpux11*)
  87         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE"
  88         IPADDR_IN_DISPLAY=yes
  89         AC_DEFINE(PAM_SUN_CODEBASE)
  90         AC_DEFINE(USE_PIPES)
  91         AC_DEFINE(DISABLE_SHADOW)
  92         AC_DEFINE(DISABLE_UTMP)
  93         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
  94         LIBS="$LIBS -lsec"
  95         MANTYPE='$(CATMAN)'
  96         mansubdir=cat
  97         ;;
  98 *-*-irix5*)
  99         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 100         LDFLAGS="$LDFLAGS"
 101         PATH="$PATH:/usr/etc"
 102         MANTYPE='$(CATMAN)'
 103         no_libsocket=1
 104         no_libnsl=1
 105         AC_DEFINE(BROKEN_INET_NTOA)
 106         ;;
 107 *-*-irix6*)
 108         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 109         LDFLAGS="$LDFLAGS"
 110         PATH="$PATH:/usr/etc"
 111         MANTYPE='$(CATMAN)'
 112         AC_DEFINE(WITH_IRIX_ARRAY)
 113         AC_DEFINE(WITH_IRIX_PROJECT)
 114         AC_DEFINE(WITH_IRIX_AUDIT)
 115         AC_CHECK_FUNC(jlimit_startjob, [AC_DEFINE(WITH_IRIX_JOBS)])
 116         no_libsocket=1
 117         no_libnsl=1
 118         AC_DEFINE(BROKEN_INET_NTOA)
 119         mansubdir=man
 120         ;;
 121 *-*-linux*)
 122         no_dev_ptmx=1
 123         check_for_libcrypt_later=1
 124         AC_DEFINE(DONT_TRY_OTHER_AF)
 125         AC_DEFINE(PAM_TTY_KLUDGE)
 126         inet6_default_4in6=yes
 127         ;;
 128 mips-sony-bsd|mips-sony-newsos4)
 129         AC_DEFINE(HAVE_NEWS4)
 130         SONY=1
 131         AC_CHECK_LIB(iberty, xatexit, AC_DEFINE(HAVE_XATEXIT),
 132                 AC_MSG_ERROR([*** libiberty missing - please install first ***])
 133         )
 134         ;;
 135 *-*-netbsd*)
 136         need_dash_r=1
 137         ;;
 138 *-next-*)
 139         conf_lastlog_location="/usr/adm/lastlog"
 140         conf_utmp_location=/etc/utmp
 141         conf_wtmp_location=/usr/adm/wtmp
 142         MAIL=/usr/spool/mail
 143         AC_DEFINE(HAVE_NEXT)
 144         AC_DEFINE(BROKEN_REALPATH)
 145         AC_DEFINE(USE_PIPES)
 146         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 147         CFLAGS="$CFLAGS"
 148         ;;
 149 *-*-solaris*)
 150         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 151         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib -L/usr/ucblib -R/usr/ucblib"
 152         need_dash_r=1
 153         AC_DEFINE(PAM_SUN_CODEBASE)
 154         # hardwire lastlog location (can't detect it on some versions)
 155         conf_lastlog_location="/var/adm/lastlog"
 156         AC_MSG_CHECKING(for obsolete utmp and wtmp in solaris2.x)
 157         sol2ver=`echo "$host"| sed -e 's/.*[[0-9]]\.//'`
 158         if test "$sol2ver" -ge 8; then
 159                 AC_MSG_RESULT(yes)
 160                 AC_DEFINE(DISABLE_UTMP)
 161                 AC_DEFINE(DISABLE_WTMP)
 162         else
 163                 AC_MSG_RESULT(no)
 164         fi
 165         ;;
 166 *-*-sunos4*)
 167         CPPFLAGS="$CPPFLAGS -DSUNOS4"
 168         AC_CHECK_FUNCS(getpwanam)
 169         AC_DEFINE(PAM_SUN_CODEBASE)
 170         conf_utmp_location=/etc/utmp
 171         conf_wtmp_location=/var/adm/wtmp
 172         conf_lastlog_location=/var/adm/lastlog
 173         AC_DEFINE(USE_PIPES)
 174         MANTYPE='$(CATMAN)'
 175         mansubdir=cat
 176         ;;
 177 *-sni-sysv*)
 178         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 179         LDFLAGS="$LDFLAGS -L/usr/local/lib -L/usr/ucblib"
 180         MANTYPE='$(CATMAN)'
 181         IPADDR_IN_DISPLAY=yes
 182         AC_DEFINE(USE_PIPES)
 183         AC_DEFINE(IP_TOS_IS_BROKEN)
 184         mansubdir=cat
 185         LIBS="$LIBS -lgen -lnsl -lucb"
 186         ;;
 187 *-*-sysv4.2*)
 188         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 189         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 190         MANTYPE='$(CATMAN)'
 191         mansubdir=cat
 192         enable_suid_ssh=no
 193         ;;
 194 *-*-sysv5*)
 195         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 196         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 197         MANTYPE='$(CATMAN)'
 198         mansubdir=cat
 199         enable_suid_ssh=no
 200         ;;
 201 *-*-sysv*)
 202         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 203         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 204         MANTYPE='$(CATMAN)'
 205         mansubdir=cat
 206         LIBS="$LIBS -lgen -lsocket"
 207         ;;
 208 *-*-sco3.2v4*)
 209         AC_DEFINE(USE_PIPES)
 210         CPPFLAGS="$CPPFLAGS -Dftruncate=chsize -I/usr/local/include"
 211         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 212         MANTYPE='$(CATMAN)'
 213         mansubdir=cat
 214         LIBS="$LIBS -lgen -lsocket -los -lprot -lx -ltinfo -lm"
 215         no_dev_ptmx=1
 216         RANLIB=true
 217         AC_DEFINE(BROKEN_SYS_TERMIO_H)
 218         rsh_path="/usr/bin/rcmd"
 219         AC_DEFINE(HAVE_SCO_PROTECTED_PW)
 220         AC_DEFINE(DISABLE_SHADOW)
 221         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 222         ;;
 223 *-*-sco3.2v5*)
 224         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 225         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 226         MANTYPE='$(CATMAN)'
 227         mansubdir=cat
 228         LIBS="$LIBS -lprot -lx -ltinfo -lm"
 229         no_dev_ptmx=1
 230         rsh_path="/usr/bin/rcmd"
 231         AC_DEFINE(HAVE_SCO_PROTECTED_PW)
 232         AC_DEFINE(DISABLE_SHADOW)
 233         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 234         ;;
 235 *-dec-osf*)
 236 # This is untested
 237         if test ! -z "USE_SIA" ; then
 238                 AC_MSG_CHECKING(for Digital Unix Security Integration Architecture)
 239                 if test -f /etc/sia/matrix.conf; then
 240                         AC_MSG_RESULT(yes)
 241                         AC_DEFINE(HAVE_OSF_SIA)
 242                         AC_DEFINE(DISABLE_LOGIN)
 243                         LIBS="$LIBS -lsecurity -ldb -lm -laud"
 244                 else
 245                         AC_MSG_RESULT(no)
 246                 fi
 247         fi
 248         ;;
 249 esac
 250
 251 # Allow user to specify flags
 252 AC_ARG_WITH(cflags,
 253         [  --with-cflags           Specify additional flags to pass to compiler],
 254         [
 255                 if test "x$withval" != "xno" ; then
 256                         CFLAGS="$CFLAGS $withval"
 257                 fi
 258         ]
 259 )
 260 AC_ARG_WITH(cppflags,
 261         [  --with-cppflags         Specify additional flags to pass to preprocessor] ,
 262         [
 263                 if test "x$withval" != "xno"; then
 264                         CPPFLAGS="$CPPFLAGS $withval"
 265                 fi
 266         ]
 267 )
 268 AC_ARG_WITH(ldflags,
 269         [  --with-ldflags          Specify additional flags to pass to linker],
 270         [
 271                 if test "x$withval" != "xno" ; then
 272                         LDFLAGS="$LDFLAGS $withval"
 273                 fi
 274         ]
 275 )
 276 AC_ARG_WITH(libs,
 277         [  --with-libs             Specify additional libraries to link with],
 278         [
 279                 if test "x$withval" != "xno" ; then
 280                         LIBS="$LIBS $withval"
 281                 fi
 282         ]
 283 )
 284
 285
 286 # Checks for libraries.
 287 if test -z "$no_libsocket" ; then
 288         AC_CHECK_LIB(nsl, yp_match, , )
 289 fi
 290 if test -z "$no_libnsl" ; then
 291         AC_CHECK_LIB(socket, main, , )
 292 fi
 293
 294 AC_CHECK_LIB(gen, getspnam, LIBS="$LIBS -lgen")
 295 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
 296 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
 297
 298 AC_CHECK_FUNC(regcomp,
 299         [ AC_DEFINE(HAVE_REGCOMP)],
 300         [
 301                 AC_CHECK_LIB(pcre, pcre_info,
 302                         AC_DEFINE(HAVE_LIBPCRE) LIBS="$LIBS -lpcreposix -lpcre")
 303         ]
 304 )
 305
 306 dnl UnixWare 2.x
 307 AC_CHECK_FUNC(strcasecmp,
 308         [], [ AC_CHECK_LIB(resolv, strcasecmp, LIBS="$LIBS -lresolv") ]
 309 )
 310 AC_CHECK_FUNC(utimes,
 311         [], [ AC_CHECK_LIB(c89, utimes, LIBS="$LIBS -lc89") ]
 312 )
 313
 314 # Checks for header files.
 315 AC_CHECK_HEADERS(bstring.h endian.h floatingpoint.h getopt.h lastlog.h limits.h login.h login_cap.h maillock.h netdb.h netgroup.h netinet/in_systm.h paths.h poll.h pty.h regex.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/queue.h sys/select.h sys/stat.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h sys/un.h stddef.h time.h ttyent.h usersec.h util.h utime.h utmp.h utmpx.h vis.h)
 316
 317 dnl    Checks for library functions.
 318 AC_CHECK_FUNCS(arc4random atexit b64_ntop bcopy bindresvport_sa clock fchmod freeaddrinfo futimes gai_strerror getcwd getaddrinfo getgrouplist getnameinfo getrlimit getrusage getttyent inet_aton inet_ntoa innetgr login_getcapbool md5_crypt memmove mkdtemp on_exit openpty realpath rresvport_af setdtablesize setenv seteuid setlogin setproctitle setreuid setrlimit setsid sigaction sigvec snprintf strerror strlcat strlcpy strmode strsep strtok_r sysconf utimes vsnprintf vhangup vis waitpid _getpty __b64_ntop)
 319 dnl    Checks for time functions
 320 AC_CHECK_FUNCS(gettimeofday time)
 321 dnl    Checks for libutil functions
 322 AC_CHECK_HEADERS(libutil.h)
 323 AC_CHECK_FUNCS(login logout updwtmp logwtmp)
 324 dnl    Checks for utmp functions
 325 AC_CHECK_FUNCS(endutent getutent getutid getutline pututline setutent)
 326 AC_CHECK_FUNCS(utmpname)
 327 dnl    Checks for utmpx functions
 328 AC_CHECK_FUNCS(endutxent getutxent getutxid getutxline pututxline )
 329 AC_CHECK_FUNCS(setutxent utmpxname)
 330
 331 AC_CHECK_FUNC(getuserattr,
 332         [AC_DEFINE(HAVE_GETUSERATTR)],
 333         [AC_CHECK_LIB(s, getuserattr, [LIBS="$LIBS -ls"; AC_DEFINE(HAVE_GETUSERATTR)])]
 334 )
 335
 336 AC_CHECK_FUNC(login,
 337         [AC_DEFINE(HAVE_LOGIN)],
 338         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 339 )
 340
 341 AC_CHECK_FUNC(daemon,
 342         [AC_DEFINE(HAVE_DAEMON)],
 343         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 344 )
 345
 346 AC_CHECK_FUNC(getpagesize,
 347         [AC_DEFINE(HAVE_GETPAGESIZE)],
 348         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 349 )
 350
 351 # Check for broken snprintf
 352 if test "x$ac_cv_func_snprintf" = "xyes" ; then
 353         AC_MSG_CHECKING([whether snprintf correctly terminates long strings])
 354         AC_TRY_RUN(
 355                 [
 356 #include <stdio.h>
 357 int main(void){char b[5];snprintf(b,5,"123456789");return(b[4]!='\0');}
 358                 ],
 359                 [AC_MSG_RESULT(yes)],
 360                 [
 361                         AC_MSG_RESULT(no)
 362                         AC_DEFINE(BROKEN_SNPRINTF)
 363                         AC_MSG_WARN([****** Your snprintf() function is broken, complain to your vendor])
 364                 ]
 365         )
 366 fi
 367
 368 AC_FUNC_GETPGRP
 369
 370 # Check for PAM libs
 371 PAM_MSG="no"
 372 AC_ARG_WITH(pam,
 373         [  --with-pam              Enable PAM support ],
 374         [
 375                 if test "x$withval" != "xno" ; then
 376                         if test "x$ac_cv_header_security_pam_appl_h" != "xyes" ; then
 377                                 AC_MSG_ERROR([PAM headers not found])
 378                         fi
 379
 380                         AC_CHECK_LIB(dl, dlopen, , )
 381                         AC_CHECK_LIB(pam, pam_set_item, , AC_MSG_ERROR([*** libpam missing]))
 382                         AC_CHECK_FUNCS(pam_getenvlist)
 383
 384                         disable_shadow=yes
 385                         PAM_MSG="yes"
 386
 387                         AC_DEFINE(USE_PAM)
 388                 fi
 389         ]
 390 )
 391
 392 # Check for older PAM
 393 if test "x$PAM_MSG" = "xyes" ; then
 394         # Check PAM strerror arguments (old PAM)
 395         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 396         AC_TRY_COMPILE(
 397                 [
 398 #include <stdlib.h>
 399 #include <security/pam_appl.h>
 400                 ],
 401                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 402                 [AC_MSG_RESULT(no)],
 403                 [
 404                         AC_DEFINE(HAVE_OLD_PAM)
 405                         AC_MSG_RESULT(yes)
 406                         PAM_MSG="yes (old library)"
 407                 ]
 408         )
 409 fi
 410
 411 # The big search for OpenSSL
 412 AC_ARG_WITH(ssl-dir,
 413         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 414         [
 415                 if test "x$withval" != "xno" ; then
 416                         tryssldir=$withval
 417                 fi
 418         ]
 419 )
 420
 421 saved_LIBS="$LIBS"
 422 saved_LDFLAGS="$LDFLAGS"
 423 saved_CPPFLAGS="$CPPFLAGS"
 424 if test "x$prefix" != "xNONE" ; then
 425         tryssldir="$tryssldir $prefix"
 426 fi
 427 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 428
 429         for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 430                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 431                         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 432                         CPPFLAGS="$saved_CPPFLAGS -I$ssldir/include"
 433                         if test ! -z "$need_dash_r" ; then
 434                                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 435                         fi
 436                 else
 437                         LDFLAGS="$saved_LDFLAGS"
 438                 fi
 439
 440                 LIBS="$saved_LIBS -lcrypto"
 441
 442                 # Basic test to check for compatible version and correct linking
 443                 # *does not* test for RSA - that comes later.
 444                 AC_TRY_RUN(
 445                         [
 446 #include <string.h>
 447 #include <openssl/rand.h>
 448 int main(void)
 449 {
 450         char a[2048];
 451         memset(a, 0, sizeof(a));
 452         RAND_add(a, sizeof(a), sizeof(a));
 453         return(RAND_status() <= 0);
 454 }
 455                         ],
 456                         [
 457                                 found_crypto=1
 458                                 break;
 459                         ], []
 460                 )
 461
 462                 if test ! -z "$found_crypto" ; then
 463                         break;
 464                 fi
 465         done
 466
 467         if test -z "$found_crypto" ; then
 468                 AC_MSG_ERROR([Could not find working SSLeay / OpenSSL libraries, please install])
 469         fi
 470         if test -z "$ssldir" ; then
 471                 ssldir="(system)"
 472         fi
 473
 474         ac_cv_openssldir=$ssldir
 475 ])
 476
 477 if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ; then
 478         AC_DEFINE(HAVE_OPENSSL)
 479         dnl Need to recover ssldir - test above runs in subshell
 480         ssldir=$ac_cv_openssldir
 481
 482         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 483                 CPPFLAGS="$saved_CPPFLAGS -I$ssldir/include"
 484                 LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 485                 if test ! -z "$need_dash_r" ; then
 486                         LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 487                 fi
 488                 if test ! -z "$blibpath" ; then
 489                         blibpath="$blibpath:$ssldir:$ssldir/lib"
 490                 fi
 491         fi
 492 fi
 493 LIBS="$saved_LIBS -lcrypto"
 494
 495 # Now test RSA support
 496 saved_LIBS="$LIBS"
 497 AC_MSG_CHECKING([for RSA support])
 498 for WANTS_RSAREF in "" 1 ; do
 499         if test -z "$WANTS_RSAREF" ; then
 500                 LIBS="$saved_LIBS"
 501         else
 502                 LIBS="$saved_LIBS -lRSAglue -lrsaref"
 503         fi
 504         AC_TRY_RUN([
 505 #include <string.h>
 506 #include <openssl/rand.h>
 507 #include <openssl/rsa.h>
 508 #include <openssl/bn.h>
 509 #include <openssl/sha.h>
 510 int main(void)
 511 {
 512         int num; RSA *key; static unsigned char p_in[] = "blahblah";
 513         unsigned char c[256], p[256];
 514         memset(c, 0, sizeof(c)); RAND_add(c, sizeof(c), sizeof(c));
 515         if ((key=RSA_generate_key(512, 3, NULL, NULL))==NULL) return(1);
 516         num = RSA_public_encrypt(sizeof(p_in) - 1, p_in, c, key, RSA_PKCS1_PADDING);
 517         return(-1 == RSA_private_decrypt(num, c, p, key, RSA_PKCS1_PADDING));
 518 }
 519         ],
 520         [
 521                 rsa_works=1
 522                 break;
 523         ], [])
 524 done
 525
 526 if test ! -z "$no_rsa" ; then
 527         AC_MSG_RESULT(disabled)
 528         RSA_MSG="disabled"
 529 else
 530         if test -z "$rsa_works" ; then
 531                 AC_MSG_WARN([*** No RSA support found *** ])
 532                 RSA_MSG="no"
 533         else
 534                 if test -z "$WANTS_RSAREF" ; then
 535                         AC_MSG_RESULT(yes)
 536                         RSA_MSG="yes"
 537                 else
 538                         RSA_MSG="yes (using RSAref)"
 539                         AC_MSG_RESULT(using RSAref)
 540                         LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 541                 fi
 542         fi
 543 fi
 544
 545 # Some Linux systems (Slackware) need crypt() from libcrypt, *not* the
 546 # version in OpenSSL. Skip this for PAM
 547 if test "x$PAM_MSG" = "xno" -a "x$check_for_libcrypt_later" = "x1"; then
 548         AC_CHECK_LIB(crypt, crypt, , )
 549 fi
 550
 551 # Cheap hack to ensure NEWS-OS libraries are arranged right.
 552 if test ! -z "$SONY" ; then
 553   LIBS="$LIBS -liberty";
 554 fi
 555
 556 # Checks for data types
 557 AC_CHECK_SIZEOF(char, 1)
 558 AC_CHECK_SIZEOF(short int, 2)
 559 AC_CHECK_SIZEOF(int, 4)
 560 AC_CHECK_SIZEOF(long int, 4)
 561 AC_CHECK_SIZEOF(long long int, 8)
 562
 563 # More checks for data types
 564 AC_CACHE_CHECK([for u_int type], ac_cv_have_u_int, [
 565         AC_TRY_COMPILE(
 566                 [ #include <sys/types.h> ],
 567                 [ u_int a; a = 1;],
 568                 [ ac_cv_have_u_int="yes" ],
 569                 [ ac_cv_have_u_int="no" ]
 570         )
 571 ])
 572 if test "x$ac_cv_have_u_int" = "xyes" ; then
 573         AC_DEFINE(HAVE_U_INT)
 574         have_u_int=1
 575 fi
 576
 577 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
 578         AC_TRY_COMPILE(
 579                 [ #include <sys/types.h> ],
 580                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
 581                 [ ac_cv_have_intxx_t="yes" ],
 582                 [ ac_cv_have_intxx_t="no" ]
 583         )
 584 ])
 585 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
 586         AC_DEFINE(HAVE_INTXX_T)
 587         have_intxx_t=1
 588 fi
 589
 590 AC_CACHE_CHECK([for int64_t type], ac_cv_have_int64_t, [
 591         AC_TRY_COMPILE(
 592                 [ #include <sys/types.h> ],
 593                 [ int64_t a; a = 1;],
 594                 [ ac_cv_have_int64_t="yes" ],
 595                 [ ac_cv_have_int64_t="no" ]
 596         )
 597 ])
 598 if test "x$ac_cv_have_int64_t" = "xyes" ; then
 599         AC_DEFINE(HAVE_INT64_T)
 600         have_int64_t=1
 601 fi
 602
 603 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
 604         AC_TRY_COMPILE(
 605                 [ #include <sys/types.h> ],
 606                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
 607                 [ ac_cv_have_u_intxx_t="yes" ],
 608                 [ ac_cv_have_u_intxx_t="no" ]
 609         )
 610 ])
 611 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
 612         AC_DEFINE(HAVE_U_INTXX_T)
 613         have_u_intxx_t=1
 614 fi
 615
 616 AC_CACHE_CHECK([for u_int64_t types], ac_cv_have_u_int64_t, [
 617         AC_TRY_COMPILE(
 618                 [ #include <sys/types.h> ],
 619                 [ u_int64_t a; a = 1;],
 620                 [ ac_cv_have_u_int64_t="yes" ],
 621                 [ ac_cv_have_u_int64_t="no" ]
 622         )
 623 ])
 624 if test "x$ac_cv_have_u_int64_t" = "xyes" ; then
 625         AC_DEFINE(HAVE_U_INT64_T)
 626         have_u_int64_t=1
 627 fi
 628
 629 if (test -z "$have_u_intxx_t" || test -z "$have_intxx_t" && \
 630            test "x$ac_cv_header_sys_bitypes_h" = "xyes")
 631 then
 632         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 633         AC_TRY_COMPILE(
 634                 [
 635 #include <sys/bitypes.h>
 636                 ],
 637                 [
 638                         int8_t a; int16_t b; int32_t c;
 639                         u_int8_t e; u_int16_t f; u_int32_t g;
 640                         a = b = c = e = f = g = 1;
 641                 ],
 642                 [
 643                         AC_DEFINE(HAVE_U_INTXX_T)
 644                         AC_DEFINE(HAVE_INTXX_T)
 645                         AC_MSG_RESULT(yes)
 646                 ],
 647                 [AC_MSG_RESULT(no)]
 648         )
 649 fi
 650
 651 if test -z "$have_u_intxx_t" ; then
 652         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
 653                 AC_TRY_COMPILE(
 654                         [
 655 #include <sys/types.h>
 656                         ],
 657                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
 658                         [ ac_cv_have_uintxx_t="yes" ],
 659                         [ ac_cv_have_uintxx_t="no" ]
 660                 )
 661         ])
 662         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
 663                 AC_DEFINE(HAVE_UINTXX_T)
 664         fi
 665 fi
 666
 667 AC_CACHE_CHECK([for socklen_t], ac_cv_have_socklen_t, [
 668         AC_TRY_COMPILE(
 669                 [
 670 #include <sys/types.h>
 671 #include <sys/socket.h>
 672                 ],
 673                 [socklen_t foo; foo = 1235;],
 674                 [ ac_cv_have_socklen_t="yes" ],
 675                 [ ac_cv_have_socklen_t="no" ]
 676         )
 677 ])
 678 if test "x$ac_cv_have_socklen_t" = "xyes" ; then
 679         AC_DEFINE(HAVE_SOCKLEN_T)
 680 fi
 681
 682 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
 683         AC_TRY_COMPILE(
 684                 [
 685 #include <sys/types.h>
 686                 ],
 687                 [ size_t foo; foo = 1235; ],
 688                 [ ac_cv_have_size_t="yes" ],
 689                 [ ac_cv_have_size_t="no" ]
 690         )
 691 ])
 692 if test "x$ac_cv_have_size_t" = "xyes" ; then
 693         AC_DEFINE(HAVE_SIZE_T)
 694 fi
 695
 696 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
 697         AC_TRY_COMPILE(
 698                 [
 699 #include <sys/types.h>
 700                 ],
 701                 [ ssize_t foo; foo = 1235; ],
 702                 [ ac_cv_have_ssize_t="yes" ],
 703                 [ ac_cv_have_ssize_t="no" ]
 704         )
 705 ])
 706 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
 707         AC_DEFINE(HAVE_SSIZE_T)
 708 fi
 709
 710 AC_CACHE_CHECK([for clock_t], ac_cv_have_clock_t, [
 711         AC_TRY_COMPILE(
 712                 [
 713 #include <time.h>
 714                 ],
 715                 [ clock_t foo; foo = 1235; ],
 716                 [ ac_cv_have_clock_t="yes" ],
 717                 [ ac_cv_have_clock_t="no" ]
 718         )
 719 ])
 720 if test "x$ac_cv_have_clock_t" = "xyes" ; then
 721         AC_DEFINE(HAVE_CLOCK_T)
 722 fi
 723
 724 AC_CACHE_CHECK([for sa_family_t], ac_cv_have_sa_family_t, [
 725         AC_TRY_COMPILE(
 726                 [
 727 #include <sys/types.h>
 728 #include <sys/socket.h>
 729                 ],
 730                 [ sa_family_t foo; foo = 1235; ],
 731                 [ ac_cv_have_sa_family_t="yes" ],
 732                 [ AC_TRY_COMPILE(
 733                   [
 734 #include <sys/types.h>
 735 #include <sys/socket.h>
 736 #include <netinet/in.h>
 737                 ],
 738                 [ sa_family_t foo; foo = 1235; ],
 739                 [ ac_cv_have_sa_family_t="yes" ],
 740
 741                 [ ac_cv_have_sa_family_t="no" ]
 742         )]
 743         )
 744 ])
 745 if test "x$ac_cv_have_sa_family_t" = "xyes" ; then
 746         AC_DEFINE(HAVE_SA_FAMILY_T)
 747 fi
 748
 749 AC_CACHE_CHECK([for pid_t], ac_cv_have_pid_t, [
 750         AC_TRY_COMPILE(
 751                 [
 752 #include <sys/types.h>
 753                 ],
 754                 [ pid_t foo; foo = 1235; ],
 755                 [ ac_cv_have_pid_t="yes" ],
 756                 [ ac_cv_have_pid_t="no" ]
 757         )
 758 ])
 759 if test "x$ac_cv_have_pid_t" = "xyes" ; then
 760         AC_DEFINE(HAVE_PID_T)
 761 fi
 762
 763 AC_CACHE_CHECK([for mode_t], ac_cv_have_mode_t, [
 764         AC_TRY_COMPILE(
 765                 [
 766 #include <sys/types.h>
 767                 ],
 768                 [ mode_t foo; foo = 1235; ],
 769                 [ ac_cv_have_mode_t="yes" ],
 770                 [ ac_cv_have_mode_t="no" ]
 771         )
 772 ])
 773 if test "x$ac_cv_have_mode_t" = "xyes" ; then
 774         AC_DEFINE(HAVE_MODE_T)
 775 fi
 776
 777
 778 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
 779         AC_TRY_COMPILE(
 780                 [
 781 #include <sys/types.h>
 782 #include <sys/socket.h>
 783                 ],
 784                 [ struct sockaddr_storage s; ],
 785                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
 786                 [ ac_cv_have_struct_sockaddr_storage="no" ]
 787         )
 788 ])
 789 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
 790         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 791 fi
 792
 793 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
 794         AC_TRY_COMPILE(
 795                 [
 796 #include <sys/types.h>
 797 #include <netinet/in.h>
 798                 ],
 799                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
 800                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
 801                 [ ac_cv_have_struct_sockaddr_in6="no" ]
 802         )
 803 ])
 804 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
 805         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 806 fi
 807
 808 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
 809         AC_TRY_COMPILE(
 810                 [
 811 #include <sys/types.h>
 812 #include <netinet/in.h>
 813                 ],
 814                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
 815                 [ ac_cv_have_struct_in6_addr="yes" ],
 816                 [ ac_cv_have_struct_in6_addr="no" ]
 817         )
 818 ])
 819 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
 820         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 821 fi
 822
 823 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
 824         AC_TRY_COMPILE(
 825                 [
 826 #include <sys/types.h>
 827 #include <sys/socket.h>
 828 #include <netdb.h>
 829                 ],
 830                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
 831                 [ ac_cv_have_struct_addrinfo="yes" ],
 832                 [ ac_cv_have_struct_addrinfo="no" ]
 833         )
 834 ])
 835 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
 836         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 837 fi
 838
 839 AC_CACHE_CHECK([for struct timeval], ac_cv_have_struct_timeval, [
 840         AC_TRY_COMPILE(
 841                 [ #include <sys/time.h> ],
 842                 [ struct timeval tv; tv.tv_sec = 1;],
 843                 [ ac_cv_have_struct_timeval="yes" ],
 844                 [ ac_cv_have_struct_timeval="no" ]
 845         )
 846 ])
 847 if test "x$ac_cv_have_struct_timeval" = "xyes" ; then
 848         AC_DEFINE(HAVE_STRUCT_TIMEVAL)
 849         have_struct_timeval=1
 850 fi
 851
 852 # If we don't have int64_t then we can't compile sftp-server.  So don't
 853 # even attempt to do it.
 854 if test "x$ac_cv_have_int64_t" = "xno" -a \
 855         "x$ac_cv_sizeof_long_int" != "x8" -a \
 856         "x$ac_cv_sizeof_long_long_int" = "x0" ; then
 857         NO_SFTP='#'
 858 fi
 859 AC_SUBST(NO_SFTP)
 860
 861 dnl Checks for structure members
 862 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
 863 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
 864 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
 865 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
 866 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
 867 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
 868 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
 869 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
 870 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmpx.h, HAVE_ID_IN_UTMPX)
 871 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
 872 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
 873 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
 874 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
 875 OSSH_CHECK_HEADER_FOR_FIELD(ut_exit, utmp.h, HAVE_EXIT_IN_UTMP)
 876 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmp.h, HAVE_TIME_IN_UTMP)
 877 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmpx.h, HAVE_TIME_IN_UTMPX)
 878 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmpx.h, HAVE_TV_IN_UTMPX)
 879 AC_STRUCT_ST_BLKSIZE
 880
 881 AC_CACHE_CHECK([for sun_len field in struct sockaddr_un],
 882                 ac_cv_have_sun_len_in_struct_sockaddr_un, [
 883         AC_TRY_COMPILE(
 884                 [
 885 #include <sys/types.h>
 886 #include <sys/socket.h>
 887                 ],
 888                 [ struct sockaddr_un s; s.sun_len = 1; ],
 889                 [ ac_cv_have_sun_len_in_struct_sockaddr_un="yes" ],
 890                 [ ac_cv_have_sun_len_in_struct_sockaddr_un="no" ],
 891         )
 892 ])
 893 if test "x$ac_cv_have_sun_len_in_struct_sockaddr_un" = "xyes" ; then
 894         AC_DEFINE(HAVE_SUN_LEN_IN_SOCKADDR_UN)
 895 fi
 896
 897 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
 898                 ac_cv_have_ss_family_in_struct_ss, [
 899         AC_TRY_COMPILE(
 900                 [
 901 #include <sys/types.h>
 902 #include <sys/socket.h>
 903                 ],
 904                 [ struct sockaddr_storage s; s.ss_family = 1; ],
 905                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
 906                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
 907         )
 908 ])
 909 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
 910         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 911 fi
 912
 913 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
 914                 ac_cv_have___ss_family_in_struct_ss, [
 915         AC_TRY_COMPILE(
 916                 [
 917 #include <sys/types.h>
 918 #include <sys/socket.h>
 919                 ],
 920                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
 921                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
 922                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
 923         )
 924 ])
 925 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
 926         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 927 fi
 928
 929 AC_CACHE_CHECK([for pw_class field in struct passwd],
 930                 ac_cv_have_pw_class_in_struct_passwd, [
 931         AC_TRY_COMPILE(
 932                 [
 933 #include <pwd.h>
 934                 ],
 935                 [ struct passwd p; p.pw_class = 0; ],
 936                 [ ac_cv_have_pw_class_in_struct_passwd="yes" ],
 937                 [ ac_cv_have_pw_class_in_struct_passwd="no" ]
 938         )
 939 ])
 940 if test "x$ac_cv_have_pw_class_in_struct_passwd" = "xyes" ; then
 941         AC_DEFINE(HAVE_PW_CLASS_IN_PASSWD)
 942 fi
 943
 944
 945 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
 946         AC_TRY_LINK([],
 947                 [ extern char *__progname; printf("%s", __progname); ],
 948                 [ ac_cv_libc_defines___progname="yes" ],
 949                 [ ac_cv_libc_defines___progname="no" ]
 950         )
 951 ])
 952 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
 953         AC_DEFINE(HAVE___PROGNAME)
 954 fi
 955
 956
 957 AC_CACHE_CHECK([if libc defines sys_errlist], ac_cv_libc_defines_sys_errlist, [
 958         AC_TRY_LINK([],
 959                 [ extern const char *const sys_errlist[]; printf("%s", sys_errlist[0]);],
 960                 [ ac_cv_libc_defines_sys_errlist="yes" ],
 961                 [ ac_cv_libc_defines_sys_errlist="no" ]
 962         )
 963 ])
 964 if test "x$ac_cv_libc_defines_sys_errlist" = "xyes" ; then
 965         AC_DEFINE(HAVE_SYS_ERRLIST)
 966 fi
 967
 968
 969 AC_CACHE_CHECK([if libc defines sys_nerr], ac_cv_libc_defines_sys_nerr, [
 970         AC_TRY_LINK([],
 971                 [ extern int sys_nerr; printf("%i", sys_nerr);],
 972                 [ ac_cv_libc_defines_sys_nerr="yes" ],
 973                 [ ac_cv_libc_defines_sys_nerr="no" ]
 974         )
 975 ])
 976 if test "x$ac_cv_libc_defines_sys_nerr" = "xyes" ; then
 977         AC_DEFINE(HAVE_SYS_NERR)
 978 fi
 979
 980
 981 # Looking for programs, paths and files
 982 AC_ARG_WITH(rsh,
 983         [  --with-rsh=PATH         Specify path to remote shell program ],
 984         [
 985                 if test "x$withval" != "$no" ; then
 986                         rsh_path=$withval
 987                 fi
 988         ],
 989         [
 990                 AC_PATH_PROG(rsh_path, rsh)
 991         ]
 992 )
 993
 994 AC_ARG_WITH(xauth,
 995         [  --with-xauth=PATH       Specify path to xauth program ],
 996         [
 997                 if test "x$withval" != "xno" ; then
 998                         xauth_path=$withval
 999                 fi
1000         ],
1001         [
1002                 AC_PATH_PROG(xauth_path, xauth,,$PATH:/usr/X/bin:/usr/bin/X11:/usr/X11R6/bin:/usr/openwin/bin)
1003                 if (test ! -z "$xauth_path" && test -x "/usr/openwin/bin/xauth") ; then
1004                         xauth_path="/usr/openwin/bin/xauth"
1005                 fi
1006         ]
1007 )
1008
1009 if test -z "$xauth_path" ; then
1010         XAUTH_PATH="undefined"
1011         AC_SUBST(XAUTH_PATH)
1012 else
1013         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
1014         XAUTH_PATH=$xauth_path
1015         AC_SUBST(XAUTH_PATH)
1016 fi
1017 if test ! -z "$rsh_path" ; then
1018         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
1019 fi
1020
1021 # Check for mail directory (last resort if we cannot get it from headers)
1022 if test ! -z "$MAIL" ; then
1023         maildir=`dirname $MAIL`
1024         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
1025 fi
1026
1027 if test -z "$no_dev_ptmx" ; then
1028         AC_CHECK_FILE("/dev/ptmx",
1029                 [
1030                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
1031                         have_dev_ptmx=1
1032                 ]
1033         )
1034 fi
1035 AC_CHECK_FILE("/dev/ptc",
1036         [
1037                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
1038                 have_dev_ptc=1
1039         ]
1040 )
1041
1042 # Options from here on. Some of these are preset by platform above
1043
1044 # Check for user-specified random device, otherwise check /dev/urandom
1045 AC_ARG_WITH(random,
1046         [  --with-random=FILE      read entropy from FILE (default=/dev/urandom)],
1047         [
1048                 if test "x$withval" != "xno" ; then
1049                         RANDOM_POOL="$withval";
1050                         AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
1051                 fi
1052         ],
1053         [
1054                 # Check for random device
1055                 AC_CHECK_FILE("/dev/urandom",
1056                         [
1057                                 RANDOM_POOL="/dev/urandom";
1058                                 AC_SUBST(RANDOM_POOL)
1059                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
1060                         ]
1061                 )
1062         ]
1063 )
1064
1065 # Check for EGD pool file
1066 AC_ARG_WITH(egd-pool,
1067         [  --with-egd-pool=FILE    read entropy from PRNGD/EGD socket FILE (default=/var/run/egd-pool)],
1068         [
1069                 if test "x$withval" != "xno" ; then
1070                         EGD_SOCKET="$withval";
1071                         AC_DEFINE_UNQUOTED(EGD_SOCKET, "$EGD_SOCKET")
1072                 fi
1073         ],
1074         [
1075                 # Check for existing socket only if we don't have a random device already
1076                 if test -z "$RANDOM_POOL" ; then
1077                         AC_MSG_CHECKING(for PRNGD/EGD socket)
1078                         # Insert other locations here
1079                         for egdsock in /var/run/egd-pool /etc/entropy ; do
1080                                 if test -S $egdsock ; then
1081                                         EGD_SOCKET="$egdsock"
1082                                         AC_DEFINE_UNQUOTED(EGD_SOCKET, "$EGD_SOCKET")
1083                                         AC_MSG_RESULT($egdsock)
1084                                         break;
1085                                 fi
1086                         done
1087                 fi
1088         ]
1089 )
1090
1091
1092 # detect pathnames for entropy gathering commands, if we need them
1093 INSTALL_SSH_PRNG_CMDS=""
1094 rm -f prng_commands
1095 if (test -z "$RANDOM_POOL" && test -z "$EGD_SOCKET") ; then
1096         # Use these commands to collect entropy
1097         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1098         OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
1099         OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
1100         OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
1101         OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
1102         OSSH_PATH_ENTROPY_PROG(PROG_W, w)
1103         OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
1104         OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
1105         OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
1106         OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
1107         OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
1108         OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
1109         OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
1110         OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
1111         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1112
1113         INSTALL_SSH_PRNG_CMDS="yes"
1114 fi
1115 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
1116
1117
1118 AC_ARG_WITH(catman,
1119         [  --with-catman=man|cat   Install preformatted manpages[no]],
1120         [
1121                 MANTYPE='$(CATMAN)'
1122                 if test x"$withval" != x"yes" ; then
1123                    mansubdir=$withval
1124                 else
1125                    mansubdir=cat
1126                 fi
1127         ], [
1128                 if test -z "$MANTYPE" ; then
1129                         MANTYPE='$(TROFFMAN)'
1130                         mansubdir=man
1131                 fi
1132         ]
1133 )
1134 AC_SUBST(MANTYPE)
1135 AC_SUBST(mansubdir)
1136
1137 # Check whether user wants Kerberos support
1138 KRB4_MSG="no"
1139 AC_ARG_WITH(kerberos4,
1140         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
1141         [
1142                 if test "x$withval" != "xno" ; then
1143
1144                         if test "x$withval" != "xyes" ; then
1145                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1146                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1147                                 if test ! -z "$need_dash_r" ; then
1148                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
1149                                 fi
1150                                 if test ! -z "$blibpath" ; then
1151                                         blibpath="$blibpath:${withval}/lib"
1152                                 fi
1153                         else
1154                                 if test -d /usr/include/kerberosIV ; then
1155                                         CPPFLAGS="$CPPFLAGS -I/usr/include/kerberosIV"
1156                                 fi
1157                         fi
1158
1159                         AC_CHECK_HEADERS(krb.h)
1160                         AC_CHECK_LIB(krb, main)
1161                         if test "$ac_cv_header_krb_h" != yes; then
1162                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
1163                         fi
1164                         if test "$ac_cv_lib_krb_main" != yes; then
1165                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
1166                         fi
1167
1168                         KLIBS="-lkrb -ldes"
1169                         AC_CHECK_LIB(resolv, dn_expand, , )
1170                         KRB4=yes
1171                         KRB4_MSG="yes"
1172                         AC_DEFINE(KRB4)
1173                 fi
1174         ]
1175 )
1176
1177 # Check whether user wants AFS support
1178 AFS_MSG="no"
1179 AC_ARG_WITH(afs,
1180         [  --with-afs=PATH         Enable AFS support],
1181         [
1182                 if test "x$withval" != "xno" ; then
1183
1184                         if test "x$withval" != "xyes" ; then
1185                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1186                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1187                         fi
1188
1189                         if test -z "$KRB4" ; then
1190                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
1191                         fi
1192
1193                         LIBS="$LIBS -lkafs"
1194                         if test ! -z "$AFS_LIBS" ; then
1195                                 LIBS="$LIBS $AFS_LIBS"
1196                         fi
1197                         AC_DEFINE(AFS)
1198                         AFS_MSG="yes"
1199                 fi
1200         ]
1201 )
1202 LIBS="$LIBS $KLIBS"
1203
1204 # Check whether user wants S/Key support
1205 SKEY_MSG="no"
1206 AC_ARG_WITH(skey,
1207         [  --with-skey=PATH         Enable S/Key support],
1208         [
1209                 if test "x$withval" != "xno" ; then
1210
1211                         if test "x$withval" != "xyes" ; then
1212                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1213                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1214                         fi
1215
1216                         AC_DEFINE(SKEY)
1217                         LIBS="$LIBS -lskey"
1218                         SKEY_MSG="yes"
1219
1220                         AC_CHECK_FUNC(skey_keyinfo,
1221                                 [],
1222                                 [
1223                                         AC_MSG_ERROR([** Incomplete or missing s/key libraries.])
1224                                 ])
1225                 fi
1226         ]
1227 )
1228
1229 # Check whether user wants TCP wrappers support
1230 TCPW_MSG="no"
1231 AC_ARG_WITH(tcp-wrappers,
1232         [  --with-tcp-wrappers     Enable tcpwrappers support],
1233         [
1234                 if test "x$withval" != "xno" ; then
1235                         saved_LIBS="$LIBS"
1236                         LIBS="$LIBS -lwrap"
1237                         AC_MSG_CHECKING(for libwrap)
1238                         AC_TRY_LINK(
1239                                 [
1240 #include <tcpd.h>
1241                                         int deny_severity = 0, allow_severity = 0;
1242                                 ],
1243                                 [hosts_access(0);],
1244                                 [
1245                                         AC_MSG_RESULT(yes)
1246                                         AC_DEFINE(LIBWRAP)
1247                                         TCPW_MSG="yes"
1248                                 ],
1249                                 [
1250                                         AC_MSG_ERROR([*** libwrap missing])
1251                                 ]
1252                         )
1253                 fi
1254         ]
1255 )
1256
1257 # Check whether to enable MD5 passwords
1258 MD5_MSG="no"
1259 AC_ARG_WITH(md5-passwords,
1260         [  --with-md5-passwords    Enable use of MD5 passwords],
1261         [
1262                 if test "x$withval" != "xno" ; then
1263                         AC_DEFINE(HAVE_MD5_PASSWORDS)
1264                         MD5_MSG="yes"
1265                 fi
1266         ]
1267 )
1268
1269 # Whether to disable shadow password support
1270 AC_ARG_WITH(shadow,
1271         [  --without-shadow        Disable shadow password support],
1272         [
1273                 if test "x$withval" = "xno" ; then
1274                         AC_DEFINE(DISABLE_SHADOW)
1275                         disable_shadow=yes
1276                 fi
1277         ]
1278 )
1279
1280 if test -z "$disable_shadow" ; then
1281         AC_MSG_CHECKING([if the systems has expire shadow information])
1282         AC_TRY_COMPILE(
1283         [
1284 #include <sys/types.h>
1285 #include <shadow.h>
1286         struct spwd sp;
1287         ],[ sp.sp_expire = sp.sp_lstchg = sp.sp_inact = 0; ],
1288         [ sp_expire_available=yes ], []
1289         )
1290
1291         if test "x$sp_expire_available" = "xyes" ; then
1292                 AC_MSG_RESULT(yes)
1293                 AC_DEFINE(HAS_SHADOW_EXPIRE)
1294         else
1295                 AC_MSG_RESULT(no)
1296         fi
1297 fi
1298
1299 # Use ip address instead of hostname in $DISPLAY
1300 if test ! -z "$IPADDR_IN_DISPLAY" ; then
1301         DISPLAY_HACK_MSG="yes"
1302         AC_DEFINE(IPADDR_IN_DISPLAY)
1303 else
1304         DISPLAY_HACK_MSG="no"
1305         AC_ARG_WITH(ipaddr-display,
1306                 [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
1307                 [
1308                         if test "x$withval" != "xno" ; then
1309                                 AC_DEFINE(IPADDR_IN_DISPLAY)
1310                                 DISPLAY_HACK_MSG="yes"
1311                         fi
1312                 ]
1313         )
1314 fi
1315
1316 # Whether to mess with the default path
1317 SERVER_PATH_MSG="(default)"
1318 AC_ARG_WITH(default-path,
1319         [  --with-default-path=PATH Specify default \$PATH environment for server],
1320         [
1321                 if test "x$withval" != "xno" ; then
1322                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
1323                         SERVER_PATH_MSG="$withval"
1324                 fi
1325         ]
1326 )
1327
1328 # Whether to force IPv4 by default (needed on broken glibc Linux)
1329 IPV4_HACK_MSG="no"
1330 AC_ARG_WITH(ipv4-default,
1331         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
1332         [
1333                 if test "x$withval" != "xno" ; then
1334                         AC_DEFINE(IPV4_DEFAULT)
1335                         IPV4_HACK_MSG="yes"
1336                 fi
1337         ]
1338 )
1339
1340 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
1341 IPV4_IN6_HACK_MSG="no"
1342 AC_ARG_WITH(4in6,
1343         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
1344         [
1345                 if test "x$withval" != "xno" ; then
1346                         AC_MSG_RESULT(yes)
1347                         AC_DEFINE(IPV4_IN_IPV6)
1348                         IPV4_IN6_HACK_MSG="yes"
1349                 else
1350                         AC_MSG_RESULT(no)
1351                 fi
1352         ],[
1353                 if test "x$inet6_default_4in6" = "xyes"; then
1354                         AC_MSG_RESULT([yes (default)])
1355                         AC_DEFINE(IPV4_IN_IPV6)
1356                         IPV4_IN6_HACK_MSG="yes"
1357                 else
1358                         AC_MSG_RESULT([no (default)])
1359                 fi
1360         ]
1361 )
1362
1363 AC_MSG_CHECKING(whether to install ssh as suid root)
1364 AC_ARG_ENABLE(suid-ssh,
1365 [  --enable-suid-ssh       Install ssh as suid root (default)
1366   --disable-suid-ssh      Install ssh without suid bit],
1367 [ case "$enableval" in
1368   no)
1369        AC_MSG_RESULT(no)
1370        SSHMODE=0711
1371        ;;
1372   *)   AC_MSG_RESULT(yes)
1373        SSHMODE=04711
1374        ;;
1375   esac ],
1376   AC_MSG_RESULT(yes)
1377   SSHMODE=04711
1378 )
1379 AC_SUBST(SSHMODE)
1380
1381
1382 # Where to place sshd.pid
1383 piddir=/var/run
1384 AC_ARG_WITH(pid-dir,
1385         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
1386         [
1387                 if test "x$withval" != "xno" ; then
1388                         piddir=$withval
1389                 fi
1390         ]
1391 )
1392
1393 # make sure the directory exists
1394 if test ! -d $piddir ; then
1395         piddir=`eval echo ${sysconfdir}`
1396         case $piddir in
1397                 NONE/*) piddir=`echo $piddir | sed "s~NONE~$ac_default_prefix~"` ;;
1398         esac
1399 fi
1400
1401 AC_DEFINE_UNQUOTED(_PATH_SSH_PIDDIR, "$piddir")
1402 AC_SUBST(piddir)
1403
1404 dnl allow user to disable some login recording features
1405 AC_ARG_ENABLE(lastlog,
1406         [  --disable-lastlog       disable use of lastlog even if detected [no]],
1407         [ AC_DEFINE(DISABLE_LASTLOG) ]
1408 )
1409 AC_ARG_ENABLE(utmp,
1410         [  --disable-utmp          disable use of utmp even if detected [no]],
1411         [ AC_DEFINE(DISABLE_UTMP) ]
1412 )
1413 AC_ARG_ENABLE(utmpx,
1414         [  --disable-utmpx         disable use of utmpx even if detected [no]],
1415         [ AC_DEFINE(DISABLE_UTMPX) ]
1416 )
1417 AC_ARG_ENABLE(wtmp,
1418         [  --disable-wtmp          disable use of wtmp even if detected [no]],
1419         [ AC_DEFINE(DISABLE_WTMP) ]
1420 )
1421 AC_ARG_ENABLE(wtmpx,
1422         [  --disable-wtmpx         disable use of wtmpx even if detected [no]],
1423         [ AC_DEFINE(DISABLE_WTMPX) ]
1424 )
1425 AC_ARG_ENABLE(libutil,
1426         [  --disable-libutil       disable use of libutil (login() etc.) [no]],
1427         [ AC_DEFINE(DISABLE_LOGIN) ]
1428 )
1429 AC_ARG_ENABLE(pututline,
1430         [  --disable-pututline     disable use of pututline() etc. ([uw]tmp) [no]],
1431         [ AC_DEFINE(DISABLE_PUTUTLINE) ]
1432 )
1433 AC_ARG_ENABLE(pututxline,
1434         [  --disable-pututxline    disable use of pututxline() etc. ([uw]tmpx) [no]],
1435         [ AC_DEFINE(DISABLE_PUTUTXLINE) ]
1436 )
1437 AC_ARG_WITH(lastlog,
1438   [  --with-lastlog=FILE|DIR specify lastlog location [common locations]],
1439   [ conf_lastlog_location="$withval";  ],)
1440
1441 dnl lastlog, [uw]tmpx? detection
1442 dnl  NOTE: set the paths in the platform section to avoid the
1443 dnl   need for command-line parameters
1444 dnl lastlog and [uw]tmp are subject to a file search if all else fails
1445
1446 dnl lastlog detection
1447 dnl  NOTE: the code itself will detect if lastlog is a directory
1448 AC_MSG_CHECKING([if your system defines LASTLOG_FILE])
1449 AC_TRY_COMPILE([
1450 #include <sys/types.h>
1451 #include <utmp.h>
1452 #ifdef HAVE_LASTLOG_H
1453 #  include <lastlog.h>
1454 #endif
1455 #ifdef HAVE_PATHS_H
1456 #  include <paths.h>
1457 #endif
1458         ],
1459         [ char *lastlog = LASTLOG_FILE; ],
1460         [ AC_MSG_RESULT(yes) ],
1461         [
1462                 AC_MSG_RESULT(no)
1463                 AC_MSG_CHECKING([if your system defines _PATH_LASTLOG])
1464                 AC_TRY_COMPILE([
1465 #include <sys/types.h>
1466 #include <utmp.h>
1467 #ifdef HAVE_LASTLOG_H
1468 #  include <lastlog.h>
1469 #endif
1470 #ifdef HAVE_PATHS_H
1471 #  include <paths.h>
1472 #endif
1473                 ],
1474                 [ char *lastlog = _PATH_LASTLOG; ],
1475                 [ AC_MSG_RESULT(yes) ],
1476                 [
1477                         AC_MSG_RESULT(no)
1478                         system_lastlog_path=no
1479                 ])
1480         ]
1481 )
1482
1483 if test -z "$conf_lastlog_location"; then
1484         if test x"$system_lastlog_path" = x"no" ; then
1485                 for f in /var/log/lastlog /usr/adm/lastlog /var/adm/lastlog /etc/security/lastlog ; do
1486                                 if (test -d "$f" || test -f "$f") ; then
1487                                         conf_lastlog_location=$f
1488                                 fi
1489                 done
1490                 if test -z "$conf_lastlog_location"; then
1491                         AC_MSG_WARN([** Cannot find lastlog **])
1492                         dnl Don't define DISABLE_LASTLOG - that means we don't try wtmp/wtmpx
1493                 fi
1494         fi
1495 fi
1496
1497 if test -n "$conf_lastlog_location"; then
1498         AC_DEFINE_UNQUOTED(CONF_LASTLOG_FILE, "$conf_lastlog_location")
1499 fi
1500
1501 dnl utmp detection
1502 AC_MSG_CHECKING([if your system defines UTMP_FILE])
1503 AC_TRY_COMPILE([
1504 #include <sys/types.h>
1505 #include <utmp.h>
1506 #ifdef HAVE_PATHS_H
1507 #  include <paths.h>
1508 #endif
1509         ],
1510         [ char *utmp = UTMP_FILE; ],
1511         [ AC_MSG_RESULT(yes) ],
1512         [ AC_MSG_RESULT(no)
1513           system_utmp_path=no ]
1514 )
1515 if test -z "$conf_utmp_location"; then
1516         if test x"$system_utmp_path" = x"no" ; then
1517                 for f in /etc/utmp /usr/adm/utmp /var/run/utmp; do
1518                         if test -f $f ; then
1519                                 conf_utmp_location=$f
1520                         fi
1521                 done
1522                 if test -z "$conf_utmp_location"; then
1523                         AC_DEFINE(DISABLE_UTMP)
1524                 fi
1525         fi
1526 fi
1527 if test -n "$conf_utmp_location"; then
1528         AC_DEFINE_UNQUOTED(CONF_UTMP_FILE, "$conf_utmp_location")
1529 fi
1530
1531 dnl wtmp detection
1532 AC_MSG_CHECKING([if your system defines WTMP_FILE])
1533 AC_TRY_COMPILE([
1534 #include <sys/types.h>
1535 #include <utmp.h>
1536 #ifdef HAVE_PATHS_H
1537 #  include <paths.h>
1538 #endif
1539         ],
1540         [ char *wtmp = WTMP_FILE; ],
1541         [ AC_MSG_RESULT(yes) ],
1542         [ AC_MSG_RESULT(no)
1543           system_wtmp_path=no ]
1544 )
1545 if test -z "$conf_wtmp_location"; then
1546         if test x"$system_wtmp_path" = x"no" ; then
1547                 for f in /usr/adm/wtmp /var/log/wtmp; do
1548                         if test -f $f ; then
1549                                 conf_wtmp_location=$f
1550                         fi
1551                 done
1552                 if test -z "$conf_wtmp_location"; then
1553                         AC_DEFINE(DISABLE_WTMP)
1554                 fi
1555         fi
1556 fi
1557 if test -n "$conf_wtmp_location"; then
1558         AC_DEFINE_UNQUOTED(CONF_WTMP_FILE, "$conf_wtmp_location")
1559 fi
1560
1561
1562 dnl utmpx detection - I don't know any system so perverse as to require
1563 dnl  utmpx, but not define UTMPX_FILE (ditto wtmpx.) No doubt it's out
1564 dnl  there, though.
1565 AC_MSG_CHECKING([if your system defines UTMPX_FILE])
1566 AC_TRY_COMPILE([
1567 #include <sys/types.h>
1568 #include <utmp.h>
1569 #ifdef HAVE_UTMPX_H
1570 #include <utmpx.h>
1571 #endif
1572 #ifdef HAVE_PATHS_H
1573 #  include <paths.h>
1574 #endif
1575         ],
1576         [ char *utmpx = UTMPX_FILE; ],
1577         [ AC_MSG_RESULT(yes) ],
1578         [ AC_MSG_RESULT(no)
1579           system_utmpx_path=no ]
1580 )
1581 if test -z "$conf_utmpx_location"; then
1582         if test x"$system_utmpx_path" = x"no" ; then
1583                 AC_DEFINE(DISABLE_UTMPX)
1584         fi
1585 else
1586         AC_DEFINE_UNQUOTED(CONF_UTMPX_FILE, "$conf_utmpx_location")
1587 fi
1588
1589 dnl wtmpx detection
1590 AC_MSG_CHECKING([if your system defines WTMPX_FILE])
1591 AC_TRY_COMPILE([
1592 #include <sys/types.h>
1593 #include <utmp.h>
1594 #ifdef HAVE_UTMPX_H
1595 #include <utmpx.h>
1596 #endif
1597 #ifdef HAVE_PATHS_H
1598 #  include <paths.h>
1599 #endif
1600         ],
1601         [ char *wtmpx = WTMPX_FILE; ],
1602         [ AC_MSG_RESULT(yes) ],
1603         [ AC_MSG_RESULT(no)
1604           system_wtmpx_path=no ]
1605 )
1606 if test -z "$conf_wtmpx_location"; then
1607         if test x"$system_wtmpx_path" = x"no" ; then
1608                 AC_DEFINE(DISABLE_WTMPX)
1609         fi
1610 else
1611         AC_DEFINE_UNQUOTED(CONF_WTMPX_FILE, "$conf_wtmpx_location")
1612 fi
1613
1614
1615 # Change default command timeout for builtin PRNG
1616 entropy_timeout=200
1617 AC_ARG_WITH(entropy-timeout,
1618         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
1619         [
1620                 if test "x$withval" != "xno" ; then
1621                         entropy_timeout=$withval
1622                 fi
1623         ]
1624 )
1625 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
1626
1627
1628 if test ! -z "$blibpath" ; then
1629         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
1630         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
1631 fi
1632
1633 AC_EXEEXT
1634
1635 AC_OUTPUT(Makefile ssh_prng_cmds)
1636
1637 # Print summary of options
1638
1639 if test x$MANTYPE = x'$(CATMAN)' ; then
1640         MAN_MSG=cat
1641 else
1642         MAN_MSG=man
1643 fi
1644 if test ! -z "$RANDOM_POOL" ; then
1645         RAND_MSG="Device ($RANDOM_POOL)"
1646 else
1647         if test ! -z "$EGD_SOCKET" ; then
1648                 RAND_MSG="EGD/PRNGD ($EGD_SOCKET)"
1649         else
1650                 RAND_MSG="Builtin (timeout $entropy_timeout)"
1651                 BUILTIN_RNG=1
1652         fi
1653 fi
1654
1655 # Someone please show me a better way :)
1656 A=`eval echo ${prefix}` ; A=`eval echo ${A}`
1657 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
1658 C=`eval echo ${sbindir}` ; C=`eval echo ${C}`
1659 D=`eval echo ${sysconfdir}` ; D=`eval echo ${D}`
1660 E=`eval echo ${libexecdir}/ssh-askpass` ; E=`eval echo ${E}`
1661 F=`eval echo ${mandir}/${mansubdir}X` ; F=`eval echo ${F}`
1662 G=`eval echo ${piddir}` ; G=`eval echo ${G}`
1663
1664 echo ""
1665 echo "OpenSSH configured has been configured with the following options."
1666 echo "                 User binaries: $B"
1667 echo "                 User binaries: $B"
1668 echo "               System binaries: $C"
1669 echo "           Configuration files: $D"
1670 echo "               Askpass program: $E"
1671 echo "                  Manual pages: $F"
1672 echo "                      PID file: $G"
1673 echo "      Random number collection: $RAND_MSG"
1674 echo "                Manpage format: $MAN_MSG"
1675 echo "                   PAM support: ${PAM_MSG}"
1676 echo "            KerberosIV support: $KRB4_MSG"
1677 echo "                   AFS support: $AFS_MSG"
1678 echo "                 S/KEY support: $SKEY_MSG"
1679 echo "          TCP Wrappers support: $TCPW_MSG"
1680 echo "          MD5 password support: $MD5_MSG"
1681 echo "   IP address in \$DISPLAY hack: $DISPLAY_HACK_MSG"
1682 echo "      Use IPv4 by default hack: $IPV4_HACK_MSG"
1683 echo "       Translate v4 in v6 hack: $IPV4_IN6_HACK_MSG"
1684
1685 echo ""
1686
1687 echo "              Host: ${host}"
1688 echo "          Compiler: ${CC}"
1689 echo "    Compiler flags: ${CFLAGS}"
1690 echo "Preprocessor flags: ${CPPFLAGS}"
1691 echo "      Linker flags: ${LDFLAGS}"
1692 echo "         Libraries: ${LIBS}"
1693
1694 echo ""
1695
1696 if test "x$PAM_MSG" = "xyes" ; then
1697         echo "PAM is enabled. You may need to install a PAM control file for sshd,"
1698         echo "otherwise password authentication may fail. Example PAM control files"
1699         echo "can be found in the contrib/ subdirectory"
1700         echo ""
1701 fi
1702
1703 if test ! -z "$BUILTIN_RNG" ; then
1704         echo "WARNING: you are using the builtin random number collection service."
1705         echo "Please read WARNING.RNG and request that your OS vendor includes"
1706         echo "/dev/random in future versions of their OS."
1707         echo ""
1708 fi
1709
1710 if test ! -z "$NO_SFTP"; then
1711         echo "sftp-server will be disabled.  Your compiler does not support"
1712         echo "64bit integers."
1713         echo ""
1714 fi