configure.ac

   1 # $Id$
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([ssh.c])
   5
   6 AC_CONFIG_HEADER(config.h)
   7 AC_PROG_CC
   8 AC_CANONICAL_HOST
   9 AC_C_BIGENDIAN
  10
  11 # Checks for programs.
  12 AC_PROG_CPP
  13 AC_PROG_RANLIB
  14 AC_PROG_INSTALL
  15 AC_PATH_PROG(AR, ar)
  16 AC_PATH_PROGS(PERL, perl5 perl)
  17 AC_PATH_PROG(SED, sed)
  18 AC_SUBST(PERL)
  19 AC_PATH_PROG(ENT, ent)
  20 AC_SUBST(ENT)
  21 AC_PATH_PROG(TEST_MINUS_S_SH, bash)
  22 AC_PATH_PROG(TEST_MINUS_S_SH, ksh)
  23 AC_PATH_PROG(TEST_MINUS_S_SH, sh)
  24 AC_PATH_PROG(SH, sh)
  25
  26 # System features
  27 AC_SYS_LARGEFILE
  28
  29 if test -z "$AR" ; then
  30         AC_MSG_ERROR([*** 'ar' missing, please install or fix your \$PATH ***])
  31 fi
  32
  33 # Use LOGIN_PROGRAM from environment if possible
  34 if test ! -z "$LOGIN_PROGRAM" ; then
  35         AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM")
  36 else
  37         # Search for login
  38         AC_PATH_PROG(LOGIN_PROGRAM_FALLBACK, login)
  39         if test ! -z "$LOGIN_PROGRAM_FALLBACK" ; then
  40                 AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM_FALLBACK")
  41         fi
  42 fi
  43
  44 if test -z "$LD" ; then
  45         LD=$CC
  46 fi
  47 AC_SUBST(LD)
  48
  49 AC_C_INLINE
  50 if test "$GCC" = "yes" || test "$GCC" = "egcs"; then
  51         CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wno-uninitialized"
  52 fi
  53
  54 # Check for some target-specific stuff
  55 case "$host" in
  56 *-*-aix*)
  57         AFS_LIBS="-lld"
  58         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
  59         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  60         AC_MSG_CHECKING([how to specify blibpath for linker ($LD)])
  61         if (test -z "$blibpath"); then
  62                 blibpath="/usr/lib:/lib:/usr/local/lib"
  63         fi
  64         saved_LDFLAGS="$LDFLAGS"
  65         for tryflags in -blibpath: -Wl,-blibpath: -Wl,-rpath, ;do
  66                 if (test -z "$blibflags"); then
  67                         LDFLAGS="$saved_LDFLAGS $tryflags$blibpath"
  68                         AC_TRY_LINK([], [], [blibflags=$tryflags])
  69                 fi
  70         done
  71         if (test -z "$blibflags"); then
  72                 AC_MSG_RESULT(not found)
  73                 AC_MSG_ERROR([*** must be able to specify blibpath on AIX - check config.log])
  74         else
  75                 AC_MSG_RESULT($blibflags)
  76         fi
  77         LDFLAGS="$saved_LDFLAGS"
  78         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)],
  79                 [AC_CHECK_LIB(s,authenticate,
  80                         [ AC_DEFINE(WITH_AIXAUTHENTICATE)
  81                                 LIBS="$LIBS -ls"
  82                         ])
  83                 ])
  84         AC_DEFINE(BROKEN_GETADDRINFO)
  85         AC_DEFINE(BROKEN_REALPATH)
  86         dnl AIX handles lastlog as part of its login message
  87         AC_DEFINE(DISABLE_LASTLOG)
  88         AC_DEFINE(LOGIN_NEEDS_UTMPX)
  89         AC_DEFINE(SPT_TYPE,SPT_REUSEARGV)
  90         ;;
  91 *-*-cygwin*)
  92         check_for_libcrypt_later=1
  93         LIBS="$LIBS /usr/lib/textmode.o"
  94         AC_DEFINE(HAVE_CYGWIN)
  95         AC_DEFINE(USE_PIPES)
  96         AC_DEFINE(DISABLE_SHADOW)
  97         AC_DEFINE(IP_TOS_IS_BROKEN)
  98         AC_DEFINE(NO_X11_UNIX_SOCKETS)
  99         AC_DEFINE(NO_IPPORT_RESERVED_CONCEPT)
 100         AC_DEFINE(DISABLE_FD_PASSING)
 101         AC_DEFINE(SETGROUPS_NOOP)
 102         ;;
 103 *-*-dgux*)
 104         AC_DEFINE(IP_TOS_IS_BROKEN)
 105         ;;
 106 *-*-darwin*)
 107         AC_MSG_CHECKING(if we have working getaddrinfo)
 108         AC_TRY_RUN([#include <mach-o/dyld.h>
 109 main() { if (NSVersionOfRunTimeLibrary("System") >= (60 << 16))
 110                 exit(0);
 111         else
 112                 exit(1);
 113 }], [AC_MSG_RESULT(working)],
 114         [AC_MSG_RESULT(buggy)
 115         AC_DEFINE(BROKEN_GETADDRINFO)],
 116         [AC_MSG_RESULT(assume it is working)])
 117         ;;
 118 *-*-hpux10.26)
 119         if test -z "$GCC"; then
 120                 CFLAGS="$CFLAGS -Ae"
 121         fi
 122         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 123         IPADDR_IN_DISPLAY=yes
 124         AC_DEFINE(HAVE_SECUREWARE)
 125         AC_DEFINE(USE_PIPES)
 126         AC_DEFINE(LOGIN_NO_ENDOPT)
 127         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 128         AC_DEFINE(DISABLE_SHADOW)
 129         AC_DEFINE(DISABLE_UTMP)
 130         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 131         LIBS="$LIBS -lsec -lsecpw"
 132         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 133         disable_ptmx_check=yes
 134         ;;
 135 *-*-hpux10*)
 136         if test -z "$GCC"; then
 137                 CFLAGS="$CFLAGS -Ae"
 138         fi
 139         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 140         IPADDR_IN_DISPLAY=yes
 141         AC_DEFINE(USE_PIPES)
 142         AC_DEFINE(LOGIN_NO_ENDOPT)
 143         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 144         AC_DEFINE(DISABLE_SHADOW)
 145         AC_DEFINE(DISABLE_UTMP)
 146         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 147         LIBS="$LIBS -lsec"
 148         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 149         ;;
 150 *-*-hpux11*)
 151         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 152         IPADDR_IN_DISPLAY=yes
 153         AC_DEFINE(PAM_SUN_CODEBASE)
 154         AC_DEFINE(USE_PIPES)
 155         AC_DEFINE(LOGIN_NO_ENDOPT)
 156         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 157         AC_DEFINE(DISABLE_SHADOW)
 158         AC_DEFINE(DISABLE_UTMP)
 159         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 160         LIBS="$LIBS -lsec"
 161         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 162         ;;
 163 *-*-irix5*)
 164         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 165         LDFLAGS="$LDFLAGS"
 166         PATH="$PATH:/usr/etc"
 167         AC_DEFINE(BROKEN_INET_NTOA)
 168         AC_DEFINE(WITH_ABBREV_NO_TTY)
 169         ;;
 170 *-*-irix6*)
 171         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 172         LDFLAGS="$LDFLAGS"
 173         PATH="$PATH:/usr/etc"
 174         AC_DEFINE(WITH_IRIX_ARRAY)
 175         AC_DEFINE(WITH_IRIX_PROJECT)
 176         AC_DEFINE(WITH_IRIX_AUDIT)
 177         AC_CHECK_FUNC(jlimit_startjob, [AC_DEFINE(WITH_IRIX_JOBS)])
 178         AC_DEFINE(BROKEN_INET_NTOA)
 179         AC_DEFINE(WITH_ABBREV_NO_TTY)
 180         ;;
 181 *-*-linux*)
 182         no_dev_ptmx=1
 183         check_for_libcrypt_later=1
 184         AC_DEFINE(DONT_TRY_OTHER_AF)
 185         AC_DEFINE(PAM_TTY_KLUDGE)
 186         AC_DEFINE(SPT_TYPE,SPT_REUSEARGV)
 187         inet6_default_4in6=yes
 188         # openpty can be in libutil, needed for controlling tty test
 189         AC_SEARCH_LIBS(openpty, util)
 190         # make sure that openpty does not reacquire controlling terminal
 191         AC_MSG_CHECKING(if openpty correctly handles controlling tty)
 192         AC_TRY_RUN(
 193                 [
 194 #include <stdio.h>
 195 #include <sys/fcntl.h>
 196 #include <sys/types.h>
 197 #include <sys/wait.h>
 198
 199 int
 200 main()
 201 {
 202         pid_t pid;
 203         int fd, ptyfd, ttyfd, status;
 204
 205         pid = fork();
 206         if (pid < 0) {          /* failed */
 207                 exit(1);
 208         } else if (pid > 0) {   /* parent */
 209                 waitpid(pid, &status, 0);
 210                 if (WIFEXITED(status))
 211                         exit(WEXITSTATUS(status));
 212                 else
 213                         exit(2);
 214         } else {                /* child */
 215                 close(0); close(1); close(2);
 216                 setsid();
 217                 openpty(&ptyfd, &ttyfd, NULL, NULL, NULL);
 218                 fd = open("/dev/tty", O_RDWR | O_NOCTTY);
 219                 if (fd >= 0)
 220                         exit(3);        /* Acquired ctty: broken */
 221                 else
 222                         exit(0);        /* Did not acquire ctty: OK */
 223         }
 224 }
 225                 ],
 226                 [
 227                         AC_MSG_RESULT(yes)
 228                 ],
 229                 [
 230                         AC_MSG_RESULT(no)
 231                         AC_DEFINE(SSHD_ACQUIRES_CTTY)
 232                 ]
 233         )
 234         case `uname -r` in
 235         1.*|2.0.*)
 236                 AC_DEFINE(BROKEN_CMSG_TYPE)
 237                 ;;
 238         esac
 239         ;;
 240 mips-sony-bsd|mips-sony-newsos4)
 241         AC_DEFINE(HAVE_NEWS4)
 242         SONY=1
 243         ;;
 244 *-*-netbsd*)
 245         check_for_libcrypt_before=1
 246         need_dash_r=1
 247         ;;
 248 *-*-freebsd*)
 249         check_for_libcrypt_later=1
 250         ;;
 251 *-next-*)
 252         conf_lastlog_location="/usr/adm/lastlog"
 253         conf_utmp_location=/etc/utmp
 254         conf_wtmp_location=/usr/adm/wtmp
 255         MAIL=/usr/spool/mail
 256         AC_DEFINE(HAVE_NEXT)
 257         AC_DEFINE(BROKEN_REALPATH)
 258         AC_DEFINE(USE_PIPES)
 259         AC_DEFINE(BROKEN_SAVED_UIDS)
 260         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 261         CFLAGS="$CFLAGS"
 262         ;;
 263 *-*-solaris*)
 264         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 265         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib"
 266         need_dash_r=1
 267         AC_DEFINE(PAM_SUN_CODEBASE)
 268         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 269         AC_DEFINE(LOGIN_NEEDS_TERM)
 270         AC_DEFINE(PAM_TTY_KLUDGE)
 271         # Pushing STREAMS modules will cause sshd to acquire a controlling tty.
 272         AC_DEFINE(SSHD_ACQUIRES_CTTY)
 273         # hardwire lastlog location (can't detect it on some versions)
 274         conf_lastlog_location="/var/adm/lastlog"
 275         AC_MSG_CHECKING(for obsolete utmp and wtmp in solaris2.x)
 276         sol2ver=`echo "$host"| sed -e 's/.*[[0-9]]\.//'`
 277         if test "$sol2ver" -ge 8; then
 278                 AC_MSG_RESULT(yes)
 279                 AC_DEFINE(DISABLE_UTMP)
 280                 AC_DEFINE(DISABLE_WTMP)
 281         else
 282                 AC_MSG_RESULT(no)
 283         fi
 284         ;;
 285 *-*-sunos4*)
 286         CPPFLAGS="$CPPFLAGS -DSUNOS4"
 287         AC_CHECK_FUNCS(getpwanam)
 288         AC_DEFINE(PAM_SUN_CODEBASE)
 289         conf_utmp_location=/etc/utmp
 290         conf_wtmp_location=/var/adm/wtmp
 291         conf_lastlog_location=/var/adm/lastlog
 292         AC_DEFINE(USE_PIPES)
 293         ;;
 294 *-ncr-sysv*)
 295         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 296         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 297         LIBS="$LIBS -lc89"
 298         AC_DEFINE(USE_PIPES)
 299         AC_DEFINE(SSHD_ACQUIRES_CTTY)
 300         ;;
 301 *-sni-sysv*)
 302         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 303         # /usr/ucblib MUST NOT be searched on ReliantUNIX
 304         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 305         IPADDR_IN_DISPLAY=yes
 306         AC_DEFINE(USE_PIPES)
 307         AC_DEFINE(IP_TOS_IS_BROKEN)
 308         AC_DEFINE(SSHD_ACQUIRES_CTTY)
 309         # /usr/ucblib/libucb.a no longer needed on ReliantUNIX
 310         # Attention: always take care to bind libsocket and libnsl before libc,
 311         # otherwise you will find lots of "SIOCGPGRP errno 22" on syslog
 312         ;;
 313 *-*-sysv4.2*)
 314         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 315         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 316         AC_DEFINE(USE_PIPES)
 317         ;;
 318 *-*-sysv5*)
 319         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 320         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 321         AC_DEFINE(USE_PIPES)
 322         ;;
 323 *-*-sysv*)
 324         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 325         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 326         ;;
 327 *-*-sco3.2v4*)
 328         CPPFLAGS="$CPPFLAGS -Dftruncate=chsize -I/usr/local/include"
 329         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 330         LIBS="$LIBS -los -lprot -lx -ltinfo -lm"
 331         RANLIB=true
 332         no_dev_ptmx=1
 333         AC_DEFINE(BROKEN_SYS_TERMIO_H)
 334         AC_DEFINE(USE_PIPES)
 335         AC_DEFINE(HAVE_SECUREWARE)
 336         AC_DEFINE(DISABLE_SHADOW)
 337         AC_DEFINE(BROKEN_SAVED_UIDS)
 338         AC_CHECK_FUNCS(getluid setluid)
 339         MANTYPE=man
 340         do_sco3_extra_lib_check=yes
 341         ;;
 342 *-*-sco3.2v5*)
 343         if test -z "$GCC"; then
 344                 CFLAGS="$CFLAGS -belf"
 345         fi
 346         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 347         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 348         LIBS="$LIBS -lprot -lx -ltinfo -lm"
 349         no_dev_ptmx=1
 350         AC_DEFINE(USE_PIPES)
 351         AC_DEFINE(HAVE_SECUREWARE)
 352         AC_DEFINE(DISABLE_SHADOW)
 353         AC_DEFINE(DISABLE_FD_PASSING)
 354         AC_CHECK_FUNCS(getluid setluid)
 355         MANTYPE=man
 356         ;;
 357 *-*-unicosmk*)
 358         AC_DEFINE(USE_PIPES)
 359         AC_DEFINE(DISABLE_FD_PASSING)
 360         LDFLAGS="$LDFLAGS"
 361         LIBS="$LIBS -lgen -lrsc -lshare -luex -lacm"
 362         MANTYPE=cat
 363         ;;
 364 *-*-unicos*)
 365         AC_DEFINE(USE_PIPES)
 366         AC_DEFINE(DISABLE_FD_PASSING)
 367         AC_DEFINE(NO_SSH_LASTLOG)
 368         LDFLAGS="$LDFLAGS -Wl,-Dmsglevel=334:fatal"
 369         LIBS="$LIBS -lgen -lrsc -lshare -luex -lacm"
 370         MANTYPE=cat
 371         ;;
 372 *-dec-osf*)
 373         AC_MSG_CHECKING(for Digital Unix SIA)
 374         no_osfsia=""
 375         AC_ARG_WITH(osfsia,
 376                 [  --with-osfsia           Enable Digital Unix SIA],
 377                 [
 378                         if test "x$withval" = "xno" ; then
 379                                 AC_MSG_RESULT(disabled)
 380                                 no_osfsia=1
 381                         fi
 382                 ],
 383         )
 384         if test -z "$no_osfsia" ; then
 385                 if test -f /etc/sia/matrix.conf; then
 386                         AC_MSG_RESULT(yes)
 387                         AC_DEFINE(HAVE_OSF_SIA)
 388                         AC_DEFINE(DISABLE_LOGIN)
 389                         AC_DEFINE(DISABLE_FD_PASSING)
 390                         LIBS="$LIBS -lsecurity -ldb -lm -laud"
 391                 else
 392                         AC_MSG_RESULT(no)
 393                 fi
 394         fi
 395         AC_DEFINE(DISABLE_FD_PASSING)
 396         ;;
 397
 398 *-*-nto-qnx)
 399         AC_DEFINE(USE_PIPES)
 400         AC_DEFINE(NO_X11_UNIX_SOCKETS)
 401         AC_DEFINE(MISSING_NFDBITS)
 402         AC_DEFINE(MISSING_HOWMANY)
 403         AC_DEFINE(MISSING_FD_MASK)
 404         ;;
 405 esac
 406
 407 # Allow user to specify flags
 408 AC_ARG_WITH(cflags,
 409         [  --with-cflags           Specify additional flags to pass to compiler],
 410         [
 411                 if test "x$withval" != "xno" ; then
 412                         CFLAGS="$CFLAGS $withval"
 413                 fi
 414         ]
 415 )
 416 AC_ARG_WITH(cppflags,
 417         [  --with-cppflags         Specify additional flags to pass to preprocessor] ,
 418         [
 419                 if test "x$withval" != "xno"; then
 420                         CPPFLAGS="$CPPFLAGS $withval"
 421                 fi
 422         ]
 423 )
 424 AC_ARG_WITH(ldflags,
 425         [  --with-ldflags          Specify additional flags to pass to linker],
 426         [
 427                 if test "x$withval" != "xno" ; then
 428                         LDFLAGS="$LDFLAGS $withval"
 429                 fi
 430         ]
 431 )
 432 AC_ARG_WITH(libs,
 433         [  --with-libs             Specify additional libraries to link with],
 434         [
 435                 if test "x$withval" != "xno" ; then
 436                         LIBS="$LIBS $withval"
 437                 fi
 438         ]
 439 )
 440
 441 # Checks for header files.
 442 AC_CHECK_HEADERS(bstring.h crypt.h endian.h features.h floatingpoint.h \
 443         getopt.h glob.h ia.h lastlog.h libgen.h limits.h login.h \
 444         login_cap.h maillock.h netdb.h netgroup.h \
 445         netinet/in_systm.h paths.h pty.h readpassphrase.h \
 446         rpc/types.h security/pam_appl.h shadow.h stddef.h stdint.h \
 447         strings.h sys/strtio.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h \
 448         sys/mman.h sys/pstat.h sys/select.h sys/stat.h \
 449         sys/stropts.h sys/sysmacros.h sys/time.h sys/timers.h \
 450         sys/un.h time.h tmpdir.h ttyent.h usersec.h \
 451         util.h utime.h utmp.h utmpx.h)
 452
 453 # Checks for libraries.
 454 AC_CHECK_FUNC(yp_match, , AC_CHECK_LIB(nsl, yp_match))
 455 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 456
 457 dnl SCO OS3 needs this for libwrap
 458 if test "x$with_tcp_wrappers" != "xno" ; then
 459     if test "x$do_sco3_extra_lib_check" = "xyes" ; then
 460         AC_CHECK_LIB(rpc, innetgr, LIBS="-lrpc -lyp -lrpc $LIBS" , , -lyp -lrpc)
 461     fi
 462 fi
 463
 464 AC_CHECK_FUNC(getspnam, ,
 465         AC_CHECK_LIB(gen, getspnam, LIBS="$LIBS -lgen"))
 466
 467 AC_ARG_WITH(rpath,
 468         [  --without-rpath         Disable auto-added -R linker paths],
 469         [
 470                 if test "x$withval" = "xno" ; then
 471                         need_dash_r=""
 472                 fi
 473                 if test "x$withval" = "xyes" ; then
 474                         need_dash_r=1
 475                 fi
 476         ]
 477 )
 478
 479 dnl zlib is required
 480 AC_ARG_WITH(zlib,
 481         [  --with-zlib=PATH        Use zlib in PATH],
 482         [
 483                 if test "x$withval" = "xno" ; then
 484                         AC_MSG_ERROR([*** zlib is required ***])
 485                 fi
 486                 if test -d "$withval/lib"; then
 487                         if test -n "${need_dash_r}"; then
 488                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 489                         else
 490                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 491                         fi
 492                 else
 493                         if test -n "${need_dash_r}"; then
 494                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 495                         else
 496                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 497                         fi
 498                 fi
 499                 if test -d "$withval/include"; then
 500                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 501                 else
 502                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 503                 fi
 504         ]
 505 )
 506
 507 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first or check config.log ***]))
 508
 509 dnl UnixWare 2.x
 510 AC_CHECK_FUNC(strcasecmp,
 511         [], [ AC_CHECK_LIB(resolv, strcasecmp, LIBS="$LIBS -lresolv") ]
 512 )
 513 AC_CHECK_FUNC(utimes,
 514         [], [ AC_CHECK_LIB(c89, utimes, [AC_DEFINE(HAVE_UTIMES)
 515                                         LIBS="$LIBS -lc89"]) ]
 516 )
 517
 518 dnl    Checks for libutil functions
 519 AC_CHECK_HEADERS(libutil.h)
 520 AC_SEARCH_LIBS(login, util bsd, [AC_DEFINE(HAVE_LOGIN)])
 521 AC_CHECK_FUNCS(logout updwtmp logwtmp)
 522
 523 AC_FUNC_STRFTIME
 524
 525 # Check for ALTDIRFUNC glob() extension
 526 AC_MSG_CHECKING(for GLOB_ALTDIRFUNC support)
 527 AC_EGREP_CPP(FOUNDIT,
 528         [
 529                 #include <glob.h>
 530                 #ifdef GLOB_ALTDIRFUNC
 531                 FOUNDIT
 532                 #endif
 533         ],
 534         [
 535                 AC_DEFINE(GLOB_HAS_ALTDIRFUNC)
 536                 AC_MSG_RESULT(yes)
 537         ],
 538         [
 539                 AC_MSG_RESULT(no)
 540         ]
 541 )
 542
 543 # Check for g.gl_matchc glob() extension
 544 AC_MSG_CHECKING(for gl_matchc field in glob_t)
 545 AC_EGREP_CPP(FOUNDIT,
 546         [
 547                 #include <glob.h>
 548                 int main(void){glob_t g; g.gl_matchc = 1;}
 549         ],
 550         [
 551                 AC_DEFINE(GLOB_HAS_GL_MATCHC)
 552                 AC_MSG_RESULT(yes)
 553         ],
 554         [
 555                 AC_MSG_RESULT(no)
 556         ]
 557 )
 558
 559 AC_MSG_CHECKING([whether struct dirent allocates space for d_name])
 560 AC_TRY_RUN(
 561         [
 562 #include <sys/types.h>
 563 #include <dirent.h>
 564 int main(void){struct dirent d;exit(sizeof(d.d_name)<=sizeof(char));}
 565         ],
 566         [AC_MSG_RESULT(yes)],
 567         [
 568                 AC_MSG_RESULT(no)
 569                 AC_DEFINE(BROKEN_ONE_BYTE_DIRENT_D_NAME)
 570         ]
 571 )
 572
 573 # Check whether user wants S/Key support
 574 SKEY_MSG="no"
 575 AC_ARG_WITH(skey,
 576         [  --with-skey[[=PATH]]      Enable S/Key support
 577                             (optionally in PATH)],
 578         [
 579                 if test "x$withval" != "xno" ; then
 580
 581                         if test "x$withval" != "xyes" ; then
 582                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 583                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 584                         fi
 585
 586                         AC_DEFINE(SKEY)
 587                         LIBS="-lskey $LIBS"
 588                         SKEY_MSG="yes"
 589
 590                         AC_MSG_CHECKING([for s/key support])
 591                         AC_TRY_RUN(
 592                                 [
 593 #include <stdio.h>
 594 #include <skey.h>
 595 int main() { char *ff = skey_keyinfo(""); ff=""; exit(0); }
 596                                 ],
 597                                 [AC_MSG_RESULT(yes)],
 598                                 [
 599                                         AC_MSG_RESULT(no)
 600                                         AC_MSG_ERROR([** Incomplete or missing s/key libraries.])
 601                                 ])
 602                 fi
 603         ]
 604 )
 605
 606 # Check whether user wants TCP wrappers support
 607 TCPW_MSG="no"
 608 AC_ARG_WITH(tcp-wrappers,
 609         [  --with-tcp-wrappers[[=PATH]]      Enable tcpwrappers support
 610                             (optionally in PATH)],
 611         [
 612                 if test "x$withval" != "xno" ; then
 613                         saved_LIBS="$LIBS"
 614                         saved_LDFLAGS="$LDFLAGS"
 615                         saved_CPPFLAGS="$CPPFLAGS"
 616                         if test -n "${withval}" -a "${withval}" != "yes"; then
 617                                 if test -d "${withval}/lib"; then
 618                                         if test -n "${need_dash_r}"; then
 619                                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 620                                         else
 621                                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 622                                         fi
 623                                 else
 624                                         if test -n "${need_dash_r}"; then
 625                                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 626                                         else
 627                                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 628                                         fi
 629                                 fi
 630                                 if test -d "${withval}/include"; then
 631                                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 632                                 else
 633                                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 634                                 fi
 635                         fi
 636                         LIBWRAP="-lwrap"
 637                         LIBS="$LIBWRAP $LIBS"
 638                         AC_MSG_CHECKING(for libwrap)
 639                         AC_TRY_LINK(
 640                                 [
 641 #include <tcpd.h>
 642                                         int deny_severity = 0, allow_severity = 0;
 643                                 ],
 644                                 [hosts_access(0);],
 645                                 [
 646                                         AC_MSG_RESULT(yes)
 647                                         AC_DEFINE(LIBWRAP)
 648                                         AC_SUBST(LIBWRAP)
 649                                         TCPW_MSG="yes"
 650                                 ],
 651                                 [
 652                                         AC_MSG_ERROR([*** libwrap missing])
 653                                 ]
 654                         )
 655                         LIBS="$saved_LIBS"
 656                 fi
 657         ]
 658 )
 659
 660 dnl    Checks for library functions. Please keep in alphabetical order
 661 AC_CHECK_FUNCS(\
 662         arc4random __b64_ntop b64_ntop __b64_pton b64_pton basename \
 663         bcopy bindresvport_sa clock fchmod fchown freeaddrinfo futimes \
 664         gai_strerror getaddrinfo getcwd getgrouplist getnameinfo getopt \
 665         getpeereid _getpty getrlimit getrusage getttyent glob inet_aton \
 666         inet_ntoa inet_ntop innetgr login_getcapbool md5_crypt memmove \
 667         mkdtemp mmap ngetaddrinfo nsleep ogetaddrinfo openlog_r openpty \
 668         pstat readpassphrase realpath recvmsg rresvport_af sendmsg \
 669         setdtablesize setegid setenv seteuid setgroups setlogin setpcred \
 670         setproctitle setregid setresgid setresuid setreuid setrlimit \
 671         setsid setvbuf sigaction sigvec snprintf socketpair strerror \
 672         strlcat strlcpy strmode strnvis sysconf tcgetpgrp truncate utimes \
 673         vhangup vsnprintf waitpid \
 674 )
 675
 676 AC_SEARCH_LIBS(nanosleep, rt posix4, AC_DEFINE(HAVE_NANOSLEEP))
 677 AC_SEARCH_LIBS(basename, gen, AC_DEFINE(HAVE_BASENAME))
 678
 679 dnl Make sure strsep prototype is defined before defining HAVE_STRSEP
 680 AC_CHECK_DECL(strsep, [AC_CHECK_FUNCS(strsep)])
 681
 682 dnl IRIX and Solaris 2.5.1 have dirname() in libgen
 683 AC_CHECK_FUNCS(dirname, [AC_CHECK_HEADERS(libgen.h)] ,[
 684         AC_CHECK_LIB(gen, dirname,[
 685                 AC_CACHE_CHECK([for broken dirname],
 686                         ac_cv_have_broken_dirname, [
 687                         save_LIBS="$LIBS"
 688                         LIBS="$LIBS -lgen"
 689                         AC_TRY_RUN(
 690                                 [
 691 #include <libgen.h>
 692 #include <string.h>
 693
 694 int main(int argc, char **argv) {
 695     char *s, buf[32];
 696
 697     strncpy(buf,"/etc", 32);
 698     s = dirname(buf);
 699     if (!s || strncmp(s, "/", 32) != 0) {
 700         exit(1);
 701     } else {
 702         exit(0);
 703     }
 704 }
 705                                 ],
 706                                 [ ac_cv_have_broken_dirname="no" ],
 707                                 [ ac_cv_have_broken_dirname="yes" ]
 708                         )
 709                         LIBS="$save_LIBS"
 710                 ])
 711                 if test "x$ac_cv_have_broken_dirname" = "xno" ; then
 712                         LIBS="$LIBS -lgen"
 713                         AC_DEFINE(HAVE_DIRNAME)
 714                         AC_CHECK_HEADERS(libgen.h)
 715                 fi
 716         ])
 717 ])
 718
 719 dnl    Checks for time functions
 720 AC_CHECK_FUNCS(gettimeofday time)
 721 dnl    Checks for utmp functions
 722 AC_CHECK_FUNCS(endutent getutent getutid getutline pututline setutent)
 723 AC_CHECK_FUNCS(utmpname)
 724 dnl    Checks for utmpx functions
 725 AC_CHECK_FUNCS(endutxent getutxent getutxid getutxline pututxline )
 726 AC_CHECK_FUNCS(setutxent utmpxname)
 727
 728 AC_CHECK_FUNC(daemon,
 729         [AC_DEFINE(HAVE_DAEMON)],
 730         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 731 )
 732
 733 AC_CHECK_FUNC(getpagesize,
 734         [AC_DEFINE(HAVE_GETPAGESIZE)],
 735         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 736 )
 737
 738 # Check for broken snprintf
 739 if test "x$ac_cv_func_snprintf" = "xyes" ; then
 740         AC_MSG_CHECKING([whether snprintf correctly terminates long strings])
 741         AC_TRY_RUN(
 742                 [
 743 #include <stdio.h>
 744 int main(void){char b[5];snprintf(b,5,"123456789");exit(b[4]!='\0');}
 745                 ],
 746                 [AC_MSG_RESULT(yes)],
 747                 [
 748                         AC_MSG_RESULT(no)
 749                         AC_DEFINE(BROKEN_SNPRINTF)
 750                         AC_MSG_WARN([****** Your snprintf() function is broken, complain to your vendor])
 751                 ]
 752         )
 753 fi
 754
 755 dnl see whether mkstemp() requires XXXXXX
 756 if test "x$ac_cv_func_mkdtemp" = "xyes" ; then
 757 AC_MSG_CHECKING([for (overly) strict mkstemp])
 758 AC_TRY_RUN(
 759         [
 760 #include <stdlib.h>
 761 main() { char template[]="conftest.mkstemp-test";
 762 if (mkstemp(template) == -1)
 763         exit(1);
 764 unlink(template); exit(0);
 765 }
 766         ],
 767         [
 768                 AC_MSG_RESULT(no)
 769         ],
 770         [
 771                 AC_MSG_RESULT(yes)
 772                 AC_DEFINE(HAVE_STRICT_MKSTEMP)
 773         ],
 774         [
 775                 AC_MSG_RESULT(yes)
 776                 AC_DEFINE(HAVE_STRICT_MKSTEMP)
 777         ]
 778 )
 779 fi
 780
 781 AC_FUNC_GETPGRP
 782
 783 # Check for PAM libs
 784 PAM_MSG="no"
 785 AC_ARG_WITH(pam,
 786         [  --with-pam              Enable PAM support ],
 787         [
 788                 if test "x$withval" != "xno" ; then
 789                         if test "x$ac_cv_header_security_pam_appl_h" != "xyes" ; then
 790                                 AC_MSG_ERROR([PAM headers not found])
 791                         fi
 792
 793                         AC_CHECK_LIB(dl, dlopen, , )
 794                         AC_CHECK_LIB(pam, pam_set_item, , AC_MSG_ERROR([*** libpam missing]))
 795                         AC_CHECK_FUNCS(pam_getenvlist)
 796
 797                         disable_shadow=yes
 798                         PAM_MSG="yes"
 799
 800                         AC_DEFINE(USE_PAM)
 801                         if test $ac_cv_lib_dl_dlopen = yes; then
 802                                 LIBPAM="-lpam -ldl"
 803                         else
 804                                 LIBPAM="-lpam"
 805                         fi
 806                         AC_SUBST(LIBPAM)
 807                 fi
 808         ]
 809 )
 810
 811 # Check for older PAM
 812 if test "x$PAM_MSG" = "xyes" ; then
 813         # Check PAM strerror arguments (old PAM)
 814         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 815         AC_TRY_COMPILE(
 816                 [
 817 #include <stdlib.h>
 818 #include <security/pam_appl.h>
 819                 ],
 820                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 821                 [AC_MSG_RESULT(no)],
 822                 [
 823                         AC_DEFINE(HAVE_OLD_PAM)
 824                         AC_MSG_RESULT(yes)
 825                         PAM_MSG="yes (old library)"
 826                 ]
 827         )
 828 fi
 829
 830 # Some systems want crypt() from libcrypt, *not* the version in OpenSSL,
 831 # because the system crypt() is more featureful.
 832 if test "x$check_for_libcrypt_before" = "x1"; then
 833         AC_CHECK_LIB(crypt, crypt)
 834 fi
 835
 836 # Search for OpenSSL
 837 saved_CPPFLAGS="$CPPFLAGS"
 838 saved_LDFLAGS="$LDFLAGS"
 839 AC_ARG_WITH(ssl-dir,
 840         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 841         [
 842                 if test "x$withval" != "xno" ; then
 843                         if test -d "$withval/lib"; then
 844                                 if test -n "${need_dash_r}"; then
 845                                         LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 846                                 else
 847                                         LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 848                                 fi
 849                         else
 850                                 if test -n "${need_dash_r}"; then
 851                                         LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 852                                 else
 853                                         LDFLAGS="-L${withval} ${LDFLAGS}"
 854                                 fi
 855                         fi
 856                         if test -d "$withval/include"; then
 857                                 CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 858                         else
 859                                 CPPFLAGS="-I${withval} ${CPPFLAGS}"
 860                         fi
 861                 fi
 862         ]
 863 )
 864 LIBS="$LIBS -lcrypto"
 865 AC_TRY_LINK_FUNC(RAND_add, AC_DEFINE(HAVE_OPENSSL),
 866         [
 867                 dnl Check default openssl install dir
 868                 if test -n "${need_dash_r}"; then
 869                         LDFLAGS="-L/usr/local/ssl/lib -R/usr/local/ssl/lib ${saved_LDFLAGS}"
 870                 else
 871                         LDFLAGS="-L/usr/local/ssl/lib ${saved_LDFLAGS}"
 872                 fi
 873                 CPPFLAGS="-I/usr/local/ssl/include ${saved_CPPFLAGS}"
 874                 AC_TRY_LINK_FUNC(RAND_add, AC_DEFINE(HAVE_OPENSSL),
 875                         [
 876                                 AC_MSG_ERROR([*** Can't find recent OpenSSL libcrypto (see config.log for details) ***])
 877                         ]
 878                 )
 879         ]
 880 )
 881
 882 # Determine OpenSSL header version
 883 AC_MSG_CHECKING([OpenSSL header version])
 884 AC_TRY_RUN(
 885         [
 886 #include <stdio.h>
 887 #include <string.h>
 888 #include <openssl/opensslv.h>
 889 #define DATA "conftest.sslincver"
 890 int main(void) {
 891         FILE *fd;
 892         int rc;
 893
 894         fd = fopen(DATA,"w");
 895         if(fd == NULL)
 896                 exit(1);
 897
 898         if ((rc = fprintf(fd ,"%x (%s)\n", OPENSSL_VERSION_NUMBER, OPENSSL_VERSION_TEXT)) <0)
 899                 exit(1);
 900
 901         exit(0);
 902 }
 903         ],
 904         [
 905                 ssl_header_ver=`cat conftest.sslincver`
 906                 AC_MSG_RESULT($ssl_header_ver)
 907         ],
 908         [
 909                 AC_MSG_RESULT(not found)
 910                 AC_MSG_ERROR(OpenSSL version header not found.)
 911         ]
 912 )
 913
 914 # Determine OpenSSL library version
 915 AC_MSG_CHECKING([OpenSSL library version])
 916 AC_TRY_RUN(
 917         [
 918 #include <stdio.h>
 919 #include <string.h>
 920 #include <openssl/opensslv.h>
 921 #include <openssl/crypto.h>
 922 #define DATA "conftest.ssllibver"
 923 int main(void) {
 924         FILE *fd;
 925         int rc;
 926
 927         fd = fopen(DATA,"w");
 928         if(fd == NULL)
 929                 exit(1);
 930
 931         if ((rc = fprintf(fd ,"%x (%s)\n", SSLeay(), SSLeay_version(SSLEAY_VERSION))) <0)
 932                 exit(1);
 933
 934         exit(0);
 935 }
 936         ],
 937         [
 938                 ssl_library_ver=`cat conftest.ssllibver`
 939                 AC_MSG_RESULT($ssl_library_ver)
 940         ],
 941         [
 942                 AC_MSG_RESULT(not found)
 943                 AC_MSG_ERROR(OpenSSL library not found.)
 944         ]
 945 )
 946
 947 # Sanity check OpenSSL headers
 948 AC_MSG_CHECKING([whether OpenSSL's headers match the library])
 949 AC_TRY_RUN(
 950         [
 951 #include <string.h>
 952 #include <openssl/opensslv.h>
 953 int main(void) { exit(SSLeay() == OPENSSL_VERSION_NUMBER ? 0 : 1); }
 954         ],
 955         [
 956                 AC_MSG_RESULT(yes)
 957         ],
 958         [
 959                 AC_MSG_RESULT(no)
 960                 AC_MSG_ERROR(Your OpenSSL headers do not match your library)
 961         ]
 962 )
 963
 964 # Some Linux systems (Slackware) need crypt() from libcrypt, *not* the
 965 # version in OpenSSL. Skip this for PAM
 966 if test "x$check_for_libcrypt_later" = "x1"; then
 967         AC_CHECK_LIB(crypt, crypt, LIBS="$LIBS -lcrypt")
 968 fi
 969
 970
 971 ### Configure cryptographic random number support
 972
 973 # Check wheter OpenSSL seeds itself
 974 AC_MSG_CHECKING([whether OpenSSL's PRNG is internally seeded])
 975 AC_TRY_RUN(
 976         [
 977 #include <string.h>
 978 #include <openssl/rand.h>
 979 int main(void) { exit(RAND_status() == 1 ? 0 : 1); }
 980         ],
 981         [
 982                 OPENSSL_SEEDS_ITSELF=yes
 983                 AC_MSG_RESULT(yes)
 984         ],
 985         [
 986                 AC_MSG_RESULT(no)
 987                 # Default to use of the rand helper if OpenSSL doesn't
 988                 # seed itself
 989                 USE_RAND_HELPER=yes
 990         ]
 991 )
 992
 993
 994 # Do we want to force the use of the rand helper?
 995 AC_ARG_WITH(rand-helper,
 996         [  --with-rand-helper      Use subprocess to gather strong randomness ],
 997         [
 998                 if test "x$withval" = "xno" ; then
 999                         # Force use of OpenSSL's internal RNG, even if
1000                         # the previous test showed it to be unseeded.
1001                         if test -z "$OPENSSL_SEEDS_ITSELF" ; then
1002                                 AC_MSG_WARN([*** Forcing use of OpenSSL's non-self-seeding PRNG])
1003                                 OPENSSL_SEEDS_ITSELF=yes
1004                                 USE_RAND_HELPER=""
1005                         fi
1006                 else
1007                         USE_RAND_HELPER=yes
1008                 fi
1009         ],
1010 )
1011
1012 # Which randomness source do we use?
1013 if test ! -z "$OPENSSL_SEEDS_ITSELF" -a -z "$USE_RAND_HELPER" ; then
1014         # OpenSSL only
1015         AC_DEFINE(OPENSSL_PRNG_ONLY)
1016         RAND_MSG="OpenSSL internal ONLY"
1017         INSTALL_SSH_RAND_HELPER=""
1018 elif test ! -z "$USE_RAND_HELPER" ; then
1019         # install rand helper
1020         RAND_MSG="ssh-rand-helper"
1021         INSTALL_SSH_RAND_HELPER="yes"
1022 fi
1023 AC_SUBST(INSTALL_SSH_RAND_HELPER)
1024
1025 ### Configuration of ssh-rand-helper
1026
1027 # PRNGD TCP socket
1028 AC_ARG_WITH(prngd-port,
1029         [  --with-prngd-port=PORT  read entropy from PRNGD/EGD TCP localhost:PORT],
1030         [
1031                 case "$withval" in
1032                 no)
1033                         withval=""
1034                         ;;
1035                 [[0-9]]*)
1036                         ;;
1037                 *)
1038                         AC_MSG_ERROR(You must specify a numeric port number for --with-prngd-port)
1039                         ;;
1040                 esac
1041                 if test ! -z "$withval" ; then
1042                         PRNGD_PORT="$withval"
1043                         AC_DEFINE_UNQUOTED(PRNGD_PORT, $PRNGD_PORT)
1044                 fi
1045         ]
1046 )
1047
1048 # PRNGD Unix domain socket
1049 AC_ARG_WITH(prngd-socket,
1050         [  --with-prngd-socket=FILE read entropy from PRNGD/EGD socket FILE (default=/var/run/egd-pool)],
1051         [
1052                 case "$withval" in
1053                 yes)
1054                         withval="/var/run/egd-pool"
1055                         ;;
1056                 no)
1057                         withval=""
1058                         ;;
1059                 /*)
1060                         ;;
1061                 *)
1062                         AC_MSG_ERROR(You must specify an absolute path to the entropy socket)
1063                         ;;
1064                 esac
1065
1066                 if test ! -z "$withval" ; then
1067                         if test ! -z "$PRNGD_PORT" ; then
1068                                 AC_MSG_ERROR(You may not specify both a PRNGD/EGD port and socket)
1069                         fi
1070                         if test ! -r "$withval" ; then
1071                                 AC_MSG_WARN(Entropy socket is not readable)
1072                         fi
1073                         PRNGD_SOCKET="$withval"
1074                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1075                 fi
1076         ],
1077         [
1078                 # Check for existing socket only if we don't have a random device already
1079                 if test "$USE_RAND_HELPER" = yes ; then
1080                         AC_MSG_CHECKING(for PRNGD/EGD socket)
1081                         # Insert other locations here
1082                         for sock in /var/run/egd-pool /dev/egd-pool /etc/entropy; do
1083                                 if test -r $sock && $TEST_MINUS_S_SH -c "test -S $sock -o -p $sock" ; then
1084                                         PRNGD_SOCKET="$sock"
1085                                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1086                                         break;
1087                                 fi
1088                         done
1089                         if test ! -z "$PRNGD_SOCKET" ; then
1090                                 AC_MSG_RESULT($PRNGD_SOCKET)
1091                         else
1092                                 AC_MSG_RESULT(not found)
1093                         fi
1094                 fi
1095         ]
1096 )
1097
1098 # Change default command timeout for hashing entropy source
1099 entropy_timeout=200
1100 AC_ARG_WITH(entropy-timeout,
1101         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
1102         [
1103                 if test "x$withval" != "xno" ; then
1104                         entropy_timeout=$withval
1105                 fi
1106         ]
1107 )
1108 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
1109
1110 SSH_PRIVSEP_USER=sshd
1111 AC_ARG_WITH(privsep-user,
1112         [  --with-privsep-user=user Specify non-privileged user for privilege separation],
1113         [
1114                 if test -n "$withval"; then
1115                         SSH_PRIVSEP_USER=$withval
1116                 fi
1117         ]
1118 )
1119 AC_DEFINE_UNQUOTED(SSH_PRIVSEP_USER, "$SSH_PRIVSEP_USER")
1120 AC_SUBST(SSH_PRIVSEP_USER)
1121
1122 # We do this little dance with the search path to insure
1123 # that programs that we select for use by installed programs
1124 # (which may be run by the super-user) come from trusted
1125 # locations before they come from the user's private area.
1126 # This should help avoid accidentally configuring some
1127 # random version of a program in someone's personal bin.
1128
1129 OPATH=$PATH
1130 PATH=/bin:/usr/bin
1131 test -h /bin 2> /dev/null && PATH=/usr/bin
1132 test -d /sbin && PATH=$PATH:/sbin
1133 test -d /usr/sbin && PATH=$PATH:/usr/sbin
1134 PATH=$PATH:/etc:$OPATH
1135
1136 # These programs are used by the command hashing source to gather entropy
1137 OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1138 OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
1139 OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
1140 OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
1141 OSSH_PATH_ENTROPY_PROG(PROG_JSTAT, jstat)
1142 OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
1143 OSSH_PATH_ENTROPY_PROG(PROG_SAR, sar)
1144 OSSH_PATH_ENTROPY_PROG(PROG_W, w)
1145 OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
1146 OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
1147 OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
1148 OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
1149 OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
1150 OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
1151 OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
1152 OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
1153 # restore PATH
1154 PATH=$OPATH
1155
1156 # Where does ssh-rand-helper get its randomness from?
1157 INSTALL_SSH_PRNG_CMDS=""
1158 if test ! -z "$INSTALL_SSH_RAND_HELPER" ; then
1159         if test ! -z "$PRNGD_PORT" ; then
1160                 RAND_HELPER_MSG="TCP localhost:$PRNGD_PORT"
1161         elif test ! -z "$PRNGD_SOCKET" ; then
1162                 RAND_HELPER_MSG="Unix domain socket \"$PRNGD_SOCKET\""
1163         else
1164                 RAND_HELPER_MSG="Command hashing (timeout $entropy_timeout)"
1165                 RAND_HELPER_CMDHASH=yes
1166                 INSTALL_SSH_PRNG_CMDS="yes"
1167         fi
1168 fi
1169 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
1170
1171
1172 # Cheap hack to ensure NEWS-OS libraries are arranged right.
1173 if test ! -z "$SONY" ; then
1174   LIBS="$LIBS -liberty";
1175 fi
1176
1177 # Checks for data types
1178 AC_CHECK_SIZEOF(char, 1)
1179 AC_CHECK_SIZEOF(short int, 2)
1180 AC_CHECK_SIZEOF(int, 4)
1181 AC_CHECK_SIZEOF(long int, 4)
1182 AC_CHECK_SIZEOF(long long int, 8)
1183
1184 # Sanity check long long for some platforms (AIX)
1185 if test "x$ac_cv_sizeof_long_long_int" = "x4" ; then
1186         ac_cv_sizeof_long_long_int=0
1187 fi
1188
1189 # More checks for data types
1190 AC_CACHE_CHECK([for u_int type], ac_cv_have_u_int, [
1191         AC_TRY_COMPILE(
1192                 [ #include <sys/types.h> ],
1193                 [ u_int a; a = 1;],
1194                 [ ac_cv_have_u_int="yes" ],
1195                 [ ac_cv_have_u_int="no" ]
1196         )
1197 ])
1198 if test "x$ac_cv_have_u_int" = "xyes" ; then
1199         AC_DEFINE(HAVE_U_INT)
1200         have_u_int=1
1201 fi
1202
1203 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
1204         AC_TRY_COMPILE(
1205                 [ #include <sys/types.h> ],
1206                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
1207                 [ ac_cv_have_intxx_t="yes" ],
1208                 [ ac_cv_have_intxx_t="no" ]
1209         )
1210 ])
1211 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
1212         AC_DEFINE(HAVE_INTXX_T)
1213         have_intxx_t=1
1214 fi
1215
1216 if (test -z "$have_intxx_t" && \
1217            test "x$ac_cv_header_stdint_h" = "xyes")
1218 then
1219     AC_MSG_CHECKING([for intXX_t types in stdint.h])
1220         AC_TRY_COMPILE(
1221                 [ #include <stdint.h> ],
1222                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
1223                 [
1224                         AC_DEFINE(HAVE_INTXX_T)
1225                         AC_MSG_RESULT(yes)
1226                 ],
1227                 [ AC_MSG_RESULT(no) ]
1228         )
1229 fi
1230
1231 AC_CACHE_CHECK([for int64_t type], ac_cv_have_int64_t, [
1232         AC_TRY_COMPILE(
1233                 [
1234 #include <sys/types.h>
1235 #ifdef HAVE_STDINT_H
1236 # include <stdint.h>
1237 #endif
1238 #include <sys/socket.h>
1239 #ifdef HAVE_SYS_BITYPES_H
1240 # include <sys/bitypes.h>
1241 #endif
1242                 ],
1243                 [ int64_t a; a = 1;],
1244                 [ ac_cv_have_int64_t="yes" ],
1245                 [ ac_cv_have_int64_t="no" ]
1246         )
1247 ])
1248 if test "x$ac_cv_have_int64_t" = "xyes" ; then
1249         AC_DEFINE(HAVE_INT64_T)
1250 fi
1251
1252 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
1253         AC_TRY_COMPILE(
1254                 [ #include <sys/types.h> ],
1255                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
1256                 [ ac_cv_have_u_intxx_t="yes" ],
1257                 [ ac_cv_have_u_intxx_t="no" ]
1258         )
1259 ])
1260 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
1261         AC_DEFINE(HAVE_U_INTXX_T)
1262         have_u_intxx_t=1
1263 fi
1264
1265 if test -z "$have_u_intxx_t" ; then
1266     AC_MSG_CHECKING([for u_intXX_t types in sys/socket.h])
1267         AC_TRY_COMPILE(
1268                 [ #include <sys/socket.h> ],
1269                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
1270                 [
1271                         AC_DEFINE(HAVE_U_INTXX_T)
1272                         AC_MSG_RESULT(yes)
1273                 ],
1274                 [ AC_MSG_RESULT(no) ]
1275         )
1276 fi
1277
1278 AC_CACHE_CHECK([for u_int64_t types], ac_cv_have_u_int64_t, [
1279         AC_TRY_COMPILE(
1280                 [ #include <sys/types.h> ],
1281                 [ u_int64_t a; a = 1;],
1282                 [ ac_cv_have_u_int64_t="yes" ],
1283                 [ ac_cv_have_u_int64_t="no" ]
1284         )
1285 ])
1286 if test "x$ac_cv_have_u_int64_t" = "xyes" ; then
1287         AC_DEFINE(HAVE_U_INT64_T)
1288         have_u_int64_t=1
1289 fi
1290
1291 if test -z "$have_u_int64_t" ; then
1292     AC_MSG_CHECKING([for u_int64_t type in sys/bitypes.h])
1293         AC_TRY_COMPILE(
1294                 [ #include <sys/bitypes.h> ],
1295                 [ u_int64_t a; a = 1],
1296                 [
1297                         AC_DEFINE(HAVE_U_INT64_T)
1298                         AC_MSG_RESULT(yes)
1299                 ],
1300                 [ AC_MSG_RESULT(no) ]
1301         )
1302 fi
1303
1304 if test -z "$have_u_intxx_t" ; then
1305         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
1306                 AC_TRY_COMPILE(
1307                         [
1308 #include <sys/types.h>
1309                         ],
1310                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
1311                         [ ac_cv_have_uintxx_t="yes" ],
1312                         [ ac_cv_have_uintxx_t="no" ]
1313                 )
1314         ])
1315         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
1316                 AC_DEFINE(HAVE_UINTXX_T)
1317         fi
1318 fi
1319
1320 if test -z "$have_uintxx_t" ; then
1321     AC_MSG_CHECKING([for uintXX_t types in stdint.h])
1322         AC_TRY_COMPILE(
1323                 [ #include <stdint.h> ],
1324                 [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1;],
1325                 [
1326                         AC_DEFINE(HAVE_UINTXX_T)
1327                         AC_MSG_RESULT(yes)
1328                 ],
1329                 [ AC_MSG_RESULT(no) ]
1330         )
1331 fi
1332
1333 if (test -z "$have_u_intxx_t" || test -z "$have_intxx_t" && \
1334            test "x$ac_cv_header_sys_bitypes_h" = "xyes")
1335 then
1336         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
1337         AC_TRY_COMPILE(
1338                 [
1339 #include <sys/bitypes.h>
1340                 ],
1341                 [
1342                         int8_t a; int16_t b; int32_t c;
1343                         u_int8_t e; u_int16_t f; u_int32_t g;
1344                         a = b = c = e = f = g = 1;
1345                 ],
1346                 [
1347                         AC_DEFINE(HAVE_U_INTXX_T)
1348                         AC_DEFINE(HAVE_INTXX_T)
1349                         AC_MSG_RESULT(yes)
1350                 ],
1351                 [AC_MSG_RESULT(no)]
1352         )
1353 fi
1354
1355
1356 AC_CACHE_CHECK([for u_char], ac_cv_have_u_char, [
1357         AC_TRY_COMPILE(
1358                 [
1359 #include <sys/types.h>
1360                 ],
1361                 [ u_char foo; foo = 125; ],
1362                 [ ac_cv_have_u_char="yes" ],
1363                 [ ac_cv_have_u_char="no" ]
1364         )
1365 ])
1366 if test "x$ac_cv_have_u_char" = "xyes" ; then
1367         AC_DEFINE(HAVE_U_CHAR)
1368 fi
1369
1370 TYPE_SOCKLEN_T
1371
1372 AC_CHECK_TYPES(sig_atomic_t,,,[#include <signal.h>])
1373
1374 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
1375         AC_TRY_COMPILE(
1376                 [
1377 #include <sys/types.h>
1378                 ],
1379                 [ size_t foo; foo = 1235; ],
1380                 [ ac_cv_have_size_t="yes" ],
1381                 [ ac_cv_have_size_t="no" ]
1382         )
1383 ])
1384 if test "x$ac_cv_have_size_t" = "xyes" ; then
1385         AC_DEFINE(HAVE_SIZE_T)
1386 fi
1387
1388 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
1389         AC_TRY_COMPILE(
1390                 [
1391 #include <sys/types.h>
1392                 ],
1393                 [ ssize_t foo; foo = 1235; ],
1394                 [ ac_cv_have_ssize_t="yes" ],
1395                 [ ac_cv_have_ssize_t="no" ]
1396         )
1397 ])
1398 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
1399         AC_DEFINE(HAVE_SSIZE_T)
1400 fi
1401
1402 AC_CACHE_CHECK([for clock_t], ac_cv_have_clock_t, [
1403         AC_TRY_COMPILE(
1404                 [
1405 #include <time.h>
1406                 ],
1407                 [ clock_t foo; foo = 1235; ],
1408                 [ ac_cv_have_clock_t="yes" ],
1409                 [ ac_cv_have_clock_t="no" ]
1410         )
1411 ])
1412 if test "x$ac_cv_have_clock_t" = "xyes" ; then
1413         AC_DEFINE(HAVE_CLOCK_T)
1414 fi
1415
1416 AC_CACHE_CHECK([for sa_family_t], ac_cv_have_sa_family_t, [
1417         AC_TRY_COMPILE(
1418                 [
1419 #include <sys/types.h>
1420 #include <sys/socket.h>
1421                 ],
1422                 [ sa_family_t foo; foo = 1235; ],
1423                 [ ac_cv_have_sa_family_t="yes" ],
1424                 [ AC_TRY_COMPILE(
1425                   [
1426 #include <sys/types.h>
1427 #include <sys/socket.h>
1428 #include <netinet/in.h>
1429                 ],
1430                 [ sa_family_t foo; foo = 1235; ],
1431                 [ ac_cv_have_sa_family_t="yes" ],
1432
1433                 [ ac_cv_have_sa_family_t="no" ]
1434         )]
1435         )
1436 ])
1437 if test "x$ac_cv_have_sa_family_t" = "xyes" ; then
1438         AC_DEFINE(HAVE_SA_FAMILY_T)
1439 fi
1440
1441 AC_CACHE_CHECK([for pid_t], ac_cv_have_pid_t, [
1442         AC_TRY_COMPILE(
1443                 [
1444 #include <sys/types.h>
1445                 ],
1446                 [ pid_t foo; foo = 1235; ],
1447                 [ ac_cv_have_pid_t="yes" ],
1448                 [ ac_cv_have_pid_t="no" ]
1449         )
1450 ])
1451 if test "x$ac_cv_have_pid_t" = "xyes" ; then
1452         AC_DEFINE(HAVE_PID_T)
1453 fi
1454
1455 AC_CACHE_CHECK([for mode_t], ac_cv_have_mode_t, [
1456         AC_TRY_COMPILE(
1457                 [
1458 #include <sys/types.h>
1459                 ],
1460                 [ mode_t foo; foo = 1235; ],
1461                 [ ac_cv_have_mode_t="yes" ],
1462                 [ ac_cv_have_mode_t="no" ]
1463         )
1464 ])
1465 if test "x$ac_cv_have_mode_t" = "xyes" ; then
1466         AC_DEFINE(HAVE_MODE_T)
1467 fi
1468
1469
1470 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
1471         AC_TRY_COMPILE(
1472                 [
1473 #include <sys/types.h>
1474 #include <sys/socket.h>
1475                 ],
1476                 [ struct sockaddr_storage s; ],
1477                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
1478                 [ ac_cv_have_struct_sockaddr_storage="no" ]
1479         )
1480 ])
1481 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
1482         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
1483 fi
1484
1485 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
1486         AC_TRY_COMPILE(
1487                 [
1488 #include <sys/types.h>
1489 #include <netinet/in.h>
1490                 ],
1491                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
1492                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
1493                 [ ac_cv_have_struct_sockaddr_in6="no" ]
1494         )
1495 ])
1496 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
1497         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
1498 fi
1499
1500 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
1501         AC_TRY_COMPILE(
1502                 [
1503 #include <sys/types.h>
1504 #include <netinet/in.h>
1505                 ],
1506                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
1507                 [ ac_cv_have_struct_in6_addr="yes" ],
1508                 [ ac_cv_have_struct_in6_addr="no" ]
1509         )
1510 ])
1511 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
1512         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
1513 fi
1514
1515 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
1516         AC_TRY_COMPILE(
1517                 [
1518 #include <sys/types.h>
1519 #include <sys/socket.h>
1520 #include <netdb.h>
1521                 ],
1522                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
1523                 [ ac_cv_have_struct_addrinfo="yes" ],
1524                 [ ac_cv_have_struct_addrinfo="no" ]
1525         )
1526 ])
1527 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
1528         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
1529 fi
1530
1531 AC_CACHE_CHECK([for struct timeval], ac_cv_have_struct_timeval, [
1532         AC_TRY_COMPILE(
1533                 [ #include <sys/time.h> ],
1534                 [ struct timeval tv; tv.tv_sec = 1;],
1535                 [ ac_cv_have_struct_timeval="yes" ],
1536                 [ ac_cv_have_struct_timeval="no" ]
1537         )
1538 ])
1539 if test "x$ac_cv_have_struct_timeval" = "xyes" ; then
1540         AC_DEFINE(HAVE_STRUCT_TIMEVAL)
1541         have_struct_timeval=1
1542 fi
1543
1544 AC_CHECK_TYPES(struct timespec)
1545
1546 # We need int64_t or else certian parts of the compile will fail.
1547 if test "x$ac_cv_have_int64_t" = "xno" -a \
1548         "x$ac_cv_sizeof_long_int" != "x8" -a \
1549         "x$ac_cv_sizeof_long_long_int" = "x0" ; then
1550         echo "OpenSSH requires int64_t support.  Contact your vendor or install"
1551         echo "an alternative compiler (I.E., GCC) before continuing."
1552         echo ""
1553         exit 1;
1554 else
1555 dnl test snprintf (broken on SCO w/gcc)
1556         AC_TRY_RUN(
1557                 [
1558 #include <stdio.h>
1559 #include <string.h>
1560 #ifdef HAVE_SNPRINTF
1561 main()
1562 {
1563         char buf[50];
1564         char expected_out[50];
1565         int mazsize = 50 ;
1566 #if (SIZEOF_LONG_INT == 8)
1567         long int num = 0x7fffffffffffffff;
1568 #else
1569         long long num = 0x7fffffffffffffffll;
1570 #endif
1571         strcpy(expected_out, "9223372036854775807");
1572         snprintf(buf, mazsize, "%lld", num);
1573         if(strcmp(buf, expected_out) != 0)
1574                 exit(1);
1575         exit(0);
1576 }
1577 #else
1578 main() { exit(0); }
1579 #endif
1580                 ], [ true ], [ AC_DEFINE(BROKEN_SNPRINTF) ]
1581         )
1582 fi
1583
1584 dnl Checks for structure members
1585 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
1586 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
1587 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
1588 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
1589 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
1590 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
1591 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
1592 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
1593 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmpx.h, HAVE_ID_IN_UTMPX)
1594 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
1595 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
1596 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
1597 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
1598 OSSH_CHECK_HEADER_FOR_FIELD(ut_exit, utmp.h, HAVE_EXIT_IN_UTMP)
1599 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmp.h, HAVE_TIME_IN_UTMP)
1600 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmpx.h, HAVE_TIME_IN_UTMPX)
1601 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmpx.h, HAVE_TV_IN_UTMPX)
1602
1603 AC_CHECK_MEMBERS([struct stat.st_blksize])
1604
1605 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
1606                 ac_cv_have_ss_family_in_struct_ss, [
1607         AC_TRY_COMPILE(
1608                 [
1609 #include <sys/types.h>
1610 #include <sys/socket.h>
1611                 ],
1612                 [ struct sockaddr_storage s; s.ss_family = 1; ],
1613                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
1614                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
1615         )
1616 ])
1617 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
1618         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
1619 fi
1620
1621 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
1622                 ac_cv_have___ss_family_in_struct_ss, [
1623         AC_TRY_COMPILE(
1624                 [
1625 #include <sys/types.h>
1626 #include <sys/socket.h>
1627                 ],
1628                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
1629                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
1630                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
1631         )
1632 ])
1633 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
1634         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
1635 fi
1636
1637 AC_CACHE_CHECK([for pw_class field in struct passwd],
1638                 ac_cv_have_pw_class_in_struct_passwd, [
1639         AC_TRY_COMPILE(
1640                 [
1641 #include <pwd.h>
1642                 ],
1643                 [ struct passwd p; p.pw_class = 0; ],
1644                 [ ac_cv_have_pw_class_in_struct_passwd="yes" ],
1645                 [ ac_cv_have_pw_class_in_struct_passwd="no" ]
1646         )
1647 ])
1648 if test "x$ac_cv_have_pw_class_in_struct_passwd" = "xyes" ; then
1649         AC_DEFINE(HAVE_PW_CLASS_IN_PASSWD)
1650 fi
1651
1652 AC_CACHE_CHECK([for pw_expire field in struct passwd],
1653                 ac_cv_have_pw_expire_in_struct_passwd, [
1654         AC_TRY_COMPILE(
1655                 [
1656 #include <pwd.h>
1657                 ],
1658                 [ struct passwd p; p.pw_expire = 0; ],
1659                 [ ac_cv_have_pw_expire_in_struct_passwd="yes" ],
1660                 [ ac_cv_have_pw_expire_in_struct_passwd="no" ]
1661         )
1662 ])
1663 if test "x$ac_cv_have_pw_expire_in_struct_passwd" = "xyes" ; then
1664         AC_DEFINE(HAVE_PW_EXPIRE_IN_PASSWD)
1665 fi
1666
1667 AC_CACHE_CHECK([for pw_change field in struct passwd],
1668                 ac_cv_have_pw_change_in_struct_passwd, [
1669         AC_TRY_COMPILE(
1670                 [
1671 #include <pwd.h>
1672                 ],
1673                 [ struct passwd p; p.pw_change = 0; ],
1674                 [ ac_cv_have_pw_change_in_struct_passwd="yes" ],
1675                 [ ac_cv_have_pw_change_in_struct_passwd="no" ]
1676         )
1677 ])
1678 if test "x$ac_cv_have_pw_change_in_struct_passwd" = "xyes" ; then
1679         AC_DEFINE(HAVE_PW_CHANGE_IN_PASSWD)
1680 fi
1681
1682 dnl make sure we're using the real structure members and not defines
1683 AC_CACHE_CHECK([for msg_accrights field in struct msghdr],
1684                 ac_cv_have_accrights_in_msghdr, [
1685         AC_TRY_RUN(
1686                 [
1687 #include <sys/types.h>
1688 #include <sys/socket.h>
1689 #include <sys/uio.h>
1690 int main() {
1691 #ifdef msg_accrights
1692 exit(1);
1693 #endif
1694 struct msghdr m;
1695 m.msg_accrights = 0;
1696 exit(0);
1697 }
1698                 ],
1699                 [ ac_cv_have_accrights_in_msghdr="yes" ],
1700                 [ ac_cv_have_accrights_in_msghdr="no" ]
1701         )
1702 ])
1703 if test "x$ac_cv_have_accrights_in_msghdr" = "xyes" ; then
1704         AC_DEFINE(HAVE_ACCRIGHTS_IN_MSGHDR)
1705 fi
1706
1707 AC_CACHE_CHECK([for msg_control field in struct msghdr],
1708                 ac_cv_have_control_in_msghdr, [
1709         AC_TRY_RUN(
1710                 [
1711 #include <sys/types.h>
1712 #include <sys/socket.h>
1713 #include <sys/uio.h>
1714 int main() {
1715 #ifdef msg_control
1716 exit(1);
1717 #endif
1718 struct msghdr m;
1719 m.msg_control = 0;
1720 exit(0);
1721 }
1722                 ],
1723                 [ ac_cv_have_control_in_msghdr="yes" ],
1724                 [ ac_cv_have_control_in_msghdr="no" ]
1725         )
1726 ])
1727 if test "x$ac_cv_have_control_in_msghdr" = "xyes" ; then
1728         AC_DEFINE(HAVE_CONTROL_IN_MSGHDR)
1729 fi
1730
1731 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
1732         AC_TRY_LINK([],
1733                 [ extern char *__progname; printf("%s", __progname); ],
1734                 [ ac_cv_libc_defines___progname="yes" ],
1735                 [ ac_cv_libc_defines___progname="no" ]
1736         )
1737 ])
1738 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
1739         AC_DEFINE(HAVE___PROGNAME)
1740 fi
1741
1742 AC_CACHE_CHECK([whether $CC implements __FUNCTION__], ac_cv_cc_implements___FUNCTION__, [
1743         AC_TRY_LINK([
1744 #include <stdio.h>
1745 ],
1746                 [ printf("%s", __FUNCTION__); ],
1747                 [ ac_cv_cc_implements___FUNCTION__="yes" ],
1748                 [ ac_cv_cc_implements___FUNCTION__="no" ]
1749         )
1750 ])
1751 if test "x$ac_cv_cc_implements___FUNCTION__" = "xyes" ; then
1752         AC_DEFINE(HAVE___FUNCTION__)
1753 fi
1754
1755 AC_CACHE_CHECK([whether $CC implements __func__], ac_cv_cc_implements___func__, [
1756         AC_TRY_LINK([
1757 #include <stdio.h>
1758 ],
1759                 [ printf("%s", __func__); ],
1760                 [ ac_cv_cc_implements___func__="yes" ],
1761                 [ ac_cv_cc_implements___func__="no" ]
1762         )
1763 ])
1764 if test "x$ac_cv_cc_implements___func__" = "xyes" ; then
1765         AC_DEFINE(HAVE___func__)
1766 fi
1767
1768 AC_CACHE_CHECK([whether getopt has optreset support],
1769                 ac_cv_have_getopt_optreset, [
1770         AC_TRY_LINK(
1771                 [
1772 #include <getopt.h>
1773                 ],
1774                 [ extern int optreset; optreset = 0; ],
1775                 [ ac_cv_have_getopt_optreset="yes" ],
1776                 [ ac_cv_have_getopt_optreset="no" ]
1777         )
1778 ])
1779 if test "x$ac_cv_have_getopt_optreset" = "xyes" ; then
1780         AC_DEFINE(HAVE_GETOPT_OPTRESET)
1781 fi
1782
1783 AC_CACHE_CHECK([if libc defines sys_errlist], ac_cv_libc_defines_sys_errlist, [
1784         AC_TRY_LINK([],
1785                 [ extern const char *const sys_errlist[]; printf("%s", sys_errlist[0]);],
1786                 [ ac_cv_libc_defines_sys_errlist="yes" ],
1787                 [ ac_cv_libc_defines_sys_errlist="no" ]
1788         )
1789 ])
1790 if test "x$ac_cv_libc_defines_sys_errlist" = "xyes" ; then
1791         AC_DEFINE(HAVE_SYS_ERRLIST)
1792 fi
1793
1794
1795 AC_CACHE_CHECK([if libc defines sys_nerr], ac_cv_libc_defines_sys_nerr, [
1796         AC_TRY_LINK([],
1797                 [ extern int sys_nerr; printf("%i", sys_nerr);],
1798                 [ ac_cv_libc_defines_sys_nerr="yes" ],
1799                 [ ac_cv_libc_defines_sys_nerr="no" ]
1800         )
1801 ])
1802 if test "x$ac_cv_libc_defines_sys_nerr" = "xyes" ; then
1803         AC_DEFINE(HAVE_SYS_NERR)
1804 fi
1805
1806 SCARD_MSG="no"
1807 # Check whether user wants sectok support
1808 AC_ARG_WITH(sectok,
1809         [  --with-sectok           Enable smartcard support using libsectok],
1810         [
1811                 if test "x$withval" != "xno" ; then
1812                         if test "x$withval" != "xyes" ; then
1813                                 CPPFLAGS="$CPPFLAGS -I${withval}"
1814                                 LDFLAGS="$LDFLAGS -L${withval}"
1815                                 if test ! -z "$need_dash_r" ; then
1816                                         LDFLAGS="$LDFLAGS -R${withval}"
1817                                 fi
1818                                 if test ! -z "$blibpath" ; then
1819                                         blibpath="$blibpath:${withval}"
1820                                 fi
1821                         fi
1822                         AC_CHECK_HEADERS(sectok.h)
1823                         if test "$ac_cv_header_sectok_h" != yes; then
1824                                 AC_MSG_ERROR(Can't find sectok.h)
1825                         fi
1826                         AC_CHECK_LIB(sectok, sectok_open)
1827                         if test "$ac_cv_lib_sectok_sectok_open" != yes; then
1828                                 AC_MSG_ERROR(Can't find libsectok)
1829                         fi
1830                         AC_DEFINE(SMARTCARD)
1831                         AC_DEFINE(USE_SECTOK)
1832                         SCARD_MSG="yes, using sectok"
1833                 fi
1834         ]
1835 )
1836
1837 # Check whether user wants OpenSC support
1838 AC_ARG_WITH(opensc,
1839         AC_HELP_STRING([--with-opensc=PFX],
1840                        [Enable smartcard support using OpenSC]),
1841         opensc_config_prefix="$withval", opensc_config_prefix="")
1842 if test x$opensc_config_prefix != x ; then
1843   OPENSC_CONFIG=$opensc_config_prefix/bin/opensc-config
1844   AC_PATH_PROG(OPENSC_CONFIG, opensc-config, no)
1845   if test "$OPENSC_CONFIG" != "no"; then
1846     LIBOPENSC_CFLAGS=`$OPENSC_CONFIG --cflags`
1847     LIBOPENSC_LIBS=`$OPENSC_CONFIG --libs`
1848     CPPFLAGS="$CPPFLAGS $LIBOPENSC_CFLAGS"
1849     LDFLAGS="$LDFLAGS $LIBOPENSC_LIBS"
1850     AC_DEFINE(SMARTCARD)
1851     AC_DEFINE(USE_OPENSC)
1852     SCARD_MSG="yes, using OpenSC"
1853   fi
1854 fi
1855
1856 # Check whether user wants DNS support
1857 DNS_MSG="no"
1858 AC_ARG_WITH(dns,
1859         [  --with-dns              Support for fetching keys from DNS (experimental)],
1860         [
1861                 if test "x$withval" != "xno" ; then
1862                         DNS_MSG="yes"
1863                         AC_DEFINE(DNS)
1864                         AC_SEARCH_LIBS(getrrsetbyname, resolv,
1865                                 [AC_DEFINE(HAVE_GETRRSETBYNAME)])
1866                 fi
1867         ]
1868 )
1869
1870 # Check whether user wants Kerberos 5 support
1871 KRB5_MSG="no"
1872 AC_ARG_WITH(kerberos5,
1873         [  --with-kerberos5=PATH   Enable Kerberos 5 support],
1874         [
1875                 if test "x$withval" != "xno" ; then
1876                         if test "x$withval" = "xyes" ; then
1877                                 KRB5ROOT="/usr/local"
1878                         else
1879                                 KRB5ROOT=${withval}
1880                         fi
1881                         CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include"
1882                         LDFLAGS="$LDFLAGS -L${KRB5ROOT}/lib"
1883                         AC_DEFINE(KRB5)
1884                         KRB5_MSG="yes"
1885                         AC_MSG_CHECKING(whether we are using Heimdal)
1886                         AC_TRY_COMPILE([ #include <krb5.h> ],
1887                                        [ char *tmp = heimdal_version; ],
1888                                        [ AC_MSG_RESULT(yes)
1889                                          AC_DEFINE(HEIMDAL)
1890                                          K5LIBS="-lkrb5 -ldes -lcom_err -lasn1 -lroken"
1891                                        ],
1892                                        [ AC_MSG_RESULT(no)
1893                                          K5LIBS="-lkrb5 -lk5crypto -lcom_err"
1894                                        ]
1895                         )
1896                         if test ! -z "$need_dash_r" ; then
1897                                 LDFLAGS="$LDFLAGS -R${KRB5ROOT}/lib"
1898                         fi
1899                         if test ! -z "$blibpath" ; then
1900                                 blibpath="$blibpath:${KRB5ROOT}/lib"
1901                         fi
1902                         AC_CHECK_LIB(resolv, dn_expand, , )
1903
1904                         KRB5=yes
1905                 fi
1906         ]
1907 )
1908 # Check whether user wants Kerberos 4 support
1909 KRB4_MSG="no"
1910 AC_ARG_WITH(kerberos4,
1911         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
1912         [
1913                 if test "x$withval" != "xno" ; then
1914                         if test "x$withval" != "xyes" ; then
1915                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1916                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1917                                 if test ! -z "$need_dash_r" ; then
1918                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
1919                                 fi
1920                                 if test ! -z "$blibpath" ; then
1921                                         blibpath="$blibpath:${withval}/lib"
1922                                 fi
1923                         else
1924                                 if test -d /usr/include/kerberosIV ; then
1925                                         CPPFLAGS="$CPPFLAGS -I/usr/include/kerberosIV"
1926                                 fi
1927                         fi
1928
1929                         AC_CHECK_HEADERS(krb.h)
1930                         if test "$ac_cv_header_krb_h" != yes; then
1931                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
1932                         fi
1933                         AC_CHECK_LIB(krb, main)
1934                         if test "$ac_cv_lib_krb_main" != yes; then
1935                                 AC_CHECK_LIB(krb4, main)
1936                                 if test "$ac_cv_lib_krb4_main" != yes; then
1937                                         AC_MSG_WARN([Cannot find libkrb nor libkrb4, build may fail])
1938                                 else
1939                                         KLIBS="-lkrb4"
1940                                 fi
1941                         else
1942                                 KLIBS="-lkrb"
1943                         fi
1944                         AC_CHECK_LIB(des, des_cbc_encrypt)
1945                         if test "$ac_cv_lib_des_des_cbc_encrypt" != yes; then
1946                                 AC_CHECK_LIB(des425, des_cbc_encrypt)
1947                                 if test "$ac_cv_lib_des425_des_cbc_encrypt" != yes; then
1948                                         AC_MSG_WARN([Cannot find libdes nor libdes425, build may fail])
1949                                 else
1950                                         KLIBS="-ldes425"
1951                                 fi
1952                         else
1953                                 KLIBS="-ldes"
1954                         fi
1955                         AC_CHECK_LIB(resolv, dn_expand, , )
1956                         KRB4=yes
1957                         KRB4_MSG="yes"
1958                         AC_DEFINE(KRB4)
1959                 fi
1960         ]
1961 )
1962
1963 # Check whether user wants AFS support
1964 AFS_MSG="no"
1965 AC_ARG_WITH(afs,
1966         [  --with-afs=PATH         Enable AFS support],
1967         [
1968                 if test "x$withval" != "xno" ; then
1969
1970                         if test "x$withval" != "xyes" ; then
1971                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1972                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1973                         fi
1974
1975                         if test -z "$KRB4" ; then
1976                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
1977                         fi
1978
1979                         LIBS="-lkafs $LIBS"
1980                         if test ! -z "$AFS_LIBS" ; then
1981                                 LIBS="$LIBS $AFS_LIBS"
1982                         fi
1983                         AC_DEFINE(AFS)
1984                         AFS_MSG="yes"
1985                 fi
1986         ]
1987 )
1988 LIBS="$LIBS $KLIBS $K5LIBS"
1989
1990 # Looking for programs, paths and files
1991
1992 PRIVSEP_PATH=/var/empty
1993 AC_ARG_WITH(privsep-path,
1994         [  --with-privsep-path=xxx Path for privilege separation chroot (default=/var/empty)],
1995         [
1996                 if test "x$withval" != "$no" ; then
1997                         PRIVSEP_PATH=$withval
1998                 fi
1999         ]
2000 )
2001 AC_SUBST(PRIVSEP_PATH)
2002
2003 AC_ARG_WITH(xauth,
2004         [  --with-xauth=PATH       Specify path to xauth program ],
2005         [
2006                 if test "x$withval" != "xno" ; then
2007                         xauth_path=$withval
2008                 fi
2009         ],
2010         [
2011                 TestPath="$PATH"
2012                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/X/bin"
2013                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/bin/X11"
2014                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/X11R6/bin"
2015                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/openwin/bin"
2016                 AC_PATH_PROG(xauth_path, xauth, , $TestPath)
2017                 if (test ! -z "$xauth_path" && test -x "/usr/openwin/bin/xauth") ; then
2018                         xauth_path="/usr/openwin/bin/xauth"
2019                 fi
2020         ]
2021 )
2022
2023 STRIP_OPT=-s
2024 AC_ARG_ENABLE(strip,
2025         [  --disable-strip         Disable calling strip(1) on install],
2026         [
2027                 if test "x$enableval" = "xno" ; then
2028                         STRIP_OPT=
2029                 fi
2030         ]
2031 )
2032 AC_SUBST(STRIP_OPT)
2033
2034 if test -z "$xauth_path" ; then
2035         XAUTH_PATH="undefined"
2036         AC_SUBST(XAUTH_PATH)
2037 else
2038         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
2039         XAUTH_PATH=$xauth_path
2040         AC_SUBST(XAUTH_PATH)
2041 fi
2042
2043 # Check for mail directory (last resort if we cannot get it from headers)
2044 if test ! -z "$MAIL" ; then
2045         maildir=`dirname $MAIL`
2046         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
2047 fi
2048
2049 if test -z "$no_dev_ptmx" ; then
2050         if test "x$disable_ptmx_check" != "xyes" ; then
2051                 AC_CHECK_FILE("/dev/ptmx",
2052                         [
2053                                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
2054                                 have_dev_ptmx=1
2055                         ]
2056                 )
2057         fi
2058 fi
2059 AC_CHECK_FILE("/dev/ptc",
2060         [
2061                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
2062                 have_dev_ptc=1
2063         ]
2064 )
2065
2066 # Options from here on. Some of these are preset by platform above
2067 AC_ARG_WITH(mantype,
2068         [  --with-mantype=man|cat|doc  Set man page type],
2069         [
2070                 case "$withval" in
2071                 man|cat|doc)
2072                         MANTYPE=$withval
2073                         ;;
2074                 *)
2075                         AC_MSG_ERROR(invalid man type: $withval)
2076                         ;;
2077                 esac
2078         ]
2079 )
2080 if test -z "$MANTYPE"; then
2081         TestPath="/usr/bin${PATH_SEPARATOR}/usr/ucb"
2082         AC_PATH_PROGS(NROFF, nroff awf, /bin/false, $TestPath)
2083         if ${NROFF} -mdoc ${srcdir}/ssh.1 >/dev/null 2>&1; then
2084                 MANTYPE=doc
2085         elif ${NROFF} -man ${srcdir}/ssh.1 >/dev/null 2>&1; then
2086                 MANTYPE=man
2087         else
2088                 MANTYPE=cat
2089         fi
2090 fi
2091 AC_SUBST(MANTYPE)
2092 if test "$MANTYPE" = "doc"; then
2093         mansubdir=man;
2094 else
2095         mansubdir=$MANTYPE;
2096 fi
2097 AC_SUBST(mansubdir)
2098
2099 # Check whether to enable MD5 passwords
2100 MD5_MSG="no"
2101 AC_ARG_WITH(md5-passwords,
2102         [  --with-md5-passwords    Enable use of MD5 passwords],
2103         [
2104                 if test "x$withval" != "xno" ; then
2105                         AC_DEFINE(HAVE_MD5_PASSWORDS)
2106                         MD5_MSG="yes"
2107                 fi
2108         ]
2109 )
2110
2111 # Whether to disable shadow password support
2112 AC_ARG_WITH(shadow,
2113         [  --without-shadow        Disable shadow password support],
2114         [
2115                 if test "x$withval" = "xno" ; then
2116                         AC_DEFINE(DISABLE_SHADOW)
2117                         disable_shadow=yes
2118                 fi
2119         ]
2120 )
2121
2122 if test -z "$disable_shadow" ; then
2123         AC_MSG_CHECKING([if the systems has expire shadow information])
2124         AC_TRY_COMPILE(
2125         [
2126 #include <sys/types.h>
2127 #include <shadow.h>
2128         struct spwd sp;
2129         ],[ sp.sp_expire = sp.sp_lstchg = sp.sp_inact = 0; ],
2130         [ sp_expire_available=yes ], []
2131         )
2132
2133         if test "x$sp_expire_available" = "xyes" ; then
2134                 AC_MSG_RESULT(yes)
2135                 AC_DEFINE(HAS_SHADOW_EXPIRE)
2136         else
2137                 AC_MSG_RESULT(no)
2138         fi
2139 fi
2140
2141 # Use ip address instead of hostname in $DISPLAY
2142 if test ! -z "$IPADDR_IN_DISPLAY" ; then
2143         DISPLAY_HACK_MSG="yes"
2144         AC_DEFINE(IPADDR_IN_DISPLAY)
2145 else
2146         DISPLAY_HACK_MSG="no"
2147         AC_ARG_WITH(ipaddr-display,
2148                 [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
2149                 [
2150                         if test "x$withval" != "xno" ; then
2151                                 AC_DEFINE(IPADDR_IN_DISPLAY)
2152                                 DISPLAY_HACK_MSG="yes"
2153                         fi
2154                 ]
2155         )
2156 fi
2157
2158 dnl BSD systems use /etc/login.conf so --with-default-path= has no effect
2159 if test $ac_cv_func_login_getcapbool = "yes" -a \
2160         $ac_cv_header_login_cap_h = "yes" ; then
2161         USES_LOGIN_CONF=yes
2162 fi
2163 # Whether to mess with the default path
2164 SERVER_PATH_MSG="(default)"
2165 AC_ARG_WITH(default-path,
2166         [  --with-default-path=    Specify default \$PATH environment for server],
2167         [
2168                 if test "$USES_LOGIN_CONF" = "yes" ; then
2169                         AC_MSG_WARN([
2170 --with-default-path=PATH has no effect on this system.
2171 Edit /etc/login.conf instead.])
2172                 elif test "x$withval" != "xno" ; then
2173                         user_path="$withval"
2174                         SERVER_PATH_MSG="$withval"
2175                 fi
2176         ],
2177         [ if test "$USES_LOGIN_CONF" = "yes" ; then
2178         AC_MSG_WARN([Make sure the path to scp is in /etc/login.conf])
2179         else
2180         AC_TRY_RUN(
2181                 [
2182 /* find out what STDPATH is */
2183 #include <stdio.h>
2184 #ifdef HAVE_PATHS_H
2185 # include <paths.h>
2186 #endif
2187 #ifndef _PATH_STDPATH
2188 # ifdef _PATH_USERPATH  /* Irix */
2189 #  define _PATH_STDPATH _PATH_USERPATH
2190 # else
2191 #  define _PATH_STDPATH "/usr/bin:/bin:/usr/sbin:/sbin"
2192 # endif
2193 #endif
2194 #include <sys/types.h>
2195 #include <sys/stat.h>
2196 #include <fcntl.h>
2197 #define DATA "conftest.stdpath"
2198
2199 main()
2200 {
2201         FILE *fd;
2202         int rc;
2203
2204         fd = fopen(DATA,"w");
2205         if(fd == NULL)
2206                 exit(1);
2207
2208         if ((rc = fprintf(fd,"%s", _PATH_STDPATH)) < 0)
2209                 exit(1);
2210
2211         exit(0);
2212 }
2213                 ], [ user_path=`cat conftest.stdpath` ],
2214                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ],
2215                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ]
2216         )
2217 # make sure $bindir is in USER_PATH so scp will work
2218                 t_bindir=`eval echo ${bindir}`
2219                 case $t_bindir in
2220                         NONE/*) t_bindir=`echo $t_bindir | sed "s~NONE~$prefix~"` ;;
2221                 esac
2222                 case $t_bindir in
2223                         NONE/*) t_bindir=`echo $t_bindir | sed "s~NONE~$ac_default_prefix~"` ;;
2224                 esac
2225                 echo $user_path | grep ":$t_bindir"  > /dev/null 2>&1
2226                 if test $? -ne 0  ; then
2227                         echo $user_path | grep "^$t_bindir"  > /dev/null 2>&1
2228                         if test $? -ne 0  ; then
2229                                 user_path=$user_path:$t_bindir
2230                                 AC_MSG_RESULT(Adding $t_bindir to USER_PATH so scp will work)
2231                         fi
2232                 fi
2233         fi ]
2234 )
2235 if test "$USES_LOGIN_CONF" != "yes" ; then
2236         AC_DEFINE_UNQUOTED(USER_PATH, "$user_path")
2237         AC_SUBST(user_path)
2238 fi
2239
2240 # Set superuser path separately to user path
2241 AC_ARG_WITH(superuser-path,
2242         [  --with-superuser-path=  Specify different path for super-user],
2243         [
2244                 if test "x$withval" != "xno" ; then
2245                         AC_DEFINE_UNQUOTED(SUPERUSER_PATH, "$withval")
2246                         superuser_path=$withval
2247                 fi
2248         ]
2249 )
2250
2251
2252 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
2253 IPV4_IN6_HACK_MSG="no"
2254 AC_ARG_WITH(4in6,
2255         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
2256         [
2257                 if test "x$withval" != "xno" ; then
2258                         AC_MSG_RESULT(yes)
2259                         AC_DEFINE(IPV4_IN_IPV6)
2260                         IPV4_IN6_HACK_MSG="yes"
2261                 else
2262                         AC_MSG_RESULT(no)
2263                 fi
2264         ],[
2265                 if test "x$inet6_default_4in6" = "xyes"; then
2266                         AC_MSG_RESULT([yes (default)])
2267                         AC_DEFINE(IPV4_IN_IPV6)
2268                         IPV4_IN6_HACK_MSG="yes"
2269                 else
2270                         AC_MSG_RESULT([no (default)])
2271                 fi
2272         ]
2273 )
2274
2275 # Whether to enable BSD auth support
2276 BSD_AUTH_MSG=no
2277 AC_ARG_WITH(bsd-auth,
2278         [  --with-bsd-auth         Enable BSD auth support],
2279         [
2280                 if test "x$withval" != "xno" ; then
2281                         AC_DEFINE(BSD_AUTH)
2282                         BSD_AUTH_MSG=yes
2283                 fi
2284         ]
2285 )
2286
2287 # Where to place sshd.pid
2288 piddir=/var/run
2289 # make sure the directory exists
2290 if test ! -d $piddir ; then
2291         piddir=`eval echo ${sysconfdir}`
2292         case $piddir in
2293                 NONE/*) piddir=`echo $piddir | sed "s~NONE~$ac_default_prefix~"` ;;
2294         esac
2295 fi
2296
2297 AC_ARG_WITH(pid-dir,
2298         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
2299         [
2300                 if test "x$withval" != "xno" ; then
2301                         piddir=$withval
2302                         if test ! -d $piddir ; then
2303                         AC_MSG_WARN([** no $piddir directory on this system **])
2304                         fi
2305                 fi
2306         ]
2307 )
2308
2309 AC_DEFINE_UNQUOTED(_PATH_SSH_PIDDIR, "$piddir")
2310 AC_SUBST(piddir)
2311
2312 dnl allow user to disable some login recording features
2313 AC_ARG_ENABLE(lastlog,
2314         [  --disable-lastlog       disable use of lastlog even if detected [no]],
2315         [ AC_DEFINE(DISABLE_LASTLOG) ]
2316 )
2317 AC_ARG_ENABLE(utmp,
2318         [  --disable-utmp          disable use of utmp even if detected [no]],
2319         [ AC_DEFINE(DISABLE_UTMP) ]
2320 )
2321 AC_ARG_ENABLE(utmpx,
2322         [  --disable-utmpx         disable use of utmpx even if detected [no]],
2323         [ AC_DEFINE(DISABLE_UTMPX) ]
2324 )
2325 AC_ARG_ENABLE(wtmp,
2326         [  --disable-wtmp          disable use of wtmp even if detected [no]],
2327         [ AC_DEFINE(DISABLE_WTMP) ]
2328 )
2329 AC_ARG_ENABLE(wtmpx,
2330         [  --disable-wtmpx         disable use of wtmpx even if detected [no]],
2331         [ AC_DEFINE(DISABLE_WTMPX) ]
2332 )
2333 AC_ARG_ENABLE(libutil,
2334         [  --disable-libutil       disable use of libutil (login() etc.) [no]],
2335         [ AC_DEFINE(DISABLE_LOGIN) ]
2336 )
2337 AC_ARG_ENABLE(pututline,
2338         [  --disable-pututline     disable use of pututline() etc. ([uw]tmp) [no]],
2339         [ AC_DEFINE(DISABLE_PUTUTLINE) ]
2340 )
2341 AC_ARG_ENABLE(pututxline,
2342         [  --disable-pututxline    disable use of pututxline() etc. ([uw]tmpx) [no]],
2343         [ AC_DEFINE(DISABLE_PUTUTXLINE) ]
2344 )
2345 AC_ARG_WITH(lastlog,
2346   [  --with-lastlog=FILE|DIR specify lastlog location [common locations]],
2347         [
2348                 if test "x$withval" = "xno" ; then
2349                         AC_DEFINE(DISABLE_LASTLOG)
2350                 else
2351                         conf_lastlog_location=$withval
2352                 fi
2353         ]
2354 )
2355
2356 dnl lastlog, [uw]tmpx? detection
2357 dnl  NOTE: set the paths in the platform section to avoid the
2358 dnl   need for command-line parameters
2359 dnl lastlog and [uw]tmp are subject to a file search if all else fails
2360
2361 dnl lastlog detection
2362 dnl  NOTE: the code itself will detect if lastlog is a directory
2363 AC_MSG_CHECKING([if your system defines LASTLOG_FILE])
2364 AC_TRY_COMPILE([
2365 #include <sys/types.h>
2366 #include <utmp.h>
2367 #ifdef HAVE_LASTLOG_H
2368 #  include <lastlog.h>
2369 #endif
2370 #ifdef HAVE_PATHS_H
2371 #  include <paths.h>
2372 #endif
2373 #ifdef HAVE_LOGIN_H
2374 # include <login.h>
2375 #endif
2376         ],
2377         [ char *lastlog = LASTLOG_FILE; ],
2378         [ AC_MSG_RESULT(yes) ],
2379         [
2380                 AC_MSG_RESULT(no)
2381                 AC_MSG_CHECKING([if your system defines _PATH_LASTLOG])
2382                 AC_TRY_COMPILE([
2383 #include <sys/types.h>
2384 #include <utmp.h>
2385 #ifdef HAVE_LASTLOG_H
2386 #  include <lastlog.h>
2387 #endif
2388 #ifdef HAVE_PATHS_H
2389 #  include <paths.h>
2390 #endif
2391                 ],
2392                 [ char *lastlog = _PATH_LASTLOG; ],
2393                 [ AC_MSG_RESULT(yes) ],
2394                 [
2395                         AC_MSG_RESULT(no)
2396                         system_lastlog_path=no
2397                 ])
2398         ]
2399 )
2400
2401 if test -z "$conf_lastlog_location"; then
2402         if test x"$system_lastlog_path" = x"no" ; then
2403                 for f in /var/log/lastlog /usr/adm/lastlog /var/adm/lastlog /etc/security/lastlog ; do
2404                                 if (test -d "$f" || test -f "$f") ; then
2405                                         conf_lastlog_location=$f
2406                                 fi
2407                 done
2408                 if test -z "$conf_lastlog_location"; then
2409                         AC_MSG_WARN([** Cannot find lastlog **])
2410                         dnl Don't define DISABLE_LASTLOG - that means we don't try wtmp/wtmpx
2411                 fi
2412         fi
2413 fi
2414
2415 if test -n "$conf_lastlog_location"; then
2416         AC_DEFINE_UNQUOTED(CONF_LASTLOG_FILE, "$conf_lastlog_location")
2417 fi
2418
2419 dnl utmp detection
2420 AC_MSG_CHECKING([if your system defines UTMP_FILE])
2421 AC_TRY_COMPILE([
2422 #include <sys/types.h>
2423 #include <utmp.h>
2424 #ifdef HAVE_PATHS_H
2425 #  include <paths.h>
2426 #endif
2427         ],
2428         [ char *utmp = UTMP_FILE; ],
2429         [ AC_MSG_RESULT(yes) ],
2430         [ AC_MSG_RESULT(no)
2431           system_utmp_path=no ]
2432 )
2433 if test -z "$conf_utmp_location"; then
2434         if test x"$system_utmp_path" = x"no" ; then
2435                 for f in /etc/utmp /usr/adm/utmp /var/run/utmp; do
2436                         if test -f $f ; then
2437                                 conf_utmp_location=$f
2438                         fi
2439                 done
2440                 if test -z "$conf_utmp_location"; then
2441                         AC_DEFINE(DISABLE_UTMP)
2442                 fi
2443         fi
2444 fi
2445 if test -n "$conf_utmp_location"; then
2446         AC_DEFINE_UNQUOTED(CONF_UTMP_FILE, "$conf_utmp_location")
2447 fi
2448
2449 dnl wtmp detection
2450 AC_MSG_CHECKING([if your system defines WTMP_FILE])
2451 AC_TRY_COMPILE([
2452 #include <sys/types.h>
2453 #include <utmp.h>
2454 #ifdef HAVE_PATHS_H
2455 #  include <paths.h>
2456 #endif
2457         ],
2458         [ char *wtmp = WTMP_FILE; ],
2459         [ AC_MSG_RESULT(yes) ],
2460         [ AC_MSG_RESULT(no)
2461           system_wtmp_path=no ]
2462 )
2463 if test -z "$conf_wtmp_location"; then
2464         if test x"$system_wtmp_path" = x"no" ; then
2465                 for f in /usr/adm/wtmp /var/log/wtmp; do
2466                         if test -f $f ; then
2467                                 conf_wtmp_location=$f
2468                         fi
2469                 done
2470                 if test -z "$conf_wtmp_location"; then
2471                         AC_DEFINE(DISABLE_WTMP)
2472                 fi
2473         fi
2474 fi
2475 if test -n "$conf_wtmp_location"; then
2476         AC_DEFINE_UNQUOTED(CONF_WTMP_FILE, "$conf_wtmp_location")
2477 fi
2478
2479
2480 dnl utmpx detection - I don't know any system so perverse as to require
2481 dnl  utmpx, but not define UTMPX_FILE (ditto wtmpx.) No doubt it's out
2482 dnl  there, though.
2483 AC_MSG_CHECKING([if your system defines UTMPX_FILE])
2484 AC_TRY_COMPILE([
2485 #include <sys/types.h>
2486 #include <utmp.h>
2487 #ifdef HAVE_UTMPX_H
2488 #include <utmpx.h>
2489 #endif
2490 #ifdef HAVE_PATHS_H
2491 #  include <paths.h>
2492 #endif
2493         ],
2494         [ char *utmpx = UTMPX_FILE; ],
2495         [ AC_MSG_RESULT(yes) ],
2496         [ AC_MSG_RESULT(no)
2497           system_utmpx_path=no ]
2498 )
2499 if test -z "$conf_utmpx_location"; then
2500         if test x"$system_utmpx_path" = x"no" ; then
2501                 AC_DEFINE(DISABLE_UTMPX)
2502         fi
2503 else
2504         AC_DEFINE_UNQUOTED(CONF_UTMPX_FILE, "$conf_utmpx_location")
2505 fi
2506
2507 dnl wtmpx detection
2508 AC_MSG_CHECKING([if your system defines WTMPX_FILE])
2509 AC_TRY_COMPILE([
2510 #include <sys/types.h>
2511 #include <utmp.h>
2512 #ifdef HAVE_UTMPX_H
2513 #include <utmpx.h>
2514 #endif
2515 #ifdef HAVE_PATHS_H
2516 #  include <paths.h>
2517 #endif
2518         ],
2519         [ char *wtmpx = WTMPX_FILE; ],
2520         [ AC_MSG_RESULT(yes) ],
2521         [ AC_MSG_RESULT(no)
2522           system_wtmpx_path=no ]
2523 )
2524 if test -z "$conf_wtmpx_location"; then
2525         if test x"$system_wtmpx_path" = x"no" ; then
2526                 AC_DEFINE(DISABLE_WTMPX)
2527         fi
2528 else
2529         AC_DEFINE_UNQUOTED(CONF_WTMPX_FILE, "$conf_wtmpx_location")
2530 fi
2531
2532
2533 if test ! -z "$blibpath" ; then
2534         LDFLAGS="$LDFLAGS $blibflags$blibpath"
2535         AC_MSG_WARN([Please check and edit blibpath in LDFLAGS in Makefile])
2536 fi
2537
2538 dnl remove pam and dl because they are in $LIBPAM
2539 if test "$PAM_MSG" = yes ; then
2540         LIBS=`echo $LIBS | sed 's/-lpam //'`
2541 fi
2542 if test "$ac_cv_lib_pam_pam_set_item" = yes ; then
2543         LIBS=`echo $LIBS | sed 's/-ldl //'`
2544 fi
2545
2546 AC_EXEEXT
2547 AC_CONFIG_FILES([Makefile openbsd-compat/Makefile scard/Makefile ssh_prng_cmds])
2548 AC_OUTPUT
2549
2550 # Print summary of options
2551
2552 # Someone please show me a better way :)
2553 A=`eval echo ${prefix}` ; A=`eval echo ${A}`
2554 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
2555 C=`eval echo ${sbindir}` ; C=`eval echo ${C}`
2556 D=`eval echo ${sysconfdir}` ; D=`eval echo ${D}`
2557 E=`eval echo ${libexecdir}/ssh-askpass` ; E=`eval echo ${E}`
2558 F=`eval echo ${mandir}/${mansubdir}X` ; F=`eval echo ${F}`
2559 G=`eval echo ${piddir}` ; G=`eval echo ${G}`
2560 H=`eval echo ${PRIVSEP_PATH}` ; H=`eval echo ${H}`
2561 I=`eval echo ${user_path}` ; I=`eval echo ${I}`
2562 J=`eval echo ${superuser_path}` ; J=`eval echo ${J}`
2563
2564 echo ""
2565 echo "OpenSSH has been configured with the following options:"
2566 echo "                     User binaries: $B"
2567 echo "                   System binaries: $C"
2568 echo "               Configuration files: $D"
2569 echo "                   Askpass program: $E"
2570 echo "                      Manual pages: $F"
2571 echo "                          PID file: $G"
2572 echo "  Privilege separation chroot path: $H"
2573 if test "$USES_LOGIN_CONF" = "yes" ; then
2574 echo "   At runtime, sshd will use the path defined in /etc/login.conf"
2575 else
2576 echo "            sshd default user PATH: $I"
2577 fi
2578 if test ! -z "$superuser_path" ; then
2579 echo "          sshd superuser user PATH: $J"
2580 fi
2581 echo "                    Manpage format: $MANTYPE"
2582 echo "                       DNS support: $DNS_MSG"
2583 echo "                       PAM support: $PAM_MSG"
2584 echo "                KerberosIV support: $KRB4_MSG"
2585 echo "                 KerberosV support: $KRB5_MSG"
2586 echo "                 Smartcard support: $SCARD_MSG"
2587 echo "                       AFS support: $AFS_MSG"
2588 echo "                     S/KEY support: $SKEY_MSG"
2589 echo "              TCP Wrappers support: $TCPW_MSG"
2590 echo "              MD5 password support: $MD5_MSG"
2591 echo "       IP address in \$DISPLAY hack: $DISPLAY_HACK_MSG"
2592 echo "           Translate v4 in v6 hack: $IPV4_IN6_HACK_MSG"
2593 echo "                  BSD Auth support: $BSD_AUTH_MSG"
2594 echo "              Random number source: $RAND_MSG"
2595 if test ! -z "$USE_RAND_HELPER" ; then
2596 echo "     ssh-rand-helper collects from: $RAND_HELPER_MSG"
2597 fi
2598
2599 echo ""
2600
2601 echo "              Host: ${host}"
2602 echo "          Compiler: ${CC}"
2603 echo "    Compiler flags: ${CFLAGS}"
2604 echo "Preprocessor flags: ${CPPFLAGS}"
2605 echo "      Linker flags: ${LDFLAGS}"
2606 echo "         Libraries: ${LIBWRAP} ${LIBPAM} ${LIBS}"
2607
2608 echo ""
2609
2610 if test "x$PAM_MSG" = "xyes" ; then
2611         echo "PAM is enabled. You may need to install a PAM control file "
2612         echo "for sshd, otherwise password authentication may fail. "
2613         echo "Example PAM control files can be found in the contrib/ "
2614         echo "subdirectory"
2615         echo ""
2616 fi
2617
2618 if test ! -z "$RAND_HELPER_CMDHASH" ; then
2619         echo "WARNING: you are using the builtin random number collection "
2620         echo "service. Please read WARNING.RNG and request that your OS "
2621         echo "vendor includes kernel-based random number collection in "
2622         echo "future versions of your OS."
2623         echo ""
2624 fi
2625