configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_CANONICAL_HOST
   5
   6 dnl Checks for programs.
   7 AC_PROG_CC
   8 AC_PROG_CPP
   9 AC_PROG_RANLIB
  10 AC_PROG_INSTALL
  11 AC_CHECK_PROG(AR, ar, ar)
  12 AC_PATH_PROG(PERL, perl)
  13 AC_SUBST(PERL)
  14
  15 AC_ARG_WITH(rsh,
  16         [  --with-rsh=PATH         Specify path to remote shell program ],
  17         [
  18                 if test "x$withval" != "$xno" ; then
  19                         AC_DEFINE_UNQUOTED(RSH_PATH, "$withval")
  20                 fi
  21         ],
  22         [
  23                 AC_PATH_PROG(rsh_path, rsh)
  24         ]
  25 )
  26
  27 AC_ARG_WITH(xauth,
  28         [  --with-xauth=PATH       Specify path to xauth program ],
  29         [
  30                 if test "x$withval" != "$xno" ; then
  31                         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$withval")
  32                 fi
  33         ],
  34         [
  35                 AC_PATH_PROG(xauth_path, xauth)
  36                 if test ! -z "$xauth_path" -a -x "/usr/openwin/bin/xauth" ; then
  37                         xauth_path="/usr/openwin/bin/xauth"
  38                 fi
  39         ]
  40 )
  41
  42 if test ! -z "$xauth_path" ; then
  43         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
  44 fi
  45 if test ! -z "$rsh_path" ; then
  46         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
  47 fi
  48
  49 if test "$GCC" = "yes"; then CFLAGS="$CFLAGS -Wall"; fi
  50
  51 AC_C_INLINE
  52
  53 AC_ARG_WITH(ssl-dir,
  54         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
  55         [
  56                 if test "x$withval" != "$xno" ; then
  57                         ssldir=$withval
  58                 fi
  59         ]
  60 )
  61
  62 AC_MSG_CHECKING([for OpenSSL/SSLeay directory])
  63 for ssldir in $ssldir $prefix /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local $prefix /usr/pkg ; do
  64         if test -f "$ssldir/include/openssl/crypto.h"; then
  65                 AC_DEFINE(HAVE_OPENSSL)
  66                 GOT_SSL="yes"
  67                 break
  68         fi
  69         if test -f "$ssldir/include/ssl/crypto.h"; then
  70                 AC_DEFINE(HAVE_SSL)
  71                 GOT_SSL="yes"
  72                 break
  73         fi
  74 done
  75 if test -z "$GOT_SSL" ; then
  76         AC_MSG_ERROR([Could not find SSLeay / OpenSSL libraries, please install])
  77 fi
  78 AC_SUBST(ssldir)
  79 AC_DEFINE_UNQUOTED(ssldir, "$ssldir")
  80 if test "$ssldir" != "/usr"; then
  81         CFLAGS="$CFLAGS -I$ssldir/include"
  82         LDFLAGS="$LDFLAGS -L$ssldir/lib"
  83 fi
  84 AC_MSG_RESULT($ssldir)
  85
  86 dnl Check for some target-specific stuff
  87 case "$host" in
  88 *-*-aix*)
  89         AFS_LIBS="-lld"
  90         AC_DEFINE(BROKEN_GETADDRINFO)
  91         ;;
  92 *-*-hpux10*)
  93         if test -z "$GCC"; then
  94                 CFLAGS="$CFLAGS -Aa"
  95         fi
  96         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  97         AC_DEFINE(IPADDR_IN_DISPLAY)
  98         AC_DEFINE(USE_UTMPX)
  99         AC_MSG_CHECKING(for HPUX trusted system password database)
 100         if test -f /tcb/files/auth/system/default; then
 101                 AC_MSG_RESULT(yes)
 102                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
 103                 LIBS="$LIBS -lsec"
 104                 AC_MSG_WARN([This configuration is untested])
 105         else
 106                 AC_MSG_RESULT(no)
 107                 AC_DEFINE(DISABLE_SHADOW)
 108         fi
 109         MANTYPE='$(CATMAN)'
 110         mansubdir=cat
 111         ;;
 112 *-*-irix5*)
 113         MANTYPE='$(CATMAN)'
 114         no_libsocket=1
 115         no_libnsl=1
 116         ;;
 117 *-*-irix6*)
 118         MANTYPE='$(CATMAN)'
 119         AC_MSG_WARN([*** Irix 6.x is not tested, please report you experiences *** ])
 120         no_libsocket=1
 121         no_libnsl=1
 122         ;;
 123 *-*-linux*)
 124         no_dev_ptmx=1
 125         ;;
 126 *-*-netbsd*)
 127         if test "$GOT_SSL" = "yes"; then
 128                 LDFLAGS="$LDFLAGS -R$ssldir/lib"
 129         fi
 130         ;;
 131 *-*-solaris*)
 132         AC_DEFINE(USE_UTMPX)
 133         ;;
 134 *-*-sysv*)
 135         AC_DEFINE(USE_UTMPX)
 136         MANTYPE='$(CATMAN)'
 137         mansubdir=cat
 138         LIBS="$LIBS -lgen -lsocket"
 139         ;;
 140 esac
 141
 142 dnl Check for RSAref library.
 143 AC_MSG_CHECKING([for RSAref library])
 144 saved_LIBS="$LIBS"
 145 LIBS="$saved_LIBS -lRSAglue -lrsaref"
 146 AC_TRY_LINK([], [],
 147 [AC_MSG_RESULT(yes);
 148  AC_DEFINE(RSAREF)],
 149 [AC_MSG_RESULT(no)]; LIBS="$saved_LIBS")
 150
 151 dnl Checks for libraries.
 152 AC_CHECK_LIB(crypto, CRYPTO_lock, ,AC_MSG_ERROR([*** libcrypto missing - please install first ***]))
 153 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
 154 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
 155
 156 if test -z "$no_libsocket" ; then
 157         AC_CHECK_LIB(nsl, yp_match, , )
 158 fi
 159 if test -z "$no_libnsl" ; then
 160         AC_CHECK_LIB(socket, main, , )
 161 fi
 162
 163 dnl Checks for header files.
 164 AC_CHECK_HEADERS(bstring.h endian.h lastlog.h login.h maillock.h netdb.h netgroup.h paths.h poll.h pty.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/select.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h stddef.h util.h utmp.h utmpx.h)
 165
 166 dnl Checks for library functions.
 167 AC_CHECK_FUNCS(arc4random bindresvport_af freeaddrinfo gai_strerror getaddrinfo getpagesize getnameinfo innetgr md5_crypt mkdtemp openpty rresvport_af setenv seteuid setlogin setproctitle setreuid snprintf strlcat strlcpy updwtmpx vsnprintf _getpty)
 168
 169 AC_CHECK_FUNC(login,
 170         [AC_DEFINE(HAVE_LOGIN)],
 171         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 172 )
 173
 174 AC_CHECK_FUNC(daemon,
 175         [AC_DEFINE(HAVE_DAEMON)],
 176         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 177 )
 178
 179 dnl Checks for data types
 180 AC_CHECK_SIZEOF(char, 1)
 181 AC_CHECK_SIZEOF(short int, 2)
 182 AC_CHECK_SIZEOF(int, 4)
 183 AC_CHECK_SIZEOF(long int, 4)
 184 AC_CHECK_SIZEOF(long long int, 8)
 185
 186 dnl More checks for data types
 187 AC_MSG_CHECKING([for intXX_t types])
 188 AC_TRY_COMPILE(
 189         [#include <sys/types.h>],
 190         [int16_t a; int32_t b; a = 1235; b = 1235;],
 191         [
 192                 AC_DEFINE(HAVE_INTXX_T)
 193                 AC_MSG_RESULT(yes)
 194                 have_intxx_t=1
 195         ],
 196         [AC_MSG_RESULT(no)]
 197 )
 198
 199 AC_MSG_CHECKING([for u_intXX_t types])
 200 AC_TRY_COMPILE(
 201         [#include <sys/types.h>],
 202         [u_int16_t c; u_int32_t d; c = 1235; d = 1235;],
 203         [
 204                 AC_DEFINE(HAVE_U_INTXX_T)
 205                 AC_MSG_RESULT(yes)
 206                 have_u_intxx_t=1
 207         ],
 208         [AC_MSG_RESULT(no)]
 209 )
 210
 211 if test -z "$have_u_intxx_t" -o -z "$have_intxx_t" -a \
 212            "x$ac_cv_header_sys_bitypes_h" = "xyes"
 213 then
 214         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 215         AC_TRY_COMPILE(
 216                 [#include <sys/bitypes.h>],
 217                 [
 218                         u_int16_t c; u_int32_t d;
 219                         int16_t e; int32_t f;
 220                         c = 1235; d = 1235;
 221                         e = 1235; f = 1235;
 222                 ],
 223                 [
 224                         AC_DEFINE(HAVE_U_INTXX_T)
 225                         AC_DEFINE(HAVE_INTXX_T)
 226                         AC_MSG_RESULT(yes)
 227                 ],
 228                 [AC_MSG_RESULT(no)]
 229         )
 230 fi
 231
 232 AC_MSG_CHECKING([for uintXX_t types])
 233 AC_TRY_COMPILE(
 234         [#include <sys/types.h>],
 235         [uint16_t c; uint32_t d; c = 1235; d = 1235;],
 236         [
 237                 AC_DEFINE(HAVE_UINTXX_T)
 238                 AC_MSG_RESULT(yes)
 239         ],
 240         [AC_MSG_RESULT(no)]
 241 )
 242
 243 AC_MSG_CHECKING([for socklen_t])
 244 AC_TRY_COMPILE(
 245         [
 246                 #include <sys/types.h>
 247                 #include <sys/socket.h>
 248         ],
 249         [socklen_t foo; foo = 1235;],
 250         [
 251                 AC_DEFINE(HAVE_SOCKLEN_T)
 252                 AC_MSG_RESULT(yes)
 253         ],
 254         [AC_MSG_RESULT(no)]
 255 )
 256
 257 AC_MSG_CHECKING([for size_t])
 258 AC_TRY_COMPILE(
 259         [#include <sys/types.h>],
 260         [size_t foo; foo = 1235;],
 261         [
 262                 AC_DEFINE(HAVE_SIZE_T)
 263                 AC_MSG_RESULT(yes)
 264         ],
 265         [AC_MSG_RESULT(no)]
 266 )
 267
 268 AC_MSG_CHECKING([for struct sockaddr_storage])
 269 AC_TRY_COMPILE(
 270         [
 271                 #include <sys/types.h>
 272                 #include <sys/socket.h>
 273         ],
 274         [struct sockaddr_storage s;],
 275         [
 276                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 277                 AC_MSG_RESULT(yes)
 278         ],
 279         [AC_MSG_RESULT(no)]
 280 )
 281
 282 AC_MSG_CHECKING([for struct sockaddr_in6])
 283 AC_TRY_COMPILE(
 284         [#include <netinet/in.h>],
 285         [struct sockaddr_in6 s; s.sin6_family = 0;],
 286         [
 287                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 288                 AC_MSG_RESULT(yes)
 289         ],
 290         [AC_MSG_RESULT(no)]
 291 )
 292
 293 AC_MSG_CHECKING([for struct in6_addr])
 294 AC_TRY_COMPILE(
 295         [#include <netinet/in.h>],
 296         [struct in6_addr s; s.s6_addr[0] = 0;],
 297         [
 298                 AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 299                 AC_MSG_RESULT(yes)
 300         ],
 301         [AC_MSG_RESULT(no)]
 302 )
 303
 304 AC_MSG_CHECKING([for struct addrinfo])
 305 AC_TRY_COMPILE(
 306         [
 307                 #include <sys/types.h>
 308                 #include <sys/socket.h>
 309                 #include <netdb.h>
 310         ],
 311         [struct addrinfo s; s.ai_flags = AI_PASSIVE;],
 312         [
 313                 AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 314                 AC_MSG_RESULT(yes)
 315         ],
 316         [AC_MSG_RESULT(no)]
 317 )
 318
 319 AC_ARG_WITH(pam,
 320         [  --without-pam           Disable PAM support ],
 321         [
 322                 if test "x$withval" = "xno" ; then
 323                         no_pam=1
 324                         AC_DEFINE(DISABLE_PAM)
 325                 fi
 326         ]
 327 )
 328
 329 if test -z "$no_pam" -a "x$ac_cv_header_security_pam_appl_h" = "xyes" ; then
 330         AC_CHECK_LIB(dl, dlopen, , )
 331         LIBS="$LIBS -lpam"
 332         dnl Check PAM strerror arguments
 333         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 334         AC_TRY_COMPILE(
 335                 [
 336                         #include <stdlib.h>
 337                         #include <security/pam_appl.h>
 338                 ],
 339                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 340                 [AC_MSG_RESULT(no)],
 341                 [
 342                         AC_DEFINE(HAVE_OLD_PAM)
 343                         AC_MSG_RESULT(yes)
 344                 ]
 345         )
 346 fi
 347
 348 AC_MSG_CHECKING([whether to build GNOME ssh-askpass])
 349 dnl Check whether user wants GNOME ssh-askpass
 350 AC_ARG_WITH(gnome-askpass,
 351         [  --with-gnome-askpass    Build the GNOME passphrase requester (default=no)],
 352         [
 353                 if test x$withval = xno ; then
 354                         GNOME_ASKPASS="";
 355                 else
 356                         GNOME_ASKPASS="gnome-ssh-askpass";
 357                 fi
 358         ])
 359 AC_SUBST(GNOME_ASKPASS)
 360
 361 if test -z "$GNOME_ASKPASS" ; then
 362         AC_MSG_RESULT(no)
 363 else
 364         AC_MSG_RESULT(yes)
 365 fi
 366
 367 dnl Check for user-specified random device
 368 AC_ARG_WITH(random,
 369         [  --with-random=FILE      read randomness from FILE (default=/dev/urandom)],
 370         [
 371                 RANDOM_POOL="$withval";
 372                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 373         ],
 374         [
 375                 dnl Check for random device
 376                 AC_CHECK_FILE("/dev/urandom",
 377                         [
 378                                 RANDOM_POOL="/dev/urandom";
 379                                 AC_SUBST(RANDOM_POOL)
 380                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 381                         ]
 382                 )
 383         ]
 384 )
 385
 386 dnl Check for EGD pool file
 387 AC_ARG_WITH(egd-pool,
 388         [  --with-egd-pool=FILE    read randomness from EGD pool FILE (default none)],
 389         [
 390                 RANDOM_POOL="$withval";
 391                 AC_DEFINE(HAVE_EGD)
 392                 AC_SUBST(RANDOM_POOL)
 393                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 394         ]
 395 )
 396
 397 dnl Make sure we have random number support
 398 if test -z "$RANDOM_POOL" -a -z "$EGD_POOL"; then
 399         AC_MSG_ERROR([No random device found, and no EGD random pool specified])
 400 fi
 401
 402 AC_MSG_CHECKING([whether utmp.h has ut_host field])
 403 AC_EGREP_HEADER(ut_host, utmp.h,
 404         [AC_DEFINE(HAVE_HOST_IN_UTMP) AC_MSG_RESULT(yes); ],
 405         [AC_MSG_RESULT(no)]
 406 )
 407 AC_MSG_CHECKING([whether utmpx.h has ut_host field])
 408 AC_EGREP_HEADER(ut_host, utmpx.h,
 409         [AC_DEFINE(HAVE_HOST_IN_UTMPX) AC_MSG_RESULT(yes); ],
 410         [AC_MSG_RESULT(no)]
 411 )
 412 AC_MSG_CHECKING([whether utmpx.h has syslen field])
 413 AC_EGREP_HEADER(syslen, utmpx.h,
 414         [AC_DEFINE(HAVE_SYSLEN_IN_UTMPX) AC_MSG_RESULT(yes); ],
 415         [AC_MSG_RESULT(no)]
 416 )
 417 AC_MSG_CHECKING([whether utmp.h has ut_pid field])
 418 AC_EGREP_HEADER(ut_pid, utmp.h,
 419         [AC_DEFINE(HAVE_PID_IN_UTMP) AC_MSG_RESULT(yes); ],
 420         [AC_MSG_RESULT(no)]
 421 )
 422 AC_MSG_CHECKING([whether utmp.h has ut_type field])
 423 AC_EGREP_HEADER(ut_type, utmp.h,
 424         [AC_DEFINE(HAVE_TYPE_IN_UTMP) AC_MSG_RESULT(yes); ],
 425         [AC_MSG_RESULT(no)]
 426 )
 427 AC_MSG_CHECKING([whether utmp.h has ut_tv field])
 428 AC_EGREP_HEADER(ut_tv, utmp.h,
 429         [AC_DEFINE(HAVE_TV_IN_UTMP) AC_MSG_RESULT(yes); ],
 430         [AC_MSG_RESULT(no)]
 431 )
 432 AC_MSG_CHECKING([whether utmp.h has ut_id field])
 433 AC_EGREP_HEADER(ut_id, utmp.h,
 434         [AC_DEFINE(HAVE_ID_IN_UTMP) AC_MSG_RESULT(yes); ],
 435         [AC_MSG_RESULT(no)]
 436 )
 437 AC_MSG_CHECKING([whether utmp.h has ut_addr field])
 438 AC_EGREP_HEADER(ut_addr, utmp.h,
 439         [AC_DEFINE(HAVE_ADDR_IN_UTMP) AC_MSG_RESULT(yes); ],
 440         [AC_MSG_RESULT(no)]
 441 )
 442 AC_MSG_CHECKING([whether utmpx.h has ut_addr field])
 443 AC_EGREP_HEADER(ut_addr, utmpx.h,
 444         [AC_DEFINE(HAVE_ADDR_IN_UTMPX) AC_MSG_RESULT(yes); ],
 445         [AC_MSG_RESULT(no)]
 446 )
 447 AC_MSG_CHECKING([whether utmp.h has ut_addr_v6 field])
 448 AC_EGREP_HEADER(ut_addr_v6, utmp.h,
 449         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMP) AC_MSG_RESULT(yes); ],
 450         [AC_MSG_RESULT(no)]
 451 )
 452 AC_MSG_CHECKING([whether utmpx.h has ut_addr_v6 field])
 453 AC_EGREP_HEADER(ut_addr_v6, utmpx.h,
 454         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMPX) AC_MSG_RESULT(yes); ],
 455         [AC_MSG_RESULT(no)]
 456 )
 457
 458 AC_MSG_CHECKING([whether struct sockaddr_storage has ss_family field])
 459 AC_TRY_COMPILE(
 460         [
 461                 #include <sys/types.h>
 462                 #include <sys/socket.h>
 463         ],
 464         [struct sockaddr_storage s; s.ss_family = 1;],
 465         [
 466                 AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 467                 AC_MSG_RESULT(yes)
 468         ],
 469         [AC_MSG_RESULT(no)]
 470 )
 471 AC_MSG_CHECKING([whether struct sockaddr_storage has __ss_family field])
 472 AC_TRY_COMPILE(
 473         [
 474                 #include <sys/types.h>
 475                 #include <sys/socket.h>
 476         ],
 477         [struct sockaddr_storage s; s.__ss_family = 1;],
 478         [
 479                 AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 480                 AC_MSG_RESULT(yes)
 481         ],
 482         [AC_MSG_RESULT(no)]
 483 )
 484
 485 dnl Look for lastlog location
 486 AC_ARG_WITH(lastlog,
 487         [  --with-lastlog=FILE     Location of lastlog file],
 488         [
 489                 if test "x$withval" = "xno" ; then
 490                         AC_DEFINE(DISABLE_LASTLOG)
 491                 else
 492                         AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$withval")
 493                 fi
 494         ],
 495         [
 496                 AC_MSG_CHECKING([location of lastlog file])
 497                 for lastlog in /var/log/lastlog /var/adm/lastlog /usr/adm/lastlog  /etc/security/lastlog ; do
 498                         if test -f $lastlog ; then
 499                                 gotlastlog="file"
 500                                 break
 501                         fi
 502                         if test -d $lastlog ; then
 503                                 gotlastlog="dir"
 504                                 break
 505                         fi
 506                 done
 507                 if test -z "$gotlastlog" ; then
 508                         AC_MSG_RESULT(not found)
 509                         nolastlog=1
 510                 else
 511                         if test "x$gotlastlog" = "xdir" ; then
 512                                 AC_MSG_RESULT(${lastlog}/)
 513                                 AC_DEFINE(LASTLOG_IS_DIR)
 514                         else
 515                                 AC_MSG_RESULT($lastlog)
 516                                 AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$lastlog")
 517                         fi
 518                 fi
 519         ]
 520 )
 521
 522 if test ! -z "$nolastlog" ; then
 523         AC_MSG_WARN([*** Disabling lastlog support *** ])
 524         AC_DEFINE(DISABLE_LASTLOG)
 525 fi
 526
 527 dnl Compile with dante SOCKS library
 528 AC_ARG_WITH(dante,
 529         [  --with-dante=DIR        Use Dante SOCKS lib (default is system library path)],
 530         [
 531                 SAVELIBS="$LIBS"
 532                 SOCKSLIBS=""
 533                 SOCKSLIBPATH=""
 534                 if test "x$withval" != "xno" ; then
 535                         if test -n $withval ; then
 536                                 LIBS="$LIBS -L$withval"
 537                                 SOCKSLIBPATH="-L$withval"
 538                         fi
 539                         AC_CHECK_LIB(socks, Rconnect, AC_DEFINE(HAVE_DANTE) SOCKSLIBS="$SOCKSLIBPATH -lsocks")
 540                 fi
 541                 LIBS="$SAVELIBS $SOCKSLIBS"
 542         ]
 543 )
 544
 545 dnl Compile with SOCKS4 SOCKS library
 546 AC_ARG_WITH(socks4,
 547         [  --with-socks4=DIR        Use Socks4 SOCKS lib (default is system library path)],
 548         [
 549                 SAVELIBS="$LIBS"
 550                 SOCKSLIBS=""
 551                 SOCKSLIBPATH=""
 552                 if test "x$withval" != "xno" ; then
 553                         if test -n $withval ; then
 554                                 LIBS="$LIBS -L$withval"
 555                                 SOCKSLIBPATH="-L$withval"
 556                         fi
 557                         AC_CHECK_LIB(socks, Rconnect, AC_DEFINE(HAVE_SOCKS4) SOCKSLIBS="$SOCKSLIBPATH -lsocks")
 558                 fi
 559                 LIBS="$SAVELIBS $SOCKSLIBS"
 560         ]
 561 )
 562
 563 dnl Compile with SOCKS5 SOCKS library
 564 AC_ARG_WITH(socks5,
 565         [  --with-socks5=DIR        Use Socks5 SOCKS lib (default is system library path)],
 566         [
 567                 SAVELIBS="$LIBS"
 568                 SOCKSLIBS=""
 569                 SOCKSLIBPATH=""
 570                 if test "x$withval" != "xno" ; then
 571                         if test -n $withval ; then
 572                                 LIBS="$LIBS -L$withval"
 573                                 SOCKSLIBPATH="-L$withval"
 574                         fi
 575                         AC_CHECK_LIB(socks5, SOCKSconnect, AC_DEFINE(HAVE_SOCKS5) SOCKSLIBS="$SOCKSLIBPATH -lsocks5")
 576                 fi
 577                 LIBS="$SAVELIBS $SOCKSLIBS"
 578         ]
 579 )
 580 AC_ARG_WITH(catman,
 581         [  --with-catman=man|cat   Install preformatted manpages[no]],
 582         [
 583                 MANTYPE='$(CATMAN)'
 584                 if test x"$withval" != x"yes" ; then
 585                    mansubdir=$withval
 586                 else
 587                    mansubdir=cat
 588                 fi
 589         ], [
 590                 if test -z "$MANTYPE" ; then
 591                         MANTYPE='$(TROFFMAN)'
 592                         mansubdir=man
 593                 fi
 594         ]
 595 )
 596 AC_SUBST(MANTYPE)
 597 AC_SUBST(mansubdir)
 598
 599 if test -z "$no_dev_ptmx" ; then
 600         AC_CHECK_FILE("/dev/ptmx", AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX))
 601 fi
 602 AC_CHECK_FILE("/dev/ptc", AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC))
 603
 604 AC_MSG_CHECKING([whether libc defines __progname])
 605 AC_TRY_LINK([],
 606         [extern char *__progname; printf("%s", __progname);],
 607         [
 608                 AC_DEFINE(HAVE___PROGNAME)
 609                 AC_MSG_RESULT(yes)
 610         ],
 611         [
 612                 AC_MSG_RESULT(no)
 613         ]
 614 )
 615
 616 dnl Check whether user wants Kerberos support
 617 AC_ARG_WITH(kerberos4,
 618         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
 619         [
 620                 if test "x$withval" != "$xno" ; then
 621
 622                         if test "x$withval" != "$xyes" ; then
 623                                 CFLAGS="$CFLAGS -I${withval}/include"
 624                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 625                         else
 626                                 if test -d /usr/include/kerberosIV ; then
 627                                         CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 628                                 fi
 629                         fi
 630
 631                         AC_CHECK_HEADERS(krb.h)
 632                         AC_CHECK_LIB(krb, main)
 633                         if test "$ac_cv_header_krb_h" != yes; then
 634                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
 635                         fi
 636                         if test "$ac_cv_lib_krb_main" != yes; then
 637                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
 638                         fi
 639
 640                         KLIBS="-lkrb -ldes"
 641                         AC_CHECK_LIB(resolv, dn_expand, , )
 642                         KRB4=yes
 643                         AC_DEFINE(KRB4)
 644                 fi
 645         ]
 646 )
 647
 648 dnl Check whether user wants AFS support
 649 AC_ARG_WITH(afs,
 650         [  --with-afs=PATH         Enable AFS support],
 651         [
 652                 if test "x$withval" != "$xno" ; then
 653
 654                         if test "x$withval" != "$xyes" ; then
 655                                 CFLAGS="$CFLAGS -I${withval}/include"
 656                                 LFLAGS="$LFLAGS -L${withval}/lib"
 657                         fi
 658
 659                         if test -z "$KRB4" ; then
 660                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
 661                         fi
 662
 663                         LIBS="$LIBS -lkafs"
 664                         if test ! -z "$AFS_LIBS" ; then
 665                                 LIBS="$LIBS $AFS_LIBS"
 666                         fi
 667                         AC_DEFINE(AFS)
 668                 fi
 669         ]
 670 )
 671 LIBS="$LIBS $KLIBS"
 672
 673 dnl Check whether user wants S/Key support
 674 AC_ARG_WITH(skey,
 675         [  --with-skey             Enable S/Key support],
 676         [
 677                 if test "x$withval" != "$xno" ; then
 678                         AC_DEFINE(SKEY)
 679                         LIBS="$LIBS -lskey"
 680                 fi
 681         ]
 682 )
 683
 684 dnl Check whether user wants TCP wrappers support
 685 AC_ARG_WITH(tcp-wrappers,
 686         [  --with-tcp-wrappers     Enable tcpwrappers support],
 687         [
 688                 if test "x$withval" != "$xno" ; then
 689                         AC_DEFINE(LIBWRAP)
 690                         LIBS="$LIBS -lwrap"
 691                 fi
 692         ]
 693 )
 694
 695 dnl Check whether to enable MD5 passwords
 696 AC_ARG_WITH(md5-passwords,
 697         [  --with-md5-passwords    Enable use of MD5 passwords],
 698         [
 699                 if test "x$withval" != "$xno" ; then
 700                         AC_DEFINE(HAVE_MD5_PASSWORDS)
 701                 fi
 702         ]
 703 )
 704
 705 dnl Check whether to enable utmpx support
 706 AC_ARG_WITH(utmpx,
 707         [  --with-utmpx            Enable utmpx support],
 708         [
 709                 if test "x$withval" != "xno" ; then
 710                         AC_DEFINE(USE_UTMPX)
 711                 fi
 712         ]
 713 )
 714
 715 dnl Whether to disable shadow password support
 716 AC_ARG_WITH(shadow,
 717         [  --without-shadow        Disable shadow password support],
 718         [
 719                 if test "x$withval" = "xno" ; then
 720                         AC_DEFINE(DISABLE_SHADOW)
 721                 fi
 722         ]
 723 )
 724
 725 dnl Use ip address instead of hostname in $DISPLAY
 726 AC_ARG_WITH(ipaddr-display,
 727         [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
 728         [
 729                 if test "x$withval" = "xno" ; then
 730                         AC_DEFINE(IPADDR_IN_DISPLAY)
 731                 fi
 732         ]
 733 )
 734
 735 AC_ARG_WITH(default-path,
 736         [  --with-default-path=PATH Specify default \$PATH environment for server],
 737         [
 738                 if test "x$withval" != "xno" ; then
 739                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
 740                 fi
 741         ]
 742 )
 743
 744 AC_ARG_WITH(ipv4-default,
 745         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
 746         [
 747                 if test "x$withval" != "xno" ; then
 748                         AC_DEFINE(IPV4_DEFAULT)
 749                 fi
 750         ]
 751 )
 752
 753 piddir=/var/run
 754 AC_ARG_WITH(pid-dir,
 755         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
 756         [
 757                 if test "x$withval" != "xno" ; then
 758                         piddir=$withval
 759                 fi
 760         ]
 761 )
 762 AC_DEFINE_UNQUOTED(PIDDIR, "$piddir")
 763 AC_SUBST(piddir)
 764
 765 dnl Check for mail directory (last resort if we cannot get it from headers)
 766 if test ! -z "$MAIL" ; then
 767         maildir=`dirname $MAIL`
 768         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
 769 fi
 770
 771 AC_OUTPUT(Makefile)