configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_PROG_CC
   5 AC_CANONICAL_HOST
   6
   7 # Checks for programs.
   8 AC_PROG_CPP
   9 AC_PROG_RANLIB
  10 AC_PROG_INSTALL
  11 AC_CHECK_PROG(AR, ar, ar)
  12 AC_PATH_PROG(PERL, perl)
  13 AC_SUBST(PERL)
  14
  15 if test -z "$LD" ; then
  16         LD=$CC
  17 fi
  18 AC_SUBST(LD)
  19
  20 # C Compiler features
  21 AC_C_INLINE
  22 if test "$GCC" = "yes"; then
  23         CFLAGS="$CFLAGS -Wall"
  24 fi
  25
  26 # Check for some target-specific stuff
  27 case "$host" in
  28 *-*-aix*)
  29         AFS_LIBS="-lld"
  30         CFLAGS="$CFLAGS -I/usr/local/include"
  31         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  32         if test "$LD" != "gcc" -a -z "$blibpath"; then
  33                 blibpath="/usr/lib:/lib:/usr/local/lib"
  34         fi
  35         AC_DEFINE(BROKEN_GETADDRINFO)
  36         ;;
  37 *-*-hpux10*)
  38         if test -z "$GCC"; then
  39                 CFLAGS="$CFLAGS -Aa"
  40         fi
  41         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  42         CFLAGS="$CFLAGS -I/usr/local/include"
  43         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  44         AC_DEFINE(IPADDR_IN_DISPLAY)
  45         AC_DEFINE(USE_UTMPX)
  46         AC_MSG_CHECKING(for HPUX trusted system password database)
  47         if test -f /tcb/files/auth/system/default; then
  48                 AC_MSG_RESULT(yes)
  49                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  50                 LIBS="$LIBS -lsec"
  51                 AC_MSG_WARN([This configuration is untested])
  52         else
  53                 AC_MSG_RESULT(no)
  54                 AC_DEFINE(DISABLE_SHADOW)
  55         fi
  56         MANTYPE='$(CATMAN)'
  57         mansubdir=cat
  58         ;;
  59 *-*-irix5*)
  60         CFLAGS="$CFLAGS -I/usr/local/include"
  61         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  62         MANTYPE='$(CATMAN)'
  63         no_libsocket=1
  64         no_libnsl=1
  65         ;;
  66 *-*-irix6*)
  67         CFLAGS="$CFLAGS -I/usr/local/include"
  68         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  69         MANTYPE='$(CATMAN)'
  70         AC_MSG_WARN([*** Irix 6.x is not tested, please report you experiences *** ])
  71         no_libsocket=1
  72         no_libnsl=1
  73         ;;
  74 *-*-linux*)
  75         no_dev_ptmx=1
  76         AC_DEFINE(DONT_TRY_OTHER_AF)
  77         inet6_default_4in6=yes
  78         ;;
  79 *-*-netbsd*)
  80         need_dash_r=1
  81         ;;
  82 *-*-solaris*)
  83         CFLAGS="$CFLAGS -I/usr/local/include"
  84         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib -L/usr/ucblib -R/usr/ucblib"
  85         need_dash_r=1
  86         AC_DEFINE(USE_UTMPX)
  87         ;;
  88 *-*-sysv*)
  89         CFLAGS="$CFLAGS -I/usr/local/include"
  90         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  91         AC_DEFINE(USE_UTMPX)
  92         MANTYPE='$(CATMAN)'
  93         mansubdir=cat
  94         LIBS="$LIBS -lgen -lsocket"
  95         ;;
  96 esac
  97
  98 # Checks for libraries.
  99 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
 100 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
 101
 102 if test -z "$no_libsocket" ; then
 103         AC_CHECK_LIB(nsl, yp_match, , )
 104 fi
 105 if test -z "$no_libnsl" ; then
 106         AC_CHECK_LIB(socket, main, , )
 107 fi
 108
 109 # Checks for header files.
 110 AC_CHECK_HEADERS(bstring.h endian.h lastlog.h login.h maillock.h netdb.h netgroup.h paths.h poll.h pty.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/select.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h stddef.h util.h utmp.h utmpx.h)
 111
 112 # Checks for library functions.
 113 AC_CHECK_FUNCS(arc4random bindresvport_af clock freeaddrinfo gai_strerror getaddrinfo getnameinfo getrusage innetgr md5_crypt mkdtemp openpty rresvport_af setenv seteuid setlogin setproctitle setreuid snprintf strlcat strlcpy updwtmpx vsnprintf _getpty)
 114
 115 AC_CHECK_FUNC(login,
 116         [AC_DEFINE(HAVE_LOGIN)],
 117         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 118 )
 119
 120 AC_CHECK_FUNC(daemon,
 121         [AC_DEFINE(HAVE_DAEMON)],
 122         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 123 )
 124
 125 AC_CHECK_FUNC(getpagesize,
 126         [AC_DEFINE(HAVE_GETPAGESIZE)],
 127         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 128 )
 129
 130 AC_ARG_WITH(pam,
 131         [  --without-pam           Disable PAM support ],
 132         [
 133                 if test "x$withval" = "xno" ; then
 134                         no_pam=1
 135                         AC_DEFINE(DISABLE_PAM)
 136                 fi
 137         ]
 138 )
 139 if test -z "$no_pam" -a "x$ac_cv_header_security_pam_appl_h" = "xyes" ; then
 140         AC_CHECK_LIB(dl, dlopen, , )
 141         LIBS="$LIBS -lpam"
 142
 143         # Check PAM strerror arguments (old PAM)
 144         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 145         AC_TRY_COMPILE(
 146                 [
 147                         #include <stdlib.h>
 148                         #include <security/pam_appl.h>
 149                 ],
 150                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 151                 [AC_MSG_RESULT(no)],
 152                 [
 153                         AC_DEFINE(HAVE_OLD_PAM)
 154                         AC_MSG_RESULT(yes)
 155                 ]
 156         )
 157 fi
 158
 159 # The big search for OpenSSL
 160 AC_ARG_WITH(ssl-dir,
 161         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 162         [
 163                 if test "x$withval" != "$xno" ; then
 164                         tryssldir=$withval
 165                 fi
 166         ]
 167 )
 168
 169 saved_LIBS="$LIBS"
 170 saved_LDFLAGS="$LDFLAGS"
 171 saved_CFLAGS="$CFLAGS"
 172 if test "x$prefix" != "xNONE" ; then
 173         tryssldir="$tryssldir $prefix"
 174 fi
 175 AC_MSG_CHECKING([for OpenSSL/SSLeay directory])
 176 for ssldir in "" $tryssldir /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 177         if test ! -z "$ssldir" ; then
 178                 LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 179                 CFLAGS="$saved_CFLAGS -I$ssldir/include"
 180                 if test ! -z "$need_dash_r" ; then
 181                         LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 182                 fi
 183         else
 184                 LDFLAGS="$saved_LDFLAGS"
 185         fi
 186
 187         for WANTS_RSAREF in "" 1 ; do
 188
 189                 if test -z "$WANTS_RSAREF" ; then
 190                         LIBS="$saved_LIBS -lcrypto"
 191                 else
 192                         LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 193                 fi
 194
 195                 AC_TRY_RUN(
 196                         [
 197                                 #include <openssl/rsa.h>
 198                                 #include <openssl/bn.h>
 199                                 #include <openssl/sha.h>
 200                                 int main(void)
 201                                 {
 202                                         RSA *key; char a[2048],b[2048];;
 203                                         memset(a, 0, sizeof(a));memset(b, 0, sizeof(b));
 204                                         RAND_add(a, sizeof(a), sizeof(a));
 205                                         key=RSA_generate_key(32,3,NULL,NULL);
 206                                         if (key==NULL) return(1);
 207                                         return(-1==RSA_private_decrypt(RSA_size(key),a,b,key,RSA_NO_PADDING));
 208                                 }
 209                         ],
 210                         [
 211                                 AC_DEFINE(HAVE_OPENSSL)
 212                                 found_crypto=1
 213                                 break;
 214                         ], []
 215                 )
 216                 AC_TRY_RUN(
 217                         [
 218                                 #include <ssl/rsa.h>
 219                                 #include <ssl/bn.h>
 220                                 #include <ssl/sha.h>
 221                                 int main(void)
 222                                 {
 223                                         RSA *key; char a[2048],b[2048];;
 224                                         memset(a, 0, sizeof(a));memset(b, 0, sizeof(b));
 225                                         RAND_seed(a, sizeof(a));
 226                                         key=RSA_generate_key(32,3,NULL,NULL);
 227                                         if (key==NULL) return(1);
 228                                         return(-1==RSA_private_decrypt(RSA_size(key),a,b,key,RSA_NO_PADDING));
 229                                 }
 230                         ],
 231                         [
 232                                 AC_DEFINE(HAVE_SSL)
 233                                 found_crypto=1
 234                                 break;
 235                         ], []
 236                 )
 237         done
 238
 239         if test ! -z "$found_crypto" ; then
 240                 break;
 241         fi
 242 done
 243
 244 if test -z "$found_crypto" ; then
 245         AC_MSG_ERROR([Could not find working SSLeay / OpenSSL libraries, please install])
 246 fi
 247 if test -z "$ssldir" ; then
 248         ssldir="(system)"
 249 else
 250         CFLAGS="$saved_CFLAGS -I$ssldir/include"
 251         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 252         if test ! -z "$need_dash_r" ; then
 253                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 254         fi
 255         if test ! -z "$blibpath" ; then
 256                 blibpath="$blibpath:$ssldir:$ssldir/lib"
 257         fi
 258 fi
 259 if test -z "$WANTS_RSAREF" ; then
 260         LIBS="$saved_LIBS -lcrypto"
 261 else
 262         LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 263 fi
 264 AC_MSG_RESULT($ssldir)
 265
 266 # Checks for data types
 267 AC_CHECK_SIZEOF(char, 1)
 268 AC_CHECK_SIZEOF(short int, 2)
 269 AC_CHECK_SIZEOF(int, 4)
 270 AC_CHECK_SIZEOF(long int, 4)
 271 AC_CHECK_SIZEOF(long long int, 8)
 272
 273 # More checks for data types
 274 AC_MSG_CHECKING([for intXX_t types])
 275 AC_TRY_COMPILE(
 276         [#include <sys/types.h>],
 277         [int8_t a; int16_t b; int32_t c; a = b = c = 1;],
 278         [
 279                 AC_DEFINE(HAVE_INTXX_T)
 280                 AC_MSG_RESULT(yes)
 281                 have_intxx_t=1
 282         ],
 283         [AC_MSG_RESULT(no)]
 284 )
 285
 286 AC_MSG_CHECKING([for u_intXX_t types])
 287 AC_TRY_COMPILE(
 288         [#include <sys/types.h>],
 289         [u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
 290         [
 291                 AC_DEFINE(HAVE_U_INTXX_T)
 292                 AC_MSG_RESULT(yes)
 293                 have_u_intxx_t=1
 294         ],
 295         [AC_MSG_RESULT(no)]
 296 )
 297
 298 if test -z "$have_u_intxx_t" -o -z "$have_intxx_t" -a \
 299            "x$ac_cv_header_sys_bitypes_h" = "xyes"
 300 then
 301         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 302         AC_TRY_COMPILE(
 303                 [#include <sys/bitypes.h>],
 304                 [
 305                         int8_t a; int16_t b; int32_t c;
 306                         u_int8_t e; u_int16_t f; u_int32_t g;
 307                         a = b = c = e = f = g = 1;
 308                 ],
 309                 [
 310                         AC_DEFINE(HAVE_U_INTXX_T)
 311                         AC_DEFINE(HAVE_INTXX_T)
 312                         AC_MSG_RESULT(yes)
 313                 ],
 314                 [AC_MSG_RESULT(no)]
 315         )
 316 fi
 317
 318 if test -z "$have_u_intxx_t" ; then
 319         AC_MSG_CHECKING([for uintXX_t types])
 320         AC_TRY_COMPILE(
 321                 [#include <sys/types.h>],
 322                 [uint8_t a; uint16_t b; uint32_t c; a = b = c = 1;],
 323                 [
 324                         AC_DEFINE(HAVE_UINTXX_T)
 325                         AC_MSG_RESULT(yes)
 326                 ],
 327                 [AC_MSG_RESULT(no)]
 328         )
 329 fi
 330
 331 AC_MSG_CHECKING([for socklen_t])
 332 AC_TRY_COMPILE(
 333         [
 334                 #include <sys/types.h>
 335                 #include <sys/socket.h>
 336         ],
 337         [socklen_t foo; foo = 1235;],
 338         [
 339                 AC_DEFINE(HAVE_SOCKLEN_T)
 340                 AC_MSG_RESULT(yes)
 341         ],
 342         [AC_MSG_RESULT(no)]
 343 )
 344
 345 AC_MSG_CHECKING([for size_t])
 346 AC_TRY_COMPILE(
 347         [#include <sys/types.h>],
 348         [size_t foo; foo = 1235;],
 349         [
 350                 AC_DEFINE(HAVE_SIZE_T)
 351                 AC_MSG_RESULT(yes)
 352         ],
 353         [AC_MSG_RESULT(no)]
 354 )
 355
 356 AC_MSG_CHECKING([for struct sockaddr_storage])
 357 AC_TRY_COMPILE(
 358         [
 359                 #include <sys/types.h>
 360                 #include <sys/socket.h>
 361         ],
 362         [struct sockaddr_storage s;],
 363         [
 364                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 365                 AC_MSG_RESULT(yes)
 366         ],
 367         [AC_MSG_RESULT(no)]
 368 )
 369
 370 AC_MSG_CHECKING([for struct sockaddr_in6])
 371 AC_TRY_COMPILE(
 372         [#include <netinet/in.h>],
 373         [struct sockaddr_in6 s; s.sin6_family = 0;],
 374         [
 375                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 376                 AC_MSG_RESULT(yes)
 377         ],
 378         [AC_MSG_RESULT(no)]
 379 )
 380
 381 AC_MSG_CHECKING([for struct in6_addr])
 382 AC_TRY_COMPILE(
 383         [#include <netinet/in.h>],
 384         [struct in6_addr s; s.s6_addr[0] = 0;],
 385         [
 386                 AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 387                 AC_MSG_RESULT(yes)
 388         ],
 389         [AC_MSG_RESULT(no)]
 390 )
 391
 392 AC_MSG_CHECKING([for struct addrinfo])
 393 AC_TRY_COMPILE(
 394         [
 395                 #include <sys/types.h>
 396                 #include <sys/socket.h>
 397                 #include <netdb.h>
 398         ],
 399         [struct addrinfo s; s.ai_flags = AI_PASSIVE;],
 400         [
 401                 AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 402                 AC_MSG_RESULT(yes)
 403         ],
 404         [AC_MSG_RESULT(no)]
 405 )
 406
 407 # Checks for structure members
 408 AC_MSG_CHECKING([whether utmp.h has ut_host field])
 409 AC_EGREP_HEADER(ut_host, utmp.h,
 410         [AC_DEFINE(HAVE_HOST_IN_UTMP) AC_MSG_RESULT(yes); ],
 411         [AC_MSG_RESULT(no)]
 412 )
 413 AC_MSG_CHECKING([whether utmpx.h has ut_host field])
 414 AC_EGREP_HEADER(ut_host, utmpx.h,
 415         [AC_DEFINE(HAVE_HOST_IN_UTMPX) AC_MSG_RESULT(yes); ],
 416         [AC_MSG_RESULT(no)]
 417 )
 418 AC_MSG_CHECKING([whether utmpx.h has syslen field])
 419 AC_EGREP_HEADER(syslen, utmpx.h,
 420         [AC_DEFINE(HAVE_SYSLEN_IN_UTMPX) AC_MSG_RESULT(yes); ],
 421         [AC_MSG_RESULT(no)]
 422 )
 423 AC_MSG_CHECKING([whether utmp.h has ut_pid field])
 424 AC_EGREP_HEADER(ut_pid, utmp.h,
 425         [AC_DEFINE(HAVE_PID_IN_UTMP) AC_MSG_RESULT(yes); ],
 426         [AC_MSG_RESULT(no)]
 427 )
 428 AC_MSG_CHECKING([whether utmp.h has ut_type field])
 429 AC_EGREP_HEADER(ut_type, utmp.h,
 430         [AC_DEFINE(HAVE_TYPE_IN_UTMP) AC_MSG_RESULT(yes); ],
 431         [AC_MSG_RESULT(no)]
 432 )
 433 AC_MSG_CHECKING([whether utmp.h has ut_tv field])
 434 AC_EGREP_HEADER(ut_tv, utmp.h,
 435         [AC_DEFINE(HAVE_TV_IN_UTMP) AC_MSG_RESULT(yes); ],
 436         [AC_MSG_RESULT(no)]
 437 )
 438 AC_MSG_CHECKING([whether utmp.h has ut_id field])
 439 AC_EGREP_HEADER(ut_id, utmp.h,
 440         [AC_DEFINE(HAVE_ID_IN_UTMP) AC_MSG_RESULT(yes); ],
 441         [AC_MSG_RESULT(no)]
 442 )
 443 AC_MSG_CHECKING([whether utmp.h has ut_addr field])
 444 AC_EGREP_HEADER(ut_addr, utmp.h,
 445         [AC_DEFINE(HAVE_ADDR_IN_UTMP) AC_MSG_RESULT(yes); ],
 446         [AC_MSG_RESULT(no)]
 447 )
 448 AC_MSG_CHECKING([whether utmpx.h has ut_addr field])
 449 AC_EGREP_HEADER(ut_addr, utmpx.h,
 450         [AC_DEFINE(HAVE_ADDR_IN_UTMPX) AC_MSG_RESULT(yes); ],
 451         [AC_MSG_RESULT(no)]
 452 )
 453 AC_MSG_CHECKING([whether utmp.h has ut_addr_v6 field])
 454 AC_EGREP_HEADER(ut_addr_v6, utmp.h,
 455         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMP) AC_MSG_RESULT(yes); ],
 456         [AC_MSG_RESULT(no)]
 457 )
 458 AC_MSG_CHECKING([whether utmpx.h has ut_addr_v6 field])
 459 AC_EGREP_HEADER(ut_addr_v6, utmpx.h,
 460         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMPX) AC_MSG_RESULT(yes); ],
 461         [AC_MSG_RESULT(no)]
 462 )
 463
 464 AC_MSG_CHECKING([whether struct sockaddr_storage has ss_family field])
 465 AC_TRY_COMPILE(
 466         [
 467                 #include <sys/types.h>
 468                 #include <sys/socket.h>
 469         ],
 470         [struct sockaddr_storage s; s.ss_family = 1;],
 471         [
 472                 AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 473                 AC_MSG_RESULT(yes)
 474         ],
 475         [AC_MSG_RESULT(no)]
 476 )
 477 AC_MSG_CHECKING([whether struct sockaddr_storage has __ss_family field])
 478 AC_TRY_COMPILE(
 479         [
 480                 #include <sys/types.h>
 481                 #include <sys/socket.h>
 482         ],
 483         [struct sockaddr_storage s; s.__ss_family = 1;],
 484         [
 485                 AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 486                 AC_MSG_RESULT(yes)
 487         ],
 488         [AC_MSG_RESULT(no)]
 489 )
 490
 491 AC_MSG_CHECKING([whether libc defines __progname])
 492 AC_TRY_LINK([],
 493         [extern char *__progname; printf("%s", __progname);],
 494         [
 495                 AC_DEFINE(HAVE___PROGNAME)
 496                 AC_MSG_RESULT(yes)
 497         ],
 498         [
 499                 AC_MSG_RESULT(no)
 500         ]
 501 )
 502
 503 # Looking for programs, paths and files
 504 AC_ARG_WITH(rsh,
 505         [  --with-rsh=PATH         Specify path to remote shell program ],
 506         [
 507                 if test "x$withval" != "$no" ; then
 508                         AC_DEFINE_UNQUOTED(RSH_PATH, "$withval")
 509                 fi
 510         ],
 511         [
 512                 AC_PATH_PROG(rsh_path, rsh)
 513         ]
 514 )
 515
 516 AC_ARG_WITH(xauth,
 517         [  --with-xauth=PATH       Specify path to xauth program ],
 518         [
 519                 if test "x$withval" != "$xno" ; then
 520                         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$withval")
 521                 fi
 522         ],
 523         [
 524                 AC_PATH_PROG(xauth_path, xauth)
 525                 if test ! -z "$xauth_path" -a -x "/usr/openwin/bin/xauth" ; then
 526                         xauth_path="/usr/openwin/bin/xauth"
 527                 fi
 528         ]
 529 )
 530
 531 if test ! -z "$xauth_path" ; then
 532         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
 533 fi
 534 if test ! -z "$rsh_path" ; then
 535         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
 536 fi
 537
 538 # Check for mail directory (last resort if we cannot get it from headers)
 539 if test ! -z "$MAIL" ; then
 540         maildir=`dirname $MAIL`
 541         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
 542 fi
 543
 544 # Look for lastlog location
 545 AC_ARG_WITH(lastlog,
 546         [  --with-lastlog=FILE     Location of lastlog file],
 547         [
 548                 if test "x$withval" = "xno" ; then
 549                         AC_DEFINE(DISABLE_LASTLOG)
 550                 else
 551                         AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$withval")
 552                 fi
 553         ],
 554         [
 555                 AC_MSG_CHECKING([location of lastlog file])
 556                 for lastlog in /var/log/lastlog /var/adm/lastlog /usr/adm/lastlog  /etc/security/lastlog ; do
 557                         if test -f $lastlog ; then
 558                                 gotlastlog="file"
 559                                 break
 560                         fi
 561                         if test -d $lastlog ; then
 562                                 gotlastlog="dir"
 563                                 break
 564                         fi
 565                 done
 566                 if test -z "$gotlastlog" ; then
 567                         AC_MSG_RESULT(not found)
 568                         nolastlog=1
 569                 else
 570                         if test "x$gotlastlog" = "xdir" ; then
 571                                 AC_MSG_RESULT(${lastlog}/)
 572                                 AC_DEFINE(LASTLOG_IS_DIR)
 573                         else
 574                                 AC_MSG_RESULT($lastlog)
 575                                 AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$lastlog")
 576                         fi
 577                 fi
 578         ]
 579 )
 580
 581 if test ! -z "$nolastlog" ; then
 582         AC_MSG_WARN([*** Disabling lastlog support *** ])
 583         AC_DEFINE(DISABLE_LASTLOG)
 584 fi
 585
 586 if test -z "$no_dev_ptmx" ; then
 587         AC_CHECK_FILE("/dev/ptmx",
 588                 [
 589                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
 590                         have_dev_ptmx=1
 591                 ]
 592         )
 593 fi
 594 AC_CHECK_FILE("/dev/ptc",
 595         [
 596                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
 597                 have_dev_ptc=1
 598         ]
 599 )
 600
 601 # Options from here on. Some of these are preset by platform above
 602
 603 # Check for user-specified random device, otherwise check /dev/urandom
 604 AC_ARG_WITH(random,
 605         [  --with-random=FILE      read randomness from FILE (default=/dev/urandom)],
 606         [
 607                 if test "x$withval" != "xno" ; then
 608                         RANDOM_POOL="$withval";
 609                         AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 610                 fi
 611         ],
 612         [
 613                 # Check for random device
 614                 AC_CHECK_FILE("/dev/urandom",
 615                         [
 616                                 RANDOM_POOL="/dev/urandom";
 617                                 AC_SUBST(RANDOM_POOL)
 618                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 619                         ]
 620                 )
 621         ]
 622 )
 623
 624 # Check for EGD pool file
 625 AC_ARG_WITH(egd-pool,
 626         [  --with-egd-pool=FILE    read randomness from EGD pool FILE (default none)],
 627         [
 628                 if test "x$withval" != "xno" ; then
 629                         EGD_SOCKET="$withval";
 630                         AC_DEFINE_UNQUOTED(EGD_SOCKET, "$EGD_SOCKET")
 631                 fi
 632         ]
 633 )
 634
 635 if test -z "$RANDOM_POOL" -a -z "$EGD_SOCKET" ; then
 636         # Use these commands to collect entropy
 637         AC_PATH_PROG(PROG_LS, ls)
 638         AC_PATH_PROG(PROG_NETSTAT, netstat)
 639         AC_PATH_PROG(PROG_ARP, arp)
 640         AC_PATH_PROG(PROG_IFCONFIG, ifconfig)
 641         AC_PATH_PROG(PROG_PS, ps)
 642         AC_PATH_PROG(PROG_W, w)
 643         AC_PATH_PROG(PROG_WHO, who)
 644         AC_PATH_PROG(PROG_LAST, last)
 645         AC_PATH_PROG(PROG_LASTLOG, lastlog)
 646         AC_PATH_PROG(PROG_DF, df)
 647         AC_PATH_PROG(PROG_VMSTAT, vmstat)
 648         AC_PATH_PROG(PROG_UPTIME, uptime)
 649         AC_PATH_PROG(PROG_IPCS, ipcs)
 650         AC_PATH_PROG(PROG_TAIL, tail)
 651         AC_PATH_PROG(PROG_LS, ls)
 652         if test ! -z "$PROG_LS" ; then
 653                 AC_DEFINE_UNQUOTED(PROG_LS, "$PROG_LS")
 654         fi
 655         if test ! -z "$PROG_NETSTAT" ; then
 656                 AC_DEFINE_UNQUOTED(PROG_NETSTAT, "$PROG_NETSTAT")
 657         fi
 658         if test ! -z "$PROG_ARP" ; then
 659                 AC_DEFINE_UNQUOTED(PROG_ARP, "$PROG_ARP")
 660         fi
 661         if test ! -z "$PROG_IFCONFIG" ; then
 662                 AC_DEFINE_UNQUOTED(PROG_IFCONFIG, "$PROG_IFCONFIG")
 663         fi
 664         if test ! -z "$PROG_PS" ; then
 665                 AC_DEFINE_UNQUOTED(PROG_PS, "$PROG_PS")
 666         fi
 667         if test ! -z "$PROG_W" ; then
 668                 AC_DEFINE_UNQUOTED(PROG_W, "$PROG_W")
 669         fi
 670         if test ! -z "$PROG_WHO" ; then
 671                 AC_DEFINE_UNQUOTED(PROG_WHO, "$PROG_WHO")
 672         fi
 673         if test ! -z "$PROG_LAST" ; then
 674                 AC_DEFINE_UNQUOTED(PROG_LAST, "$PROG_LAST")
 675         fi
 676         if test ! -z "$PROG_LASTLOG" ; then
 677                 AC_DEFINE_UNQUOTED(PROG_LASTLOG, "$PROG_LASTLOG")
 678         fi
 679         if test ! -z "$PROG_DF" ; then
 680                 AC_DEFINE_UNQUOTED(PROG_DF, "$PROG_DF")
 681         fi
 682         if test ! -z "$PROG_VMSTAT" ; then
 683                 AC_DEFINE_UNQUOTED(PROG_VMSTAT, "$PROG_VMSTAT")
 684         fi
 685         if test ! -z "$PROG_UPTIME" ; then
 686                 AC_DEFINE_UNQUOTED(PROG_UPTIME, "$PROG_UPTIME")
 687         fi
 688         if test ! -z "$PROG_UPTIME" ; then
 689                 AC_DEFINE_UNQUOTED(PROG_UPTIME, "$PROG_UPTIME")
 690         fi
 691         if test ! -z "$PROG_TAIL" ; then
 692                 AC_DEFINE_UNQUOTED(PROG_TAIL, "$PROG_TAIL")
 693         fi
 694 fi
 695
 696 AC_ARG_WITH(catman,
 697         [  --with-catman=man|cat   Install preformatted manpages[no]],
 698         [
 699                 MANTYPE='$(CATMAN)'
 700                 if test x"$withval" != x"yes" ; then
 701                    mansubdir=$withval
 702                 else
 703                    mansubdir=cat
 704                 fi
 705         ], [
 706                 if test -z "$MANTYPE" ; then
 707                         MANTYPE='$(TROFFMAN)'
 708                         mansubdir=man
 709                 fi
 710         ]
 711 )
 712 AC_SUBST(MANTYPE)
 713 AC_SUBST(mansubdir)
 714
 715 # Check whether user wants Kerberos support
 716 AC_ARG_WITH(kerberos4,
 717         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
 718         [
 719                 if test "x$withval" != "xno" ; then
 720
 721                         if test "x$withval" != "$xyes" ; then
 722                                 CFLAGS="$CFLAGS -I${withval}/include"
 723                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 724                                 if test ! -z "$need_dash_r" ; then
 725                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
 726                                 fi
 727                                 if test ! -z "$blibpath" ; then
 728                                         blibpath="$blibpath:${withval}/lib"
 729                                 fi
 730                         else
 731                                 if test -d /usr/include/kerberosIV ; then
 732                                         CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 733                                 fi
 734                         fi
 735
 736                         AC_CHECK_HEADERS(krb.h)
 737                         AC_CHECK_LIB(krb, main)
 738                         if test "$ac_cv_header_krb_h" != yes; then
 739                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
 740                         fi
 741                         if test "$ac_cv_lib_krb_main" != yes; then
 742                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
 743                         fi
 744
 745                         KLIBS="-lkrb -ldes"
 746                         AC_CHECK_LIB(resolv, dn_expand, , )
 747                         KRB4=yes
 748                         AC_DEFINE(KRB4)
 749                 fi
 750         ]
 751 )
 752
 753 # Check whether user wants AFS support
 754 AC_ARG_WITH(afs,
 755         [  --with-afs=PATH         Enable AFS support],
 756         [
 757                 if test "x$withval" != "xno" ; then
 758
 759                         if test "x$withval" != "$xyes" ; then
 760                                 CFLAGS="$CFLAGS -I${withval}/include"
 761                                 LFLAGS="$LFLAGS -L${withval}/lib"
 762                         fi
 763
 764                         if test -z "$KRB4" ; then
 765                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
 766                         fi
 767
 768                         LIBS="$LIBS -lkafs"
 769                         if test ! -z "$AFS_LIBS" ; then
 770                                 LIBS="$LIBS $AFS_LIBS"
 771                         fi
 772                         AC_DEFINE(AFS)
 773                 fi
 774         ]
 775 )
 776 LIBS="$LIBS $KLIBS"
 777
 778 # Check whether user wants S/Key support
 779 AC_ARG_WITH(skey,
 780         [  --with-skey             Enable S/Key support],
 781         [
 782                 if test "x$withval" != "xno" ; then
 783                         AC_DEFINE(SKEY)
 784                         LIBS="$LIBS -lskey"
 785                 fi
 786         ]
 787 )
 788
 789 # Check whether user wants TCP wrappers support
 790 AC_ARG_WITH(tcp-wrappers,
 791         [  --with-tcp-wrappers     Enable tcpwrappers support],
 792         [
 793                 if test "x$withval" != "xno" ; then
 794                         saved_LIBS="$LIBS"
 795                         LIBS="$LIBS -lwrap"
 796                         AC_MSG_CHECKING(for libwrap)
 797                         AC_TRY_LINK(
 798                                 [
 799                                         #include <tcpd.h>
 800                                         int deny_severity = 0, allow_severity = 0;
 801                                 ],
 802                                 [hosts_access(0);],
 803                                 [
 804                                         AC_MSG_RESULT(yes)
 805                                         AC_DEFINE(LIBWRAP)
 806                                 ],
 807                                 [
 808                                         AC_MSG_RESULT(no)
 809                                         AC_MSG_WARN([*** libwrap missing - tcpwrapper support disabled ***])
 810                                         LIBS="$saved_LIBS"
 811                                 ]
 812                         )
 813                 fi
 814         ]
 815 )
 816
 817 # Check whether to enable MD5 passwords
 818 AC_ARG_WITH(md5-passwords,
 819         [  --with-md5-passwords    Enable use of MD5 passwords],
 820         [
 821                 if test "x$withval" != "xno" ; then
 822                         AC_DEFINE(HAVE_MD5_PASSWORDS)
 823                 fi
 824         ]
 825 )
 826
 827 # Check whether to enable utmpx support
 828 AC_ARG_WITH(utmpx,
 829         [  --with-utmpx            Enable utmpx support],
 830         [
 831                 if test "x$withval" != "xno" ; then
 832                         AC_DEFINE(USE_UTMPX)
 833                 fi
 834         ]
 835 )
 836
 837 # Whether to disable shadow password support
 838 AC_ARG_WITH(shadow,
 839         [  --without-shadow        Disable shadow password support],
 840         [
 841                 if test "x$withval" = "xno" ; then
 842                         AC_DEFINE(DISABLE_SHADOW)
 843                 fi
 844         ]
 845 )
 846
 847 # Use ip address instead of hostname in $DISPLAY
 848 AC_ARG_WITH(ipaddr-display,
 849         [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
 850         [
 851                 if test "x$withval" = "xno" ; then
 852                         AC_DEFINE(IPADDR_IN_DISPLAY)
 853                 fi
 854         ]
 855 )
 856
 857 # Whether to mess with the default path
 858 AC_ARG_WITH(default-path,
 859         [  --with-default-path=PATH Specify default \$PATH environment for server],
 860         [
 861                 if test "x$withval" != "xno" ; then
 862                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
 863                 fi
 864         ]
 865 )
 866
 867 # Whether to force IPv4 by default (needed on broken glibc Linux)
 868 AC_ARG_WITH(ipv4-default,
 869         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
 870         [
 871                 if test "x$withval" != "xno" ; then
 872                         AC_DEFINE(IPV4_DEFAULT)
 873                 fi
 874         ]
 875 )
 876
 877 AC_MSG_CHECKING([to convert IPv4 in IPv6-mapped addresses])
 878 AC_ARG_WITH(4in6,
 879         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
 880         [
 881                 if test "x$withval" != "xno" ; then
 882                         AC_MSG_RESULT(yes)
 883                         AC_DEFINE(IPV4_IN_IPV6)
 884                 else
 885                         AC_MSG_RESULT(no)
 886                 fi
 887         ],[
 888                 if test "x$inet6_default_4in6" = "xyes"; then
 889                         AC_MSG_RESULT([yes (default)])
 890                         AC_DEFINE(IPV4_IN_IPV6)
 891                 else
 892                         AC_MSG_RESULT([no (default)])
 893                 fi
 894         ]
 895 )
 896
 897 # Where to place sshd.pid
 898 piddir=/var/run
 899 AC_ARG_WITH(pid-dir,
 900         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
 901         [
 902                 if test "x$withval" != "xno" ; then
 903                         piddir=$withval
 904                 fi
 905         ]
 906 )
 907 AC_DEFINE_UNQUOTED(PIDDIR, "$piddir")
 908 AC_SUBST(piddir)
 909
 910 if test ! -z "$blibpath" ; then
 911         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
 912         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
 913 fi
 914
 915 AC_OUTPUT(Makefile)