configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_PROG_CC
   5 AC_CANONICAL_HOST
   6
   7 # Checks for programs.
   8 AC_PROG_CPP
   9 AC_PROG_RANLIB
  10 AC_PROG_INSTALL
  11 AC_CHECK_PROG(AR, ar, ar)
  12 AC_PATH_PROG(PERL, perl)
  13 AC_SUBST(PERL)
  14 AC_PATH_PROG(ENT, ent)
  15 AC_SUBST(ENT)
  16
  17 if test -z "$LD" ; then
  18         LD=$CC
  19 fi
  20 AC_SUBST(LD)
  21
  22 # C Compiler features
  23 AC_C_INLINE
  24 if test "$GCC" = "yes"; then
  25         CFLAGS="$CFLAGS -Wall"
  26 fi
  27
  28 # Check for some target-specific stuff
  29 case "$host" in
  30 *-*-aix*)
  31         AFS_LIBS="-lld"
  32         CFLAGS="$CFLAGS -I/usr/local/include"
  33         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  34         if test "$LD" != "gcc" -a -z "$blibpath"; then
  35                 blibpath="/usr/lib:/lib:/usr/local/lib"
  36         fi
  37         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)])
  38         AC_DEFINE(BROKEN_GETADDRINFO)
  39         MANTYPE='$(CATMAN)'
  40         mansubdir=cat
  41         dnl AIX handles lastlog as part of its login message
  42         AC_DEFINE(DISABLE_LASTLOG)
  43         ;;
  44 *-*-hpux10*)
  45         if test -z "$GCC"; then
  46                 CFLAGS="$CFLAGS -Ae"
  47         fi
  48         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  49         AC_DEFINE(IPADDR_IN_DISPLAY)
  50         AC_MSG_CHECKING(for HPUX trusted system password database)
  51         if test -f /tcb/files/auth/system/default; then
  52                 AC_MSG_RESULT(yes)
  53                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  54                 LIBS="$LIBS -lsec"
  55                 AC_MSG_WARN([This configuration is untested])
  56         else
  57                 AC_MSG_RESULT(no)
  58                 AC_DEFINE(DISABLE_SHADOW)
  59         fi
  60         MANTYPE='$(CATMAN)'
  61         mansubdir=cat
  62         ;;
  63 *-*-hpux11*)
  64         if test -z "$GCC"; then
  65                 CFLAGS="$CFLAGS -Ae"
  66         fi
  67         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  68         AC_DEFINE(IPADDR_IN_DISPLAY)
  69         AC_MSG_CHECKING(for HPUX trusted system password database)
  70         if test -f /tcb/files/auth/system/default; then
  71                 AC_MSG_RESULT(yes)
  72                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  73                 LIBS="$LIBS -lsec"
  74                 AC_MSG_WARN([This configuration is untested])
  75         else
  76                 AC_MSG_RESULT(no)
  77                 AC_DEFINE(DISABLE_SHADOW)
  78         fi
  79         MANTYPE='$(CATMAN)'
  80         mansubdir=cat
  81         ;;
  82 *-*-irix5*)
  83         CFLAGS="$CFLAGS -I/usr/local/include"
  84         LDFLAGS="$LDFLAGS"
  85         MANTYPE='$(CATMAN)'
  86         no_libsocket=1
  87         no_libnsl=1
  88         ;;
  89 *-*-irix6*)
  90         CFLAGS="$CFLAGS -I/usr/local/include"
  91         LDFLAGS="$LDFLAGS"
  92         MANTYPE='$(CATMAN)'
  93         AC_MSG_WARN([*** Irix 6.x is not tested, please report you experiences *** ])
  94         no_libsocket=1
  95         no_libnsl=1
  96         ;;
  97 *-*-linux*)
  98         no_dev_ptmx=1
  99         AC_DEFINE(DONT_TRY_OTHER_AF)
 100         inet6_default_4in6=yes
 101         ;;
 102 *-*-netbsd*)
 103         need_dash_r=1
 104         ;;
 105 *-next-*)
 106         # hardwire lastlog location (can't detect it on some versions)
 107         conf_lastlog_location="/usr/adm/lastlog"
 108         AC_DEFINE(HAVE_NEXT)
 109         CFLAGS="$CFLAGS -I/usr/local/include"
 110         MAIL=/usr/spool/mail
 111         conf_utmp_location=/etc/utmp
 112         AC_MSG_WARN([*** Tested: PA-RISC/m68k  Untested: Sparc/Intel])
 113         AC_MSG_WARN([*** Expect 'scp' to fail!])
 114         AC_MSG_WARN([*** Please report any problems, thanks])
 115         ;;
 116 *-*-solaris*)
 117         CFLAGS="$CFLAGS -I/usr/local/include"
 118         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib -L/usr/ucblib -R/usr/ucblib"
 119         need_dash_r=1
 120         # hardwire lastlog location (can't detect it on some versions)
 121         conf_lastlog_location="/var/adm/lastlog"
 122         AC_MSG_CHECKING(for obsolete utmp and wtmp in solaris2.x)
 123         sol2ver=`echo "$host"| sed -e 's/.*[[0-9]]\.//'`
 124         if test "$sol2ver" -ge 8; then
 125                 AC_MSG_RESULT(yes)
 126                 AC_DEFINE(DISABLE_UTMP)
 127                 AC_DEFINE(DISABLE_WTMP)
 128         else
 129                 AC_MSG_RESULT(no)
 130         fi
 131         ;;
 132 *-*-sunos4*)
 133         CFLAGS="$CFLAGS -DSUNOS4"
 134         AC_CHECK_FUNCS(getpwanam)
 135         ;;
 136 *-*-sysv*)
 137         CFLAGS="$CFLAGS -I/usr/local/include"
 138         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 139         MANTYPE='$(CATMAN)'
 140         mansubdir=cat
 141         LIBS="$LIBS -lgen -lsocket"
 142         ;;
 143 *-*-sco3*)
 144         CFLAGS="$CFLAGS -I/usr/local/include"
 145         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 146         MANTYPE='$(CATMAN)'
 147         mansubdir=cat
 148         LIBS="$LIBS -lgen -lsocket"
 149         no_dev_ptmx=1
 150         ;;
 151 esac
 152
 153 # Allow user to specify flags
 154 AC_ARG_WITH(cflags,
 155         [  --with-cflags           Specify additional flags to pass to compiler],
 156         [
 157                 if test "x$withval" != "xno" ; then
 158                         CFLAGS="$CFLAGS $withval"
 159                 fi
 160         ]
 161 )
 162 AC_ARG_WITH(ldflags,
 163         [  --with-ldlags           Specify additional flags to pass to linker],
 164         [
 165                 if test "x$withval" != "xno" ; then
 166                         LDFLAGS="$LDFLAGS $withval"
 167                 fi
 168         ]
 169 )
 170 AC_ARG_WITH(libs,
 171         [  --with-libs             Specify additional libraries to link with],
 172         [
 173                 if test "x$withval" != "xno" ; then
 174                         LIBS="$LIBS $withval"
 175                 fi
 176         ]
 177 )
 178
 179
 180 # Checks for libraries.
 181 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
 182 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
 183
 184 if test -z "$no_libsocket" ; then
 185         AC_CHECK_LIB(nsl, yp_match, , )
 186 fi
 187 if test -z "$no_libnsl" ; then
 188         AC_CHECK_LIB(socket, main, , )
 189 fi
 190
 191 # Checks for header files.
 192 AC_CHECK_HEADERS(bstring.h endian.h lastlog.h limits.h login.h maillock.h netdb.h netgroup.h netinet/in_systm.h paths.h poll.h pty.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/select.h sys/stat.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h stddef.h time.h util.h utmp.h utmpx.h)
 193
 194 # Checks for library functions.
 195 AC_CHECK_FUNCS(arc4random atexit b64_ntop bcopy bindresvport_af clock freeaddrinfo gai_strerror getaddrinfo getnameinfo getrusage innetgr md5_crypt memmove mkdtemp on_exit openpty rresvport_af setenv seteuid setlogin setproctitle setreuid snprintf strlcat strlcpy vsnprintf vhangup _getpty __b64_ntop)
 196 dnl    checks for time functions
 197 AC_CHECK_FUNCS(gettimeofday time)
 198 dnl    checks for libutil functions
 199 AC_CHECK_FUNCS(login logout updwtmp logwtmp)
 200 dnl    checks for utmp functions
 201 AC_CHECK_FUNCS(entutent getutent getutid getutline pututline setutent)
 202 AC_CHECK_FUNCS(utmpname)
 203 dnl    checks for utmpx functions
 204 AC_CHECK_FUNCS(entutxent getutxent getutxid getutxline pututxline )
 205 AC_CHECK_FUNCS(setutxent utmpxname)
 206
 207 AC_CHECK_FUNC(login,
 208         [AC_DEFINE(HAVE_LOGIN)],
 209         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 210 )
 211
 212 AC_CHECK_FUNC(daemon,
 213         [AC_DEFINE(HAVE_DAEMON)],
 214         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 215 )
 216
 217 AC_CHECK_FUNC(getpagesize,
 218         [AC_DEFINE(HAVE_GETPAGESIZE)],
 219         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 220 )
 221
 222 PAM_MSG="no"
 223 AC_ARG_WITH(pam,
 224         [  --without-pam           Disable PAM support ],
 225         [
 226                 if test "x$withval" = "xno" ; then
 227                         no_pam=1
 228                         AC_DEFINE(DISABLE_PAM)
 229                         PAM_MSG="disabled"
 230                 fi
 231         ]
 232 )
 233 if test -z "$no_pam" -a "x$ac_cv_header_security_pam_appl_h" = "xyes" ; then
 234         AC_CHECK_LIB(dl, dlopen, , )
 235         LIBS="$LIBS -lpam"
 236
 237         AC_CHECK_FUNCS(pam_getenvlist)
 238
 239         PAM_MSG="yes"
 240
 241         # Check PAM strerror arguments (old PAM)
 242         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 243         AC_TRY_COMPILE(
 244                 [
 245 #include <stdlib.h>
 246 #include <security/pam_appl.h>
 247                 ],
 248                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 249                 [AC_MSG_RESULT(no)],
 250                 [
 251                         AC_DEFINE(HAVE_OLD_PAM)
 252                         AC_MSG_RESULT(yes)
 253                         PAM_MSG="yes (old library)"
 254                 ]
 255         )
 256 fi
 257
 258 # The big search for OpenSSL
 259 AC_ARG_WITH(ssl-dir,
 260         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 261         [
 262                 if test "x$withval" != "$xno" ; then
 263                         tryssldir=$withval
 264                 fi
 265         ]
 266 )
 267
 268 saved_LIBS="$LIBS"
 269 saved_LDFLAGS="$LDFLAGS"
 270 saved_CFLAGS="$CFLAGS"
 271 if test "x$prefix" != "xNONE" ; then
 272         tryssldir="$tryssldir $prefix"
 273 fi
 274 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 275
 276         for ssldir in "" $tryssldir /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 277                 if test ! -z "$ssldir" ; then
 278                         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 279                         CFLAGS="$saved_CFLAGS -I$ssldir/include"
 280                         if test ! -z "$need_dash_r" ; then
 281                                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 282                         fi
 283                 else
 284                         LDFLAGS="$saved_LDFLAGS"
 285                 fi
 286
 287                 LIBS="$saved_LIBS -lcrypto"
 288
 289                 # Basic test to check for compatible version and correct linking
 290                 # *does not* test for RSA - that comes later.
 291                 AC_TRY_RUN(
 292                         [
 293 #include <string.h>
 294 #include <openssl/rand.h>
 295 int main(void)
 296 {
 297         char a[2048];
 298         memset(a, 0, sizeof(a));
 299         RAND_add(a, sizeof(a), sizeof(a));
 300         return(RAND_status() <= 0);
 301 }
 302                         ],
 303                         [
 304                                 found_crypto=1
 305                                 break;
 306                         ], []
 307                 )
 308
 309                 if test ! -z "$found_crypto" ; then
 310                         break;
 311                 fi
 312         done
 313
 314         if test -z "$found_crypto" ; then
 315                 AC_MSG_ERROR([Could not find working SSLeay / OpenSSL libraries, please install])
 316         fi
 317         if test -z "$ssldir" ; then
 318                 ssldir="(system)"
 319         fi
 320
 321         ac_cv_openssldir=$ssldir
 322 ])
 323
 324 if test ! -z "$ac_cv_openssldir" -a ! "x$ac_cv_openssldir" = "x(system)" ; then
 325         AC_DEFINE(HAVE_OPENSSL)
 326         dnl Need to recover ssldir - test above runs in subshell
 327         ssldir=$ac_cv_openssldir
 328         CFLAGS="$saved_CFLAGS -I$ssldir/include"
 329         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 330         if test ! -z "$need_dash_r" ; then
 331                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 332         fi
 333         if test ! -z "$blibpath" ; then
 334                 blibpath="$blibpath:$ssldir:$ssldir/lib"
 335         fi
 336 fi
 337 LIBS="$saved_LIBS -lcrypto"
 338
 339 # Now test RSA support
 340 saved_LIBS="$LIBS"
 341 AC_MSG_CHECKING([for RSA support])
 342 for WANTS_RSAREF in "" 1 ; do
 343         if test -z "$WANTS_RSAREF" ; then
 344                 LIBS="$saved_LIBS"
 345         else
 346                 LIBS="$saved_LIBS -lRSAglue -lrsaref"
 347         fi
 348         AC_TRY_RUN([
 349 #include <string.h>
 350 #include <openssl/rand.h>
 351 #include <openssl/rsa.h>
 352 #include <openssl/bn.h>
 353 #include <openssl/sha.h>
 354 int main(void)
 355 {
 356         int num; RSA *key; static unsigned char p_in[] = "blahblah";
 357         unsigned char c[256], p[256];
 358         memset(c, 0, sizeof(c)); RAND_add(c, sizeof(c), sizeof(c));
 359         if ((key=RSA_generate_key(512, 3, NULL, NULL))==NULL) return(1);
 360         num = RSA_public_encrypt(sizeof(p_in) - 1, p_in, c, key, RSA_PKCS1_PADDING);
 361         return(-1 == RSA_private_decrypt(num, c, p, key, RSA_PKCS1_PADDING));
 362 }
 363         ],
 364         [
 365                 rsa_works=1
 366                 break;
 367         ], [])
 368 done
 369
 370 if test ! -z "$no_rsa" ; then
 371         AC_MSG_RESULT(disabled)
 372         RSA_MSG="disabled"
 373 else
 374         if test -z "$rsa_works" ; then
 375                 AC_MSG_WARN([*** No RSA support found *** ])
 376                 RSA_MSG="no"
 377         else
 378                 if test -z "$WANTS_RSAREF" ; then
 379                         AC_MSG_RESULT(yes)
 380                         RSA_MSG="yes"
 381                 else
 382                         RSA_MSG="yes (using RSAref)"
 383                         AC_MSG_RESULT(using RSAref)
 384                         LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 385                 fi
 386         fi
 387 fi
 388
 389 # Checks for data types
 390 AC_CHECK_SIZEOF(char, 1)
 391 AC_CHECK_SIZEOF(short int, 2)
 392 AC_CHECK_SIZEOF(int, 4)
 393 AC_CHECK_SIZEOF(long int, 4)
 394 AC_CHECK_SIZEOF(long long int, 8)
 395
 396 # More checks for data types
 397 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
 398         AC_TRY_COMPILE(
 399                 [ #include <sys/types.h> ],
 400                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
 401                 [ ac_cv_have_intxx_t="yes" ],
 402                 [ ac_cv_have_intxx_t="no" ]
 403         )
 404 ])
 405 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
 406         AC_DEFINE(HAVE_INTXX_T)
 407         have_intxx_t=1
 408 fi
 409
 410 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
 411         AC_TRY_COMPILE(
 412                 [ #include <sys/types.h> ],
 413                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
 414                 [ ac_cv_have_u_intxx_t="yes" ],
 415                 [ ac_cv_have_u_intxx_t="no" ]
 416         )
 417 ])
 418 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
 419         AC_DEFINE(HAVE_U_INTXX_T)
 420         have_u_intxx_t=1
 421 fi
 422
 423
 424 if test -z "$have_u_intxx_t" -o -z "$have_intxx_t" -a \
 425            "x$ac_cv_header_sys_bitypes_h" = "xyes"
 426 then
 427         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 428         AC_TRY_COMPILE(
 429                 [
 430 #include <sys/bitypes.h>
 431                 ],
 432                 [
 433                         int8_t a; int16_t b; int32_t c;
 434                         u_int8_t e; u_int16_t f; u_int32_t g;
 435                         a = b = c = e = f = g = 1;
 436                 ],
 437                 [
 438                         AC_DEFINE(HAVE_U_INTXX_T)
 439                         AC_DEFINE(HAVE_INTXX_T)
 440                         AC_MSG_RESULT(yes)
 441                 ],
 442                 [AC_MSG_RESULT(no)]
 443         )
 444 fi
 445
 446 if test -z "$have_u_intxx_t" ; then
 447         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
 448                 AC_TRY_COMPILE(
 449                         [
 450 #include <sys/types.h>
 451                         ],
 452                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
 453                         [ ac_cv_have_uintxx_t="yes" ],
 454                         [ ac_cv_have_uintxx_t="no" ]
 455                 )
 456         ])
 457         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
 458                 AC_DEFINE(HAVE_UINTXX_T)
 459         fi
 460 fi
 461
 462 AC_CACHE_CHECK([for socklen_t], ac_cv_have_socklen_t, [
 463         AC_TRY_COMPILE(
 464                 [
 465 #include <sys/types.h>
 466 #include <sys/socket.h>
 467                 ],
 468                 [socklen_t foo; foo = 1235;],
 469                 [ ac_cv_have_socklen_t="yes" ],
 470                 [ ac_cv_have_socklen_t="no" ]
 471         )
 472 ])
 473 if test "x$ac_cv_have_socklen_t" = "xyes" ; then
 474         AC_DEFINE(HAVE_SOCKLEN_T)
 475 fi
 476
 477 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
 478         AC_TRY_COMPILE(
 479                 [
 480 #include <sys/types.h>
 481                 ],
 482                 [ size_t foo; foo = 1235; ],
 483                 [ ac_cv_have_size_t="yes" ],
 484                 [ ac_cv_have_size_t="no" ]
 485         )
 486 ])
 487 if test "x$ac_cv_have_size_t" = "xyes" ; then
 488         AC_DEFINE(HAVE_SIZE_T)
 489 fi
 490
 491 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
 492         AC_TRY_COMPILE(
 493                 [
 494 #include <sys/types.h>
 495                 ],
 496                 [ ssize_t foo; foo = 1235; ],
 497                 [ ac_cv_have_ssize_t="yes" ],
 498                 [ ac_cv_have_ssize_t="no" ]
 499         )
 500 ])
 501 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
 502         AC_DEFINE(HAVE_SSIZE_T)
 503 fi
 504
 505 AC_CACHE_CHECK([for pid_t], ac_cv_have_pid_t, [
 506         AC_TRY_COMPILE(
 507                 [
 508 #include <sys/types.h>
 509                 ],
 510                 [ pid_t foo; foo = 1235; ],
 511                 [ ac_cv_have_pid_t="yes" ],
 512                 [ ac_cv_have_pid_t="no" ]
 513         )
 514 ])
 515 if test "x$ac_cv_have_pid_t" = "xyes" ; then
 516         AC_DEFINE(HAVE_PID_T)
 517 fi
 518
 519 AC_CACHE_CHECK([for mode_t], ac_cv_have_mode_t, [
 520         AC_TRY_COMPILE(
 521                 [
 522 #include <sys/types.h>
 523                 ],
 524                 [ mode_t foo; foo = 1235; ],
 525                 [ ac_cv_have_mode_t="yes" ],
 526                 [ ac_cv_have_mode_t="no" ]
 527         )
 528 ])
 529 if test "x$ac_cv_have_mode_t" = "xyes" ; then
 530         AC_DEFINE(HAVE_MODE_T)
 531 fi
 532
 533
 534 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
 535         AC_TRY_COMPILE(
 536                 [
 537 #include <sys/types.h>
 538 #include <sys/socket.h>
 539                 ],
 540                 [ struct sockaddr_storage s; ],
 541                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
 542                 [ ac_cv_have_struct_sockaddr_storage="no" ]
 543         )
 544 ])
 545 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
 546         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 547 fi
 548
 549 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
 550         AC_TRY_COMPILE(
 551                 [
 552 #include <sys/types.h>
 553 #include <netinet/in.h>
 554                 ],
 555                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
 556                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
 557                 [ ac_cv_have_struct_sockaddr_in6="no" ]
 558         )
 559 ])
 560 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
 561         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 562 fi
 563
 564 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
 565         AC_TRY_COMPILE(
 566                 [
 567 #include <sys/types.h>
 568 #include <netinet/in.h>
 569                 ],
 570                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
 571                 [ ac_cv_have_struct_in6_addr="yes" ],
 572                 [ ac_cv_have_struct_in6_addr="no" ]
 573         )
 574 ])
 575 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
 576         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 577 fi
 578
 579 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
 580         AC_TRY_COMPILE(
 581                 [
 582 #include <sys/types.h>
 583 #include <sys/socket.h>
 584 #include <netdb.h>
 585                 ],
 586                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
 587                 [ ac_cv_have_struct_addrinfo="yes" ],
 588                 [ ac_cv_have_struct_addrinfo="no" ]
 589         )
 590 ])
 591 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
 592         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 593 fi
 594
 595
 596 # Checks for structure members
 597
 598 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
 599 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
 600 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
 601 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
 602 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
 603 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
 604 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
 605 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
 606 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
 607 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
 608 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
 609 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
 610 OSSH_CHECK_HEADER_FOR_FIELD(ut_exit, utmp.h, HAVE_EXIT_IN_UTMP)
 611 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmp.h, HAVE_TIME_IN_UTMP)
 612 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmpx.h, HAVE_TIME_IN_UTMPX)
 613 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmpx.h, HAVE_TV_IN_UTMPX)
 614
 615 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
 616                 ac_cv_have_ss_family_in_struct_ss, [
 617         AC_TRY_COMPILE(
 618                 [
 619 #include <sys/types.h>
 620 #include <sys/socket.h>
 621                 ],
 622                 [ struct sockaddr_storage s; s.ss_family = 1; ],
 623                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
 624                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
 625         )
 626 ])
 627 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
 628         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 629 fi
 630
 631 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
 632                 ac_cv_have___ss_family_in_struct_ss, [
 633         AC_TRY_COMPILE(
 634                 [
 635 #include <sys/types.h>
 636 #include <sys/socket.h>
 637                 ],
 638                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
 639                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
 640                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
 641         )
 642 ])
 643 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
 644         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 645 fi
 646
 647
 648 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
 649         AC_TRY_LINK([],
 650                 [ extern char *__progname; printf("%s", __progname); ],
 651                 [ ac_cv_libc_defines___progname="yes" ],
 652                 [ ac_cv_libc_defines___progname="no" ]
 653         )
 654 ])
 655 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
 656         AC_DEFINE(HAVE___PROGNAME)
 657 fi
 658
 659
 660 # Looking for programs, paths and files
 661 AC_ARG_WITH(rsh,
 662         [  --with-rsh=PATH         Specify path to remote shell program ],
 663         [
 664                 if test "x$withval" != "$no" ; then
 665                         rsa_path=$withval
 666                 fi
 667         ],
 668         [
 669                 AC_PATH_PROG(rsh_path, rsh)
 670         ]
 671 )
 672
 673 AC_ARG_WITH(xauth,
 674         [  --with-xauth=PATH       Specify path to xauth program ],
 675         [
 676                 if test "x$withval" != "$xno" ; then
 677                         xauth_path=$withval
 678                 fi
 679         ],
 680         [
 681                 AC_PATH_PROG(xauth_path, xauth)
 682                 if test ! -z "$xauth_path" -a -x "/usr/openwin/bin/xauth" ; then
 683                         xauth_path="/usr/openwin/bin/xauth"
 684                 fi
 685         ]
 686 )
 687
 688 if test ! -z "$xauth_path" ; then
 689         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
 690 fi
 691 if test ! -z "$rsh_path" ; then
 692         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
 693 fi
 694
 695 # Check for mail directory (last resort if we cannot get it from headers)
 696 if test ! -z "$MAIL" ; then
 697         maildir=`dirname $MAIL`
 698         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
 699 fi
 700
 701 if test -z "$no_dev_ptmx" ; then
 702         AC_CHECK_FILE("/dev/ptmx",
 703                 [
 704                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
 705                         have_dev_ptmx=1
 706                 ]
 707         )
 708 fi
 709 AC_CHECK_FILE("/dev/ptc",
 710         [
 711                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
 712                 have_dev_ptc=1
 713         ]
 714 )
 715
 716 # Options from here on. Some of these are preset by platform above
 717
 718 # Check for user-specified random device, otherwise check /dev/urandom
 719 AC_ARG_WITH(random,
 720         [  --with-random=FILE      read randomness from FILE (default=/dev/urandom)],
 721         [
 722                 if test "x$withval" != "xno" ; then
 723                         RANDOM_POOL="$withval";
 724                         AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 725                 fi
 726         ],
 727         [
 728                 # Check for random device
 729                 AC_CHECK_FILE("/dev/urandom",
 730                         [
 731                                 RANDOM_POOL="/dev/urandom";
 732                                 AC_SUBST(RANDOM_POOL)
 733                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 734                         ]
 735                 )
 736         ]
 737 )
 738
 739 # Check for EGD pool file
 740 AC_ARG_WITH(egd-pool,
 741         [  --with-egd-pool=FILE    read randomness from EGD pool FILE (default none)],
 742         [
 743                 if test "x$withval" != "xno" ; then
 744                         EGD_SOCKET="$withval";
 745                         AC_DEFINE_UNQUOTED(EGD_SOCKET, "$EGD_SOCKET")
 746                 fi
 747         ]
 748 )
 749
 750 # detect pathnames for entropy gathering commands, if we need them
 751 INSTALL_SSH_PRNG_CMDS=""
 752 rm -f prng_commands
 753 if test -z "$RANDOM_POOL" -a -z "$EGD_SOCKET" ; then
 754         # Use these commands to collect entropy
 755         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
 756         OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
 757         OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
 758         OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
 759         OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
 760         OSSH_PATH_ENTROPY_PROG(PROG_W, w)
 761         OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
 762         OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
 763         OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
 764         OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
 765         OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
 766         OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
 767         OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
 768         OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
 769         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
 770
 771         INSTALL_SSH_PRNG_CMDS="yes"
 772 fi
 773 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
 774
 775
 776 AC_ARG_WITH(catman,
 777         [  --with-catman=man|cat   Install preformatted manpages[no]],
 778         [
 779                 MANTYPE='$(CATMAN)'
 780                 if test x"$withval" != x"yes" ; then
 781                    mansubdir=$withval
 782                 else
 783                    mansubdir=cat
 784                 fi
 785         ], [
 786                 if test -z "$MANTYPE" ; then
 787                         MANTYPE='$(TROFFMAN)'
 788                         mansubdir=man
 789                 fi
 790         ]
 791 )
 792 AC_SUBST(MANTYPE)
 793 AC_SUBST(mansubdir)
 794
 795 # Check whether user wants Kerberos support
 796 KRB4_MSG="no"
 797 AC_ARG_WITH(kerberos4,
 798         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
 799         [
 800                 if test "x$withval" != "xno" ; then
 801
 802                         if test "x$withval" != "$xyes" ; then
 803                                 CFLAGS="$CFLAGS -I${withval}/include"
 804                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 805                                 if test ! -z "$need_dash_r" ; then
 806                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
 807                                 fi
 808                                 if test ! -z "$blibpath" ; then
 809                                         blibpath="$blibpath:${withval}/lib"
 810                                 fi
 811                         else
 812                                 if test -d /usr/include/kerberosIV ; then
 813                                         CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 814                                 fi
 815                         fi
 816
 817                         AC_CHECK_HEADERS(krb.h)
 818                         AC_CHECK_LIB(krb, main)
 819                         if test "$ac_cv_header_krb_h" != yes; then
 820                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
 821                         fi
 822                         if test "$ac_cv_lib_krb_main" != yes; then
 823                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
 824                         fi
 825
 826                         KLIBS="-lkrb -ldes"
 827                         AC_CHECK_LIB(resolv, dn_expand, , )
 828                         KRB4=yes
 829                         KRB4_MSG="yes"
 830                         AC_DEFINE(KRB4)
 831                 fi
 832         ]
 833 )
 834
 835 # Check whether user wants AFS support
 836 AFS_MSG="no"
 837 AC_ARG_WITH(afs,
 838         [  --with-afs=PATH         Enable AFS support],
 839         [
 840                 if test "x$withval" != "xno" ; then
 841
 842                         if test "x$withval" != "$xyes" ; then
 843                                 CFLAGS="$CFLAGS -I${withval}/include"
 844                                 LFLAGS="$LFLAGS -L${withval}/lib"
 845                         fi
 846
 847                         if test -z "$KRB4" ; then
 848                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
 849                         fi
 850
 851                         LIBS="$LIBS -lkafs"
 852                         if test ! -z "$AFS_LIBS" ; then
 853                                 LIBS="$LIBS $AFS_LIBS"
 854                         fi
 855                         AC_DEFINE(AFS)
 856                         AFS_MSG="yes"
 857                 fi
 858         ]
 859 )
 860 LIBS="$LIBS $KLIBS"
 861
 862 # Check whether user wants S/Key support
 863 SKEY_MSG="no"
 864 AC_ARG_WITH(skey,
 865         [  --with-skey             Enable S/Key support],
 866         [
 867                 if test "x$withval" != "xno" ; then
 868                         AC_DEFINE(SKEY)
 869                         LIBS="$LIBS -lskey"
 870                         SKEY_MSG="yes"
 871                 fi
 872         ]
 873 )
 874
 875 # Check whether user wants TCP wrappers support
 876 TCPW_MSG="no"
 877 AC_ARG_WITH(tcp-wrappers,
 878         [  --with-tcp-wrappers     Enable tcpwrappers support],
 879         [
 880                 if test "x$withval" != "xno" ; then
 881                         saved_LIBS="$LIBS"
 882                         LIBS="$LIBS -lwrap"
 883                         AC_MSG_CHECKING(for libwrap)
 884                         AC_TRY_LINK(
 885                                 [
 886 #include <tcpd.h>
 887                                         int deny_severity = 0, allow_severity = 0;
 888                                 ],
 889                                 [hosts_access(0);],
 890                                 [
 891                                         AC_MSG_RESULT(yes)
 892                                         AC_DEFINE(LIBWRAP)
 893                                         TCPW_MSG="yes"
 894                                 ],
 895                                 [
 896                                         AC_MSG_ERROR([*** libwrap missing])
 897                                 ]
 898                         )
 899                 fi
 900         ]
 901 )
 902
 903 # Check whether to enable MD5 passwords
 904 MD5_MSG="no"
 905 AC_ARG_WITH(md5-passwords,
 906         [  --with-md5-passwords    Enable use of MD5 passwords],
 907         [
 908                 if test "x$withval" != "xno" ; then
 909                         AC_DEFINE(HAVE_MD5_PASSWORDS)
 910                         MD5_MSG="yes"
 911                 fi
 912         ]
 913 )
 914
 915 # Whether to disable shadow password support
 916 AC_ARG_WITH(shadow,
 917         [  --without-shadow        Disable shadow password support],
 918         [
 919                 if test "x$withval" = "xno" ; then
 920                         AC_DEFINE(DISABLE_SHADOW)
 921                 fi
 922         ]
 923 )
 924
 925 # Use ip address instead of hostname in $DISPLAY
 926 DISPLAY_HACK_MSG="no"
 927 AC_ARG_WITH(ipaddr-display,
 928         [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
 929         [
 930                 if test "x$withval" = "xno" ; then
 931                         AC_DEFINE(IPADDR_IN_DISPLAY)
 932                         DISPLAY_HACK_MSG="yes"
 933                 fi
 934         ]
 935 )
 936
 937 # Whether to mess with the default path
 938 SERVER_PATH_MSG="(default)"
 939 AC_ARG_WITH(default-path,
 940         [  --with-default-path=PATH Specify default \$PATH environment for server],
 941         [
 942                 if test "x$withval" != "xno" ; then
 943                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
 944                         SERVER_PATH_MSG="$withval"
 945                 fi
 946         ]
 947 )
 948
 949 # Whether to force IPv4 by default (needed on broken glibc Linux)
 950 IPV4_HACK_MSG="no"
 951 AC_ARG_WITH(ipv4-default,
 952         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
 953         [
 954                 if test "x$withval" != "xno" ; then
 955                         AC_DEFINE(IPV4_DEFAULT)
 956                         IPV4_HACK_MSG="yes"
 957                 fi
 958         ]
 959 )
 960
 961 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
 962 IPV4_IN6_HACK_MSG="no"
 963 AC_ARG_WITH(4in6,
 964         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
 965         [
 966                 if test "x$withval" != "xno" ; then
 967                         AC_MSG_RESULT(yes)
 968                         AC_DEFINE(IPV4_IN_IPV6)
 969                         IPV4_IN6_HACK_MSG="yes"
 970                 else
 971                         AC_MSG_RESULT(no)
 972                 fi
 973         ],[
 974                 if test "x$inet6_default_4in6" = "xyes"; then
 975                         AC_MSG_RESULT([yes (default)])
 976                         AC_DEFINE(IPV4_IN_IPV6)
 977                         IPV4_IN6_HACK_MSG="yes"
 978                 else
 979                         AC_MSG_RESULT([no (default)])
 980                 fi
 981         ]
 982 )
 983
 984 # Where to place sshd.pid
 985 piddir=/var/run
 986 AC_ARG_WITH(pid-dir,
 987         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
 988         [
 989                 if test "x$withval" != "xno" ; then
 990                         piddir=$withval
 991                 fi
 992         ]
 993 )
 994
 995 AC_DEFINE_UNQUOTED(PIDDIR, "$piddir")
 996 AC_SUBST(piddir)
 997
 998 dnl allow user to disable some login recording features
 999 AC_ARG_ENABLE(lastlog,
1000         [ --disable-lastlog        disable use of lastlog even if detected [no]],
1001         [ AC_DEFINE(DISABLE_LASTLOG) ]
1002 )
1003 AC_ARG_ENABLE(utmp,
1004         [ --disable-utmp           disable use of utmp even if detected [no]],
1005         [ AC_DEFINE(DISABLE_UTMP) ]
1006 )
1007 AC_ARG_ENABLE(utmpx,
1008         [ --disable-utmpx          disable use of utmpx even if detected [no]],
1009         [ AC_DEFINE(DISABLE_UTMPX) ]
1010 )
1011 AC_ARG_ENABLE(wtmp,
1012         [ --disable-wtmp           disable use of wtmp even if detected [no]],
1013         [ AC_DEFINE(DISABLE_WTMP) ]
1014 )
1015 AC_ARG_ENABLE(wtmpx,
1016         [ --disable-wtmpx          disable use of wtmpx even if detected [no]],
1017         [ AC_DEFINE(DISABLE_WTMPX) ]
1018 )
1019 AC_ARG_ENABLE(libutil,
1020         [ --disable-libutil        disable use of libutil (login() etc.) [no]],
1021         [ AC_DEFINE(DISABLE_LOGIN) ]
1022 )
1023 AC_ARG_ENABLE(pututline,
1024         [ --disable-pututline      disable use of pututline() etc. ([uw]tmp) [no]],
1025         [ AC_DEFINE(DISABLE_PUTUTLINE) ]
1026 )
1027 AC_ARG_ENABLE(pututxline,
1028         [ --disable-pututxline      disable use of pututxline() etc. ([uw]tmpx) [no]],
1029         [ AC_DEFINE(DISABLE_PUTUTXLINE) ]
1030 )
1031 AC_ARG_WITH(lastlog,
1032   [ --with-lastlog=FILE|DIR  specify lastlog location [common locations]],
1033   [ conf_lastlog_location="$withval";  ],)
1034
1035 dnl lastlog, [uw]tmpx? detection
1036 dnl  NOTE: set the paths in the platform section to avoid the
1037 dnl   need for command-line parameters
1038 dnl lastlog and [uw]tmp are subject to a file search if all else fails
1039
1040 dnl lastlog detection
1041 dnl  NOTE: the code itself will detect if lastlog is a directory
1042 AC_MSG_CHECKING([if your system defines LASTLOG_FILE])
1043 AC_TRY_COMPILE([
1044 #include <sys/types.h>
1045 #include <utmp.h>
1046 #ifdef HAVE_LASTLOG_H
1047 #  include <lastlog.h>
1048 #endif
1049 #ifdef HAVE_PATHS_H
1050 #  include <paths.h>
1051 #endif
1052         ],
1053         [ char *lastlog = LASTLOG_FILE; ],
1054         [ AC_MSG_RESULT(yes) ],
1055         [
1056                 AC_MSG_RESULT(no)
1057                 AC_MSG_CHECKING([if your system defines _PATH_LASTLOG])
1058                 AC_TRY_COMPILE([
1059 #include <sys/types.h>
1060 #include <utmp.h>
1061 #ifdef HAVE_LASTLOG_H
1062 #  include <lastlog.h>
1063 #endif
1064 #ifdef HAVE_PATHS_H
1065 #  include <paths.h>
1066 #endif
1067                 ],
1068                 [ char *lastlog = _PATH_LASTLOG; ],
1069                 [ AC_MSG_RESULT(yes) ],
1070                 [
1071                         AC_MSG_RESULT(no)
1072                         system_lastlog_path=no
1073                 ])
1074         ]
1075 )
1076
1077 if test -z "$conf_lastlog_location"; then
1078         if test x"$system_lastlog_path" = x"no" ; then
1079                 for f in /var/log/lastlog /usr/adm/lastlog /var/adm/lastlog /etc/security/lastlog ; do
1080                                 if test -d "$f" -o -f "$f" ; then
1081                                         conf_lastlog_location=$f
1082                                 fi
1083                 done
1084                 if test -z "$conf_lastlog_location"; then
1085                         AC_MSG_WARN([** Cannot find lastlog **])
1086                         dnl Don't define DISABLE_LASTLOG - that means we don't try wtmp/wtmpx
1087                 fi
1088         fi
1089 fi
1090
1091 if test -n "$conf_lastlog_location"; then
1092         AC_DEFINE_UNQUOTED(CONF_LASTLOG_FILE, "$conf_lastlog_location")
1093 fi
1094
1095 dnl utmp detection
1096 AC_MSG_CHECKING([if your system defines UTMP_FILE])
1097 AC_TRY_COMPILE([
1098 #include <sys/types.h>
1099 #include <utmp.h>
1100 #ifdef HAVE_PATHS_H
1101 #  include <paths.h>
1102 #endif
1103         ],
1104         [ char *utmp = UTMP_FILE; ],
1105         [ AC_MSG_RESULT(yes) ],
1106         [ AC_MSG_RESULT(no)
1107           system_utmp_path=no ]
1108 )
1109 if test -z "$conf_utmp_location"; then
1110         if test x"$system_utmp_path" = x"no" ; then
1111                 for f in /etc/utmp /usr/adm/utmp /var/run/utmp; do
1112                         if test -f $f ; then
1113                                 conf_utmp_location=$f
1114                         fi
1115                 done
1116                 if test -z "$conf_utmp_location"; then
1117                         AC_DEFINE(DISABLE_UTMP)
1118                 fi
1119         fi
1120 fi
1121 if test -n "$conf_utmp_location"; then
1122         AC_DEFINE_UNQUOTED(CONF_UTMP_FILE, "$conf_utmp_location")
1123 fi
1124
1125 dnl wtmp detection
1126 AC_MSG_CHECKING([if your system defines WTMP_FILE])
1127 AC_TRY_COMPILE([
1128 #include <sys/types.h>
1129 #include <utmp.h>
1130 #ifdef HAVE_PATHS_H
1131 #  include <paths.h>
1132 #endif
1133         ],
1134         [ char *wtmp = WTMP_FILE; ],
1135         [ AC_MSG_RESULT(yes) ],
1136         [ AC_MSG_RESULT(no)
1137           system_wtmp_path=no ]
1138 )
1139 if test -z "$conf_wtmp_location"; then
1140         if test x"$system_wtmp_path" = x"no" ; then
1141                 for f in /usr/adm/wtmp /var/log/wtmp; do
1142                         if test -f $f ; then
1143                                 conf_wtmp_location=$f
1144                         fi
1145                 done
1146                 if test -z "$conf_wtmp_location"; then
1147                         AC_DEFINE(DISABLE_WTMP)
1148                 fi
1149         fi
1150 fi
1151 if test -n "$conf_wtmp_location"; then
1152         AC_DEFINE_UNQUOTED(CONF_WTMP_FILE, "$conf_wtmp_location")
1153 fi
1154
1155
1156 dnl utmpx detection - I don't know any system so perverse as to require
1157 dnl  utmpx, but not define UTMPX_FILE (ditto wtmpx.) No doubt it's out
1158 dnl  there, though.
1159 AC_MSG_CHECKING([if your system defines UTMPX_FILE])
1160 AC_TRY_COMPILE([
1161 #include <sys/types.h>
1162 #include <utmp.h>
1163 #ifdef HAVE_UTMPX_H
1164 #include <utmpx.h>
1165 #endif
1166 #ifdef HAVE_PATHS_H
1167 #  include <paths.h>
1168 #endif
1169         ],
1170         [ char *utmpx = UTMPX_FILE; ],
1171         [ AC_MSG_RESULT(yes) ],
1172         [ AC_MSG_RESULT(no)
1173           system_utmpx_path=no ]
1174 )
1175 if test -z "$conf_utmpx_location"; then
1176         if test x"$system_utmpx_path" = x"no" ; then
1177                 AC_DEFINE(DISABLE_UTMPX)
1178         fi
1179 else
1180         AC_DEFINE_UNQUOTED(CONF_UTMPX_FILE, "$conf_utmpx_location")
1181 fi
1182
1183 dnl wtmpx detection
1184 AC_MSG_CHECKING([if your system defines WTMPX_FILE])
1185 AC_TRY_COMPILE([
1186 #include <sys/types.h>
1187 #include <utmp.h>
1188 #ifdef HAVE_UTMPX_H
1189 #include <utmpx.h>
1190 #endif
1191 #ifdef HAVE_PATHS_H
1192 #  include <paths.h>
1193 #endif
1194         ],
1195         [ char *wtmpx = WTMPX_FILE; ],
1196         [ AC_MSG_RESULT(yes) ],
1197         [ AC_MSG_RESULT(no)
1198           system_wtmpx_path=no ]
1199 )
1200 if test -z "$conf_wtmpx_location"; then
1201         if test x"$system_wtmpx_path" = x"no" ; then
1202                 AC_DEFINE(DISABLE_WTMPX)
1203         fi
1204 else
1205         AC_DEFINE_UNQUOTED(CONF_WTMPX_FILE, "$conf_wtmpx_location")
1206 fi
1207
1208
1209 # Change default command timeout for builtin PRNG
1210 entropy_timeout=200
1211 AC_ARG_WITH(entropy-timeout,
1212         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
1213         [
1214                 if test "x$withval" != "xno" ; then
1215                         entropy_timeout=$withval
1216                 fi
1217         ]
1218 )
1219 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
1220
1221
1222 if test ! -z "$blibpath" ; then
1223         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
1224         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
1225 fi
1226
1227 AC_OUTPUT(Makefile ssh_prng_cmds)
1228
1229 # Print summary of options
1230
1231 if test x$MANTYPE = x'$(CATMAN)' ; then
1232         MAN_MSG=cat
1233 else
1234         MAN_MSG=man
1235 fi
1236 if test ! -z "$RANDOM_POOL" ; then
1237         RAND_MSG="Device ($RANDOM_POOL)"
1238 else
1239         if test ! -z "$EGD_SOCKET" ; then
1240                 RAND_MSG="EGD ($EGD_SOCKET)"
1241         else
1242                 RAND_MSG="Builtin (timeout $entropy_timeout)"
1243         fi
1244 fi
1245
1246 # Someone please show me a better way :)
1247 A=`eval echo ${prefix}` ; A=`eval echo ${A}`
1248 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
1249 C=`eval echo ${sbindir}` ; C=`eval echo ${C}`
1250 D=`eval echo ${sysconfdir}` ; D=`eval echo ${D}`
1251 E=`eval echo ${libexecdir}/ssh/ssh-askpass` ; E=`eval echo ${E}`
1252 F=`eval echo ${mandir}/${mansubdir}X` ; F=`eval echo ${F}`
1253 G=`eval echo ${piddir}` ; G=`eval echo ${G}`
1254
1255 echo ""
1256 echo "OpenSSH configured has been configured with the following options."
1257 echo "                 User binaries: $B"
1258 echo "               System binaries: $C"
1259 echo "           Configuration files: $D"
1260 echo "               Askpass program: $E"
1261 echo "                  Manual pages: $F"
1262 echo "                      PID file: $G"
1263 echo "      Random number collection: $RAND_MSG"
1264 echo "                Manpage format: $MAN_MSG"
1265 echo "                   PAM support: ${PAM_MSG}"
1266 echo "            KerberosIV support: $KRB4_MSG"
1267 echo "                   AFS support: $AFS_MSG"
1268 echo "                 S/KEY support: $SKEY_MSG"
1269 echo "          TCP Wrappers support: $TCPW_MSG"
1270 echo "          MD5 password support: $MD5_MSG"
1271 echo "   IP address in \$DISPLAY hack: $DISPLAY_HACK_MSG"
1272 echo "      Use IPv4 by default hack: $IPV4_HACK_MSG"
1273 echo "       Translate v4 in v6 hack: $IPV4_IN6_HACK_MSG"
1274
1275 echo ""
1276
1277 echo "Compiler flags: ${CFLAGS}"
1278 echo "Linker flags: ${LDFLAGS}"
1279 echo "Libraries: ${LIBS}"
1280
1281 echo ""
1282