configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_PROG_CC
   5 AC_CANONICAL_HOST
   6
   7 # Checks for programs.
   8 AC_PROG_CPP
   9 AC_PROG_RANLIB
  10 AC_PROG_INSTALL
  11 AC_CHECK_PROG(AR, ar, ar)
  12 AC_PATH_PROG(PERL, perl)
  13 AC_SUBST(PERL)
  14 AC_PATH_PROG(ENT, ent)
  15 AC_SUBST(ENT)
  16
  17 if test -z "$LD" ; then
  18         LD=$CC
  19 fi
  20 AC_SUBST(LD)
  21
  22 # C Compiler features
  23 AC_C_INLINE
  24 if test "$GCC" = "yes"; then
  25         CFLAGS="$CFLAGS -Wall"
  26 fi
  27
  28 # Check for some target-specific stuff
  29 case "$host" in
  30 *-*-aix*)
  31         AFS_LIBS="-lld"
  32         CFLAGS="$CFLAGS -I/usr/local/include"
  33         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  34         if test "$LD" != "gcc" -a -z "$blibpath"; then
  35                 blibpath="/usr/lib:/lib:/usr/local/lib"
  36         fi
  37         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)])
  38         AC_DEFINE(BROKEN_GETADDRINFO)
  39         ;;
  40 *-*-hpux10*)
  41         if test -z "$GCC"; then
  42                 CFLAGS="$CFLAGS -Aa"
  43         fi
  44         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  45         CFLAGS="$CFLAGS -I/usr/local/include"
  46         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  47         AC_DEFINE(IPADDR_IN_DISPLAY)
  48         AC_DEFINE(USE_UTMPX)
  49         AC_MSG_CHECKING(for HPUX trusted system password database)
  50         if test -f /tcb/files/auth/system/default; then
  51                 AC_MSG_RESULT(yes)
  52                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  53                 LIBS="$LIBS -lsec"
  54                 AC_MSG_WARN([This configuration is untested])
  55         else
  56                 AC_MSG_RESULT(no)
  57                 AC_DEFINE(DISABLE_SHADOW)
  58         fi
  59         MANTYPE='$(CATMAN)'
  60         mansubdir=cat
  61         ;;
  62 *-*-hpux11*)
  63         if test -z "$GCC"; then
  64                 CFLAGS="$CFLAGS -Ae"
  65         fi
  66         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  67         CFLAGS="$CFLAGS -I/usr/local/include"
  68         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  69         AC_DEFINE(IPADDR_IN_DISPLAY)
  70         AC_DEFINE(USE_UTMPX)
  71         AC_MSG_CHECKING(for HPUX trusted system password database)
  72         if test -f /tcb/files/auth/system/default; then
  73                 AC_MSG_RESULT(yes)
  74                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  75                 LIBS="$LIBS -lsec"
  76                 AC_MSG_WARN([This configuration is untested])
  77         else
  78                 AC_MSG_RESULT(no)
  79                 AC_DEFINE(DISABLE_SHADOW)
  80         fi
  81         MANTYPE='$(CATMAN)'
  82         mansubdir=cat
  83         ;;
  84 *-*-irix5*)
  85         CFLAGS="$CFLAGS -I/usr/local/include"
  86         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  87         MANTYPE='$(CATMAN)'
  88         no_libsocket=1
  89         no_libnsl=1
  90         ;;
  91 *-*-irix6*)
  92         CFLAGS="$CFLAGS -I/usr/local/include"
  93         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  94         MANTYPE='$(CATMAN)'
  95         AC_MSG_WARN([*** Irix 6.x is not tested, please report you experiences *** ])
  96         no_libsocket=1
  97         no_libnsl=1
  98         ;;
  99 *-*-linux*)
 100         no_dev_ptmx=1
 101         AC_DEFINE(DONT_TRY_OTHER_AF)
 102         inet6_default_4in6=yes
 103         ;;
 104 *-*-netbsd*)
 105         need_dash_r=1
 106         ;;
 107 *-*-solaris*)
 108         CFLAGS="$CFLAGS -I/usr/local/include"
 109         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib -L/usr/ucblib -R/usr/ucblib"
 110         need_dash_r=1
 111         AC_DEFINE(USE_UTMPX)
 112         ;;
 113 *-*-sunos4*)
 114         CFLAGS="$CFLAGS -DSUNOS4"
 115         AC_CHECK_FUNCS(getpwanam)
 116         ;;
 117 *-*-sysv*)
 118         CFLAGS="$CFLAGS -I/usr/local/include"
 119         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 120         AC_DEFINE(USE_UTMPX)
 121         MANTYPE='$(CATMAN)'
 122         mansubdir=cat
 123         LIBS="$LIBS -lgen -lsocket"
 124         ;;
 125 esac
 126
 127 # Checks for libraries.
 128 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
 129 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
 130
 131 if test -z "$no_libsocket" ; then
 132         AC_CHECK_LIB(nsl, yp_match, , )
 133 fi
 134 if test -z "$no_libnsl" ; then
 135         AC_CHECK_LIB(socket, main, , )
 136 fi
 137
 138 # Checks for header files.
 139 AC_CHECK_HEADERS(bstring.h endian.h lastlog.h login.h maillock.h netdb.h netgroup.h netinet/in_systm.h paths.h poll.h pty.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/select.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h stddef.h util.h utmp.h utmpx.h)
 140
 141 # Checks for library functions.
 142 AC_CHECK_FUNCS(arc4random b64_ntop bcopy bindresvport_af clock freeaddrinfo gai_strerror getaddrinfo getnameinfo getrusage innetgr md5_crypt memmove mkdtemp openpty rresvport_af setenv seteuid setlogin setproctitle setreuid snprintf strlcat strlcpy updwtmpx vsnprintf vhangup _getpty __b64_ntop)
 143
 144 AC_CHECK_FUNC(login,
 145         [AC_DEFINE(HAVE_LOGIN)],
 146         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 147 )
 148
 149 AC_CHECK_FUNC(daemon,
 150         [AC_DEFINE(HAVE_DAEMON)],
 151         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 152 )
 153
 154 AC_CHECK_FUNC(getpagesize,
 155         [AC_DEFINE(HAVE_GETPAGESIZE)],
 156         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 157 )
 158
 159 AC_ARG_WITH(pam,
 160         [  --without-pam           Disable PAM support ],
 161         [
 162                 if test "x$withval" = "xno" ; then
 163                         no_pam=1
 164                         AC_DEFINE(DISABLE_PAM)
 165                 fi
 166         ]
 167 )
 168 if test -z "$no_pam" -a "x$ac_cv_header_security_pam_appl_h" = "xyes" ; then
 169         AC_CHECK_LIB(dl, dlopen, , )
 170         LIBS="$LIBS -lpam"
 171
 172         AC_CHECK_FUNCS(pam_getenvlist)
 173
 174         # Check PAM strerror arguments (old PAM)
 175         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 176         AC_TRY_COMPILE(
 177                 [
 178 #include <stdlib.h>
 179 #include <security/pam_appl.h>
 180                 ],
 181                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 182                 [AC_MSG_RESULT(no)],
 183                 [
 184                         AC_DEFINE(HAVE_OLD_PAM)
 185                         AC_MSG_RESULT(yes)
 186                 ]
 187         )
 188 fi
 189
 190 # The big search for OpenSSL
 191 AC_ARG_WITH(ssl-dir,
 192         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 193         [
 194                 if test "x$withval" != "$xno" ; then
 195                         tryssldir=$withval
 196                 fi
 197         ]
 198 )
 199
 200 saved_LIBS="$LIBS"
 201 saved_LDFLAGS="$LDFLAGS"
 202 saved_CFLAGS="$CFLAGS"
 203 if test "x$prefix" != "xNONE" ; then
 204         tryssldir="$tryssldir $prefix"
 205 fi
 206 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 207
 208         for ssldir in "" $tryssldir /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 209                 if test ! -z "$ssldir" ; then
 210                         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 211                         CFLAGS="$saved_CFLAGS -I$ssldir/include"
 212                         if test ! -z "$need_dash_r" ; then
 213                                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 214                         fi
 215                 else
 216                         LDFLAGS="$saved_LDFLAGS"
 217                 fi
 218
 219                 LIBS="$saved_LIBS -lcrypto"
 220
 221                 # Basic test to check for compatible version and correct linking
 222                 # *does not* test for RSA - that comes later.
 223                 AC_TRY_RUN(
 224                         [
 225 #include <string.h>
 226 #include <openssl/rand.h>
 227 int main(void)
 228 {
 229         char a[2048];
 230         memset(a, 0, sizeof(a));
 231         RAND_add(a, sizeof(a), sizeof(a));
 232         return(RAND_status() <= 0);
 233 }
 234                         ],
 235                         [
 236                                 found_crypto=1
 237                                 break;
 238                         ], []
 239                 )
 240
 241                 if test ! -z "$found_crypto" ; then
 242                         break;
 243                 fi
 244         done
 245
 246         if test -z "$found_crypto" ; then
 247                 AC_MSG_ERROR([Could not find working SSLeay / OpenSSL libraries, please install])
 248         fi
 249         if test -z "$ssldir" ; then
 250                 ssldir="(system)"
 251         fi
 252
 253         ac_cv_openssldir=$ssldir
 254 ])
 255
 256 if test ! -z "$ac_cv_openssldir" -a ! "x$ac_cv_openssldir" = "x(system)" ; then
 257         AC_DEFINE(HAVE_OPENSSL)
 258         dnl Need to recover ssldir - test above runs in subshell
 259         ssldir=$ac_cv_openssldir
 260         CFLAGS="$saved_CFLAGS -I$ssldir/include"
 261         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 262         if test ! -z "$need_dash_r" ; then
 263                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 264         fi
 265         if test ! -z "$blibpath" ; then
 266                 blibpath="$blibpath:$ssldir:$ssldir/lib"
 267         fi
 268 fi
 269 LIBS="$saved_LIBS -lcrypto"
 270
 271 # Now test RSA support
 272 saved_LIBS="$LIBS"
 273 AC_MSG_CHECKING([for RSA support])
 274 for WANTS_RSAREF in "" 1 ; do
 275         if test -z "$WANTS_RSAREF" ; then
 276                 LIBS="$saved_LIBS"
 277         else
 278                 LIBS="$saved_LIBS -lRSAglue -lrsaref"
 279         fi
 280         AC_TRY_RUN([
 281 #include <string.h>
 282 #include <openssl/rand.h>
 283 #include <openssl/rsa.h>
 284 #include <openssl/bn.h>
 285 #include <openssl/sha.h>
 286 int main(void)
 287 {
 288         int num; RSA *key; static unsigned char p_in[] = "blahblah";
 289         unsigned char c[256], p[256];
 290         memset(c, 0, sizeof(c)); RAND_add(c, sizeof(c), sizeof(c));
 291         if ((key=RSA_generate_key(512, 3, NULL, NULL))==NULL) return(1);
 292         num = RSA_public_encrypt(sizeof(p_in) - 1, p_in, c, key, RSA_PKCS1_PADDING);
 293         return(-1 == RSA_private_decrypt(num, c, p, key, RSA_PKCS1_PADDING));
 294 }
 295         ],
 296         [
 297                 rsa_works=1
 298                 break;
 299         ], [])
 300 done
 301
 302 if test ! -z "$no_rsa" ; then
 303         AC_MSG_RESULT(disabled)
 304 else
 305         if test -z "$rsa_works" ; then
 306                 AC_MSG_WARN([*** No RSA support found *** ])
 307         else
 308                 if test -z "$WANTS_RSAREF" ; then
 309                         AC_MSG_RESULT(yes)
 310                 else
 311                         AC_MSG_RESULT(using RSAref)
 312                         LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 313                 fi
 314         fi
 315 fi
 316
 317 # Checks for data types
 318 AC_CHECK_SIZEOF(char, 1)
 319 AC_CHECK_SIZEOF(short int, 2)
 320 AC_CHECK_SIZEOF(int, 4)
 321 AC_CHECK_SIZEOF(long int, 4)
 322 AC_CHECK_SIZEOF(long long int, 8)
 323
 324 # More checks for data types
 325 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
 326         AC_TRY_COMPILE(
 327                 [ #include <sys/types.h> ],
 328                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
 329                 [ ac_cv_have_intxx_t="yes" ],
 330                 [ ac_cv_have_intxx_t="no" ]
 331         )
 332 ])
 333 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
 334         AC_DEFINE(HAVE_INTXX_T)
 335         have_intxx_t=1
 336 fi
 337
 338 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
 339         AC_TRY_COMPILE(
 340                 [ #include <sys/types.h> ],
 341                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
 342                 [ ac_cv_have_u_intxx_t="yes" ],
 343                 [ ac_cv_have_u_intxx_t="no" ]
 344         )
 345 ])
 346 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
 347         AC_DEFINE(HAVE_U_INTXX_T)
 348         have_u_intxx_t=1
 349 fi
 350
 351
 352 if test -z "$have_u_intxx_t" -o -z "$have_intxx_t" -a \
 353            "x$ac_cv_header_sys_bitypes_h" = "xyes"
 354 then
 355         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 356         AC_TRY_COMPILE(
 357                 [
 358 #include <sys/bitypes.h>
 359                 ],
 360                 [
 361                         int8_t a; int16_t b; int32_t c;
 362                         u_int8_t e; u_int16_t f; u_int32_t g;
 363                         a = b = c = e = f = g = 1;
 364                 ],
 365                 [
 366                         AC_DEFINE(HAVE_U_INTXX_T)
 367                         AC_DEFINE(HAVE_INTXX_T)
 368                         AC_MSG_RESULT(yes)
 369                 ],
 370                 [AC_MSG_RESULT(no)]
 371         )
 372 fi
 373
 374 if test -z "$have_u_intxx_t" ; then
 375         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
 376                 AC_TRY_COMPILE(
 377                         [
 378 #include <sys/types.h>
 379                         ],
 380                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
 381                         [ ac_cv_have_uintxx_t="yes" ],
 382                         [ ac_cv_have_uintxx_t="no" ]
 383                 )
 384         ])
 385         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
 386                 AC_DEFINE(HAVE_UINTXX_T)
 387         fi
 388 fi
 389
 390 AC_CACHE_CHECK([for socklen_t], ac_cv_have_socklen_t, [
 391         AC_TRY_COMPILE(
 392                 [
 393 #include <sys/types.h>
 394 #include <sys/socket.h>
 395                 ],
 396                 [socklen_t foo; foo = 1235;],
 397                 [ ac_cv_have_socklen_t="yes" ],
 398                 [ ac_cv_have_socklen_t="no" ]
 399         )
 400 ])
 401 if test "x$ac_cv_have_socklen_t" = "xyes" ; then
 402         AC_DEFINE(HAVE_SOCKLEN_T)
 403 fi
 404
 405 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
 406         AC_TRY_COMPILE(
 407                 [
 408 #include <sys/types.h>
 409                 ],
 410                 [ size_t foo; foo = 1235; ],
 411                 [ ac_cv_have_size_t="yes" ],
 412                 [ ac_cv_have_size_t="no" ]
 413         )
 414 ])
 415 if test "x$ac_cv_have_size_t" = "xyes" ; then
 416         AC_DEFINE(HAVE_SIZE_T)
 417 fi
 418
 419 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
 420         AC_TRY_COMPILE(
 421                 [
 422 #include <sys/types.h>
 423                 ],
 424                 [ ssize_t foo; foo = 1235; ],
 425                 [ ac_cv_have_ssize_t="yes" ],
 426                 [ ac_cv_have_ssize_t="no" ]
 427         )
 428 ])
 429 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
 430         AC_DEFINE(HAVE_SSIZE_T)
 431 fi
 432
 433
 434 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
 435         AC_TRY_COMPILE(
 436                 [
 437 #include <sys/types.h>
 438 #include <sys/socket.h>
 439                 ],
 440                 [ struct sockaddr_storage s; ],
 441                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
 442                 [ ac_cv_have_struct_sockaddr_storage="no" ]
 443         )
 444 ])
 445 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
 446         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 447 fi
 448
 449 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
 450         AC_TRY_COMPILE(
 451                 [
 452 #include <netinet/in.h>
 453                 ],
 454                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
 455                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
 456                 [ ac_cv_have_struct_sockaddr_in6="no" ]
 457         )
 458 ])
 459 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
 460         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 461 fi
 462
 463 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
 464         AC_TRY_COMPILE(
 465                 [
 466 #include <netinet/in.h>
 467                 ],
 468                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
 469                 [ ac_cv_have_struct_in6_addr="yes" ],
 470                 [ ac_cv_have_struct_in6_addr="no" ]
 471         )
 472 ])
 473 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
 474         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 475 fi
 476
 477 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
 478         AC_TRY_COMPILE(
 479                 [
 480 #include <sys/types.h>
 481 #include <sys/socket.h>
 482 #include <netdb.h>
 483                 ],
 484                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
 485                 [ ac_cv_have_struct_addrinfo="yes" ],
 486                 [ ac_cv_have_struct_addrinfo="no" ]
 487         )
 488 ])
 489 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
 490         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 491 fi
 492
 493
 494 # Checks for structure members
 495
 496 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
 497 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
 498 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
 499 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
 500 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
 501 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
 502 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
 503 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
 504 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
 505 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
 506 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
 507 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
 508
 509
 510 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
 511                 ac_cv_have_ss_family_in_struct_ss, [
 512         AC_TRY_COMPILE(
 513                 [
 514 #include <sys/types.h>
 515 #include <sys/socket.h>
 516                 ],
 517                 [ struct sockaddr_storage s; s.ss_family = 1; ],
 518                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
 519                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
 520         )
 521 ])
 522 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
 523         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 524 fi
 525
 526
 527 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
 528                 ac_cv_have___ss_family_in_struct_ss, [
 529         AC_TRY_COMPILE(
 530                 [
 531 #include <sys/types.h>
 532 #include <sys/socket.h>
 533                 ],
 534                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
 535                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
 536                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
 537         )
 538 ])
 539 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
 540         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 541 fi
 542
 543
 544 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
 545         AC_TRY_LINK([],
 546                 [ extern char *__progname; printf("%s", __progname); ],
 547                 [ ac_cv_libc_defines___progname="yes" ],
 548                 [ ac_cv_libc_defines___progname="no" ]
 549         )
 550 ])
 551 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
 552         AC_DEFINE(HAVE___PROGNAME)
 553 fi
 554
 555
 556 # Looking for programs, paths and files
 557 AC_ARG_WITH(rsh,
 558         [  --with-rsh=PATH         Specify path to remote shell program ],
 559         [
 560                 if test "x$withval" != "$no" ; then
 561                         AC_DEFINE_UNQUOTED(RSH_PATH, "$withval")
 562                 fi
 563         ],
 564         [
 565                 AC_PATH_PROG(rsh_path, rsh)
 566         ]
 567 )
 568
 569 AC_ARG_WITH(xauth,
 570         [  --with-xauth=PATH       Specify path to xauth program ],
 571         [
 572                 if test "x$withval" != "$xno" ; then
 573                         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$withval")
 574                 fi
 575         ],
 576         [
 577                 AC_PATH_PROG(xauth_path, xauth)
 578                 if test ! -z "$xauth_path" -a -x "/usr/openwin/bin/xauth" ; then
 579                         xauth_path="/usr/openwin/bin/xauth"
 580                 fi
 581         ]
 582 )
 583
 584 if test ! -z "$xauth_path" ; then
 585         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
 586 fi
 587 if test ! -z "$rsh_path" ; then
 588         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
 589 fi
 590
 591 # Check for mail directory (last resort if we cannot get it from headers)
 592 if test ! -z "$MAIL" ; then
 593         maildir=`dirname $MAIL`
 594         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
 595 fi
 596
 597 # Look for lastlog location
 598 AC_ARG_WITH(lastlog,
 599         [  --with-lastlog=FILE     Location of lastlog file],
 600         [
 601                 if test "x$withval" = "xno" ; then
 602                         AC_DEFINE(DISABLE_LASTLOG)
 603                 else
 604                         AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$withval")
 605                 fi
 606         ],
 607         [
 608                 AC_MSG_CHECKING([location of lastlog file])
 609                 for lastlog in /var/log/lastlog /var/adm/lastlog /usr/adm/lastlog  /etc/security/lastlog ; do
 610                         if test -f $lastlog ; then
 611                                 gotlastlog="file"
 612                                 break
 613                         fi
 614                         if test -d $lastlog ; then
 615                                 gotlastlog="dir"
 616                                 break
 617                         fi
 618                 done
 619                 if test -z "$gotlastlog" ; then
 620                         AC_MSG_RESULT(not found)
 621                         nolastlog=1
 622                 else
 623                         if test "x$gotlastlog" = "xdir" ; then
 624                                 AC_MSG_RESULT(${lastlog}/)
 625                                 AC_DEFINE(LASTLOG_IS_DIR)
 626                         else
 627                                 AC_MSG_RESULT($lastlog)
 628                                 AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$lastlog")
 629                         fi
 630                 fi
 631         ]
 632 )
 633
 634 if test ! -z "$nolastlog" ; then
 635         AC_MSG_WARN([*** Disabling lastlog support *** ])
 636         AC_DEFINE(DISABLE_LASTLOG)
 637 fi
 638
 639 if test -z "$no_dev_ptmx" ; then
 640         AC_CHECK_FILE("/dev/ptmx",
 641                 [
 642                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
 643                         have_dev_ptmx=1
 644                 ]
 645         )
 646 fi
 647 AC_CHECK_FILE("/dev/ptc",
 648         [
 649                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
 650                 have_dev_ptc=1
 651         ]
 652 )
 653
 654 # Options from here on. Some of these are preset by platform above
 655
 656 # Check for user-specified random device, otherwise check /dev/urandom
 657 AC_ARG_WITH(random,
 658         [  --with-random=FILE      read randomness from FILE (default=/dev/urandom)],
 659         [
 660                 if test "x$withval" != "xno" ; then
 661                         RANDOM_POOL="$withval";
 662                         AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 663                 fi
 664         ],
 665         [
 666                 # Check for random device
 667                 AC_CHECK_FILE("/dev/urandom",
 668                         [
 669                                 RANDOM_POOL="/dev/urandom";
 670                                 AC_SUBST(RANDOM_POOL)
 671                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 672                         ]
 673                 )
 674         ]
 675 )
 676
 677 # Check for EGD pool file
 678 AC_ARG_WITH(egd-pool,
 679         [  --with-egd-pool=FILE    read randomness from EGD pool FILE (default none)],
 680         [
 681                 if test "x$withval" != "xno" ; then
 682                         EGD_SOCKET="$withval";
 683                         AC_DEFINE_UNQUOTED(EGD_SOCKET, "$EGD_SOCKET")
 684                 fi
 685         ]
 686 )
 687
 688 # detect pathnames for entropy gathering commands, if we need them
 689 INSTALL_SSH_PRNG_CMDS=""
 690 rm -f prng_commands
 691 if test -z "$RANDOM_POOL" -a -z "$EGD_SOCKET" ; then
 692         # Use these commands to collect entropy
 693         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
 694         OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
 695         OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
 696         OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
 697         OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
 698         OSSH_PATH_ENTROPY_PROG(PROG_W, w)
 699         OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
 700         OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
 701         OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
 702         OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
 703         OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
 704         OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
 705         OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
 706         OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
 707         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
 708
 709         INSTALL_SSH_PRNG_CMDS="yes"
 710 fi
 711 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
 712
 713
 714 AC_ARG_WITH(catman,
 715         [  --with-catman=man|cat   Install preformatted manpages[no]],
 716         [
 717                 MANTYPE='$(CATMAN)'
 718                 if test x"$withval" != x"yes" ; then
 719                    mansubdir=$withval
 720                 else
 721                    mansubdir=cat
 722                 fi
 723         ], [
 724                 if test -z "$MANTYPE" ; then
 725                         MANTYPE='$(TROFFMAN)'
 726                         mansubdir=man
 727                 fi
 728         ]
 729 )
 730 AC_SUBST(MANTYPE)
 731 AC_SUBST(mansubdir)
 732
 733 # Check whether user wants Kerberos support
 734 AC_ARG_WITH(kerberos4,
 735         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
 736         [
 737                 if test "x$withval" != "xno" ; then
 738
 739                         if test "x$withval" != "$xyes" ; then
 740                                 CFLAGS="$CFLAGS -I${withval}/include"
 741                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 742                                 if test ! -z "$need_dash_r" ; then
 743                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
 744                                 fi
 745                                 if test ! -z "$blibpath" ; then
 746                                         blibpath="$blibpath:${withval}/lib"
 747                                 fi
 748                         else
 749                                 if test -d /usr/include/kerberosIV ; then
 750                                         CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 751                                 fi
 752                         fi
 753
 754                         AC_CHECK_HEADERS(krb.h)
 755                         AC_CHECK_LIB(krb, main)
 756                         if test "$ac_cv_header_krb_h" != yes; then
 757                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
 758                         fi
 759                         if test "$ac_cv_lib_krb_main" != yes; then
 760                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
 761                         fi
 762
 763                         KLIBS="-lkrb -ldes"
 764                         AC_CHECK_LIB(resolv, dn_expand, , )
 765                         KRB4=yes
 766                         AC_DEFINE(KRB4)
 767                 fi
 768         ]
 769 )
 770
 771 # Check whether user wants AFS support
 772 AC_ARG_WITH(afs,
 773         [  --with-afs=PATH         Enable AFS support],
 774         [
 775                 if test "x$withval" != "xno" ; then
 776
 777                         if test "x$withval" != "$xyes" ; then
 778                                 CFLAGS="$CFLAGS -I${withval}/include"
 779                                 LFLAGS="$LFLAGS -L${withval}/lib"
 780                         fi
 781
 782                         if test -z "$KRB4" ; then
 783                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
 784                         fi
 785
 786                         LIBS="$LIBS -lkafs"
 787                         if test ! -z "$AFS_LIBS" ; then
 788                                 LIBS="$LIBS $AFS_LIBS"
 789                         fi
 790                         AC_DEFINE(AFS)
 791                 fi
 792         ]
 793 )
 794 LIBS="$LIBS $KLIBS"
 795
 796 # Check whether user wants S/Key support
 797 AC_ARG_WITH(skey,
 798         [  --with-skey             Enable S/Key support],
 799         [
 800                 if test "x$withval" != "xno" ; then
 801                         AC_DEFINE(SKEY)
 802                         LIBS="$LIBS -lskey"
 803                 fi
 804         ]
 805 )
 806
 807 # Check whether user wants TCP wrappers support
 808 AC_ARG_WITH(tcp-wrappers,
 809         [  --with-tcp-wrappers     Enable tcpwrappers support],
 810         [
 811                 if test "x$withval" != "xno" ; then
 812                         saved_LIBS="$LIBS"
 813                         LIBS="$LIBS -lwrap"
 814                         AC_MSG_CHECKING(for libwrap)
 815                         AC_TRY_LINK(
 816                                 [
 817 #include <tcpd.h>
 818                                         int deny_severity = 0, allow_severity = 0;
 819                                 ],
 820                                 [hosts_access(0);],
 821                                 [
 822                                         AC_MSG_RESULT(yes)
 823                                         AC_DEFINE(LIBWRAP)
 824                                 ],
 825                                 [
 826                                         AC_MSG_RESULT(no)
 827                                         AC_MSG_WARN([*** libwrap missing - tcpwrapper support disabled ***])
 828                                         LIBS="$saved_LIBS"
 829                                 ]
 830                         )
 831                 fi
 832         ]
 833 )
 834
 835 # Check whether to enable MD5 passwords
 836 AC_ARG_WITH(md5-passwords,
 837         [  --with-md5-passwords    Enable use of MD5 passwords],
 838         [
 839                 if test "x$withval" != "xno" ; then
 840                         AC_DEFINE(HAVE_MD5_PASSWORDS)
 841                 fi
 842         ]
 843 )
 844
 845 # Check whether to enable utmpx support
 846 AC_ARG_WITH(utmpx,
 847         [  --with-utmpx            Enable utmpx support],
 848         [
 849                 if test "x$withval" != "xno" ; then
 850                         AC_DEFINE(USE_UTMPX)
 851                 fi
 852         ]
 853 )
 854
 855 # Whether to disable shadow password support
 856 AC_ARG_WITH(shadow,
 857         [  --without-shadow        Disable shadow password support],
 858         [
 859                 if test "x$withval" = "xno" ; then
 860                         AC_DEFINE(DISABLE_SHADOW)
 861                 fi
 862         ]
 863 )
 864
 865 # Use ip address instead of hostname in $DISPLAY
 866 AC_ARG_WITH(ipaddr-display,
 867         [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
 868         [
 869                 if test "x$withval" = "xno" ; then
 870                         AC_DEFINE(IPADDR_IN_DISPLAY)
 871                 fi
 872         ]
 873 )
 874
 875 # Whether to mess with the default path
 876 AC_ARG_WITH(default-path,
 877         [  --with-default-path=PATH Specify default \$PATH environment for server],
 878         [
 879                 if test "x$withval" != "xno" ; then
 880                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
 881                 fi
 882         ]
 883 )
 884
 885 # Whether to force IPv4 by default (needed on broken glibc Linux)
 886 AC_ARG_WITH(ipv4-default,
 887         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
 888         [
 889                 if test "x$withval" != "xno" ; then
 890                         AC_DEFINE(IPV4_DEFAULT)
 891                 fi
 892         ]
 893 )
 894
 895 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
 896 AC_ARG_WITH(4in6,
 897         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
 898         [
 899                 if test "x$withval" != "xno" ; then
 900                         AC_MSG_RESULT(yes)
 901                         AC_DEFINE(IPV4_IN_IPV6)
 902                 else
 903                         AC_MSG_RESULT(no)
 904                 fi
 905         ],[
 906                 if test "x$inet6_default_4in6" = "xyes"; then
 907                         AC_MSG_RESULT([yes (default)])
 908                         AC_DEFINE(IPV4_IN_IPV6)
 909                 else
 910                         AC_MSG_RESULT([no (default)])
 911                 fi
 912         ]
 913 )
 914
 915 # Where to place sshd.pid
 916 piddir=/var/run
 917 AC_ARG_WITH(pid-dir,
 918         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
 919         [
 920                 if test "x$withval" != "xno" ; then
 921                         piddir=$withval
 922                 fi
 923         ]
 924 )
 925
 926 AC_DEFINE_UNQUOTED(PIDDIR, "$piddir")
 927 AC_SUBST(piddir)
 928
 929
 930 # Change default command timeout for builtin PRNG
 931 entropy_timeout=100
 932 AC_ARG_WITH(entropy-timeout,
 933         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
 934         [
 935                 if test "x$withval" != "xno" ; then
 936                         entropy_timeout=$withval
 937                 fi
 938         ]
 939 )
 940 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
 941
 942
 943 if test ! -z "$blibpath" ; then
 944         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
 945         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
 946 fi
 947
 948 AC_OUTPUT(Makefile ssh_prng_cmds)
 949
 950