configure.ac

   1 # $Id$
   2 #
   3 # Copyright (c) 1999-2004 Damien Miller
   4 #
   5 # Permission to use, copy, modify, and distribute this software for any
   6 # purpose with or without fee is hereby granted, provided that the above
   7 # copyright notice and this permission notice appear in all copies.
   8 #
   9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  16
  17 AC_INIT(OpenSSH, Portable)
  18 AC_CONFIG_SRCDIR([ssh.c])
  19
  20 AC_CONFIG_HEADER(config.h)
  21 AC_PROG_CC
  22 AC_CANONICAL_HOST
  23 AC_C_BIGENDIAN
  24
  25 # Checks for programs.
  26 AC_PROG_AWK
  27 AC_PROG_CPP
  28 AC_PROG_RANLIB
  29 AC_PROG_INSTALL
  30 AC_PATH_PROG(AR, ar)
  31 AC_PATH_PROG(CAT, cat)
  32 AC_PATH_PROG(KILL, kill)
  33 AC_PATH_PROGS(PERL, perl5 perl)
  34 AC_PATH_PROG(SED, sed)
  35 AC_SUBST(PERL)
  36 AC_PATH_PROG(ENT, ent)
  37 AC_SUBST(ENT)
  38 AC_PATH_PROG(TEST_MINUS_S_SH, bash)
  39 AC_PATH_PROG(TEST_MINUS_S_SH, ksh)
  40 AC_PATH_PROG(TEST_MINUS_S_SH, sh)
  41 AC_PATH_PROG(SH, sh)
  42 AC_SUBST(TEST_SHELL,sh)
  43
  44 dnl for buildpkg.sh
  45 AC_PATH_PROG(PATH_GROUPADD_PROG, groupadd, groupadd,
  46         [/usr/sbin${PATH_SEPARATOR}/etc])
  47 AC_PATH_PROG(PATH_USERADD_PROG, useradd, useradd,
  48         [/usr/sbin${PATH_SEPARATOR}/etc])
  49 AC_CHECK_PROG(MAKE_PACKAGE_SUPPORTED, pkgmk, yes, no)
  50
  51 # System features
  52 AC_SYS_LARGEFILE
  53
  54 if test -z "$AR" ; then
  55         AC_MSG_ERROR([*** 'ar' missing, please install or fix your \$PATH ***])
  56 fi
  57
  58 # Use LOGIN_PROGRAM from environment if possible
  59 if test ! -z "$LOGIN_PROGRAM" ; then
  60         AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM")
  61 else
  62         # Search for login
  63         AC_PATH_PROG(LOGIN_PROGRAM_FALLBACK, login)
  64         if test ! -z "$LOGIN_PROGRAM_FALLBACK" ; then
  65                 AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM_FALLBACK")
  66         fi
  67 fi
  68
  69 AC_PATH_PROG(PATH_PASSWD_PROG, passwd)
  70 if test ! -z "$PATH_PASSWD_PROG" ; then
  71         AC_DEFINE_UNQUOTED(_PATH_PASSWD_PROG, "$PATH_PASSWD_PROG")
  72 fi
  73
  74 if test -z "$LD" ; then
  75         LD=$CC
  76 fi
  77 AC_SUBST(LD)
  78
  79 AC_C_INLINE
  80 if test "$GCC" = "yes" || test "$GCC" = "egcs"; then
  81         CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wno-uninitialized"
  82 fi
  83
  84 AC_ARG_WITH(rpath,
  85         [  --without-rpath         Disable auto-added -R linker paths],
  86         [
  87                 if test "x$withval" = "xno" ; then
  88                         need_dash_r=""
  89                 fi
  90                 if test "x$withval" = "xyes" ; then
  91                         need_dash_r=1
  92                 fi
  93         ]
  94 )
  95
  96 # Check for some target-specific stuff
  97 case "$host" in
  98 *-*-aix*)
  99         AC_MSG_CHECKING([how to specify blibpath for linker ($LD)])
 100         if (test -z "$blibpath"); then
 101                 blibpath="/usr/lib:/lib"
 102         fi
 103         saved_LDFLAGS="$LDFLAGS"
 104         for tryflags in -blibpath: -Wl,-blibpath: -Wl,-rpath, ;do
 105                 if (test -z "$blibflags"); then
 106                         LDFLAGS="$saved_LDFLAGS $tryflags$blibpath"
 107                         AC_TRY_LINK([], [], [blibflags=$tryflags])
 108                 fi
 109         done
 110         if (test -z "$blibflags"); then
 111                 AC_MSG_RESULT(not found)
 112                 AC_MSG_ERROR([*** must be able to specify blibpath on AIX - check config.log])
 113         else
 114                 AC_MSG_RESULT($blibflags)
 115         fi
 116         LDFLAGS="$saved_LDFLAGS"
 117         dnl Check for authenticate.  Might be in libs.a on older AIXes
 118         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)],
 119                 [AC_CHECK_LIB(s,authenticate,
 120                         [ AC_DEFINE(WITH_AIXAUTHENTICATE)
 121                                 LIBS="$LIBS -ls"
 122                         ])
 123                 ])
 124         dnl Check for various auth function declarations in headers.
 125         AC_CHECK_DECLS([authenticate, loginrestrictions, loginsuccess,
 126             passwdexpired], , , [#include <usersec.h>])
 127         dnl Check if loginfailed is declared and takes 4 arguments (AIX >= 5.2)
 128         AC_CHECK_DECLS(loginfailed,
 129                  [AC_MSG_CHECKING(if loginfailed takes 4 arguments)
 130                   AC_TRY_COMPILE(
 131                         [#include <usersec.h>],
 132                         [(void)loginfailed("user","host","tty",0);],
 133                         [AC_MSG_RESULT(yes)
 134                          AC_DEFINE(AIX_LOGINFAILED_4ARG)],
 135                         [AC_MSG_RESULT(no)]
 136                 )],
 137                 [],
 138                 [#include <usersec.h>]
 139         )
 140         AC_CHECK_FUNCS(setauthdb)
 141         check_for_aix_broken_getaddrinfo=1
 142         AC_DEFINE(BROKEN_REALPATH)
 143         AC_DEFINE(SETEUID_BREAKS_SETUID)
 144         AC_DEFINE(BROKEN_SETREUID)
 145         AC_DEFINE(BROKEN_SETREGID)
 146         dnl AIX handles lastlog as part of its login message
 147         AC_DEFINE(DISABLE_LASTLOG)
 148         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 149         AC_DEFINE(SPT_TYPE,SPT_REUSEARGV)
 150         ;;
 151 *-*-cygwin*)
 152         check_for_libcrypt_later=1
 153         LIBS="$LIBS /usr/lib/textmode.o"
 154         AC_DEFINE(HAVE_CYGWIN)
 155         AC_DEFINE(USE_PIPES)
 156         AC_DEFINE(DISABLE_SHADOW)
 157         AC_DEFINE(IP_TOS_IS_BROKEN)
 158         AC_DEFINE(NO_X11_UNIX_SOCKETS)
 159         AC_DEFINE(NO_IPPORT_RESERVED_CONCEPT)
 160         AC_DEFINE(DISABLE_FD_PASSING)
 161         ;;
 162 *-*-dgux*)
 163         AC_DEFINE(IP_TOS_IS_BROKEN)
 164         AC_DEFINE(SETEUID_BREAKS_SETUID)
 165         AC_DEFINE(BROKEN_SETREUID)
 166         AC_DEFINE(BROKEN_SETREGID)
 167         ;;
 168 *-*-darwin*)
 169         AC_MSG_CHECKING(if we have working getaddrinfo)
 170         AC_TRY_RUN([#include <mach-o/dyld.h>
 171 main() { if (NSVersionOfRunTimeLibrary("System") >= (60 << 16))
 172                 exit(0);
 173         else
 174                 exit(1);
 175 }], [AC_MSG_RESULT(working)],
 176         [AC_MSG_RESULT(buggy)
 177         AC_DEFINE(BROKEN_GETADDRINFO)],
 178         [AC_MSG_RESULT(assume it is working)])
 179         AC_DEFINE(SETEUID_BREAKS_SETUID)
 180         AC_DEFINE(BROKEN_SETREUID)
 181         AC_DEFINE(BROKEN_SETREGID)
 182         AC_DEFINE_UNQUOTED(BIND_8_COMPAT, 1)
 183         ;;
 184 *-*-hpux10.26)
 185         if test -z "$GCC"; then
 186                 CFLAGS="$CFLAGS -Ae"
 187         fi
 188         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 189         IPADDR_IN_DISPLAY=yes
 190         AC_DEFINE(HAVE_SECUREWARE)
 191         AC_DEFINE(USE_PIPES)
 192         AC_DEFINE(LOGIN_NO_ENDOPT)
 193         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 194         AC_DEFINE(LOCKED_PASSWD_STRING, "*")
 195         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 196         LIBS="$LIBS -lsec -lsecpw"
 197         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 198         disable_ptmx_check=yes
 199         ;;
 200 *-*-hpux10*)
 201         if test -z "$GCC"; then
 202                 CFLAGS="$CFLAGS -Ae"
 203         fi
 204         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 205         IPADDR_IN_DISPLAY=yes
 206         AC_DEFINE(USE_PIPES)
 207         AC_DEFINE(LOGIN_NO_ENDOPT)
 208         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 209         AC_DEFINE(LOCKED_PASSWD_STRING, "*")
 210         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 211         LIBS="$LIBS -lsec"
 212         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 213         ;;
 214 *-*-hpux11*)
 215         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 216         IPADDR_IN_DISPLAY=yes
 217         AC_DEFINE(PAM_SUN_CODEBASE)
 218         AC_DEFINE(USE_PIPES)
 219         AC_DEFINE(LOGIN_NO_ENDOPT)
 220         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 221         AC_DEFINE(DISABLE_UTMP)
 222         AC_DEFINE(LOCKED_PASSWD_STRING, "*")
 223         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 224         AC_DEFINE(USE_BTMP, 1, [Use btmp to log bad logins])
 225         check_for_hpux_broken_getaddrinfo=1
 226         check_for_conflicting_getspnam=1
 227         LIBS="$LIBS -lsec"
 228         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 229         ;;
 230 *-*-irix5*)
 231         PATH="$PATH:/usr/etc"
 232         AC_DEFINE(BROKEN_INET_NTOA)
 233         AC_DEFINE(SETEUID_BREAKS_SETUID)
 234         AC_DEFINE(BROKEN_SETREUID)
 235         AC_DEFINE(BROKEN_SETREGID)
 236         AC_DEFINE(WITH_ABBREV_NO_TTY)
 237         AC_DEFINE(LOCKED_PASSWD_STRING, "*LK*")
 238         ;;
 239 *-*-irix6*)
 240         PATH="$PATH:/usr/etc"
 241         AC_DEFINE(WITH_IRIX_ARRAY)
 242         AC_DEFINE(WITH_IRIX_PROJECT)
 243         AC_DEFINE(WITH_IRIX_AUDIT)
 244         AC_CHECK_FUNC(jlimit_startjob, [AC_DEFINE(WITH_IRIX_JOBS)])
 245         AC_DEFINE(BROKEN_INET_NTOA)
 246         AC_DEFINE(SETEUID_BREAKS_SETUID)
 247         AC_DEFINE(BROKEN_SETREUID)
 248         AC_DEFINE(BROKEN_SETREGID)
 249         AC_DEFINE(BROKEN_UPDWTMPX)
 250         AC_DEFINE(WITH_ABBREV_NO_TTY)
 251         AC_DEFINE(LOCKED_PASSWD_STRING, "*LK*")
 252         ;;
 253 *-*-linux*)
 254         no_dev_ptmx=1
 255         check_for_libcrypt_later=1
 256         check_for_openpty_ctty_bug=1
 257         AC_DEFINE(DONT_TRY_OTHER_AF)
 258         AC_DEFINE(PAM_TTY_KLUDGE)
 259         AC_DEFINE(LOCKED_PASSWD_PREFIX, "!")
 260         AC_DEFINE(SPT_TYPE,SPT_REUSEARGV)
 261         AC_DEFINE(LINK_OPNOTSUPP_ERRNO, EPERM)
 262         AC_DEFINE(_PATH_BTMP, "/var/log/btmp", [log for bad login attempts])
 263         AC_DEFINE(USE_BTMP, 1, [Use btmp to log bad logins])
 264         inet6_default_4in6=yes
 265         case `uname -r` in
 266         1.*|2.0.*)
 267                 AC_DEFINE(BROKEN_CMSG_TYPE)
 268                 ;;
 269         esac
 270         ;;
 271 mips-sony-bsd|mips-sony-newsos4)
 272         AC_DEFINE(HAVE_NEWS4)
 273         SONY=1
 274         ;;
 275 *-*-netbsd*)
 276         check_for_libcrypt_before=1
 277         if test "x$withval" != "xno" ; then
 278                 need_dash_r=1
 279         fi
 280         ;;
 281 *-*-freebsd*)
 282         check_for_libcrypt_later=1
 283         ;;
 284 *-*-bsdi*)
 285         AC_DEFINE(SETEUID_BREAKS_SETUID)
 286         AC_DEFINE(BROKEN_SETREUID)
 287         AC_DEFINE(BROKEN_SETREGID)
 288         ;;
 289 *-next-*)
 290         conf_lastlog_location="/usr/adm/lastlog"
 291         conf_utmp_location=/etc/utmp
 292         conf_wtmp_location=/usr/adm/wtmp
 293         MAIL=/usr/spool/mail
 294         AC_DEFINE(HAVE_NEXT)
 295         AC_DEFINE(BROKEN_REALPATH)
 296         AC_DEFINE(USE_PIPES)
 297         AC_DEFINE(BROKEN_SAVED_UIDS)
 298         ;;
 299 *-*-solaris*)
 300         if test "x$withval" != "xno" ; then
 301                 need_dash_r=1
 302         fi
 303         AC_DEFINE(PAM_SUN_CODEBASE)
 304         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 305         AC_DEFINE(LOGIN_NEEDS_TERM)
 306         AC_DEFINE(PAM_TTY_KLUDGE)
 307         AC_DEFINE(SSHPAM_CHAUTHTOK_NEEDS_RUID)
 308         AC_DEFINE(LOCKED_PASSWD_STRING, "*LK*")
 309         # Pushing STREAMS modules will cause sshd to acquire a controlling tty.
 310         AC_DEFINE(SSHD_ACQUIRES_CTTY)
 311         external_path_file=/etc/default/login
 312         # hardwire lastlog location (can't detect it on some versions)
 313         conf_lastlog_location="/var/adm/lastlog"
 314         AC_MSG_CHECKING(for obsolete utmp and wtmp in solaris2.x)
 315         sol2ver=`echo "$host"| sed -e 's/.*[[0-9]]\.//'`
 316         if test "$sol2ver" -ge 8; then
 317                 AC_MSG_RESULT(yes)
 318                 AC_DEFINE(DISABLE_UTMP)
 319                 AC_DEFINE(DISABLE_WTMP)
 320         else
 321                 AC_MSG_RESULT(no)
 322         fi
 323         ;;
 324 *-*-sunos4*)
 325         CPPFLAGS="$CPPFLAGS -DSUNOS4"
 326         AC_CHECK_FUNCS(getpwanam)
 327         AC_DEFINE(PAM_SUN_CODEBASE)
 328         conf_utmp_location=/etc/utmp
 329         conf_wtmp_location=/var/adm/wtmp
 330         conf_lastlog_location=/var/adm/lastlog
 331         AC_DEFINE(USE_PIPES)
 332         ;;
 333 *-ncr-sysv*)
 334         LIBS="$LIBS -lc89"
 335         AC_DEFINE(USE_PIPES)
 336         AC_DEFINE(SSHD_ACQUIRES_CTTY)
 337         AC_DEFINE(SETEUID_BREAKS_SETUID)
 338         AC_DEFINE(BROKEN_SETREUID)
 339         AC_DEFINE(BROKEN_SETREGID)
 340         ;;
 341 *-sni-sysv*)
 342         # /usr/ucblib MUST NOT be searched on ReliantUNIX
 343         AC_CHECK_LIB(dl, dlsym, ,)
 344         # -lresolv needs to be at then end of LIBS or DNS lookups break
 345         AC_CHECK_LIB(res_query, resolv, [ LIBS="$LIBS -lresolv" ])
 346         IPADDR_IN_DISPLAY=yes
 347         AC_DEFINE(USE_PIPES)
 348         AC_DEFINE(IP_TOS_IS_BROKEN)
 349         AC_DEFINE(SETEUID_BREAKS_SETUID)
 350         AC_DEFINE(BROKEN_SETREUID)
 351         AC_DEFINE(BROKEN_SETREGID)
 352         AC_DEFINE(SSHD_ACQUIRES_CTTY)
 353         external_path_file=/etc/default/login
 354         # /usr/ucblib/libucb.a no longer needed on ReliantUNIX
 355         # Attention: always take care to bind libsocket and libnsl before libc,
 356         # otherwise you will find lots of "SIOCGPGRP errno 22" on syslog
 357         ;;
 358 # UnixWare 1.x, UnixWare 2.x, and others based on code from Univel.
 359 *-*-sysv4.2*)
 360         AC_DEFINE(USE_PIPES)
 361         AC_DEFINE(SETEUID_BREAKS_SETUID)
 362         AC_DEFINE(BROKEN_SETREUID)
 363         AC_DEFINE(BROKEN_SETREGID)
 364         ;;
 365 # UnixWare 7.x, OpenUNIX 8
 366 *-*-sysv5*)
 367         AC_DEFINE(USE_PIPES)
 368         AC_DEFINE(SETEUID_BREAKS_SETUID)
 369         AC_DEFINE(BROKEN_SETREUID)
 370         AC_DEFINE(BROKEN_SETREGID)
 371         ;;
 372 *-*-sysv*)
 373         ;;
 374 # SCO UNIX and OEM versions of SCO UNIX
 375 *-*-sco3.2v4*)
 376         AC_MSG_ERROR("This Platform is no longer supported.")
 377         ;;
 378 # SCO OpenServer 5.x
 379 *-*-sco3.2v5*)
 380         if test -z "$GCC"; then
 381                 CFLAGS="$CFLAGS -belf"
 382         fi
 383         LIBS="$LIBS -lprot -lx -ltinfo -lm"
 384         no_dev_ptmx=1
 385         AC_DEFINE(USE_PIPES)
 386         AC_DEFINE(HAVE_SECUREWARE)
 387         AC_DEFINE(DISABLE_SHADOW)
 388         AC_DEFINE(DISABLE_FD_PASSING)
 389         AC_DEFINE(SETEUID_BREAKS_SETUID)
 390         AC_DEFINE(BROKEN_SETREUID)
 391         AC_DEFINE(BROKEN_SETREGID)
 392         AC_DEFINE(WITH_ABBREV_NO_TTY)
 393         AC_DEFINE(BROKEN_UPDWTMPX)
 394         AC_DEFINE(PASSWD_NEEDS_USERNAME, 1, [must supply username to passwd])
 395         AC_CHECK_FUNCS(getluid setluid)
 396         MANTYPE=man
 397         TEST_SHELL=ksh
 398         ;;
 399 *-*-unicosmk*)
 400         AC_DEFINE(NO_SSH_LASTLOG)
 401         AC_DEFINE(SETEUID_BREAKS_SETUID)
 402         AC_DEFINE(BROKEN_SETREUID)
 403         AC_DEFINE(BROKEN_SETREGID)
 404         AC_DEFINE(USE_PIPES)
 405         AC_DEFINE(DISABLE_FD_PASSING)
 406         LDFLAGS="$LDFLAGS"
 407         LIBS="$LIBS -lgen -lrsc -lshare -luex -lacm"
 408         MANTYPE=cat
 409         ;;
 410 *-*-unicosmp*)
 411         AC_DEFINE(SETEUID_BREAKS_SETUID)
 412         AC_DEFINE(BROKEN_SETREUID)
 413         AC_DEFINE(BROKEN_SETREGID)
 414         AC_DEFINE(WITH_ABBREV_NO_TTY)
 415         AC_DEFINE(USE_PIPES)
 416         AC_DEFINE(DISABLE_FD_PASSING)
 417         LDFLAGS="$LDFLAGS"
 418         LIBS="$LIBS -lgen -lacid -ldb"
 419         MANTYPE=cat
 420         ;;
 421 *-*-unicos*)
 422         AC_DEFINE(SETEUID_BREAKS_SETUID)
 423         AC_DEFINE(BROKEN_SETREUID)
 424         AC_DEFINE(BROKEN_SETREGID)
 425         AC_DEFINE(USE_PIPES)
 426         AC_DEFINE(DISABLE_FD_PASSING)
 427         AC_DEFINE(NO_SSH_LASTLOG)
 428         LDFLAGS="$LDFLAGS -Wl,-Dmsglevel=334:fatal"
 429         LIBS="$LIBS -lgen -lrsc -lshare -luex -lacm"
 430         MANTYPE=cat
 431         ;;
 432 *-dec-osf*)
 433         AC_MSG_CHECKING(for Digital Unix SIA)
 434         no_osfsia=""
 435         AC_ARG_WITH(osfsia,
 436                 [  --with-osfsia           Enable Digital Unix SIA],
 437                 [
 438                         if test "x$withval" = "xno" ; then
 439                                 AC_MSG_RESULT(disabled)
 440                                 no_osfsia=1
 441                         fi
 442                 ],
 443         )
 444         if test -z "$no_osfsia" ; then
 445                 if test -f /etc/sia/matrix.conf; then
 446                         AC_MSG_RESULT(yes)
 447                         AC_DEFINE(HAVE_OSF_SIA)
 448                         AC_DEFINE(DISABLE_LOGIN)
 449                         AC_DEFINE(DISABLE_FD_PASSING)
 450                         LIBS="$LIBS -lsecurity -ldb -lm -laud"
 451                 else
 452                         AC_MSG_RESULT(no)
 453                         AC_DEFINE(LOCKED_PASSWD_SUBSTR, "Nologin")
 454                 fi
 455         fi
 456         AC_DEFINE(BROKEN_GETADDRINFO)
 457         AC_DEFINE(SETEUID_BREAKS_SETUID)
 458         AC_DEFINE(BROKEN_SETREUID)
 459         AC_DEFINE(BROKEN_SETREGID)
 460         ;;
 461
 462 *-*-nto-qnx)
 463         AC_DEFINE(USE_PIPES)
 464         AC_DEFINE(NO_X11_UNIX_SOCKETS)
 465         AC_DEFINE(MISSING_NFDBITS)
 466         AC_DEFINE(MISSING_HOWMANY)
 467         AC_DEFINE(MISSING_FD_MASK)
 468         ;;
 469 esac
 470
 471 # Allow user to specify flags
 472 AC_ARG_WITH(cflags,
 473         [  --with-cflags           Specify additional flags to pass to compiler],
 474         [
 475                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
 476                     test "x${withval}" != "xyes"; then
 477                         CFLAGS="$CFLAGS $withval"
 478                 fi
 479         ]
 480 )
 481 AC_ARG_WITH(cppflags,
 482         [  --with-cppflags         Specify additional flags to pass to preprocessor] ,
 483         [
 484                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
 485                     test "x${withval}" != "xyes"; then
 486                         CPPFLAGS="$CPPFLAGS $withval"
 487                 fi
 488         ]
 489 )
 490 AC_ARG_WITH(ldflags,
 491         [  --with-ldflags          Specify additional flags to pass to linker],
 492         [
 493                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
 494                     test "x${withval}" != "xyes"; then
 495                         LDFLAGS="$LDFLAGS $withval"
 496                 fi
 497         ]
 498 )
 499 AC_ARG_WITH(libs,
 500         [  --with-libs             Specify additional libraries to link with],
 501         [
 502                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
 503                     test "x${withval}" != "xyes"; then
 504                         LIBS="$LIBS $withval"
 505                 fi
 506         ]
 507 )
 508
 509 AC_MSG_CHECKING(compiler and flags for sanity)
 510 AC_RUN_IFELSE(
 511         [AC_LANG_SOURCE([
 512 #include <stdio.h>
 513 int main(){exit(0);}
 514         ])],
 515         [       AC_MSG_RESULT(yes) ],
 516         [
 517                 AC_MSG_RESULT(no)
 518                 AC_MSG_ERROR([*** compiler cannot create working executables, check config.log ***])
 519         ],
 520         [       AC_MSG_WARN([cross compiling: not checking compiler sanity]) ]
 521 )
 522
 523 # Checks for header files.
 524 AC_CHECK_HEADERS(bstring.h crypt.h dirent.h endian.h features.h \
 525         floatingpoint.h getopt.h glob.h ia.h lastlog.h limits.h login.h \
 526         login_cap.h maillock.h ndir.h netdb.h netgroup.h \
 527         netinet/in_systm.h pam/pam_appl.h paths.h pty.h readpassphrase.h \
 528         rpc/types.h security/pam_appl.h shadow.h stddef.h stdint.h \
 529         strings.h sys/dir.h sys/strtio.h sys/audit.h sys/bitypes.h \
 530         sys/bsdtty.h sys/cdefs.h sys/mman.h sys/ndir.h sys/prctl.h \
 531         sys/pstat.h sys/select.h sys/stat.h sys/stream.h \
 532         sys/stropts.h sys/sysmacros.h sys/time.h sys/timers.h sys/un.h \
 533         time.h tmpdir.h ttyent.h usersec.h util.h utime.h utmp.h utmpx.h vis.h)
 534
 535 # sys/ptms.h requires sys/stream.h to be included first on Solaris
 536 AC_CHECK_HEADERS(sys/ptms.h, [], [], [
 537 #ifdef HAVE_SYS_STREAM_H
 538 # include <sys/stream.h>
 539 #endif
 540 ])
 541
 542 # Checks for libraries.
 543 AC_CHECK_FUNC(yp_match, , AC_CHECK_LIB(nsl, yp_match))
 544 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 545
 546 dnl IRIX and Solaris 2.5.1 have dirname() in libgen
 547 AC_CHECK_FUNCS(dirname, [AC_CHECK_HEADERS(libgen.h)] ,[
 548         AC_CHECK_LIB(gen, dirname,[
 549                 AC_CACHE_CHECK([for broken dirname],
 550                         ac_cv_have_broken_dirname, [
 551                         save_LIBS="$LIBS"
 552                         LIBS="$LIBS -lgen"
 553                         AC_TRY_RUN(
 554                                 [
 555 #include <libgen.h>
 556 #include <string.h>
 557
 558 int main(int argc, char **argv) {
 559     char *s, buf[32];
 560
 561     strncpy(buf,"/etc", 32);
 562     s = dirname(buf);
 563     if (!s || strncmp(s, "/", 32) != 0) {
 564         exit(1);
 565     } else {
 566         exit(0);
 567     }
 568 }
 569                                 ],
 570                                 [ ac_cv_have_broken_dirname="no" ],
 571                                 [ ac_cv_have_broken_dirname="yes" ]
 572                         )
 573                         LIBS="$save_LIBS"
 574                 ])
 575                 if test "x$ac_cv_have_broken_dirname" = "xno" ; then
 576                         LIBS="$LIBS -lgen"
 577                         AC_DEFINE(HAVE_DIRNAME)
 578                         AC_CHECK_HEADERS(libgen.h)
 579                 fi
 580         ])
 581 ])
 582
 583 AC_CHECK_FUNC(getspnam, ,
 584         AC_CHECK_LIB(gen, getspnam, LIBS="$LIBS -lgen"))
 585 AC_SEARCH_LIBS(basename, gen, AC_DEFINE(HAVE_BASENAME))
 586
 587 dnl zlib is required
 588 AC_ARG_WITH(zlib,
 589         [  --with-zlib=PATH        Use zlib in PATH],
 590         [ if test "x$withval" = "xno" ; then
 591                 AC_MSG_ERROR([*** zlib is required ***])
 592           elif test "x$withval" != "xyes"; then
 593                 if test -d "$withval/lib"; then
 594                         if test -n "${need_dash_r}"; then
 595                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 596                         else
 597                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 598                         fi
 599                 else
 600                         if test -n "${need_dash_r}"; then
 601                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 602                         else
 603                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 604                         fi
 605                 fi
 606                 if test -d "$withval/include"; then
 607                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 608                 else
 609                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 610                 fi
 611         fi ]
 612 )
 613
 614 AC_CHECK_LIB(z, deflate, ,
 615         [
 616                 saved_CPPFLAGS="$CPPFLAGS"
 617                 saved_LDFLAGS="$LDFLAGS"
 618                 save_LIBS="$LIBS"
 619                 dnl Check default zlib install dir
 620                 if test -n "${need_dash_r}"; then
 621                         LDFLAGS="-L/usr/local/lib -R/usr/local/lib ${saved_LDFLAGS}"
 622                 else
 623                         LDFLAGS="-L/usr/local/lib ${saved_LDFLAGS}"
 624                 fi
 625                 CPPFLAGS="-I/usr/local/include ${saved_CPPFLAGS}"
 626                 LIBS="$LIBS -lz"
 627                 AC_TRY_LINK_FUNC(deflate, AC_DEFINE(HAVE_LIBZ),
 628                         [
 629                                 AC_MSG_ERROR([*** zlib missing - please install first or check config.log ***])
 630                         ]
 631                 )
 632         ]
 633 )
 634 AC_CHECK_HEADER([zlib.h], ,AC_MSG_ERROR([*** zlib.h missing - please install first or check config.log ***]))
 635
 636 AC_ARG_WITH(zlib-version-check,
 637         [  --without-zlib-version-check Disable zlib version check],
 638         [  if test "x$withval" = "xno" ; then
 639                 zlib_check_nonfatal=1
 640            fi
 641         ]
 642 )
 643
 644 AC_MSG_CHECKING(for zlib 1.1.4 or greater)
 645 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 646 #include <zlib.h>
 647 int main()
 648 {
 649         int a, b, c, v;
 650         if (sscanf(ZLIB_VERSION, "%d.%d.%d", &a, &b, &c) != 3)
 651                 exit(1);
 652         v = a*1000000 + b*1000 + c;
 653         if (v >= 1001004)
 654                 exit(0);
 655         exit(2);
 656 }
 657         ]])],
 658         AC_MSG_RESULT(yes),
 659         [ AC_MSG_RESULT(no)
 660           if test -z "$zlib_check_nonfatal" ; then
 661                 AC_MSG_ERROR([*** zlib too old - check config.log ***
 662 Your reported zlib version has known security problems.  It's possible your
 663 vendor has fixed these problems without changing the version number.  If you
 664 are sure this is the case, you can disable the check by running
 665 "./configure --without-zlib-version-check".
 666 If you are in doubt, upgrade zlib to version 1.1.4 or greater.])
 667           else
 668                 AC_MSG_WARN([zlib version may have security problems])
 669           fi
 670         ],
 671         [       AC_MSG_WARN([cross compiling: not checking zlib version]) ]
 672 )
 673
 674 dnl UnixWare 2.x
 675 AC_CHECK_FUNC(strcasecmp,
 676         [], [ AC_CHECK_LIB(resolv, strcasecmp, LIBS="$LIBS -lresolv") ]
 677 )
 678 AC_CHECK_FUNC(utimes,
 679         [], [ AC_CHECK_LIB(c89, utimes, [AC_DEFINE(HAVE_UTIMES)
 680                                         LIBS="$LIBS -lc89"]) ]
 681 )
 682
 683 dnl    Checks for libutil functions
 684 AC_CHECK_HEADERS(libutil.h)
 685 AC_SEARCH_LIBS(login, util bsd, [AC_DEFINE(HAVE_LOGIN)])
 686 AC_CHECK_FUNCS(logout updwtmp logwtmp)
 687
 688 AC_FUNC_STRFTIME
 689
 690 # Check for ALTDIRFUNC glob() extension
 691 AC_MSG_CHECKING(for GLOB_ALTDIRFUNC support)
 692 AC_EGREP_CPP(FOUNDIT,
 693         [
 694                 #include <glob.h>
 695                 #ifdef GLOB_ALTDIRFUNC
 696                 FOUNDIT
 697                 #endif
 698         ],
 699         [
 700                 AC_DEFINE(GLOB_HAS_ALTDIRFUNC)
 701                 AC_MSG_RESULT(yes)
 702         ],
 703         [
 704                 AC_MSG_RESULT(no)
 705         ]
 706 )
 707
 708 # Check for g.gl_matchc glob() extension
 709 AC_MSG_CHECKING(for gl_matchc field in glob_t)
 710 AC_EGREP_CPP(FOUNDIT,
 711         [
 712                 #include <glob.h>
 713                 int main(void){glob_t g; g.gl_matchc = 1;}
 714         ],
 715         [
 716                 AC_DEFINE(GLOB_HAS_GL_MATCHC)
 717                 AC_MSG_RESULT(yes)
 718         ],
 719         [
 720                 AC_MSG_RESULT(no)
 721         ]
 722 )
 723
 724 AC_MSG_CHECKING([whether struct dirent allocates space for d_name])
 725 AC_RUN_IFELSE(
 726         [AC_LANG_SOURCE([[
 727 #include <sys/types.h>
 728 #include <dirent.h>
 729 int main(void){struct dirent d;exit(sizeof(d.d_name)<=sizeof(char));}
 730         ]])],
 731         [AC_MSG_RESULT(yes)],
 732         [
 733                 AC_MSG_RESULT(no)
 734                 AC_DEFINE(BROKEN_ONE_BYTE_DIRENT_D_NAME)
 735         ],
 736         [
 737                 AC_MSG_WARN([cross compiling: assuming BROKEN_ONE_BYTE_DIRENT_D_NAME])
 738                 AC_DEFINE(BROKEN_ONE_BYTE_DIRENT_D_NAME)
 739         ]
 740 )
 741
 742 AC_MSG_CHECKING([for /proc/pid/fd directory])
 743 if test -d "/proc/$$/fd" ; then
 744         AC_DEFINE(HAVE_PROC_PID)
 745         AC_MSG_RESULT(yes)
 746 else
 747         AC_MSG_RESULT(no)
 748 fi
 749
 750 # Check whether user wants S/Key support
 751 SKEY_MSG="no"
 752 AC_ARG_WITH(skey,
 753         [  --with-skey[[=PATH]]      Enable S/Key support (optionally in PATH)],
 754         [
 755                 if test "x$withval" != "xno" ; then
 756
 757                         if test "x$withval" != "xyes" ; then
 758                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 759                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 760                         fi
 761
 762                         AC_DEFINE(SKEY)
 763                         LIBS="-lskey $LIBS"
 764                         SKEY_MSG="yes"
 765
 766                         AC_MSG_CHECKING([for s/key support])
 767                         AC_TRY_RUN(
 768                                 [
 769 #include <stdio.h>
 770 #include <skey.h>
 771 int main() { char *ff = skey_keyinfo(""); ff=""; exit(0); }
 772                                 ],
 773                                 [AC_MSG_RESULT(yes)],
 774                                 [
 775                                         AC_MSG_RESULT(no)
 776                                         AC_MSG_ERROR([** Incomplete or missing s/key libraries.])
 777                                 ])
 778                         AC_MSG_CHECKING(if skeychallenge takes 4 arguments)
 779                         AC_TRY_COMPILE(
 780                                 [#include <stdio.h>
 781                                  #include <skey.h>],
 782                                 [(void)skeychallenge(NULL,"name","",0);],
 783                                 [AC_MSG_RESULT(yes)
 784                                  AC_DEFINE(SKEYCHALLENGE_4ARG)],
 785                                 [AC_MSG_RESULT(no)]
 786                         )
 787                 fi
 788         ]
 789 )
 790
 791 # Check whether user wants TCP wrappers support
 792 TCPW_MSG="no"
 793 AC_ARG_WITH(tcp-wrappers,
 794         [  --with-tcp-wrappers[[=PATH]] Enable tcpwrappers support (optionally in PATH)],
 795         [
 796                 if test "x$withval" != "xno" ; then
 797                         saved_LIBS="$LIBS"
 798                         saved_LDFLAGS="$LDFLAGS"
 799                         saved_CPPFLAGS="$CPPFLAGS"
 800                         if test -n "${withval}" && \
 801                             test "x${withval}" != "xyes"; then
 802                                 if test -d "${withval}/lib"; then
 803                                         if test -n "${need_dash_r}"; then
 804                                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 805                                         else
 806                                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 807                                         fi
 808                                 else
 809                                         if test -n "${need_dash_r}"; then
 810                                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 811                                         else
 812                                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 813                                         fi
 814                                 fi
 815                                 if test -d "${withval}/include"; then
 816                                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 817                                 else
 818                                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 819                                 fi
 820                         fi
 821                         LIBWRAP="-lwrap"
 822                         LIBS="$LIBWRAP $LIBS"
 823                         AC_MSG_CHECKING(for libwrap)
 824                         AC_TRY_LINK(
 825                                 [
 826 #include <sys/types.h>
 827 #include <sys/socket.h>
 828 #include <netinet/in.h>
 829 #include <tcpd.h>
 830                                         int deny_severity = 0, allow_severity = 0;
 831                                 ],
 832                                 [hosts_access(0);],
 833                                 [
 834                                         AC_MSG_RESULT(yes)
 835                                         AC_DEFINE(LIBWRAP)
 836                                         AC_SUBST(LIBWRAP)
 837                                         TCPW_MSG="yes"
 838                                 ],
 839                                 [
 840                                         AC_MSG_ERROR([*** libwrap missing])
 841                                 ]
 842                         )
 843                         LIBS="$saved_LIBS"
 844                 fi
 845         ]
 846 )
 847
 848 # Check whether user wants libedit support
 849 LIBEDIT_MSG="no"
 850 AC_ARG_WITH(libedit,
 851         [  --with-libedit[[=PATH]]   Enable libedit support for sftp],
 852         [ if test "x$withval" != "xno" ; then
 853                 if test "x$withval" != "xyes"; then
 854                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 855                         LDFLAGS="$LDFLAGS -L$withval/lib"
 856                 fi
 857                 AC_CHECK_LIB(edit, el_init,
 858                         [ AC_DEFINE(USE_LIBEDIT, [], [Use libedit for sftp])
 859                           LIBEDIT="-ledit -lcurses"
 860                           LIBEDIT_MSG="yes"
 861                           AC_SUBST(LIBEDIT)
 862                         ],
 863                         [ AC_MSG_ERROR(libedit not found) ],
 864                         [ -lcurses ]
 865                 )
 866         fi ]
 867 )
 868
 869 AUDIT_MODULE=none
 870 AC_ARG_WITH(audit,
 871         [  --with-audit=module     Enable EXPERIMENTAL audit support (modules=debug,bsm)],
 872         [
 873           AC_MSG_CHECKING(for supported audit module)
 874           case "$withval" in
 875           bsm)
 876                 AC_MSG_RESULT(bsm)
 877                 AUDIT_MODULE=bsm
 878                 dnl    Checks for headers, libs and functions
 879                 AC_CHECK_HEADERS(bsm/audit.h, [],
 880                     [AC_MSG_ERROR(BSM enabled and bsm/audit.h not found)])
 881                 AC_CHECK_LIB(bsm, getaudit, [],
 882                     [AC_MSG_ERROR(BSM enabled and required library not found)])
 883                 AC_CHECK_FUNCS(getaudit, [],
 884                     [AC_MSG_ERROR(BSM enabled and required function not found)])
 885                 # These are optional
 886                 AC_CHECK_FUNCS(getaudit_addr)
 887                 AC_DEFINE(USE_BSM_AUDIT, [], [Use BSM audit module])
 888                 ;;
 889           debug)
 890                 AUDIT_MODULE=debug
 891                 AC_MSG_RESULT(debug)
 892                 AC_DEFINE(SSH_AUDIT_EVENTS, [], Use audit debugging module)
 893                 ;;
 894           *)
 895                 AC_MSG_ERROR([Unknown audit module $withval])
 896                 ;;
 897         esac ]
 898 )
 899
 900 dnl    Checks for library functions. Please keep in alphabetical order
 901 AC_CHECK_FUNCS(\
 902         arc4random __b64_ntop b64_ntop __b64_pton b64_pton bcopy \
 903         bindresvport_sa clock closefrom dirfd fchdir fchmod fchown \
 904         freeaddrinfo futimes getaddrinfo getcwd getgrouplist getnameinfo \
 905         getopt getpeereid _getpty getrlimit getttyent glob inet_aton \
 906         inet_ntoa inet_ntop innetgr login_getcapbool md5_crypt memmove \
 907         mkdtemp mmap ngetaddrinfo nsleep ogetaddrinfo openlog_r openpty \
 908         pstat prctl readpassphrase realpath recvmsg rresvport_af sendmsg \
 909         setdtablesize setegid setenv seteuid setgroups setlogin setpcred \
 910         setproctitle setregid setreuid setrlimit \
 911         setsid setvbuf sigaction sigvec snprintf socketpair strerror \
 912         strlcat strlcpy strmode strnvis strtoul sysconf tcgetpgrp \
 913         truncate unsetenv updwtmpx utimes vhangup vsnprintf waitpid \
 914 )
 915
 916 # IRIX has a const char return value for gai_strerror()
 917 AC_CHECK_FUNCS(gai_strerror,[
 918         AC_DEFINE(HAVE_GAI_STRERROR)
 919         AC_TRY_COMPILE([
 920 #include <sys/types.h>
 921 #include <sys/socket.h>
 922 #include <netdb.h>
 923
 924 const char *gai_strerror(int);],[
 925 char *str;
 926
 927 str = gai_strerror(0);],[
 928                 AC_DEFINE(HAVE_CONST_GAI_STRERROR_PROTO, 1,
 929                 [Define if gai_strerror() returns const char *])])])
 930
 931 AC_SEARCH_LIBS(nanosleep, rt posix4, AC_DEFINE(HAVE_NANOSLEEP))
 932
 933 dnl Make sure prototypes are defined for these before using them.
 934 AC_CHECK_DECL(strsep, [AC_CHECK_FUNCS(strsep)])
 935 AC_CHECK_DECL(getrusage, [AC_CHECK_FUNCS(getrusage)])
 936
 937 dnl tcsendbreak might be a macro
 938 AC_CHECK_DECL(tcsendbreak,
 939         [AC_DEFINE(HAVE_TCSENDBREAK)],
 940         [AC_CHECK_FUNCS(tcsendbreak)],
 941         [#include <termios.h>]
 942 )
 943
 944 AC_CHECK_DECLS(h_errno, , ,[#include <netdb.h>])
 945
 946 AC_CHECK_FUNCS(setresuid, [
 947         dnl Some platorms have setresuid that isn't implemented, test for this
 948         AC_MSG_CHECKING(if setresuid seems to work)
 949         AC_RUN_IFELSE(
 950                 [AC_LANG_SOURCE([[
 951 #include <stdlib.h>
 952 #include <errno.h>
 953 int main(){errno=0; setresuid(0,0,0); if (errno==ENOSYS) exit(1); else exit(0);}
 954                 ]])],
 955                 [AC_MSG_RESULT(yes)],
 956                 [AC_DEFINE(BROKEN_SETRESUID)
 957                  AC_MSG_RESULT(not implemented)],
 958                 [AC_MSG_WARN([cross compiling: not checking setresuid])]
 959         )
 960 ])
 961
 962 AC_CHECK_FUNCS(setresgid, [
 963         dnl Some platorms have setresgid that isn't implemented, test for this
 964         AC_MSG_CHECKING(if setresgid seems to work)
 965         AC_RUN_IFELSE(
 966                 [AC_LANG_SOURCE([[
 967 #include <stdlib.h>
 968 #include <errno.h>
 969 int main(){errno=0; setresgid(0,0,0); if (errno==ENOSYS) exit(1); else exit(0);}
 970                 ]])],
 971                 [AC_MSG_RESULT(yes)],
 972                 [AC_DEFINE(BROKEN_SETRESGID)
 973                  AC_MSG_RESULT(not implemented)],
 974                 [AC_MSG_WARN([cross compiling: not checking setresuid])]
 975         )
 976 ])
 977
 978 dnl    Checks for time functions
 979 AC_CHECK_FUNCS(gettimeofday time)
 980 dnl    Checks for utmp functions
 981 AC_CHECK_FUNCS(endutent getutent getutid getutline pututline setutent)
 982 AC_CHECK_FUNCS(utmpname)
 983 dnl    Checks for utmpx functions
 984 AC_CHECK_FUNCS(endutxent getutxent getutxid getutxline pututxline )
 985 AC_CHECK_FUNCS(setutxent utmpxname)
 986
 987 AC_CHECK_FUNC(daemon,
 988         [AC_DEFINE(HAVE_DAEMON)],
 989         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 990 )
 991
 992 AC_CHECK_FUNC(getpagesize,
 993         [AC_DEFINE(HAVE_GETPAGESIZE)],
 994         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 995 )
 996
 997 # Check for broken snprintf
 998 if test "x$ac_cv_func_snprintf" = "xyes" ; then
 999         AC_MSG_CHECKING([whether snprintf correctly terminates long strings])
1000         AC_RUN_IFELSE(
1001                 [AC_LANG_SOURCE([[
1002 #include <stdio.h>
1003 int main(void){char b[5];snprintf(b,5,"123456789");exit(b[4]!='\0');}
1004                 ]])],
1005                 [AC_MSG_RESULT(yes)],
1006                 [
1007                         AC_MSG_RESULT(no)
1008                         AC_DEFINE(BROKEN_SNPRINTF)
1009                         AC_MSG_WARN([****** Your snprintf() function is broken, complain to your vendor])
1010                 ],
1011                 [ AC_MSG_WARN([cross compiling: Assuming working snprintf()]) ]
1012         )
1013 fi
1014
1015 # Check for missing getpeereid (or equiv) support
1016 NO_PEERCHECK=""
1017 if test "x$ac_cv_func_getpeereid" != "xyes" ; then
1018         AC_MSG_CHECKING([whether system supports SO_PEERCRED getsockopt])
1019         AC_TRY_COMPILE(
1020                 [#include <sys/types.h>
1021                  #include <sys/socket.h>],
1022                 [int i = SO_PEERCRED;],
1023                 [AC_MSG_RESULT(yes)],
1024                 [AC_MSG_RESULT(no)
1025                 NO_PEERCHECK=1]
1026         )
1027 fi
1028
1029 dnl see whether mkstemp() requires XXXXXX
1030 if test "x$ac_cv_func_mkdtemp" = "xyes" ; then
1031 AC_MSG_CHECKING([for (overly) strict mkstemp])
1032 AC_TRY_RUN(
1033         [
1034 #include <stdlib.h>
1035 main() { char template[]="conftest.mkstemp-test";
1036 if (mkstemp(template) == -1)
1037         exit(1);
1038 unlink(template); exit(0);
1039 }
1040         ],
1041         [
1042                 AC_MSG_RESULT(no)
1043         ],
1044         [
1045                 AC_MSG_RESULT(yes)
1046                 AC_DEFINE(HAVE_STRICT_MKSTEMP)
1047         ],
1048         [
1049                 AC_MSG_RESULT(yes)
1050                 AC_DEFINE(HAVE_STRICT_MKSTEMP)
1051         ]
1052 )
1053 fi
1054
1055 dnl make sure that openpty does not reacquire controlling terminal
1056 if test ! -z "$check_for_openpty_ctty_bug"; then
1057         AC_MSG_CHECKING(if openpty correctly handles controlling tty)
1058         AC_TRY_RUN(
1059                 [
1060 #include <stdio.h>
1061 #include <sys/fcntl.h>
1062 #include <sys/types.h>
1063 #include <sys/wait.h>
1064
1065 int
1066 main()
1067 {
1068         pid_t pid;
1069         int fd, ptyfd, ttyfd, status;
1070
1071         pid = fork();
1072         if (pid < 0) {          /* failed */
1073                 exit(1);
1074         } else if (pid > 0) {   /* parent */
1075                 waitpid(pid, &status, 0);
1076                 if (WIFEXITED(status))
1077                         exit(WEXITSTATUS(status));
1078                 else
1079                         exit(2);
1080         } else {                /* child */
1081                 close(0); close(1); close(2);
1082                 setsid();
1083                 openpty(&ptyfd, &ttyfd, NULL, NULL, NULL);
1084                 fd = open("/dev/tty", O_RDWR | O_NOCTTY);
1085                 if (fd >= 0)
1086                         exit(3);        /* Acquired ctty: broken */
1087                 else
1088                         exit(0);        /* Did not acquire ctty: OK */
1089         }
1090 }
1091                 ],
1092                 [
1093                         AC_MSG_RESULT(yes)
1094                 ],
1095                 [
1096                         AC_MSG_RESULT(no)
1097                         AC_DEFINE(SSHD_ACQUIRES_CTTY)
1098                 ]
1099         )
1100 fi
1101
1102 if test "x$ac_cv_func_getaddrinfo" = "xyes" && \
1103     test "x$check_for_hpux_broken_getaddrinfo" = "x1"; then
1104         AC_MSG_CHECKING(if getaddrinfo seems to work)
1105         AC_TRY_RUN(
1106                 [
1107 #include <stdio.h>
1108 #include <sys/socket.h>
1109 #include <netdb.h>
1110 #include <errno.h>
1111 #include <netinet/in.h>
1112
1113 #define TEST_PORT "2222"
1114
1115 int
1116 main(void)
1117 {
1118         int err, sock;
1119         struct addrinfo *gai_ai, *ai, hints;
1120         char ntop[NI_MAXHOST], strport[NI_MAXSERV], *name = NULL;
1121
1122         memset(&hints, 0, sizeof(hints));
1123         hints.ai_family = PF_UNSPEC;
1124         hints.ai_socktype = SOCK_STREAM;
1125         hints.ai_flags = AI_PASSIVE;
1126
1127         err = getaddrinfo(name, TEST_PORT, &hints, &gai_ai);
1128         if (err != 0) {
1129                 fprintf(stderr, "getaddrinfo failed (%s)", gai_strerror(err));
1130                 exit(1);
1131         }
1132
1133         for (ai = gai_ai; ai != NULL; ai = ai->ai_next) {
1134                 if (ai->ai_family != AF_INET6)
1135                         continue;
1136
1137                 err = getnameinfo(ai->ai_addr, ai->ai_addrlen, ntop,
1138                     sizeof(ntop), strport, sizeof(strport),
1139                     NI_NUMERICHOST|NI_NUMERICSERV);
1140
1141                 if (err != 0) {
1142                         if (err == EAI_SYSTEM)
1143                                 perror("getnameinfo EAI_SYSTEM");
1144                         else
1145                                 fprintf(stderr, "getnameinfo failed: %s\n",
1146                                     gai_strerror(err));
1147                         exit(2);
1148                 }
1149
1150                 sock = socket(ai->ai_family, ai->ai_socktype, ai->ai_protocol);
1151                 if (sock < 0)
1152                         perror("socket");
1153                 if (bind(sock, ai->ai_addr, ai->ai_addrlen) < 0) {
1154                         if (errno == EBADF)
1155                                 exit(3);
1156                 }
1157         }
1158         exit(0);
1159 }
1160                 ],
1161                 [
1162                         AC_MSG_RESULT(yes)
1163                 ],
1164                 [
1165                         AC_MSG_RESULT(no)
1166                         AC_DEFINE(BROKEN_GETADDRINFO)
1167                 ]
1168         )
1169 fi
1170
1171 if test "x$ac_cv_func_getaddrinfo" = "xyes" && \
1172     test "x$check_for_aix_broken_getaddrinfo" = "x1"; then
1173         AC_MSG_CHECKING(if getaddrinfo seems to work)
1174         AC_TRY_RUN(
1175                 [
1176 #include <stdio.h>
1177 #include <sys/socket.h>
1178 #include <netdb.h>
1179 #include <errno.h>
1180 #include <netinet/in.h>
1181
1182 #define TEST_PORT "2222"
1183
1184 int
1185 main(void)
1186 {
1187         int err, sock;
1188         struct addrinfo *gai_ai, *ai, hints;
1189         char ntop[NI_MAXHOST], strport[NI_MAXSERV], *name = NULL;
1190
1191         memset(&hints, 0, sizeof(hints));
1192         hints.ai_family = PF_UNSPEC;
1193         hints.ai_socktype = SOCK_STREAM;
1194         hints.ai_flags = AI_PASSIVE;
1195
1196         err = getaddrinfo(name, TEST_PORT, &hints, &gai_ai);
1197         if (err != 0) {
1198                 fprintf(stderr, "getaddrinfo failed (%s)", gai_strerror(err));
1199                 exit(1);
1200         }
1201
1202         for (ai = gai_ai; ai != NULL; ai = ai->ai_next) {
1203                 if (ai->ai_family != AF_INET && ai->ai_family != AF_INET6)
1204                         continue;
1205
1206                 err = getnameinfo(ai->ai_addr, ai->ai_addrlen, ntop,
1207                     sizeof(ntop), strport, sizeof(strport),
1208                     NI_NUMERICHOST|NI_NUMERICSERV);
1209
1210                 if (ai->ai_family == AF_INET && err != 0) {
1211                         perror("getnameinfo");
1212                         exit(2);
1213                 }
1214         }
1215         exit(0);
1216 }
1217                 ],
1218                 [
1219                         AC_MSG_RESULT(yes)
1220                         AC_DEFINE(AIX_GETNAMEINFO_HACK, [],
1221 [Define if you have a getaddrinfo that fails for the all-zeros IPv6 address])
1222                 ],
1223                 [
1224                         AC_MSG_RESULT(no)
1225                         AC_DEFINE(BROKEN_GETADDRINFO)
1226                 ]
1227         )
1228 fi
1229
1230 if test "x$check_for_conflicting_getspnam" = "x1"; then
1231         AC_MSG_CHECKING(for conflicting getspnam in shadow.h)
1232         AC_COMPILE_IFELSE(
1233                 [
1234 #include <shadow.h>
1235 int main(void) {exit(0);}
1236                 ],
1237                 [
1238                         AC_MSG_RESULT(no)
1239                 ],
1240                 [
1241                         AC_MSG_RESULT(yes)
1242                         AC_DEFINE(GETSPNAM_CONFLICTING_DEFS, 1,
1243                             [Conflicting defs for getspnam])
1244                 ]
1245         )
1246 fi
1247
1248 AC_FUNC_GETPGRP
1249
1250 # Check for PAM libs
1251 PAM_MSG="no"
1252 AC_ARG_WITH(pam,
1253         [  --with-pam              Enable PAM support ],
1254         [
1255                 if test "x$withval" != "xno" ; then
1256                         if test "x$ac_cv_header_security_pam_appl_h" != "xyes" && \
1257                            test "x$ac_cv_header_pam_pam_appl_h" != "xyes" ; then
1258                                 AC_MSG_ERROR([PAM headers not found])
1259                         fi
1260
1261                         AC_CHECK_LIB(dl, dlopen, , )
1262                         AC_CHECK_LIB(pam, pam_set_item, , AC_MSG_ERROR([*** libpam missing]))
1263                         AC_CHECK_FUNCS(pam_getenvlist)
1264                         AC_CHECK_FUNCS(pam_putenv)
1265
1266                         PAM_MSG="yes"
1267
1268                         AC_DEFINE(USE_PAM)
1269                         if test $ac_cv_lib_dl_dlopen = yes; then
1270                                 LIBPAM="-lpam -ldl"
1271                         else
1272                                 LIBPAM="-lpam"
1273                         fi
1274                         AC_SUBST(LIBPAM)
1275                 fi
1276         ]
1277 )
1278
1279 # Check for older PAM
1280 if test "x$PAM_MSG" = "xyes" ; then
1281         # Check PAM strerror arguments (old PAM)
1282         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
1283         AC_TRY_COMPILE(
1284                 [
1285 #include <stdlib.h>
1286 #if defined(HAVE_SECURITY_PAM_APPL_H)
1287 #include <security/pam_appl.h>
1288 #elif defined (HAVE_PAM_PAM_APPL_H)
1289 #include <pam/pam_appl.h>
1290 #endif
1291                 ],
1292                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
1293                 [AC_MSG_RESULT(no)],
1294                 [
1295                         AC_DEFINE(HAVE_OLD_PAM)
1296                         AC_MSG_RESULT(yes)
1297                         PAM_MSG="yes (old library)"
1298                 ]
1299         )
1300 fi
1301
1302 # Search for OpenSSL
1303 saved_CPPFLAGS="$CPPFLAGS"
1304 saved_LDFLAGS="$LDFLAGS"
1305 AC_ARG_WITH(ssl-dir,
1306         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
1307         [
1308                 if test "x$withval" != "xno" ; then
1309                         case "$withval" in
1310                                 # Relative paths
1311                                 ./*|../*)       withval="`pwd`/$withval"
1312                         esac
1313                         if test -d "$withval/lib"; then
1314                                 if test -n "${need_dash_r}"; then
1315                                         LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
1316                                 else
1317                                         LDFLAGS="-L${withval}/lib ${LDFLAGS}"
1318                                 fi
1319                         else
1320                                 if test -n "${need_dash_r}"; then
1321                                         LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
1322                                 else
1323                                         LDFLAGS="-L${withval} ${LDFLAGS}"
1324                                 fi
1325                         fi
1326                         if test -d "$withval/include"; then
1327                                 CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
1328                         else
1329                                 CPPFLAGS="-I${withval} ${CPPFLAGS}"
1330                         fi
1331                 fi
1332         ]
1333 )
1334 LIBS="-lcrypto $LIBS"
1335 AC_TRY_LINK_FUNC(RAND_add, AC_DEFINE(HAVE_OPENSSL),
1336         [
1337                 dnl Check default openssl install dir
1338                 if test -n "${need_dash_r}"; then
1339                         LDFLAGS="-L/usr/local/ssl/lib -R/usr/local/ssl/lib ${saved_LDFLAGS}"
1340                 else
1341                         LDFLAGS="-L/usr/local/ssl/lib ${saved_LDFLAGS}"
1342                 fi
1343                 CPPFLAGS="-I/usr/local/ssl/include ${saved_CPPFLAGS}"
1344                 AC_TRY_LINK_FUNC(RAND_add, AC_DEFINE(HAVE_OPENSSL),
1345                         [
1346                                 AC_MSG_ERROR([*** Can't find recent OpenSSL libcrypto (see config.log for details) ***])
1347                         ]
1348                 )
1349         ]
1350 )
1351
1352 # Determine OpenSSL header version
1353 AC_MSG_CHECKING([OpenSSL header version])
1354 AC_RUN_IFELSE(
1355         [AC_LANG_SOURCE([[
1356 #include <stdio.h>
1357 #include <string.h>
1358 #include <openssl/opensslv.h>
1359 #define DATA "conftest.sslincver"
1360 int main(void) {
1361         FILE *fd;
1362         int rc;
1363
1364         fd = fopen(DATA,"w");
1365         if(fd == NULL)
1366                 exit(1);
1367
1368         if ((rc = fprintf(fd ,"%x (%s)\n", OPENSSL_VERSION_NUMBER, OPENSSL_VERSION_TEXT)) <0)
1369                 exit(1);
1370
1371         exit(0);
1372 }
1373         ]])],
1374         [
1375                 ssl_header_ver=`cat conftest.sslincver`
1376                 AC_MSG_RESULT($ssl_header_ver)
1377         ],
1378         [
1379                 AC_MSG_RESULT(not found)
1380                 AC_MSG_ERROR(OpenSSL version header not found.)
1381         ],
1382         [
1383                 AC_MSG_WARN([cross compiling: not checking])
1384         ]
1385 )
1386
1387 # Determine OpenSSL library version
1388 AC_MSG_CHECKING([OpenSSL library version])
1389 AC_RUN_IFELSE(
1390         [AC_LANG_SOURCE([[
1391 #include <stdio.h>
1392 #include <string.h>
1393 #include <openssl/opensslv.h>
1394 #include <openssl/crypto.h>
1395 #define DATA "conftest.ssllibver"
1396 int main(void) {
1397         FILE *fd;
1398         int rc;
1399
1400         fd = fopen(DATA,"w");
1401         if(fd == NULL)
1402                 exit(1);
1403
1404         if ((rc = fprintf(fd ,"%x (%s)\n", SSLeay(), SSLeay_version(SSLEAY_VERSION))) <0)
1405                 exit(1);
1406
1407         exit(0);
1408 }
1409         ]])],
1410         [
1411                 ssl_library_ver=`cat conftest.ssllibver`
1412                 AC_MSG_RESULT($ssl_library_ver)
1413         ],
1414         [
1415                 AC_MSG_RESULT(not found)
1416                 AC_MSG_ERROR(OpenSSL library not found.)
1417         ],
1418         [
1419                 AC_MSG_WARN([cross compiling: not checking])
1420         ]
1421 )
1422
1423 # Sanity check OpenSSL headers
1424 AC_MSG_CHECKING([whether OpenSSL's headers match the library])
1425 AC_RUN_IFELSE(
1426         [AC_LANG_SOURCE([[
1427 #include <string.h>
1428 #include <openssl/opensslv.h>
1429 int main(void) { exit(SSLeay() == OPENSSL_VERSION_NUMBER ? 0 : 1); }
1430         ]])],
1431         [
1432                 AC_MSG_RESULT(yes)
1433         ],
1434         [
1435                 AC_MSG_RESULT(no)
1436                 AC_MSG_ERROR([Your OpenSSL headers do not match your library.
1437 Check config.log for details.
1438 Also see contrib/findssl.sh for help identifying header/library mismatches.])
1439         ],
1440         [
1441                 AC_MSG_WARN([cross compiling: not checking])
1442         ]
1443 )
1444
1445 # Some systems want crypt() from libcrypt, *not* the version in OpenSSL,
1446 # because the system crypt() is more featureful.
1447 if test "x$check_for_libcrypt_before" = "x1"; then
1448         AC_CHECK_LIB(crypt, crypt)
1449 fi
1450
1451 # Some Linux systems (Slackware) need crypt() from libcrypt, *not* the
1452 # version in OpenSSL.
1453 if test "x$check_for_libcrypt_later" = "x1"; then
1454         AC_CHECK_LIB(crypt, crypt, LIBS="$LIBS -lcrypt")
1455 fi
1456
1457
1458 ### Configure cryptographic random number support
1459
1460 # Check wheter OpenSSL seeds itself
1461 AC_MSG_CHECKING([whether OpenSSL's PRNG is internally seeded])
1462 AC_RUN_IFELSE(
1463         [AC_LANG_SOURCE([[
1464 #include <string.h>
1465 #include <openssl/rand.h>
1466 int main(void) { exit(RAND_status() == 1 ? 0 : 1); }
1467         ]])],
1468         [
1469                 OPENSSL_SEEDS_ITSELF=yes
1470                 AC_MSG_RESULT(yes)
1471         ],
1472         [
1473                 AC_MSG_RESULT(no)
1474                 # Default to use of the rand helper if OpenSSL doesn't
1475                 # seed itself
1476                 USE_RAND_HELPER=yes
1477         ],
1478         [
1479                 AC_MSG_WARN([cross compiling: assuming yes])
1480                 # This is safe, since all recent OpenSSL versions will
1481                 # complain at runtime if not seeded correctly.
1482                 OPENSSL_SEEDS_ITSELF=yes
1483         ]
1484 )
1485
1486
1487 # Do we want to force the use of the rand helper?
1488 AC_ARG_WITH(rand-helper,
1489         [  --with-rand-helper      Use subprocess to gather strong randomness ],
1490         [
1491                 if test "x$withval" = "xno" ; then
1492                         # Force use of OpenSSL's internal RNG, even if
1493                         # the previous test showed it to be unseeded.
1494                         if test -z "$OPENSSL_SEEDS_ITSELF" ; then
1495                                 AC_MSG_WARN([*** Forcing use of OpenSSL's non-self-seeding PRNG])
1496                                 OPENSSL_SEEDS_ITSELF=yes
1497                                 USE_RAND_HELPER=""
1498                         fi
1499                 else
1500                         USE_RAND_HELPER=yes
1501                 fi
1502         ],
1503 )
1504
1505 # Which randomness source do we use?
1506 if test ! -z "$OPENSSL_SEEDS_ITSELF" && test -z "$USE_RAND_HELPER" ; then
1507         # OpenSSL only
1508         AC_DEFINE(OPENSSL_PRNG_ONLY)
1509         RAND_MSG="OpenSSL internal ONLY"
1510         INSTALL_SSH_RAND_HELPER=""
1511 elif test ! -z "$USE_RAND_HELPER" ; then
1512         # install rand helper
1513         RAND_MSG="ssh-rand-helper"
1514         INSTALL_SSH_RAND_HELPER="yes"
1515 fi
1516 AC_SUBST(INSTALL_SSH_RAND_HELPER)
1517
1518 ### Configuration of ssh-rand-helper
1519
1520 # PRNGD TCP socket
1521 AC_ARG_WITH(prngd-port,
1522         [  --with-prngd-port=PORT  read entropy from PRNGD/EGD TCP localhost:PORT],
1523         [
1524                 case "$withval" in
1525                 no)
1526                         withval=""
1527                         ;;
1528                 [[0-9]]*)
1529                         ;;
1530                 *)
1531                         AC_MSG_ERROR(You must specify a numeric port number for --with-prngd-port)
1532                         ;;
1533                 esac
1534                 if test ! -z "$withval" ; then
1535                         PRNGD_PORT="$withval"
1536                         AC_DEFINE_UNQUOTED(PRNGD_PORT, $PRNGD_PORT)
1537                 fi
1538         ]
1539 )
1540
1541 # PRNGD Unix domain socket
1542 AC_ARG_WITH(prngd-socket,
1543         [  --with-prngd-socket=FILE read entropy from PRNGD/EGD socket FILE (default=/var/run/egd-pool)],
1544         [
1545                 case "$withval" in
1546                 yes)
1547                         withval="/var/run/egd-pool"
1548                         ;;
1549                 no)
1550                         withval=""
1551                         ;;
1552                 /*)
1553                         ;;
1554                 *)
1555                         AC_MSG_ERROR(You must specify an absolute path to the entropy socket)
1556                         ;;
1557                 esac
1558
1559                 if test ! -z "$withval" ; then
1560                         if test ! -z "$PRNGD_PORT" ; then
1561                                 AC_MSG_ERROR(You may not specify both a PRNGD/EGD port and socket)
1562                         fi
1563                         if test ! -r "$withval" ; then
1564                                 AC_MSG_WARN(Entropy socket is not readable)
1565                         fi
1566                         PRNGD_SOCKET="$withval"
1567                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1568                 fi
1569         ],
1570         [
1571                 # Check for existing socket only if we don't have a random device already
1572                 if test "$USE_RAND_HELPER" = yes ; then
1573                         AC_MSG_CHECKING(for PRNGD/EGD socket)
1574                         # Insert other locations here
1575                         for sock in /var/run/egd-pool /dev/egd-pool /etc/entropy; do
1576                                 if test -r $sock && $TEST_MINUS_S_SH -c "test -S $sock -o -p $sock" ; then
1577                                         PRNGD_SOCKET="$sock"
1578                                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1579                                         break;
1580                                 fi
1581                         done
1582                         if test ! -z "$PRNGD_SOCKET" ; then
1583                                 AC_MSG_RESULT($PRNGD_SOCKET)
1584                         else
1585                                 AC_MSG_RESULT(not found)
1586                         fi
1587                 fi
1588         ]
1589 )
1590
1591 # Change default command timeout for hashing entropy source
1592 entropy_timeout=200
1593 AC_ARG_WITH(entropy-timeout,
1594         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
1595         [
1596                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
1597                     test "x${withval}" != "xyes"; then
1598                         entropy_timeout=$withval
1599                 fi
1600         ]
1601 )
1602 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
1603
1604 SSH_PRIVSEP_USER=sshd
1605 AC_ARG_WITH(privsep-user,
1606         [  --with-privsep-user=user Specify non-privileged user for privilege separation],
1607         [
1608                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
1609                     test "x${withval}" != "xyes"; then
1610                         SSH_PRIVSEP_USER=$withval
1611                 fi
1612         ]
1613 )
1614 AC_DEFINE_UNQUOTED(SSH_PRIVSEP_USER, "$SSH_PRIVSEP_USER")
1615 AC_SUBST(SSH_PRIVSEP_USER)
1616
1617 # We do this little dance with the search path to insure
1618 # that programs that we select for use by installed programs
1619 # (which may be run by the super-user) come from trusted
1620 # locations before they come from the user's private area.
1621 # This should help avoid accidentally configuring some
1622 # random version of a program in someone's personal bin.
1623
1624 OPATH=$PATH
1625 PATH=/bin:/usr/bin
1626 test -h /bin 2> /dev/null && PATH=/usr/bin
1627 test -d /sbin && PATH=$PATH:/sbin
1628 test -d /usr/sbin && PATH=$PATH:/usr/sbin
1629 PATH=$PATH:/etc:$OPATH
1630
1631 # These programs are used by the command hashing source to gather entropy
1632 OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1633 OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
1634 OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
1635 OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
1636 OSSH_PATH_ENTROPY_PROG(PROG_JSTAT, jstat)
1637 OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
1638 OSSH_PATH_ENTROPY_PROG(PROG_SAR, sar)
1639 OSSH_PATH_ENTROPY_PROG(PROG_W, w)
1640 OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
1641 OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
1642 OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
1643 OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
1644 OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
1645 OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
1646 OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
1647 OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
1648 # restore PATH
1649 PATH=$OPATH
1650
1651 # Where does ssh-rand-helper get its randomness from?
1652 INSTALL_SSH_PRNG_CMDS=""
1653 if test ! -z "$INSTALL_SSH_RAND_HELPER" ; then
1654         if test ! -z "$PRNGD_PORT" ; then
1655                 RAND_HELPER_MSG="TCP localhost:$PRNGD_PORT"
1656         elif test ! -z "$PRNGD_SOCKET" ; then
1657                 RAND_HELPER_MSG="Unix domain socket \"$PRNGD_SOCKET\""
1658         else
1659                 RAND_HELPER_MSG="Command hashing (timeout $entropy_timeout)"
1660                 RAND_HELPER_CMDHASH=yes
1661                 INSTALL_SSH_PRNG_CMDS="yes"
1662         fi
1663 fi
1664 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
1665
1666
1667 # Cheap hack to ensure NEWS-OS libraries are arranged right.
1668 if test ! -z "$SONY" ; then
1669   LIBS="$LIBS -liberty";
1670 fi
1671
1672 # Checks for data types
1673 AC_CHECK_SIZEOF(char, 1)
1674 AC_CHECK_SIZEOF(short int, 2)
1675 AC_CHECK_SIZEOF(int, 4)
1676 AC_CHECK_SIZEOF(long int, 4)
1677 AC_CHECK_SIZEOF(long long int, 8)
1678
1679 # Sanity check long long for some platforms (AIX)
1680 if test "x$ac_cv_sizeof_long_long_int" = "x4" ; then
1681         ac_cv_sizeof_long_long_int=0
1682 fi
1683
1684 # More checks for data types
1685 AC_CACHE_CHECK([for u_int type], ac_cv_have_u_int, [
1686         AC_TRY_COMPILE(
1687                 [ #include <sys/types.h> ],
1688                 [ u_int a; a = 1;],
1689                 [ ac_cv_have_u_int="yes" ],
1690                 [ ac_cv_have_u_int="no" ]
1691         )
1692 ])
1693 if test "x$ac_cv_have_u_int" = "xyes" ; then
1694         AC_DEFINE(HAVE_U_INT)
1695         have_u_int=1
1696 fi
1697
1698 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
1699         AC_TRY_COMPILE(
1700                 [ #include <sys/types.h> ],
1701                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
1702                 [ ac_cv_have_intxx_t="yes" ],
1703                 [ ac_cv_have_intxx_t="no" ]
1704         )
1705 ])
1706 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
1707         AC_DEFINE(HAVE_INTXX_T)
1708         have_intxx_t=1
1709 fi
1710
1711 if (test -z "$have_intxx_t" && \
1712            test "x$ac_cv_header_stdint_h" = "xyes")
1713 then
1714     AC_MSG_CHECKING([for intXX_t types in stdint.h])
1715         AC_TRY_COMPILE(
1716                 [ #include <stdint.h> ],
1717                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
1718                 [
1719                         AC_DEFINE(HAVE_INTXX_T)
1720                         AC_MSG_RESULT(yes)
1721                 ],
1722                 [ AC_MSG_RESULT(no) ]
1723         )
1724 fi
1725
1726 AC_CACHE_CHECK([for int64_t type], ac_cv_have_int64_t, [
1727         AC_TRY_COMPILE(
1728                 [
1729 #include <sys/types.h>
1730 #ifdef HAVE_STDINT_H
1731 # include <stdint.h>
1732 #endif
1733 #include <sys/socket.h>
1734 #ifdef HAVE_SYS_BITYPES_H
1735 # include <sys/bitypes.h>
1736 #endif
1737                 ],
1738                 [ int64_t a; a = 1;],
1739                 [ ac_cv_have_int64_t="yes" ],
1740                 [ ac_cv_have_int64_t="no" ]
1741         )
1742 ])
1743 if test "x$ac_cv_have_int64_t" = "xyes" ; then
1744         AC_DEFINE(HAVE_INT64_T)
1745 fi
1746
1747 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
1748         AC_TRY_COMPILE(
1749                 [ #include <sys/types.h> ],
1750                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
1751                 [ ac_cv_have_u_intxx_t="yes" ],
1752                 [ ac_cv_have_u_intxx_t="no" ]
1753         )
1754 ])
1755 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
1756         AC_DEFINE(HAVE_U_INTXX_T)
1757         have_u_intxx_t=1
1758 fi
1759
1760 if test -z "$have_u_intxx_t" ; then
1761     AC_MSG_CHECKING([for u_intXX_t types in sys/socket.h])
1762         AC_TRY_COMPILE(
1763                 [ #include <sys/socket.h> ],
1764                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
1765                 [
1766                         AC_DEFINE(HAVE_U_INTXX_T)
1767                         AC_MSG_RESULT(yes)
1768                 ],
1769                 [ AC_MSG_RESULT(no) ]
1770         )
1771 fi
1772
1773 AC_CACHE_CHECK([for u_int64_t types], ac_cv_have_u_int64_t, [
1774         AC_TRY_COMPILE(
1775                 [ #include <sys/types.h> ],
1776                 [ u_int64_t a; a = 1;],
1777                 [ ac_cv_have_u_int64_t="yes" ],
1778                 [ ac_cv_have_u_int64_t="no" ]
1779         )
1780 ])
1781 if test "x$ac_cv_have_u_int64_t" = "xyes" ; then
1782         AC_DEFINE(HAVE_U_INT64_T)
1783         have_u_int64_t=1
1784 fi
1785
1786 if test -z "$have_u_int64_t" ; then
1787     AC_MSG_CHECKING([for u_int64_t type in sys/bitypes.h])
1788         AC_TRY_COMPILE(
1789                 [ #include <sys/bitypes.h> ],
1790                 [ u_int64_t a; a = 1],
1791                 [
1792                         AC_DEFINE(HAVE_U_INT64_T)
1793                         AC_MSG_RESULT(yes)
1794                 ],
1795                 [ AC_MSG_RESULT(no) ]
1796         )
1797 fi
1798
1799 if test -z "$have_u_intxx_t" ; then
1800         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
1801                 AC_TRY_COMPILE(
1802                         [
1803 #include <sys/types.h>
1804                         ],
1805                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
1806                         [ ac_cv_have_uintxx_t="yes" ],
1807                         [ ac_cv_have_uintxx_t="no" ]
1808                 )
1809         ])
1810         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
1811                 AC_DEFINE(HAVE_UINTXX_T)
1812         fi
1813 fi
1814
1815 if test -z "$have_uintxx_t" ; then
1816     AC_MSG_CHECKING([for uintXX_t types in stdint.h])
1817         AC_TRY_COMPILE(
1818                 [ #include <stdint.h> ],
1819                 [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1;],
1820                 [
1821                         AC_DEFINE(HAVE_UINTXX_T)
1822                         AC_MSG_RESULT(yes)
1823                 ],
1824                 [ AC_MSG_RESULT(no) ]
1825         )
1826 fi
1827
1828 if (test -z "$have_u_intxx_t" || test -z "$have_intxx_t" && \
1829            test "x$ac_cv_header_sys_bitypes_h" = "xyes")
1830 then
1831         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
1832         AC_TRY_COMPILE(
1833                 [
1834 #include <sys/bitypes.h>
1835                 ],
1836                 [
1837                         int8_t a; int16_t b; int32_t c;
1838                         u_int8_t e; u_int16_t f; u_int32_t g;
1839                         a = b = c = e = f = g = 1;
1840                 ],
1841                 [
1842                         AC_DEFINE(HAVE_U_INTXX_T)
1843                         AC_DEFINE(HAVE_INTXX_T)
1844                         AC_MSG_RESULT(yes)
1845                 ],
1846                 [AC_MSG_RESULT(no)]
1847         )
1848 fi
1849
1850
1851 AC_CACHE_CHECK([for u_char], ac_cv_have_u_char, [
1852         AC_TRY_COMPILE(
1853                 [
1854 #include <sys/types.h>
1855                 ],
1856                 [ u_char foo; foo = 125; ],
1857                 [ ac_cv_have_u_char="yes" ],
1858                 [ ac_cv_have_u_char="no" ]
1859         )
1860 ])
1861 if test "x$ac_cv_have_u_char" = "xyes" ; then
1862         AC_DEFINE(HAVE_U_CHAR)
1863 fi
1864
1865 TYPE_SOCKLEN_T
1866
1867 AC_CHECK_TYPES(sig_atomic_t,,,[#include <signal.h>])
1868
1869 AC_CHECK_TYPES(in_addr_t,,,
1870 [#include <sys/types.h>
1871 #include <netinet/in.h>])
1872
1873 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
1874         AC_TRY_COMPILE(
1875                 [
1876 #include <sys/types.h>
1877                 ],
1878                 [ size_t foo; foo = 1235; ],
1879                 [ ac_cv_have_size_t="yes" ],
1880                 [ ac_cv_have_size_t="no" ]
1881         )
1882 ])
1883 if test "x$ac_cv_have_size_t" = "xyes" ; then
1884         AC_DEFINE(HAVE_SIZE_T)
1885 fi
1886
1887 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
1888         AC_TRY_COMPILE(
1889                 [
1890 #include <sys/types.h>
1891                 ],
1892                 [ ssize_t foo; foo = 1235; ],
1893                 [ ac_cv_have_ssize_t="yes" ],
1894                 [ ac_cv_have_ssize_t="no" ]
1895         )
1896 ])
1897 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
1898         AC_DEFINE(HAVE_SSIZE_T)
1899 fi
1900
1901 AC_CACHE_CHECK([for clock_t], ac_cv_have_clock_t, [
1902         AC_TRY_COMPILE(
1903                 [
1904 #include <time.h>
1905                 ],
1906                 [ clock_t foo; foo = 1235; ],
1907                 [ ac_cv_have_clock_t="yes" ],
1908                 [ ac_cv_have_clock_t="no" ]
1909         )
1910 ])
1911 if test "x$ac_cv_have_clock_t" = "xyes" ; then
1912         AC_DEFINE(HAVE_CLOCK_T)
1913 fi
1914
1915 AC_CACHE_CHECK([for sa_family_t], ac_cv_have_sa_family_t, [
1916         AC_TRY_COMPILE(
1917                 [
1918 #include <sys/types.h>
1919 #include <sys/socket.h>
1920                 ],
1921                 [ sa_family_t foo; foo = 1235; ],
1922                 [ ac_cv_have_sa_family_t="yes" ],
1923                 [ AC_TRY_COMPILE(
1924                   [
1925 #include <sys/types.h>
1926 #include <sys/socket.h>
1927 #include <netinet/in.h>
1928                 ],
1929                 [ sa_family_t foo; foo = 1235; ],
1930                 [ ac_cv_have_sa_family_t="yes" ],
1931
1932                 [ ac_cv_have_sa_family_t="no" ]
1933         )]
1934         )
1935 ])
1936 if test "x$ac_cv_have_sa_family_t" = "xyes" ; then
1937         AC_DEFINE(HAVE_SA_FAMILY_T)
1938 fi
1939
1940 AC_CACHE_CHECK([for pid_t], ac_cv_have_pid_t, [
1941         AC_TRY_COMPILE(
1942                 [
1943 #include <sys/types.h>
1944                 ],
1945                 [ pid_t foo; foo = 1235; ],
1946                 [ ac_cv_have_pid_t="yes" ],
1947                 [ ac_cv_have_pid_t="no" ]
1948         )
1949 ])
1950 if test "x$ac_cv_have_pid_t" = "xyes" ; then
1951         AC_DEFINE(HAVE_PID_T)
1952 fi
1953
1954 AC_CACHE_CHECK([for mode_t], ac_cv_have_mode_t, [
1955         AC_TRY_COMPILE(
1956                 [
1957 #include <sys/types.h>
1958                 ],
1959                 [ mode_t foo; foo = 1235; ],
1960                 [ ac_cv_have_mode_t="yes" ],
1961                 [ ac_cv_have_mode_t="no" ]
1962         )
1963 ])
1964 if test "x$ac_cv_have_mode_t" = "xyes" ; then
1965         AC_DEFINE(HAVE_MODE_T)
1966 fi
1967
1968
1969 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
1970         AC_TRY_COMPILE(
1971                 [
1972 #include <sys/types.h>
1973 #include <sys/socket.h>
1974                 ],
1975                 [ struct sockaddr_storage s; ],
1976                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
1977                 [ ac_cv_have_struct_sockaddr_storage="no" ]
1978         )
1979 ])
1980 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
1981         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
1982 fi
1983
1984 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
1985         AC_TRY_COMPILE(
1986                 [
1987 #include <sys/types.h>
1988 #include <netinet/in.h>
1989                 ],
1990                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
1991                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
1992                 [ ac_cv_have_struct_sockaddr_in6="no" ]
1993         )
1994 ])
1995 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
1996         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
1997 fi
1998
1999 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
2000         AC_TRY_COMPILE(
2001                 [
2002 #include <sys/types.h>
2003 #include <netinet/in.h>
2004                 ],
2005                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
2006                 [ ac_cv_have_struct_in6_addr="yes" ],
2007                 [ ac_cv_have_struct_in6_addr="no" ]
2008         )
2009 ])
2010 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
2011         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
2012 fi
2013
2014 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
2015         AC_TRY_COMPILE(
2016                 [
2017 #include <sys/types.h>
2018 #include <sys/socket.h>
2019 #include <netdb.h>
2020                 ],
2021                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
2022                 [ ac_cv_have_struct_addrinfo="yes" ],
2023                 [ ac_cv_have_struct_addrinfo="no" ]
2024         )
2025 ])
2026 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
2027         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
2028 fi
2029
2030 AC_CACHE_CHECK([for struct timeval], ac_cv_have_struct_timeval, [
2031         AC_TRY_COMPILE(
2032                 [ #include <sys/time.h> ],
2033                 [ struct timeval tv; tv.tv_sec = 1;],
2034                 [ ac_cv_have_struct_timeval="yes" ],
2035                 [ ac_cv_have_struct_timeval="no" ]
2036         )
2037 ])
2038 if test "x$ac_cv_have_struct_timeval" = "xyes" ; then
2039         AC_DEFINE(HAVE_STRUCT_TIMEVAL)
2040         have_struct_timeval=1
2041 fi
2042
2043 AC_CHECK_TYPES(struct timespec)
2044
2045 # We need int64_t or else certian parts of the compile will fail.
2046 if test "x$ac_cv_have_int64_t" = "xno" && \
2047         test "x$ac_cv_sizeof_long_int" != "x8" && \
2048         test "x$ac_cv_sizeof_long_long_int" = "x0" ; then
2049         echo "OpenSSH requires int64_t support.  Contact your vendor or install"
2050         echo "an alternative compiler (I.E., GCC) before continuing."
2051         echo ""
2052         exit 1;
2053 else
2054 dnl test snprintf (broken on SCO w/gcc)
2055         AC_RUN_IFELSE(
2056                 [AC_LANG_SOURCE([[
2057 #include <stdio.h>
2058 #include <string.h>
2059 #ifdef HAVE_SNPRINTF
2060 main()
2061 {
2062         char buf[50];
2063         char expected_out[50];
2064         int mazsize = 50 ;
2065 #if (SIZEOF_LONG_INT == 8)
2066         long int num = 0x7fffffffffffffff;
2067 #else
2068         long long num = 0x7fffffffffffffffll;
2069 #endif
2070         strcpy(expected_out, "9223372036854775807");
2071         snprintf(buf, mazsize, "%lld", num);
2072         if(strcmp(buf, expected_out) != 0)
2073                 exit(1);
2074         exit(0);
2075 }
2076 #else
2077 main() { exit(0); }
2078 #endif
2079                 ]])], [ true ], [ AC_DEFINE(BROKEN_SNPRINTF) ],
2080                 AC_MSG_WARN([cross compiling: Assuming working snprintf()])
2081         )
2082 fi
2083
2084 dnl Checks for structure members
2085 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
2086 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
2087 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
2088 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
2089 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
2090 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
2091 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
2092 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
2093 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmpx.h, HAVE_ID_IN_UTMPX)
2094 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
2095 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
2096 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
2097 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
2098 OSSH_CHECK_HEADER_FOR_FIELD(ut_exit, utmp.h, HAVE_EXIT_IN_UTMP)
2099 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmp.h, HAVE_TIME_IN_UTMP)
2100 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmpx.h, HAVE_TIME_IN_UTMPX)
2101 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmpx.h, HAVE_TV_IN_UTMPX)
2102
2103 AC_CHECK_MEMBERS([struct stat.st_blksize])
2104
2105 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
2106                 ac_cv_have_ss_family_in_struct_ss, [
2107         AC_TRY_COMPILE(
2108                 [
2109 #include <sys/types.h>
2110 #include <sys/socket.h>
2111                 ],
2112                 [ struct sockaddr_storage s; s.ss_family = 1; ],
2113                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
2114                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
2115         )
2116 ])
2117 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
2118         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
2119 fi
2120
2121 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
2122                 ac_cv_have___ss_family_in_struct_ss, [
2123         AC_TRY_COMPILE(
2124                 [
2125 #include <sys/types.h>
2126 #include <sys/socket.h>
2127                 ],
2128                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
2129                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
2130                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
2131         )
2132 ])
2133 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
2134         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
2135 fi
2136
2137 AC_CACHE_CHECK([for pw_class field in struct passwd],
2138                 ac_cv_have_pw_class_in_struct_passwd, [
2139         AC_TRY_COMPILE(
2140                 [
2141 #include <pwd.h>
2142                 ],
2143                 [ struct passwd p; p.pw_class = 0; ],
2144                 [ ac_cv_have_pw_class_in_struct_passwd="yes" ],
2145                 [ ac_cv_have_pw_class_in_struct_passwd="no" ]
2146         )
2147 ])
2148 if test "x$ac_cv_have_pw_class_in_struct_passwd" = "xyes" ; then
2149         AC_DEFINE(HAVE_PW_CLASS_IN_PASSWD)
2150 fi
2151
2152 AC_CACHE_CHECK([for pw_expire field in struct passwd],
2153                 ac_cv_have_pw_expire_in_struct_passwd, [
2154         AC_TRY_COMPILE(
2155                 [
2156 #include <pwd.h>
2157                 ],
2158                 [ struct passwd p; p.pw_expire = 0; ],
2159                 [ ac_cv_have_pw_expire_in_struct_passwd="yes" ],
2160                 [ ac_cv_have_pw_expire_in_struct_passwd="no" ]
2161         )
2162 ])
2163 if test "x$ac_cv_have_pw_expire_in_struct_passwd" = "xyes" ; then
2164         AC_DEFINE(HAVE_PW_EXPIRE_IN_PASSWD)
2165 fi
2166
2167 AC_CACHE_CHECK([for pw_change field in struct passwd],
2168                 ac_cv_have_pw_change_in_struct_passwd, [
2169         AC_TRY_COMPILE(
2170                 [
2171 #include <pwd.h>
2172                 ],
2173                 [ struct passwd p; p.pw_change = 0; ],
2174                 [ ac_cv_have_pw_change_in_struct_passwd="yes" ],
2175                 [ ac_cv_have_pw_change_in_struct_passwd="no" ]
2176         )
2177 ])
2178 if test "x$ac_cv_have_pw_change_in_struct_passwd" = "xyes" ; then
2179         AC_DEFINE(HAVE_PW_CHANGE_IN_PASSWD)
2180 fi
2181
2182 dnl make sure we're using the real structure members and not defines
2183 AC_CACHE_CHECK([for msg_accrights field in struct msghdr],
2184                 ac_cv_have_accrights_in_msghdr, [
2185         AC_COMPILE_IFELSE(
2186                 [
2187 #include <sys/types.h>
2188 #include <sys/socket.h>
2189 #include <sys/uio.h>
2190 int main() {
2191 #ifdef msg_accrights
2192 #error "msg_accrights is a macro"
2193 exit(1);
2194 #endif
2195 struct msghdr m;
2196 m.msg_accrights = 0;
2197 exit(0);
2198 }
2199                 ],
2200                 [ ac_cv_have_accrights_in_msghdr="yes" ],
2201                 [ ac_cv_have_accrights_in_msghdr="no" ]
2202         )
2203 ])
2204 if test "x$ac_cv_have_accrights_in_msghdr" = "xyes" ; then
2205         AC_DEFINE(HAVE_ACCRIGHTS_IN_MSGHDR)
2206 fi
2207
2208 AC_CACHE_CHECK([for msg_control field in struct msghdr],
2209                 ac_cv_have_control_in_msghdr, [
2210         AC_COMPILE_IFELSE(
2211                 [
2212 #include <sys/types.h>
2213 #include <sys/socket.h>
2214 #include <sys/uio.h>
2215 int main() {
2216 #ifdef msg_control
2217 #error "msg_control is a macro"
2218 exit(1);
2219 #endif
2220 struct msghdr m;
2221 m.msg_control = 0;
2222 exit(0);
2223 }
2224                 ],
2225                 [ ac_cv_have_control_in_msghdr="yes" ],
2226                 [ ac_cv_have_control_in_msghdr="no" ]
2227         )
2228 ])
2229 if test "x$ac_cv_have_control_in_msghdr" = "xyes" ; then
2230         AC_DEFINE(HAVE_CONTROL_IN_MSGHDR)
2231 fi
2232
2233 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
2234         AC_TRY_LINK([],
2235                 [ extern char *__progname; printf("%s", __progname); ],
2236                 [ ac_cv_libc_defines___progname="yes" ],
2237                 [ ac_cv_libc_defines___progname="no" ]
2238         )
2239 ])
2240 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
2241         AC_DEFINE(HAVE___PROGNAME)
2242 fi
2243
2244 AC_CACHE_CHECK([whether $CC implements __FUNCTION__], ac_cv_cc_implements___FUNCTION__, [
2245         AC_TRY_LINK([
2246 #include <stdio.h>
2247 ],
2248                 [ printf("%s", __FUNCTION__); ],
2249                 [ ac_cv_cc_implements___FUNCTION__="yes" ],
2250                 [ ac_cv_cc_implements___FUNCTION__="no" ]
2251         )
2252 ])
2253 if test "x$ac_cv_cc_implements___FUNCTION__" = "xyes" ; then
2254         AC_DEFINE(HAVE___FUNCTION__)
2255 fi
2256
2257 AC_CACHE_CHECK([whether $CC implements __func__], ac_cv_cc_implements___func__, [
2258         AC_TRY_LINK([
2259 #include <stdio.h>
2260 ],
2261                 [ printf("%s", __func__); ],
2262                 [ ac_cv_cc_implements___func__="yes" ],
2263                 [ ac_cv_cc_implements___func__="no" ]
2264         )
2265 ])
2266 if test "x$ac_cv_cc_implements___func__" = "xyes" ; then
2267         AC_DEFINE(HAVE___func__)
2268 fi
2269
2270 AC_CACHE_CHECK([whether getopt has optreset support],
2271                 ac_cv_have_getopt_optreset, [
2272         AC_TRY_LINK(
2273                 [
2274 #include <getopt.h>
2275                 ],
2276                 [ extern int optreset; optreset = 0; ],
2277                 [ ac_cv_have_getopt_optreset="yes" ],
2278                 [ ac_cv_have_getopt_optreset="no" ]
2279         )
2280 ])
2281 if test "x$ac_cv_have_getopt_optreset" = "xyes" ; then
2282         AC_DEFINE(HAVE_GETOPT_OPTRESET)
2283 fi
2284
2285 AC_CACHE_CHECK([if libc defines sys_errlist], ac_cv_libc_defines_sys_errlist, [
2286         AC_TRY_LINK([],
2287                 [ extern const char *const sys_errlist[]; printf("%s", sys_errlist[0]);],
2288                 [ ac_cv_libc_defines_sys_errlist="yes" ],
2289                 [ ac_cv_libc_defines_sys_errlist="no" ]
2290         )
2291 ])
2292 if test "x$ac_cv_libc_defines_sys_errlist" = "xyes" ; then
2293         AC_DEFINE(HAVE_SYS_ERRLIST)
2294 fi
2295
2296
2297 AC_CACHE_CHECK([if libc defines sys_nerr], ac_cv_libc_defines_sys_nerr, [
2298         AC_TRY_LINK([],
2299                 [ extern int sys_nerr; printf("%i", sys_nerr);],
2300                 [ ac_cv_libc_defines_sys_nerr="yes" ],
2301                 [ ac_cv_libc_defines_sys_nerr="no" ]
2302         )
2303 ])
2304 if test "x$ac_cv_libc_defines_sys_nerr" = "xyes" ; then
2305         AC_DEFINE(HAVE_SYS_NERR)
2306 fi
2307
2308 SCARD_MSG="no"
2309 # Check whether user wants sectok support
2310 AC_ARG_WITH(sectok,
2311         [  --with-sectok           Enable smartcard support using libsectok],
2312         [
2313                 if test "x$withval" != "xno" ; then
2314                         if test "x$withval" != "xyes" ; then
2315                                 CPPFLAGS="$CPPFLAGS -I${withval}"
2316                                 LDFLAGS="$LDFLAGS -L${withval}"
2317                                 if test ! -z "$need_dash_r" ; then
2318                                         LDFLAGS="$LDFLAGS -R${withval}"
2319                                 fi
2320                                 if test ! -z "$blibpath" ; then
2321                                         blibpath="$blibpath:${withval}"
2322                                 fi
2323                         fi
2324                         AC_CHECK_HEADERS(sectok.h)
2325                         if test "$ac_cv_header_sectok_h" != yes; then
2326                                 AC_MSG_ERROR(Can't find sectok.h)
2327                         fi
2328                         AC_CHECK_LIB(sectok, sectok_open)
2329                         if test "$ac_cv_lib_sectok_sectok_open" != yes; then
2330                                 AC_MSG_ERROR(Can't find libsectok)
2331                         fi
2332                         AC_DEFINE(SMARTCARD)
2333                         AC_DEFINE(USE_SECTOK)
2334                         SCARD_MSG="yes, using sectok"
2335                 fi
2336         ]
2337 )
2338
2339 # Check whether user wants OpenSC support
2340 OPENSC_CONFIG="no"
2341 AC_ARG_WITH(opensc,
2342         [--with-opensc[[=PFX]]       Enable smartcard support using OpenSC (optionally in PATH)],
2343         [
2344             if test "x$withval" != "xno" ; then
2345                 if test "x$withval" != "xyes" ; then
2346                         OPENSC_CONFIG=$withval/bin/opensc-config
2347                 else
2348                         AC_PATH_PROG(OPENSC_CONFIG, opensc-config, no)
2349                 fi
2350                 if test "$OPENSC_CONFIG" != "no"; then
2351                         LIBOPENSC_CFLAGS=`$OPENSC_CONFIG --cflags`
2352                         LIBOPENSC_LIBS=`$OPENSC_CONFIG --libs`
2353                         CPPFLAGS="$CPPFLAGS $LIBOPENSC_CFLAGS"
2354                         LDFLAGS="$LDFLAGS $LIBOPENSC_LIBS"
2355                         AC_DEFINE(SMARTCARD)
2356                         AC_DEFINE(USE_OPENSC)
2357                         SCARD_MSG="yes, using OpenSC"
2358                 fi
2359             fi
2360         ]
2361 )
2362
2363 # Check libraries needed by DNS fingerprint support
2364 AC_SEARCH_LIBS(getrrsetbyname, resolv,
2365         [AC_DEFINE(HAVE_GETRRSETBYNAME)],
2366         [
2367                 # Needed by our getrrsetbyname()
2368                 AC_SEARCH_LIBS(res_query, resolv)
2369                 AC_SEARCH_LIBS(dn_expand, resolv)
2370                 AC_MSG_CHECKING(if res_query will link)
2371                 AC_TRY_LINK_FUNC(res_query, AC_MSG_RESULT(yes),
2372                    [AC_MSG_RESULT(no)
2373                     saved_LIBS="$LIBS"
2374                     LIBS="$LIBS -lresolv"
2375                     AC_MSG_CHECKING(for res_query in -lresolv)
2376                     AC_LINK_IFELSE([
2377 #include <resolv.h>
2378 int main()
2379 {
2380         res_query (0, 0, 0, 0, 0);
2381         return 0;
2382 }
2383                         ],
2384                         [LIBS="$LIBS -lresolv"
2385                          AC_MSG_RESULT(yes)],
2386                         [LIBS="$saved_LIBS"
2387                          AC_MSG_RESULT(no)])
2388                     ])
2389                 AC_CHECK_FUNCS(_getshort _getlong)
2390                 AC_CHECK_MEMBER(HEADER.ad,
2391                         [AC_DEFINE(HAVE_HEADER_AD)],,
2392                         [#include <arpa/nameser.h>])
2393         ])
2394
2395 # Check whether user wants Kerberos 5 support
2396 KRB5_MSG="no"
2397 AC_ARG_WITH(kerberos5,
2398         [  --with-kerberos5=PATH   Enable Kerberos 5 support],
2399         [ if test "x$withval" != "xno" ; then
2400                 if test "x$withval" = "xyes" ; then
2401                         KRB5ROOT="/usr/local"
2402                 else
2403                         KRB5ROOT=${withval}
2404                 fi
2405
2406                 AC_DEFINE(KRB5)
2407                 KRB5_MSG="yes"
2408
2409                 AC_MSG_CHECKING(for krb5-config)
2410                 if test -x  $KRB5ROOT/bin/krb5-config ; then
2411                         KRB5CONF=$KRB5ROOT/bin/krb5-config
2412                         AC_MSG_RESULT($KRB5CONF)
2413
2414                         AC_MSG_CHECKING(for gssapi support)
2415                         if $KRB5CONF | grep gssapi >/dev/null ; then
2416                                 AC_MSG_RESULT(yes)
2417                                 AC_DEFINE(GSSAPI)
2418                                 k5confopts=gssapi
2419                         else
2420                                 AC_MSG_RESULT(no)
2421                                 k5confopts=""
2422                         fi
2423                         K5CFLAGS="`$KRB5CONF --cflags $k5confopts`"
2424                         K5LIBS="`$KRB5CONF --libs $k5confopts`"
2425                         CPPFLAGS="$CPPFLAGS $K5CFLAGS"
2426                         AC_MSG_CHECKING(whether we are using Heimdal)
2427                         AC_TRY_COMPILE([ #include <krb5.h> ],
2428                                        [ char *tmp = heimdal_version; ],
2429                                        [ AC_MSG_RESULT(yes)
2430                                          AC_DEFINE(HEIMDAL) ],
2431                                          AC_MSG_RESULT(no)
2432                         )
2433                 else
2434                         AC_MSG_RESULT(no)
2435                         CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include"
2436                         LDFLAGS="$LDFLAGS -L${KRB5ROOT}/lib"
2437                         AC_MSG_CHECKING(whether we are using Heimdal)
2438                         AC_TRY_COMPILE([ #include <krb5.h> ],
2439                                        [ char *tmp = heimdal_version; ],
2440                                        [ AC_MSG_RESULT(yes)
2441                                          AC_DEFINE(HEIMDAL)
2442                                          K5LIBS="-lkrb5 -ldes"
2443                                          K5LIBS="$K5LIBS -lcom_err -lasn1"
2444                                          AC_CHECK_LIB(roken, net_write,
2445                                            [K5LIBS="$K5LIBS -lroken"])
2446                                        ],
2447                                        [ AC_MSG_RESULT(no)
2448                                          K5LIBS="-lkrb5 -lk5crypto -lcom_err"
2449                                        ]
2450                         )
2451                         AC_SEARCH_LIBS(dn_expand, resolv)
2452
2453                         AC_CHECK_LIB(gssapi,gss_init_sec_context,
2454                                 [ AC_DEFINE(GSSAPI)
2455                                   K5LIBS="-lgssapi $K5LIBS" ],
2456                                 [ AC_CHECK_LIB(gssapi_krb5,gss_init_sec_context,
2457                                         [ AC_DEFINE(GSSAPI)
2458                                           K5LIBS="-lgssapi_krb5 $K5LIBS" ],
2459                                         AC_MSG_WARN([Cannot find any suitable gss-api library - build may fail]),
2460                                         $K5LIBS)
2461                                 ],
2462                                 $K5LIBS)
2463
2464                         AC_CHECK_HEADER(gssapi.h, ,
2465                                 [ unset ac_cv_header_gssapi_h
2466                                   CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include/gssapi"
2467                                   AC_CHECK_HEADERS(gssapi.h, ,
2468                                         AC_MSG_WARN([Cannot find any suitable gss-api header - build may fail])
2469                                   )
2470                                 ]
2471                         )
2472
2473                         oldCPP="$CPPFLAGS"
2474                         CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include/gssapi"
2475                         AC_CHECK_HEADER(gssapi_krb5.h, ,
2476                                         [ CPPFLAGS="$oldCPP" ])
2477
2478                 fi
2479                 if test ! -z "$need_dash_r" ; then
2480                         LDFLAGS="$LDFLAGS -R${KRB5ROOT}/lib"
2481                 fi
2482                 if test ! -z "$blibpath" ; then
2483                         blibpath="$blibpath:${KRB5ROOT}/lib"
2484                 fi
2485         fi
2486
2487         AC_CHECK_HEADERS(gssapi.h gssapi/gssapi.h)
2488         AC_CHECK_HEADERS(gssapi_krb5.h gssapi/gssapi_krb5.h)
2489         AC_CHECK_HEADERS(gssapi_generic.h gssapi/gssapi_generic.h)
2490
2491         LIBS="$LIBS $K5LIBS"
2492         AC_SEARCH_LIBS(k_hasafs, kafs, AC_DEFINE(USE_AFS))
2493         AC_SEARCH_LIBS(krb5_init_ets, $K5LIBS, AC_DEFINE(KRB5_INIT_ETS))
2494         ]
2495 )
2496
2497 # Looking for programs, paths and files
2498
2499 PRIVSEP_PATH=/var/empty
2500 AC_ARG_WITH(privsep-path,
2501         [  --with-privsep-path=xxx Path for privilege separation chroot (default=/var/empty)],
2502         [
2503                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
2504                     test "x${withval}" != "xyes"; then
2505                         PRIVSEP_PATH=$withval
2506                 fi
2507         ]
2508 )
2509 AC_SUBST(PRIVSEP_PATH)
2510
2511 AC_ARG_WITH(xauth,
2512         [  --with-xauth=PATH       Specify path to xauth program ],
2513         [
2514                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
2515                     test "x${withval}" != "xyes"; then
2516                         xauth_path=$withval
2517                 fi
2518         ],
2519         [
2520                 TestPath="$PATH"
2521                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/X/bin"
2522                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/bin/X11"
2523                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/X11R6/bin"
2524                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/openwin/bin"
2525                 AC_PATH_PROG(xauth_path, xauth, , $TestPath)
2526                 if (test ! -z "$xauth_path" && test -x "/usr/openwin/bin/xauth") ; then
2527                         xauth_path="/usr/openwin/bin/xauth"
2528                 fi
2529         ]
2530 )
2531
2532 STRIP_OPT=-s
2533 AC_ARG_ENABLE(strip,
2534         [  --disable-strip         Disable calling strip(1) on install],
2535         [
2536                 if test "x$enableval" = "xno" ; then
2537                         STRIP_OPT=
2538                 fi
2539         ]
2540 )
2541 AC_SUBST(STRIP_OPT)
2542
2543 if test -z "$xauth_path" ; then
2544         XAUTH_PATH="undefined"
2545         AC_SUBST(XAUTH_PATH)
2546 else
2547         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
2548         XAUTH_PATH=$xauth_path
2549         AC_SUBST(XAUTH_PATH)
2550 fi
2551
2552 # Check for mail directory (last resort if we cannot get it from headers)
2553 if test ! -z "$MAIL" ; then
2554         maildir=`dirname $MAIL`
2555         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
2556 fi
2557
2558 if test ! -z "$cross_compiling" && test "x$cross_compiling" = "xyes"; then
2559         AC_MSG_WARN([cross compiling: Disabling /dev/ptmx test])
2560         disable_ptmx_check=yes
2561 fi
2562 if test -z "$no_dev_ptmx" ; then
2563         if test "x$disable_ptmx_check" != "xyes" ; then
2564                 AC_CHECK_FILE("/dev/ptmx",
2565                         [
2566                                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
2567                                 have_dev_ptmx=1
2568                         ]
2569                 )
2570         fi
2571 fi
2572
2573 if test ! -z "$cross_compiling" && test "x$cross_compiling" != "xyes"; then
2574         AC_CHECK_FILE("/dev/ptc",
2575                 [
2576                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
2577                         have_dev_ptc=1
2578                 ]
2579         )
2580 else
2581         AC_MSG_WARN([cross compiling: Disabling /dev/ptc test])
2582 fi
2583
2584 # Options from here on. Some of these are preset by platform above
2585 AC_ARG_WITH(mantype,
2586         [  --with-mantype=man|cat|doc  Set man page type],
2587         [
2588                 case "$withval" in
2589                 man|cat|doc)
2590                         MANTYPE=$withval
2591                         ;;
2592                 *)
2593                         AC_MSG_ERROR(invalid man type: $withval)
2594                         ;;
2595                 esac
2596         ]
2597 )
2598 if test -z "$MANTYPE"; then
2599         TestPath="/usr/bin${PATH_SEPARATOR}/usr/ucb"
2600         AC_PATH_PROGS(NROFF, nroff awf, /bin/false, $TestPath)
2601         if ${NROFF} -mdoc ${srcdir}/ssh.1 >/dev/null 2>&1; then
2602                 MANTYPE=doc
2603         elif ${NROFF} -man ${srcdir}/ssh.1 >/dev/null 2>&1; then
2604                 MANTYPE=man
2605         else
2606                 MANTYPE=cat
2607         fi
2608 fi
2609 AC_SUBST(MANTYPE)
2610 if test "$MANTYPE" = "doc"; then
2611         mansubdir=man;
2612 else
2613         mansubdir=$MANTYPE;
2614 fi
2615 AC_SUBST(mansubdir)
2616
2617 # Check whether to enable MD5 passwords
2618 MD5_MSG="no"
2619 AC_ARG_WITH(md5-passwords,
2620         [  --with-md5-passwords    Enable use of MD5 passwords],
2621         [
2622                 if test "x$withval" != "xno" ; then
2623                         AC_DEFINE(HAVE_MD5_PASSWORDS)
2624                         MD5_MSG="yes"
2625                 fi
2626         ]
2627 )
2628
2629 # Whether to disable shadow password support
2630 AC_ARG_WITH(shadow,
2631         [  --without-shadow        Disable shadow password support],
2632         [
2633                 if test "x$withval" = "xno" ; then
2634                         AC_DEFINE(DISABLE_SHADOW)
2635                         disable_shadow=yes
2636                 fi
2637         ]
2638 )
2639
2640 if test -z "$disable_shadow" ; then
2641         AC_MSG_CHECKING([if the systems has expire shadow information])
2642         AC_TRY_COMPILE(
2643         [
2644 #include <sys/types.h>
2645 #include <shadow.h>
2646         struct spwd sp;
2647         ],[ sp.sp_expire = sp.sp_lstchg = sp.sp_inact = 0; ],
2648         [ sp_expire_available=yes ], []
2649         )
2650
2651         if test "x$sp_expire_available" = "xyes" ; then
2652                 AC_MSG_RESULT(yes)
2653                 AC_DEFINE(HAS_SHADOW_EXPIRE)
2654         else
2655                 AC_MSG_RESULT(no)
2656         fi
2657 fi
2658
2659 # Use ip address instead of hostname in $DISPLAY
2660 if test ! -z "$IPADDR_IN_DISPLAY" ; then
2661         DISPLAY_HACK_MSG="yes"
2662         AC_DEFINE(IPADDR_IN_DISPLAY)
2663 else
2664         DISPLAY_HACK_MSG="no"
2665         AC_ARG_WITH(ipaddr-display,
2666                 [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
2667                 [
2668                         if test "x$withval" != "xno" ; then
2669                                 AC_DEFINE(IPADDR_IN_DISPLAY)
2670                                 DISPLAY_HACK_MSG="yes"
2671                         fi
2672                 ]
2673         )
2674 fi
2675
2676 # check for /etc/default/login and use it if present.
2677 AC_ARG_ENABLE(etc-default-login,
2678         [  --disable-etc-default-login Disable using PATH from /etc/default/login [no]],
2679         [ if test "x$enableval" = "xno"; then
2680                 AC_MSG_NOTICE([/etc/default/login handling disabled])
2681                 etc_default_login=no
2682           else
2683                 etc_default_login=yes
2684           fi ],
2685         [ etc_default_login=yes ]
2686 )
2687
2688 if test "x$etc_default_login" != "xno"; then
2689         AC_CHECK_FILE("/etc/default/login",
2690             [ external_path_file=/etc/default/login ])
2691         if test ! -z "$cross_compiling" && test "x$cross_compiling" = "xyes";
2692         then
2693                 AC_MSG_WARN([cross compiling: Disabling /etc/default/login test])
2694         elif test "x$external_path_file" = "x/etc/default/login"; then
2695                 AC_DEFINE(HAVE_ETC_DEFAULT_LOGIN)
2696         fi
2697 fi
2698
2699 dnl BSD systems use /etc/login.conf so --with-default-path= has no effect
2700 if test $ac_cv_func_login_getcapbool = "yes" && \
2701         test $ac_cv_header_login_cap_h = "yes" ; then
2702         external_path_file=/etc/login.conf
2703 fi
2704
2705 # Whether to mess with the default path
2706 SERVER_PATH_MSG="(default)"
2707 AC_ARG_WITH(default-path,
2708         [  --with-default-path=    Specify default \$PATH environment for server],
2709         [
2710                 if test "x$external_path_file" = "x/etc/login.conf" ; then
2711                         AC_MSG_WARN([
2712 --with-default-path=PATH has no effect on this system.
2713 Edit /etc/login.conf instead.])
2714                 elif test "x$withval" != "xno" ; then
2715                         if test ! -z "$external_path_file" ; then
2716                                 AC_MSG_WARN([
2717 --with-default-path=PATH will only be used if PATH is not defined in
2718 $external_path_file .])
2719                         fi
2720                         user_path="$withval"
2721                         SERVER_PATH_MSG="$withval"
2722                 fi
2723         ],
2724         [ if test "x$external_path_file" = "x/etc/login.conf" ; then
2725                 AC_MSG_WARN([Make sure the path to scp is in /etc/login.conf])
2726         else
2727                 if test ! -z "$external_path_file" ; then
2728                         AC_MSG_WARN([
2729 If PATH is defined in $external_path_file, ensure the path to scp is included,
2730 otherwise scp will not work.])
2731                 fi
2732                 AC_TRY_RUN(
2733                         [
2734 /* find out what STDPATH is */
2735 #include <stdio.h>
2736 #ifdef HAVE_PATHS_H
2737 # include <paths.h>
2738 #endif
2739 #ifndef _PATH_STDPATH
2740 # ifdef _PATH_USERPATH  /* Irix */
2741 #  define _PATH_STDPATH _PATH_USERPATH
2742 # else
2743 #  define _PATH_STDPATH "/usr/bin:/bin:/usr/sbin:/sbin"
2744 # endif
2745 #endif
2746 #include <sys/types.h>
2747 #include <sys/stat.h>
2748 #include <fcntl.h>
2749 #define DATA "conftest.stdpath"
2750
2751 main()
2752 {
2753         FILE *fd;
2754         int rc;
2755
2756         fd = fopen(DATA,"w");
2757         if(fd == NULL)
2758                 exit(1);
2759
2760         if ((rc = fprintf(fd,"%s", _PATH_STDPATH)) < 0)
2761                 exit(1);
2762
2763         exit(0);
2764 }
2765                 ], [ user_path=`cat conftest.stdpath` ],
2766                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ],
2767                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ]
2768         )
2769 # make sure $bindir is in USER_PATH so scp will work
2770                 t_bindir=`eval echo ${bindir}`
2771                 case $t_bindir in
2772                         NONE/*) t_bindir=`echo $t_bindir | sed "s~NONE~$prefix~"` ;;
2773                 esac
2774                 case $t_bindir in
2775                         NONE/*) t_bindir=`echo $t_bindir | sed "s~NONE~$ac_default_prefix~"` ;;
2776                 esac
2777                 echo $user_path | grep ":$t_bindir"  > /dev/null 2>&1
2778                 if test $? -ne 0  ; then
2779                         echo $user_path | grep "^$t_bindir"  > /dev/null 2>&1
2780                         if test $? -ne 0  ; then
2781                                 user_path=$user_path:$t_bindir
2782                                 AC_MSG_RESULT(Adding $t_bindir to USER_PATH so scp will work)
2783                         fi
2784                 fi
2785         fi ]
2786 )
2787 if test "x$external_path_file" != "x/etc/login.conf" ; then
2788         AC_DEFINE_UNQUOTED(USER_PATH, "$user_path")
2789         AC_SUBST(user_path)
2790 fi
2791
2792 # Set superuser path separately to user path
2793 AC_ARG_WITH(superuser-path,
2794         [  --with-superuser-path=  Specify different path for super-user],
2795         [
2796                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
2797                     test "x${withval}" != "xyes"; then
2798                         AC_DEFINE_UNQUOTED(SUPERUSER_PATH, "$withval")
2799                         superuser_path=$withval
2800                 fi
2801         ]
2802 )
2803
2804
2805 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
2806 IPV4_IN6_HACK_MSG="no"
2807 AC_ARG_WITH(4in6,
2808         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
2809         [
2810                 if test "x$withval" != "xno" ; then
2811                         AC_MSG_RESULT(yes)
2812                         AC_DEFINE(IPV4_IN_IPV6)
2813                         IPV4_IN6_HACK_MSG="yes"
2814                 else
2815                         AC_MSG_RESULT(no)
2816                 fi
2817         ],[
2818                 if test "x$inet6_default_4in6" = "xyes"; then
2819                         AC_MSG_RESULT([yes (default)])
2820                         AC_DEFINE(IPV4_IN_IPV6)
2821                         IPV4_IN6_HACK_MSG="yes"
2822                 else
2823                         AC_MSG_RESULT([no (default)])
2824                 fi
2825         ]
2826 )
2827
2828 # Whether to enable BSD auth support
2829 BSD_AUTH_MSG=no
2830 AC_ARG_WITH(bsd-auth,
2831         [  --with-bsd-auth         Enable BSD auth support],
2832         [
2833                 if test "x$withval" != "xno" ; then
2834                         AC_DEFINE(BSD_AUTH)
2835                         BSD_AUTH_MSG=yes
2836                 fi
2837         ]
2838 )
2839
2840 # Where to place sshd.pid
2841 piddir=/var/run
2842 # make sure the directory exists
2843 if test ! -d $piddir ; then
2844         piddir=`eval echo ${sysconfdir}`
2845         case $piddir in
2846                 NONE/*) piddir=`echo $piddir | sed "s~NONE~$ac_default_prefix~"` ;;
2847         esac
2848 fi
2849
2850 AC_ARG_WITH(pid-dir,
2851         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
2852         [
2853                 if test -n "$withval"  &&  test "x$withval" != "xno"  &&  \
2854                     test "x${withval}" != "xyes"; then
2855                         piddir=$withval
2856                         if test ! -d $piddir ; then
2857                         AC_MSG_WARN([** no $piddir directory on this system **])
2858                         fi
2859                 fi
2860         ]
2861 )
2862
2863 AC_DEFINE_UNQUOTED(_PATH_SSH_PIDDIR, "$piddir")
2864 AC_SUBST(piddir)
2865
2866 dnl allow user to disable some login recording features
2867 AC_ARG_ENABLE(lastlog,
2868         [  --disable-lastlog       disable use of lastlog even if detected [no]],
2869         [
2870                 if test "x$enableval" = "xno" ; then
2871                         AC_DEFINE(DISABLE_LASTLOG)
2872                 fi
2873         ]
2874 )
2875 AC_ARG_ENABLE(utmp,
2876         [  --disable-utmp          disable use of utmp even if detected [no]],
2877         [
2878                 if test "x$enableval" = "xno" ; then
2879                         AC_DEFINE(DISABLE_UTMP)
2880                 fi
2881         ]
2882 )
2883 AC_ARG_ENABLE(utmpx,
2884         [  --disable-utmpx         disable use of utmpx even if detected [no]],
2885         [
2886                 if test "x$enableval" = "xno" ; then
2887                         AC_DEFINE(DISABLE_UTMPX)
2888                 fi
2889         ]
2890 )
2891 AC_ARG_ENABLE(wtmp,
2892         [  --disable-wtmp          disable use of wtmp even if detected [no]],
2893         [
2894                 if test "x$enableval" = "xno" ; then
2895                         AC_DEFINE(DISABLE_WTMP)
2896                 fi
2897         ]
2898 )
2899 AC_ARG_ENABLE(wtmpx,
2900         [  --disable-wtmpx         disable use of wtmpx even if detected [no]],
2901         [
2902                 if test "x$enableval" = "xno" ; then
2903                         AC_DEFINE(DISABLE_WTMPX)
2904                 fi
2905         ]
2906 )
2907 AC_ARG_ENABLE(libutil,
2908         [  --disable-libutil       disable use of libutil (login() etc.) [no]],
2909         [
2910                 if test "x$enableval" = "xno" ; then
2911                         AC_DEFINE(DISABLE_LOGIN)
2912                 fi
2913         ]
2914 )
2915 AC_ARG_ENABLE(pututline,
2916         [  --disable-pututline     disable use of pututline() etc. ([uw]tmp) [no]],
2917         [
2918                 if test "x$enableval" = "xno" ; then
2919                         AC_DEFINE(DISABLE_PUTUTLINE)
2920                 fi
2921         ]
2922 )
2923 AC_ARG_ENABLE(pututxline,
2924         [  --disable-pututxline    disable use of pututxline() etc. ([uw]tmpx) [no]],
2925         [
2926                 if test "x$enableval" = "xno" ; then
2927                         AC_DEFINE(DISABLE_PUTUTXLINE)
2928                 fi
2929         ]
2930 )
2931 AC_ARG_WITH(lastlog,
2932   [  --with-lastlog=FILE|DIR specify lastlog location [common locations]],
2933         [
2934                 if test "x$withval" = "xno" ; then
2935                         AC_DEFINE(DISABLE_LASTLOG)
2936                 elif test -n "$withval"  &&  test "x${withval}" != "xyes"; then
2937                         conf_lastlog_location=$withval
2938                 fi
2939         ]
2940 )
2941
2942 dnl lastlog, [uw]tmpx? detection
2943 dnl  NOTE: set the paths in the platform section to avoid the
2944 dnl   need for command-line parameters
2945 dnl lastlog and [uw]tmp are subject to a file search if all else fails
2946
2947 dnl lastlog detection
2948 dnl  NOTE: the code itself will detect if lastlog is a directory
2949 AC_MSG_CHECKING([if your system defines LASTLOG_FILE])
2950 AC_TRY_COMPILE([
2951 #include <sys/types.h>
2952 #include <utmp.h>
2953 #ifdef HAVE_LASTLOG_H
2954 #  include <lastlog.h>
2955 #endif
2956 #ifdef HAVE_PATHS_H
2957 #  include <paths.h>
2958 #endif
2959 #ifdef HAVE_LOGIN_H
2960 # include <login.h>
2961 #endif
2962         ],
2963         [ char *lastlog = LASTLOG_FILE; ],
2964         [ AC_MSG_RESULT(yes) ],
2965         [
2966                 AC_MSG_RESULT(no)
2967                 AC_MSG_CHECKING([if your system defines _PATH_LASTLOG])
2968                 AC_TRY_COMPILE([
2969 #include <sys/types.h>
2970 #include <utmp.h>
2971 #ifdef HAVE_LASTLOG_H
2972 #  include <lastlog.h>
2973 #endif
2974 #ifdef HAVE_PATHS_H
2975 #  include <paths.h>
2976 #endif
2977                 ],
2978                 [ char *lastlog = _PATH_LASTLOG; ],
2979                 [ AC_MSG_RESULT(yes) ],
2980                 [
2981                         AC_MSG_RESULT(no)
2982                         system_lastlog_path=no
2983                 ])
2984         ]
2985 )
2986
2987 if test -z "$conf_lastlog_location"; then
2988         if test x"$system_lastlog_path" = x"no" ; then
2989                 for f in /var/log/lastlog /usr/adm/lastlog /var/adm/lastlog /etc/security/lastlog ; do
2990                                 if (test -d "$f" || test -f "$f") ; then
2991                                         conf_lastlog_location=$f
2992                                 fi
2993                 done
2994                 if test -z "$conf_lastlog_location"; then
2995                         AC_MSG_WARN([** Cannot find lastlog **])
2996                         dnl Don't define DISABLE_LASTLOG - that means we don't try wtmp/wtmpx
2997                 fi
2998         fi
2999 fi
3000
3001 if test -n "$conf_lastlog_location"; then
3002         AC_DEFINE_UNQUOTED(CONF_LASTLOG_FILE, "$conf_lastlog_location")
3003 fi
3004
3005 dnl utmp detection
3006 AC_MSG_CHECKING([if your system defines UTMP_FILE])
3007 AC_TRY_COMPILE([
3008 #include <sys/types.h>
3009 #include <utmp.h>
3010 #ifdef HAVE_PATHS_H
3011 #  include <paths.h>
3012 #endif
3013         ],
3014         [ char *utmp = UTMP_FILE; ],
3015         [ AC_MSG_RESULT(yes) ],
3016         [ AC_MSG_RESULT(no)
3017           system_utmp_path=no ]
3018 )
3019 if test -z "$conf_utmp_location"; then
3020         if test x"$system_utmp_path" = x"no" ; then
3021                 for f in /etc/utmp /usr/adm/utmp /var/run/utmp; do
3022                         if test -f $f ; then
3023                                 conf_utmp_location=$f
3024                         fi
3025                 done
3026                 if test -z "$conf_utmp_location"; then
3027                         AC_DEFINE(DISABLE_UTMP)
3028                 fi
3029         fi
3030 fi
3031 if test -n "$conf_utmp_location"; then
3032         AC_DEFINE_UNQUOTED(CONF_UTMP_FILE, "$conf_utmp_location")
3033 fi
3034
3035 dnl wtmp detection
3036 AC_MSG_CHECKING([if your system defines WTMP_FILE])
3037 AC_TRY_COMPILE([
3038 #include <sys/types.h>
3039 #include <utmp.h>
3040 #ifdef HAVE_PATHS_H
3041 #  include <paths.h>
3042 #endif
3043         ],
3044         [ char *wtmp = WTMP_FILE; ],
3045         [ AC_MSG_RESULT(yes) ],
3046         [ AC_MSG_RESULT(no)
3047           system_wtmp_path=no ]
3048 )
3049 if test -z "$conf_wtmp_location"; then
3050         if test x"$system_wtmp_path" = x"no" ; then
3051                 for f in /usr/adm/wtmp /var/log/wtmp; do
3052                         if test -f $f ; then
3053                                 conf_wtmp_location=$f
3054                         fi
3055                 done
3056                 if test -z "$conf_wtmp_location"; then
3057                         AC_DEFINE(DISABLE_WTMP)
3058                 fi
3059         fi
3060 fi
3061 if test -n "$conf_wtmp_location"; then
3062         AC_DEFINE_UNQUOTED(CONF_WTMP_FILE, "$conf_wtmp_location")
3063 fi
3064
3065
3066 dnl utmpx detection - I don't know any system so perverse as to require
3067 dnl  utmpx, but not define UTMPX_FILE (ditto wtmpx.) No doubt it's out
3068 dnl  there, though.
3069 AC_MSG_CHECKING([if your system defines UTMPX_FILE])
3070 AC_TRY_COMPILE([
3071 #include <sys/types.h>
3072 #include <utmp.h>
3073 #ifdef HAVE_UTMPX_H
3074 #include <utmpx.h>
3075 #endif
3076 #ifdef HAVE_PATHS_H
3077 #  include <paths.h>
3078 #endif
3079         ],
3080         [ char *utmpx = UTMPX_FILE; ],
3081         [ AC_MSG_RESULT(yes) ],
3082         [ AC_MSG_RESULT(no)
3083           system_utmpx_path=no ]
3084 )
3085 if test -z "$conf_utmpx_location"; then
3086         if test x"$system_utmpx_path" = x"no" ; then
3087                 AC_DEFINE(DISABLE_UTMPX)
3088         fi
3089 else
3090         AC_DEFINE_UNQUOTED(CONF_UTMPX_FILE, "$conf_utmpx_location")
3091 fi
3092
3093 dnl wtmpx detection
3094 AC_MSG_CHECKING([if your system defines WTMPX_FILE])
3095 AC_TRY_COMPILE([
3096 #include <sys/types.h>
3097 #include <utmp.h>
3098 #ifdef HAVE_UTMPX_H
3099 #include <utmpx.h>
3100 #endif
3101 #ifdef HAVE_PATHS_H
3102 #  include <paths.h>
3103 #endif
3104         ],
3105         [ char *wtmpx = WTMPX_FILE; ],
3106         [ AC_MSG_RESULT(yes) ],
3107         [ AC_MSG_RESULT(no)
3108           system_wtmpx_path=no ]
3109 )
3110 if test -z "$conf_wtmpx_location"; then
3111         if test x"$system_wtmpx_path" = x"no" ; then
3112                 AC_DEFINE(DISABLE_WTMPX)
3113         fi
3114 else
3115         AC_DEFINE_UNQUOTED(CONF_WTMPX_FILE, "$conf_wtmpx_location")
3116 fi
3117
3118
3119 if test ! -z "$blibpath" ; then
3120         LDFLAGS="$LDFLAGS $blibflags$blibpath"
3121         AC_MSG_WARN([Please check and edit blibpath in LDFLAGS in Makefile])
3122 fi
3123
3124 dnl remove pam and dl because they are in $LIBPAM
3125 if test "$PAM_MSG" = yes ; then
3126         LIBS=`echo $LIBS | sed 's/-lpam //'`
3127 fi
3128 if test "$ac_cv_lib_pam_pam_set_item" = yes ; then
3129         LIBS=`echo $LIBS | sed 's/-ldl //'`
3130 fi
3131
3132 AC_EXEEXT
3133 AC_CONFIG_FILES([Makefile buildpkg.sh opensshd.init openbsd-compat/Makefile \
3134         scard/Makefile ssh_prng_cmds survey.sh])
3135 AC_OUTPUT
3136
3137 # Print summary of options
3138
3139 # Someone please show me a better way :)
3140 A=`eval echo ${prefix}` ; A=`eval echo ${A}`
3141 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
3142 C=`eval echo ${sbindir}` ; C=`eval echo ${C}`
3143 D=`eval echo ${sysconfdir}` ; D=`eval echo ${D}`
3144 E=`eval echo ${libexecdir}/ssh-askpass` ; E=`eval echo ${E}`
3145 F=`eval echo ${mandir}/${mansubdir}X` ; F=`eval echo ${F}`
3146 G=`eval echo ${piddir}` ; G=`eval echo ${G}`
3147 H=`eval echo ${PRIVSEP_PATH}` ; H=`eval echo ${H}`
3148 I=`eval echo ${user_path}` ; I=`eval echo ${I}`
3149 J=`eval echo ${superuser_path}` ; J=`eval echo ${J}`
3150
3151 echo ""
3152 echo "OpenSSH has been configured with the following options:"
3153 echo "                     User binaries: $B"
3154 echo "                   System binaries: $C"
3155 echo "               Configuration files: $D"
3156 echo "                   Askpass program: $E"
3157 echo "                      Manual pages: $F"
3158 echo "                          PID file: $G"
3159 echo "  Privilege separation chroot path: $H"
3160 if test "x$external_path_file" = "x/etc/login.conf" ; then
3161 echo "   At runtime, sshd will use the path defined in $external_path_file"
3162 echo "   Make sure the path to scp is present, otherwise scp will not work"
3163 else
3164 echo "            sshd default user PATH: $I"
3165         if test ! -z "$external_path_file"; then
3166 echo "   (If PATH is set in $external_path_file it will be used instead. If"
3167 echo "   used, ensure the path to scp is present, otherwise scp will not work.)"
3168         fi
3169 fi
3170 if test ! -z "$superuser_path" ; then
3171 echo "          sshd superuser user PATH: $J"
3172 fi
3173 echo "                    Manpage format: $MANTYPE"
3174 echo "                       PAM support: $PAM_MSG"
3175 echo "                 KerberosV support: $KRB5_MSG"
3176 echo "                 Smartcard support: $SCARD_MSG"
3177 echo "                     S/KEY support: $SKEY_MSG"
3178 echo "              TCP Wrappers support: $TCPW_MSG"
3179 echo "              MD5 password support: $MD5_MSG"
3180 echo "                   libedit support: $LIBEDIT_MSG"
3181 echo "       IP address in \$DISPLAY hack: $DISPLAY_HACK_MSG"
3182 echo "           Translate v4 in v6 hack: $IPV4_IN6_HACK_MSG"
3183 echo "                  BSD Auth support: $BSD_AUTH_MSG"
3184 echo "              Random number source: $RAND_MSG"
3185 if test ! -z "$USE_RAND_HELPER" ; then
3186 echo "     ssh-rand-helper collects from: $RAND_HELPER_MSG"
3187 fi
3188
3189 echo ""
3190
3191 echo "              Host: ${host}"
3192 echo "          Compiler: ${CC}"
3193 echo "    Compiler flags: ${CFLAGS}"
3194 echo "Preprocessor flags: ${CPPFLAGS}"
3195 echo "      Linker flags: ${LDFLAGS}"
3196 echo "         Libraries: ${LIBWRAP} ${LIBPAM} ${LIBS}"
3197
3198 echo ""
3199
3200 if test "x$MAKE_PACKAGE_SUPPORTED" = "xyes" ; then
3201         echo "SVR4 style packages are supported with \"make package\""
3202         echo ""
3203 fi
3204
3205 if test "x$PAM_MSG" = "xyes" ; then
3206         echo "PAM is enabled. You may need to install a PAM control file "
3207         echo "for sshd, otherwise password authentication may fail. "
3208         echo "Example PAM control files can be found in the contrib/ "
3209         echo "subdirectory"
3210         echo ""
3211 fi
3212
3213 if test ! -z "$RAND_HELPER_CMDHASH" ; then
3214         echo "WARNING: you are using the builtin random number collection "
3215         echo "service. Please read WARNING.RNG and request that your OS "
3216         echo "vendor includes kernel-based random number collection in "
3217         echo "future versions of your OS."
3218         echo ""
3219 fi
3220
3221 if test ! -z "$NO_PEERCHECK" ; then
3222         echo "WARNING: the operating system that you are using does not "
3223         echo "appear to support either the getpeereid() API nor the "
3224         echo "SO_PEERCRED getsockopt() option. These facilities are used to "
3225         echo "enforce security checks to prevent unauthorised connections to "
3226         echo "ssh-agent. Their absence increases the risk that a malicious "
3227         echo "user can connect to your agent. "
3228         echo ""
3229 fi
3230
3231 if test "$AUDIT_MODULE" = "bsm" ; then
3232         echo "WARNING: BSM audit support is currently considered EXPERIMENTAL."
3233         echo "See the Solaris section in README.platform for details."
3234 fi