configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_CANONICAL_HOST
   5
   6 # C Compiler features
   7 if test "$GCC" = "yes"; then CFLAGS="$CFLAGS -Wall"; fi
   8 AC_C_INLINE
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_CPP
  13 AC_PROG_RANLIB
  14 AC_PROG_INSTALL
  15 AC_CHECK_PROG(AR, ar, ar)
  16 AC_PATH_PROG(PERL, perl)
  17 AC_SUBST(PERL)
  18
  19 # Check for some target-specific stuff
  20 case "$host" in
  21 *-*-aix*)
  22         AFS_LIBS="-lld"
  23         CFLAGS="$CFLAGS -I/usr/local/include"
  24         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  25         AC_DEFINE(BROKEN_GETADDRINFO)
  26         ;;
  27 *-*-hpux10*)
  28         if test -z "$GCC"; then
  29                 CFLAGS="$CFLAGS -Aa"
  30         fi
  31         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  32         CFLAGS="$CFLAGS -I/usr/local/include"
  33         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  34         AC_DEFINE(IPADDR_IN_DISPLAY)
  35         AC_DEFINE(USE_UTMPX)
  36         AC_MSG_CHECKING(for HPUX trusted system password database)
  37         if test -f /tcb/files/auth/system/default; then
  38                 AC_MSG_RESULT(yes)
  39                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  40                 LIBS="$LIBS -lsec"
  41                 AC_MSG_WARN([This configuration is untested])
  42         else
  43                 AC_MSG_RESULT(no)
  44                 AC_DEFINE(DISABLE_SHADOW)
  45         fi
  46         MANTYPE='$(CATMAN)'
  47         mansubdir=cat
  48         ;;
  49 *-*-irix5*)
  50         CFLAGS="$CFLAGS -I/usr/local/include"
  51         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  52         MANTYPE='$(CATMAN)'
  53         no_libsocket=1
  54         no_libnsl=1
  55         ;;
  56 *-*-irix6*)
  57         CFLAGS="$CFLAGS -I/usr/local/include"
  58         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  59         MANTYPE='$(CATMAN)'
  60         AC_MSG_WARN([*** Irix 6.x is not tested, please report you experiences *** ])
  61         no_libsocket=1
  62         no_libnsl=1
  63         ;;
  64 *-*-linux*)
  65         no_dev_ptmx=1
  66         AC_DEFINE(DONT_TRY_OTHER_AF)
  67         inet6_default_4in6=yes
  68         ;;
  69 *-*-netbsd*)
  70         need_dash_r=1
  71         ;;
  72 *-*-solaris*)
  73         CFLAGS="$CFLAGS -I/usr/local/include"
  74         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib"
  75         need_dash_r=1
  76         LDFLAGS="-L/usr/ucblib -R/usr/ucblib"
  77         AC_DEFINE(USE_UTMPX)
  78         ;;
  79 *-*-sysv*)
  80         CFLAGS="$CFLAGS -I/usr/local/include"
  81         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  82         AC_DEFINE(USE_UTMPX)
  83         MANTYPE='$(CATMAN)'
  84         mansubdir=cat
  85         LIBS="$LIBS -lgen -lsocket"
  86         ;;
  87 esac
  88
  89 # Checks for libraries.
  90 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
  91 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
  92
  93 if test -z "$no_libsocket" ; then
  94         AC_CHECK_LIB(nsl, yp_match, , )
  95 fi
  96 if test -z "$no_libnsl" ; then
  97         AC_CHECK_LIB(socket, main, , )
  98 fi
  99
 100 # Checks for header files.
 101 AC_CHECK_HEADERS(bstring.h endian.h lastlog.h login.h maillock.h netdb.h netgroup.h paths.h poll.h pty.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/select.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h stddef.h util.h utmp.h utmpx.h)
 102
 103 # Checks for library functions.
 104 AC_CHECK_FUNCS(arc4random bindresvport_af freeaddrinfo gai_strerror getaddrinfo getnameinfo innetgr md5_crypt mkdtemp openpty rresvport_af setenv seteuid setlogin setproctitle setreuid snprintf strlcat strlcpy updwtmpx vsnprintf _getpty)
 105
 106 AC_CHECK_FUNC(login,
 107         [AC_DEFINE(HAVE_LOGIN)],
 108         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 109 )
 110
 111 AC_CHECK_FUNC(daemon,
 112         [AC_DEFINE(HAVE_DAEMON)],
 113         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 114 )
 115
 116 AC_CHECK_FUNC(getpagesize,
 117         [AC_DEFINE(HAVE_GETPAGESIZE)],
 118         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 119 )
 120
 121 AC_ARG_WITH(pam,
 122         [  --without-pam           Disable PAM support ],
 123         [
 124                 if test "x$withval" = "xno" ; then
 125                         no_pam=1
 126                         AC_DEFINE(DISABLE_PAM)
 127                 fi
 128         ]
 129 )
 130 if test -z "$no_pam" -a "x$ac_cv_header_security_pam_appl_h" = "xyes" ; then
 131         AC_CHECK_LIB(dl, dlopen, , )
 132         LIBS="$LIBS -lpam"
 133
 134         # Check PAM strerror arguments (old PAM)
 135         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 136         AC_TRY_COMPILE(
 137                 [
 138                         #include <stdlib.h>
 139                         #include <security/pam_appl.h>
 140                 ],
 141                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 142                 [AC_MSG_RESULT(no)],
 143                 [
 144                         AC_DEFINE(HAVE_OLD_PAM)
 145                         AC_MSG_RESULT(yes)
 146                 ]
 147         )
 148 fi
 149
 150 # The big search for OpenSSL
 151 AC_ARG_WITH(ssl-dir,
 152         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 153         [
 154                 if test "x$withval" != "$xno" ; then
 155                         tryssldir=$withval
 156                 fi
 157         ]
 158 )
 159
 160 saved_LIBS="$LIBS"
 161 saved_CFLAGS="$CFLAGS"
 162 if test "x$prefix" != "xNONE" ; then
 163         tryssldir="$tryssldir $prefix"
 164 fi
 165 AC_MSG_CHECKING([for OpenSSL/SSLeay directory])
 166 for ssldir in "" $tryssldir /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 167         if test ! -z "$ssldir" ; then
 168                 LIBS="$saved_LIBS -L$ssldir/lib -L$ssldir -lcrypto"
 169                 CFLAGS="$CFLAGS -I$ssldir/include"
 170                 if test "x$need_dash_r" = "x1" ; then
 171                         LIBS="$LIBS -R$ssldir/lib -L$ssldir"
 172                 fi
 173         else
 174                 LIBS="$saved_LIBS -lcrypto"
 175         fi
 176
 177         for WANTS_RSAREF in "" 1 ; do
 178
 179                 if test ! -z "$WANTS_RSAREF" ; then
 180                         LIBS="$LIBS -lRSAglue -lrsaref"
 181                 fi
 182
 183                 AC_TRY_RUN(
 184                         [
 185                                 #include <openssl/rsa.h>
 186                                 #include <openssl/bn.h>
 187                                 #include <openssl/sha.h>
 188                                 int main(void)
 189                                 {RSA *key; char seed[2048];memset(seed, 0, sizeof(seed));
 190                                 RAND_seed(seed, sizeof(seed));key=RSA_generate_key(32,3,NULL,NULL);
 191                                 return(key==NULL);}
 192                         ],
 193                         [
 194                                 AC_DEFINE(HAVE_OPENSSL)
 195                                 found_crypto=1
 196                                 break;
 197                         ], []
 198                 )
 199                 AC_TRY_RUN(
 200                         [
 201                                 #include <ssl/rsa.h>
 202                                 #include <ssl/bn.h>
 203                                 #include <ssl/sha.h>
 204                                 int main(void)
 205                                 {RSA *key; char seed[2048];memset(seed, 0, sizeof(seed));
 206                                 RAND_seed(seed, sizeof(seed));key=RSA_generate_key(32,3,NULL,NULL);
 207                                 return(key==NULL);}
 208                         ],
 209                         [
 210                                 AC_DEFINE(HAVE_SSL)
 211                                 found_crypto=1
 212                                 break;
 213                         ], []
 214                 )
 215         done
 216
 217         if test ! -z "$found_crypto" ; then
 218                 break;
 219         fi
 220 done
 221
 222 if test -z "$found_crypto" ; then
 223         AC_MSG_ERROR([Could not find working SSLeay / OpenSSL libraries, please install])
 224 fi
 225 if test -z "$ssldir" ; then
 226         ssldir="(system)"
 227 else
 228         CFLAGS="$CFLAGS -I$ssldir/include"
 229         LDFLAGS="$LDFLAGS -L$ssldir/lib"
 230         if test "x$need_dash_r" = "x1" ; then
 231                 LDFLAGS="$LDFLAGS -R$ssldir"
 232         fi
 233 fi
 234 LIBS="$saved_LIBS -lcrypto"
 235 if test ! -z "$WANTS_RSAREF" ; then
 236         LIBS="$LIBS -lRSAglue -lrsaref"
 237 fi
 238 AC_MSG_RESULT($ssldir)
 239
 240 # Checks for data types
 241 AC_CHECK_SIZEOF(char, 1)
 242 AC_CHECK_SIZEOF(short int, 2)
 243 AC_CHECK_SIZEOF(int, 4)
 244 AC_CHECK_SIZEOF(long int, 4)
 245 AC_CHECK_SIZEOF(long long int, 8)
 246
 247 # More checks for data types
 248 AC_MSG_CHECKING([for intXX_t types])
 249 AC_TRY_COMPILE(
 250         [#include <sys/types.h>],
 251         [int16_t a; int32_t b; a = 1235; b = 1235;],
 252         [
 253                 AC_DEFINE(HAVE_INTXX_T)
 254                 AC_MSG_RESULT(yes)
 255                 have_intxx_t=1
 256         ],
 257         [AC_MSG_RESULT(no)]
 258 )
 259
 260 AC_MSG_CHECKING([for u_intXX_t types])
 261 AC_TRY_COMPILE(
 262         [#include <sys/types.h>],
 263         [u_int16_t c; u_int32_t d; c = 1235; d = 1235;],
 264         [
 265                 AC_DEFINE(HAVE_U_INTXX_T)
 266                 AC_MSG_RESULT(yes)
 267                 have_u_intxx_t=1
 268         ],
 269         [AC_MSG_RESULT(no)]
 270 )
 271
 272 if test -z "$have_u_intxx_t" -o -z "$have_intxx_t" -a \
 273            "x$ac_cv_header_sys_bitypes_h" = "xyes"
 274 then
 275         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 276         AC_TRY_COMPILE(
 277                 [#include <sys/bitypes.h>],
 278                 [
 279                         u_int16_t c; u_int32_t d;
 280                         int16_t e; int32_t f;
 281                         c = 1235; d = 1235;
 282                         e = 1235; f = 1235;
 283                 ],
 284                 [
 285                         AC_DEFINE(HAVE_U_INTXX_T)
 286                         AC_DEFINE(HAVE_INTXX_T)
 287                         AC_MSG_RESULT(yes)
 288                 ],
 289                 [AC_MSG_RESULT(no)]
 290         )
 291 fi
 292
 293 AC_MSG_CHECKING([for uintXX_t types])
 294 AC_TRY_COMPILE(
 295         [#include <sys/types.h>],
 296         [uint16_t c; uint32_t d; c = 1235; d = 1235;],
 297         [
 298                 AC_DEFINE(HAVE_UINTXX_T)
 299                 AC_MSG_RESULT(yes)
 300         ],
 301         [AC_MSG_RESULT(no)]
 302 )
 303
 304 AC_MSG_CHECKING([for socklen_t])
 305 AC_TRY_COMPILE(
 306         [
 307                 #include <sys/types.h>
 308                 #include <sys/socket.h>
 309         ],
 310         [socklen_t foo; foo = 1235;],
 311         [
 312                 AC_DEFINE(HAVE_SOCKLEN_T)
 313                 AC_MSG_RESULT(yes)
 314         ],
 315         [AC_MSG_RESULT(no)]
 316 )
 317
 318 AC_MSG_CHECKING([for size_t])
 319 AC_TRY_COMPILE(
 320         [#include <sys/types.h>],
 321         [size_t foo; foo = 1235;],
 322         [
 323                 AC_DEFINE(HAVE_SIZE_T)
 324                 AC_MSG_RESULT(yes)
 325         ],
 326         [AC_MSG_RESULT(no)]
 327 )
 328
 329 AC_MSG_CHECKING([for struct sockaddr_storage])
 330 AC_TRY_COMPILE(
 331         [
 332                 #include <sys/types.h>
 333                 #include <sys/socket.h>
 334         ],
 335         [struct sockaddr_storage s;],
 336         [
 337                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 338                 AC_MSG_RESULT(yes)
 339         ],
 340         [AC_MSG_RESULT(no)]
 341 )
 342
 343 AC_MSG_CHECKING([for struct sockaddr_in6])
 344 AC_TRY_COMPILE(
 345         [#include <netinet/in.h>],
 346         [struct sockaddr_in6 s; s.sin6_family = 0;],
 347         [
 348                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 349                 AC_MSG_RESULT(yes)
 350         ],
 351         [AC_MSG_RESULT(no)]
 352 )
 353
 354 AC_MSG_CHECKING([for struct in6_addr])
 355 AC_TRY_COMPILE(
 356         [#include <netinet/in.h>],
 357         [struct in6_addr s; s.s6_addr[0] = 0;],
 358         [
 359                 AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 360                 AC_MSG_RESULT(yes)
 361         ],
 362         [AC_MSG_RESULT(no)]
 363 )
 364
 365 AC_MSG_CHECKING([for struct addrinfo])
 366 AC_TRY_COMPILE(
 367         [
 368                 #include <sys/types.h>
 369                 #include <sys/socket.h>
 370                 #include <netdb.h>
 371         ],
 372         [struct addrinfo s; s.ai_flags = AI_PASSIVE;],
 373         [
 374                 AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 375                 AC_MSG_RESULT(yes)
 376         ],
 377         [AC_MSG_RESULT(no)]
 378 )
 379
 380 # Checks for structure members
 381 AC_MSG_CHECKING([whether utmp.h has ut_host field])
 382 AC_EGREP_HEADER(ut_host, utmp.h,
 383         [AC_DEFINE(HAVE_HOST_IN_UTMP) AC_MSG_RESULT(yes); ],
 384         [AC_MSG_RESULT(no)]
 385 )
 386 AC_MSG_CHECKING([whether utmpx.h has ut_host field])
 387 AC_EGREP_HEADER(ut_host, utmpx.h,
 388         [AC_DEFINE(HAVE_HOST_IN_UTMPX) AC_MSG_RESULT(yes); ],
 389         [AC_MSG_RESULT(no)]
 390 )
 391 AC_MSG_CHECKING([whether utmpx.h has syslen field])
 392 AC_EGREP_HEADER(syslen, utmpx.h,
 393         [AC_DEFINE(HAVE_SYSLEN_IN_UTMPX) AC_MSG_RESULT(yes); ],
 394         [AC_MSG_RESULT(no)]
 395 )
 396 AC_MSG_CHECKING([whether utmp.h has ut_pid field])
 397 AC_EGREP_HEADER(ut_pid, utmp.h,
 398         [AC_DEFINE(HAVE_PID_IN_UTMP) AC_MSG_RESULT(yes); ],
 399         [AC_MSG_RESULT(no)]
 400 )
 401 AC_MSG_CHECKING([whether utmp.h has ut_type field])
 402 AC_EGREP_HEADER(ut_type, utmp.h,
 403         [AC_DEFINE(HAVE_TYPE_IN_UTMP) AC_MSG_RESULT(yes); ],
 404         [AC_MSG_RESULT(no)]
 405 )
 406 AC_MSG_CHECKING([whether utmp.h has ut_tv field])
 407 AC_EGREP_HEADER(ut_tv, utmp.h,
 408         [AC_DEFINE(HAVE_TV_IN_UTMP) AC_MSG_RESULT(yes); ],
 409         [AC_MSG_RESULT(no)]
 410 )
 411 AC_MSG_CHECKING([whether utmp.h has ut_id field])
 412 AC_EGREP_HEADER(ut_id, utmp.h,
 413         [AC_DEFINE(HAVE_ID_IN_UTMP) AC_MSG_RESULT(yes); ],
 414         [AC_MSG_RESULT(no)]
 415 )
 416 AC_MSG_CHECKING([whether utmp.h has ut_addr field])
 417 AC_EGREP_HEADER(ut_addr, utmp.h,
 418         [AC_DEFINE(HAVE_ADDR_IN_UTMP) AC_MSG_RESULT(yes); ],
 419         [AC_MSG_RESULT(no)]
 420 )
 421 AC_MSG_CHECKING([whether utmpx.h has ut_addr field])
 422 AC_EGREP_HEADER(ut_addr, utmpx.h,
 423         [AC_DEFINE(HAVE_ADDR_IN_UTMPX) AC_MSG_RESULT(yes); ],
 424         [AC_MSG_RESULT(no)]
 425 )
 426 AC_MSG_CHECKING([whether utmp.h has ut_addr_v6 field])
 427 AC_EGREP_HEADER(ut_addr_v6, utmp.h,
 428         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMP) AC_MSG_RESULT(yes); ],
 429         [AC_MSG_RESULT(no)]
 430 )
 431 AC_MSG_CHECKING([whether utmpx.h has ut_addr_v6 field])
 432 AC_EGREP_HEADER(ut_addr_v6, utmpx.h,
 433         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMPX) AC_MSG_RESULT(yes); ],
 434         [AC_MSG_RESULT(no)]
 435 )
 436
 437 AC_MSG_CHECKING([whether struct sockaddr_storage has ss_family field])
 438 AC_TRY_COMPILE(
 439         [
 440                 #include <sys/types.h>
 441                 #include <sys/socket.h>
 442         ],
 443         [struct sockaddr_storage s; s.ss_family = 1;],
 444         [
 445                 AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 446                 AC_MSG_RESULT(yes)
 447         ],
 448         [AC_MSG_RESULT(no)]
 449 )
 450 AC_MSG_CHECKING([whether struct sockaddr_storage has __ss_family field])
 451 AC_TRY_COMPILE(
 452         [
 453                 #include <sys/types.h>
 454                 #include <sys/socket.h>
 455         ],
 456         [struct sockaddr_storage s; s.__ss_family = 1;],
 457         [
 458                 AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 459                 AC_MSG_RESULT(yes)
 460         ],
 461         [AC_MSG_RESULT(no)]
 462 )
 463
 464 AC_MSG_CHECKING([whether libc defines __progname])
 465 AC_TRY_LINK([],
 466         [extern char *__progname; printf("%s", __progname);],
 467         [
 468                 AC_DEFINE(HAVE___PROGNAME)
 469                 AC_MSG_RESULT(yes)
 470         ],
 471         [
 472                 AC_MSG_RESULT(no)
 473         ]
 474 )
 475
 476 # Looking for programs, paths and files
 477 AC_ARG_WITH(rsh,
 478         [  --with-rsh=PATH         Specify path to remote shell program ],
 479         [
 480                 if test "x$withval" != "$no" ; then
 481                         AC_DEFINE_UNQUOTED(RSH_PATH, "$withval")
 482                 fi
 483         ],
 484         [
 485                 AC_PATH_PROG(rsh_path, rsh)
 486         ]
 487 )
 488
 489 AC_ARG_WITH(xauth,
 490         [  --with-xauth=PATH       Specify path to xauth program ],
 491         [
 492                 if test "x$withval" != "$xno" ; then
 493                         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$withval")
 494                 fi
 495         ],
 496         [
 497                 AC_PATH_PROG(xauth_path, xauth)
 498                 if test ! -z "$xauth_path" -a -x "/usr/openwin/bin/xauth" ; then
 499                         xauth_path="/usr/openwin/bin/xauth"
 500                 fi
 501         ]
 502 )
 503
 504 if test ! -z "$xauth_path" ; then
 505         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
 506 fi
 507 if test ! -z "$rsh_path" ; then
 508         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
 509 fi
 510
 511 # Check for mail directory (last resort if we cannot get it from headers)
 512 if test ! -z "$MAIL" ; then
 513         maildir=`dirname $MAIL`
 514         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
 515 fi
 516
 517 # Look for lastlog location
 518 AC_ARG_WITH(lastlog,
 519         [  --with-lastlog=FILE     Location of lastlog file],
 520         [
 521                 if test "x$withval" = "xno" ; then
 522                         AC_DEFINE(DISABLE_LASTLOG)
 523                 else
 524                         AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$withval")
 525                 fi
 526         ],
 527         [
 528                 AC_MSG_CHECKING([location of lastlog file])
 529                 for lastlog in /var/log/lastlog /var/adm/lastlog /usr/adm/lastlog  /etc/security/lastlog ; do
 530                         if test -f $lastlog ; then
 531                                 gotlastlog="file"
 532                                 break
 533                         fi
 534                         if test -d $lastlog ; then
 535                                 gotlastlog="dir"
 536                                 break
 537                         fi
 538                 done
 539                 if test -z "$gotlastlog" ; then
 540                         AC_MSG_RESULT(not found)
 541                         nolastlog=1
 542                 else
 543                         if test "x$gotlastlog" = "xdir" ; then
 544                                 AC_MSG_RESULT(${lastlog}/)
 545                                 AC_DEFINE(LASTLOG_IS_DIR)
 546                         else
 547                                 AC_MSG_RESULT($lastlog)
 548                                 AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$lastlog")
 549                         fi
 550                 fi
 551         ]
 552 )
 553
 554 if test ! -z "$nolastlog" ; then
 555         AC_MSG_WARN([*** Disabling lastlog support *** ])
 556         AC_DEFINE(DISABLE_LASTLOG)
 557 fi
 558
 559 if test -z "$no_dev_ptmx" ; then
 560         AC_CHECK_FILE("/dev/ptmx",
 561                 [
 562                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
 563                         have_dev_ptmx=1
 564                 ]
 565         )
 566 fi
 567 AC_CHECK_FILE("/dev/ptc",
 568         [
 569                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
 570                 have_dev_ptc=1
 571         ]
 572 )
 573
 574 # Options from here on. Some of these are preset by platform above
 575
 576 # Check whether user wants GNOME ssh-askpass
 577 AC_MSG_CHECKING([whether to build GNOME ssh-askpass])
 578 AC_ARG_WITH(gnome-askpass,
 579         [  --with-gnome-askpass    Build the GNOME passphrase requester (default=no)],
 580         [
 581                 if test "x$withval" = "xno" ; then
 582                         GNOME_ASKPASS="";
 583                 else
 584                         GNOME_ASKPASS="gnome-ssh-askpass";
 585                 fi
 586         ])
 587 AC_SUBST(GNOME_ASKPASS)
 588
 589 if test -z "$GNOME_ASKPASS" ; then
 590         AC_MSG_RESULT(no)
 591 else
 592         AC_MSG_RESULT(yes)
 593 fi
 594
 595 # Check for user-specified random device, otherwise check /dev/urandom
 596 AC_ARG_WITH(random,
 597         [  --with-random=FILE      read randomness from FILE (default=/dev/urandom)],
 598         [
 599                 RANDOM_POOL="$withval";
 600                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 601         ],
 602         [
 603                 # Check for random device
 604                 AC_CHECK_FILE("/dev/urandom",
 605                         [
 606                                 RANDOM_POOL="/dev/urandom";
 607                                 AC_SUBST(RANDOM_POOL)
 608                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 609                         ]
 610                 )
 611         ]
 612 )
 613
 614 # Check for EGD pool file
 615 AC_ARG_WITH(egd-pool,
 616         [  --with-egd-pool=FILE    read randomness from EGD pool FILE (default none)],
 617         [
 618                 RANDOM_POOL="$withval";
 619                 AC_DEFINE(HAVE_EGD)
 620                 AC_SUBST(RANDOM_POOL)
 621                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 622         ]
 623 )
 624
 625 # Make sure we have some random number support
 626 if test -z "$RANDOM_POOL" -a -z "$EGD_POOL"; then
 627         AC_MSG_ERROR([No random device found, and no EGD random pool specified])
 628 fi
 629
 630 AC_ARG_WITH(catman,
 631         [  --with-catman=man|cat   Install preformatted manpages[no]],
 632         [
 633                 MANTYPE='$(CATMAN)'
 634                 if test x"$withval" != x"yes" ; then
 635                    mansubdir=$withval
 636                 else
 637                    mansubdir=cat
 638                 fi
 639         ], [
 640                 if test -z "$MANTYPE" ; then
 641                         MANTYPE='$(TROFFMAN)'
 642                         mansubdir=man
 643                 fi
 644         ]
 645 )
 646 AC_SUBST(MANTYPE)
 647 AC_SUBST(mansubdir)
 648
 649 # Check whether user wants Kerberos support
 650 AC_ARG_WITH(kerberos4,
 651         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
 652         [
 653                 if test "x$withval" != "xno" ; then
 654
 655                         if test "x$withval" != "$xyes" ; then
 656                                 CFLAGS="$CFLAGS -I${withval}/include"
 657                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 658                         else
 659                                 if test -d /usr/include/kerberosIV ; then
 660                                         CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 661                                 fi
 662                         fi
 663
 664                         AC_CHECK_HEADERS(krb.h)
 665                         AC_CHECK_LIB(krb, main)
 666                         if test "$ac_cv_header_krb_h" != yes; then
 667                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
 668                         fi
 669                         if test "$ac_cv_lib_krb_main" != yes; then
 670                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
 671                         fi
 672
 673                         KLIBS="-lkrb -ldes"
 674                         AC_CHECK_LIB(resolv, dn_expand, , )
 675                         KRB4=yes
 676                         AC_DEFINE(KRB4)
 677                 fi
 678         ]
 679 )
 680
 681 # Check whether user wants AFS support
 682 AC_ARG_WITH(afs,
 683         [  --with-afs=PATH         Enable AFS support],
 684         [
 685                 if test "x$withval" != "xno" ; then
 686
 687                         if test "x$withval" != "$xyes" ; then
 688                                 CFLAGS="$CFLAGS -I${withval}/include"
 689                                 LFLAGS="$LFLAGS -L${withval}/lib"
 690                         fi
 691
 692                         if test -z "$KRB4" ; then
 693                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
 694                         fi
 695
 696                         LIBS="$LIBS -lkafs"
 697                         if test ! -z "$AFS_LIBS" ; then
 698                                 LIBS="$LIBS $AFS_LIBS"
 699                         fi
 700                         AC_DEFINE(AFS)
 701                 fi
 702         ]
 703 )
 704 LIBS="$LIBS $KLIBS"
 705
 706 # Check whether user wants S/Key support
 707 AC_ARG_WITH(skey,
 708         [  --with-skey             Enable S/Key support],
 709         [
 710                 if test "x$withval" != "xno" ; then
 711                         AC_DEFINE(SKEY)
 712                         LIBS="$LIBS -lskey"
 713                 fi
 714         ]
 715 )
 716
 717 # Check whether user wants TCP wrappers support
 718 AC_ARG_WITH(tcp-wrappers,
 719         [  --with-tcp-wrappers     Enable tcpwrappers support],
 720         [
 721                 if test "x$withval" != "xno" ; then
 722                         saved_LIBS="$LIBS"
 723                         LIBS="$LIBS -lwrap"
 724                         AC_MSG_CHECKING(for libwrap)
 725                         AC_TRY_LINK(
 726                                 [
 727                                         #include <tcpd.h>
 728                                         int deny_severity = 0, allow_severity = 0;
 729                                 ],
 730                                 [hosts_access(0);],
 731                                 [
 732                                         AC_MSG_RESULT(yes)
 733                                         AC_DEFINE(LIBWRAP)
 734                                 ],
 735                                 [
 736                                         AC_MSG_RESULT(no)
 737                                         AC_MSG_WARN([*** libwrap missing - tcpwrapper support disabled ***])
 738                                         LIBS="$saved_LIBS"
 739                                 ]
 740                         )
 741                 fi
 742         ]
 743 )
 744
 745 # Check whether to enable MD5 passwords
 746 AC_ARG_WITH(md5-passwords,
 747         [  --with-md5-passwords    Enable use of MD5 passwords],
 748         [
 749                 if test "x$withval" != "xno" ; then
 750                         AC_DEFINE(HAVE_MD5_PASSWORDS)
 751                 fi
 752         ]
 753 )
 754
 755 # Check whether to enable utmpx support
 756 AC_ARG_WITH(utmpx,
 757         [  --with-utmpx            Enable utmpx support],
 758         [
 759                 if test "x$withval" != "xno" ; then
 760                         AC_DEFINE(USE_UTMPX)
 761                 fi
 762         ]
 763 )
 764
 765 # Whether to disable shadow password support
 766 AC_ARG_WITH(shadow,
 767         [  --without-shadow        Disable shadow password support],
 768         [
 769                 if test "x$withval" = "xno" ; then
 770                         AC_DEFINE(DISABLE_SHADOW)
 771                 fi
 772         ]
 773 )
 774
 775 # Use ip address instead of hostname in $DISPLAY
 776 AC_ARG_WITH(ipaddr-display,
 777         [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
 778         [
 779                 if test "x$withval" = "xno" ; then
 780                         AC_DEFINE(IPADDR_IN_DISPLAY)
 781                 fi
 782         ]
 783 )
 784
 785 # Whether to mess with the default path
 786 AC_ARG_WITH(default-path,
 787         [  --with-default-path=PATH Specify default \$PATH environment for server],
 788         [
 789                 if test "x$withval" != "xno" ; then
 790                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
 791                 fi
 792         ]
 793 )
 794
 795 # Whether to force IPv4 by default (needed on broken glibc Linux)
 796 AC_ARG_WITH(ipv4-default,
 797         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
 798         [
 799                 if test "x$withval" != "xno" ; then
 800                         AC_DEFINE(IPV4_DEFAULT)
 801                 fi
 802         ]
 803 )
 804
 805 AC_MSG_CHECKING([to convert IPv4 in IPv6-mapped addresses])
 806 AC_ARG_WITH(4in6,
 807         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
 808         [
 809                 if test "x$withval" != "xno" ; then
 810                         AC_MSG_RESULT(yes)
 811                         AC_DEFINE(IPV4_IN_IPV6)
 812                 else
 813                         AC_MSG_RESULT(no)
 814                 fi
 815         ],[
 816                 if test "x$inet6_default_4in6" = "xyes"; then
 817                         AC_MSG_RESULT([yes (default)])
 818                         AC_DEFINE(IPV4_IN_IPV6)
 819                 else
 820                         AC_MSG_RESULT([no (default)])
 821                 fi
 822         ]
 823 )
 824
 825 # Where to place sshd.pid
 826 piddir=/var/run
 827 AC_ARG_WITH(pid-dir,
 828         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
 829         [
 830                 if test "x$withval" != "xno" ; then
 831                         piddir=$withval
 832                 fi
 833         ]
 834 )
 835 AC_DEFINE_UNQUOTED(PIDDIR, "$piddir")
 836 AC_SUBST(piddir)
 837
 838 AC_OUTPUT(Makefile)