configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_CANONICAL_HOST
   5
   6 # C Compiler features
   7 if test "$GCC" = "yes"; then CFLAGS="$CFLAGS -Wall"; fi
   8 AC_C_INLINE
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_CPP
  13 AC_PROG_RANLIB
  14 AC_PROG_INSTALL
  15 AC_CHECK_PROG(AR, ar, ar)
  16 AC_PATH_PROG(PERL, perl)
  17 AC_SUBST(PERL)
  18
  19 # Check for some target-specific stuff
  20 case "$host" in
  21 *-*-aix*)
  22         AFS_LIBS="-lld"
  23         AC_DEFINE(BROKEN_GETADDRINFO)
  24         ;;
  25 *-*-hpux10*)
  26         if test -z "$GCC"; then
  27                 CFLAGS="$CFLAGS -Aa"
  28         fi
  29         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  30         AC_DEFINE(IPADDR_IN_DISPLAY)
  31         AC_DEFINE(USE_UTMPX)
  32         AC_MSG_CHECKING(for HPUX trusted system password database)
  33         if test -f /tcb/files/auth/system/default; then
  34                 AC_MSG_RESULT(yes)
  35                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  36                 LIBS="$LIBS -lsec"
  37                 AC_MSG_WARN([This configuration is untested])
  38         else
  39                 AC_MSG_RESULT(no)
  40                 AC_DEFINE(DISABLE_SHADOW)
  41         fi
  42         MANTYPE='$(CATMAN)'
  43         mansubdir=cat
  44         ;;
  45 *-*-irix5*)
  46         MANTYPE='$(CATMAN)'
  47         no_libsocket=1
  48         no_libnsl=1
  49         ;;
  50 *-*-irix6*)
  51         MANTYPE='$(CATMAN)'
  52         AC_MSG_WARN([*** Irix 6.x is not tested, please report you experiences *** ])
  53         no_libsocket=1
  54         no_libnsl=1
  55         ;;
  56 *-*-linux*)
  57         no_dev_ptmx=1
  58         need_pty_removed_on_close=1
  59         ;;
  60 *-*-netbsd*)
  61         need_dash_r=1
  62         ;;
  63 *-*-solaris*)
  64         need_dash_r=1
  65         AC_DEFINE(USE_UTMPX)
  66         ;;
  67 *-*-sysv*)
  68         AC_DEFINE(USE_UTMPX)
  69         MANTYPE='$(CATMAN)'
  70         mansubdir=cat
  71         LIBS="$LIBS -lgen -lsocket"
  72         ;;
  73 esac
  74
  75 # Checks for libraries.
  76 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
  77 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
  78
  79 if test -z "$no_libsocket" ; then
  80         AC_CHECK_LIB(nsl, yp_match, , )
  81 fi
  82 if test -z "$no_libnsl" ; then
  83         AC_CHECK_LIB(socket, main, , )
  84 fi
  85
  86 # Checks for header files.
  87 AC_CHECK_HEADERS(bstring.h endian.h lastlog.h login.h maillock.h netdb.h netgroup.h paths.h poll.h pty.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/select.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h stddef.h util.h utmp.h utmpx.h)
  88
  89 # Checks for library functions.
  90 AC_CHECK_FUNCS(arc4random bindresvport_af freeaddrinfo gai_strerror getaddrinfo getpagesize getnameinfo innetgr md5_crypt mkdtemp openpty rresvport_af setenv seteuid setlogin setproctitle setreuid snprintf strlcat strlcpy updwtmpx vsnprintf _getpty)
  91
  92 AC_CHECK_FUNC(login,
  93         [AC_DEFINE(HAVE_LOGIN)],
  94         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
  95 )
  96
  97 AC_CHECK_FUNC(daemon,
  98         [AC_DEFINE(HAVE_DAEMON)],
  99         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 100 )
 101
 102 AC_ARG_WITH(pam,
 103         [  --without-pam           Disable PAM support ],
 104         [
 105                 if test "x$withval" = "xno" ; then
 106                         no_pam=1
 107                         AC_DEFINE(DISABLE_PAM)
 108                 fi
 109         ]
 110 )
 111 if test -z "$no_pam" -a "x$ac_cv_header_security_pam_appl_h" = "xyes" ; then
 112         AC_CHECK_LIB(dl, dlopen, , )
 113         LIBS="$LIBS -lpam"
 114
 115         # Check PAM strerror arguments (old PAM)
 116         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 117         AC_TRY_COMPILE(
 118                 [
 119                         #include <stdlib.h>
 120                         #include <security/pam_appl.h>
 121                 ],
 122                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 123                 [AC_MSG_RESULT(no)],
 124                 [
 125                         AC_DEFINE(HAVE_OLD_PAM)
 126                         AC_MSG_RESULT(yes)
 127                 ]
 128         )
 129 fi
 130
 131 # The big search for OpenSSL
 132 AC_ARG_WITH(ssl-dir,
 133         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 134         [
 135                 if test "x$withval" != "$xno" ; then
 136                         tryssldir=$withval
 137                 fi
 138         ]
 139 )
 140
 141 saved_LIBS="$LIBS"
 142 saved_CFLAGS="$CFLAGS"
 143 if test "x$prefix" != "xNONE" ; then
 144         tryssldir="$tryssldir $prefix"
 145 fi
 146 AC_MSG_CHECKING([for OpenSSL/SSLeay directory])
 147 for ssldir in "" $tryssldir /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 148         if test ! -z "$ssldir" ; then
 149                 LIBS="$saved_LIBS -L$ssldir"
 150                 CFLAGS="$CFLAGS -I$ssldir/include"
 151                 if test "x$need_dash_r" = "x1" ; then
 152                         LIBS="$LIBS -R$ssldir"
 153                 fi
 154         fi
 155         LIBS="$LIBS -lcrypto"
 156
 157         AC_TRY_RUN(
 158                 [
 159                         #include <openssl/rsa.h>
 160                         #include <openssl/bn.h>
 161                         #include <openssl/sha.h>
 162                         int main(void)
 163                         {RSA *key;key=RSA_generate_key(32,3,NULL,NULL);return(key==NULL);}
 164                 ],
 165                 [
 166                         AC_DEFINE(HAVE_OPENSSL)
 167                         found_crypto=1
 168                         break;
 169                 ], []
 170         )
 171         AC_TRY_RUN(
 172                 [
 173                         #include <ssl/rsa.h>
 174                         #include <ssl/bn.h>
 175                         #include <ssl/sha.h>
 176                         int main(void)
 177                         {RSA *key;key=RSA_generate_key(32,3,NULL,NULL);return(key==NULL);}
 178                 ],
 179                 [
 180                         AC_DEFINE(HAVE_SSL)
 181                         found_crypto=1
 182                         break;
 183                 ], []
 184         )
 185 done
 186
 187 if test -z "$found_crypto" ; then
 188         AC_MSG_ERROR([Could not find working SSLeay / OpenSSL libraries, please install])
 189 fi
 190 if test -z "$ssldir" ; then
 191         ssldir="(system)"
 192 else
 193         CFLAGS="$CFLAGS -I$ssldir/include"
 194         LDFLAGS="$LDFLAGS -L$ssldir/lib"
 195         if test "x$need_dash_r" = "x1" ; then
 196                 LDFLAGS="$LDFLAGS -R$ssldir"
 197         fi
 198 fi
 199 LIBS="$saved_LIBS -lcrypto"
 200 AC_MSG_RESULT($ssldir)
 201
 202 # Checks for data types
 203 AC_CHECK_SIZEOF(char, 1)
 204 AC_CHECK_SIZEOF(short int, 2)
 205 AC_CHECK_SIZEOF(int, 4)
 206 AC_CHECK_SIZEOF(long int, 4)
 207 AC_CHECK_SIZEOF(long long int, 8)
 208
 209 # More checks for data types
 210 AC_MSG_CHECKING([for intXX_t types])
 211 AC_TRY_COMPILE(
 212         [#include <sys/types.h>],
 213         [int16_t a; int32_t b; a = 1235; b = 1235;],
 214         [
 215                 AC_DEFINE(HAVE_INTXX_T)
 216                 AC_MSG_RESULT(yes)
 217                 have_intxx_t=1
 218         ],
 219         [AC_MSG_RESULT(no)]
 220 )
 221
 222 AC_MSG_CHECKING([for u_intXX_t types])
 223 AC_TRY_COMPILE(
 224         [#include <sys/types.h>],
 225         [u_int16_t c; u_int32_t d; c = 1235; d = 1235;],
 226         [
 227                 AC_DEFINE(HAVE_U_INTXX_T)
 228                 AC_MSG_RESULT(yes)
 229                 have_u_intxx_t=1
 230         ],
 231         [AC_MSG_RESULT(no)]
 232 )
 233
 234 if test -z "$have_u_intxx_t" -o -z "$have_intxx_t" -a \
 235            "x$ac_cv_header_sys_bitypes_h" = "xyes"
 236 then
 237         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 238         AC_TRY_COMPILE(
 239                 [#include <sys/bitypes.h>],
 240                 [
 241                         u_int16_t c; u_int32_t d;
 242                         int16_t e; int32_t f;
 243                         c = 1235; d = 1235;
 244                         e = 1235; f = 1235;
 245                 ],
 246                 [
 247                         AC_DEFINE(HAVE_U_INTXX_T)
 248                         AC_DEFINE(HAVE_INTXX_T)
 249                         AC_MSG_RESULT(yes)
 250                 ],
 251                 [AC_MSG_RESULT(no)]
 252         )
 253 fi
 254
 255 AC_MSG_CHECKING([for uintXX_t types])
 256 AC_TRY_COMPILE(
 257         [#include <sys/types.h>],
 258         [uint16_t c; uint32_t d; c = 1235; d = 1235;],
 259         [
 260                 AC_DEFINE(HAVE_UINTXX_T)
 261                 AC_MSG_RESULT(yes)
 262         ],
 263         [AC_MSG_RESULT(no)]
 264 )
 265
 266 AC_MSG_CHECKING([for socklen_t])
 267 AC_TRY_COMPILE(
 268         [
 269                 #include <sys/types.h>
 270                 #include <sys/socket.h>
 271         ],
 272         [socklen_t foo; foo = 1235;],
 273         [
 274                 AC_DEFINE(HAVE_SOCKLEN_T)
 275                 AC_MSG_RESULT(yes)
 276         ],
 277         [AC_MSG_RESULT(no)]
 278 )
 279
 280 AC_MSG_CHECKING([for size_t])
 281 AC_TRY_COMPILE(
 282         [#include <sys/types.h>],
 283         [size_t foo; foo = 1235;],
 284         [
 285                 AC_DEFINE(HAVE_SIZE_T)
 286                 AC_MSG_RESULT(yes)
 287         ],
 288         [AC_MSG_RESULT(no)]
 289 )
 290
 291 AC_MSG_CHECKING([for struct sockaddr_storage])
 292 AC_TRY_COMPILE(
 293         [
 294                 #include <sys/types.h>
 295                 #include <sys/socket.h>
 296         ],
 297         [struct sockaddr_storage s;],
 298         [
 299                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 300                 AC_MSG_RESULT(yes)
 301         ],
 302         [AC_MSG_RESULT(no)]
 303 )
 304
 305 AC_MSG_CHECKING([for struct sockaddr_in6])
 306 AC_TRY_COMPILE(
 307         [#include <netinet/in.h>],
 308         [struct sockaddr_in6 s; s.sin6_family = 0;],
 309         [
 310                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 311                 AC_MSG_RESULT(yes)
 312         ],
 313         [AC_MSG_RESULT(no)]
 314 )
 315
 316 AC_MSG_CHECKING([for struct in6_addr])
 317 AC_TRY_COMPILE(
 318         [#include <netinet/in.h>],
 319         [struct in6_addr s; s.s6_addr[0] = 0;],
 320         [
 321                 AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 322                 AC_MSG_RESULT(yes)
 323         ],
 324         [AC_MSG_RESULT(no)]
 325 )
 326
 327 AC_MSG_CHECKING([for struct addrinfo])
 328 AC_TRY_COMPILE(
 329         [
 330                 #include <sys/types.h>
 331                 #include <sys/socket.h>
 332                 #include <netdb.h>
 333         ],
 334         [struct addrinfo s; s.ai_flags = AI_PASSIVE;],
 335         [
 336                 AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 337                 AC_MSG_RESULT(yes)
 338         ],
 339         [AC_MSG_RESULT(no)]
 340 )
 341
 342 # Checks for structure members
 343 AC_MSG_CHECKING([whether utmp.h has ut_host field])
 344 AC_EGREP_HEADER(ut_host, utmp.h,
 345         [AC_DEFINE(HAVE_HOST_IN_UTMP) AC_MSG_RESULT(yes); ],
 346         [AC_MSG_RESULT(no)]
 347 )
 348 AC_MSG_CHECKING([whether utmpx.h has ut_host field])
 349 AC_EGREP_HEADER(ut_host, utmpx.h,
 350         [AC_DEFINE(HAVE_HOST_IN_UTMPX) AC_MSG_RESULT(yes); ],
 351         [AC_MSG_RESULT(no)]
 352 )
 353 AC_MSG_CHECKING([whether utmpx.h has syslen field])
 354 AC_EGREP_HEADER(syslen, utmpx.h,
 355         [AC_DEFINE(HAVE_SYSLEN_IN_UTMPX) AC_MSG_RESULT(yes); ],
 356         [AC_MSG_RESULT(no)]
 357 )
 358 AC_MSG_CHECKING([whether utmp.h has ut_pid field])
 359 AC_EGREP_HEADER(ut_pid, utmp.h,
 360         [AC_DEFINE(HAVE_PID_IN_UTMP) AC_MSG_RESULT(yes); ],
 361         [AC_MSG_RESULT(no)]
 362 )
 363 AC_MSG_CHECKING([whether utmp.h has ut_type field])
 364 AC_EGREP_HEADER(ut_type, utmp.h,
 365         [AC_DEFINE(HAVE_TYPE_IN_UTMP) AC_MSG_RESULT(yes); ],
 366         [AC_MSG_RESULT(no)]
 367 )
 368 AC_MSG_CHECKING([whether utmp.h has ut_tv field])
 369 AC_EGREP_HEADER(ut_tv, utmp.h,
 370         [AC_DEFINE(HAVE_TV_IN_UTMP) AC_MSG_RESULT(yes); ],
 371         [AC_MSG_RESULT(no)]
 372 )
 373 AC_MSG_CHECKING([whether utmp.h has ut_id field])
 374 AC_EGREP_HEADER(ut_id, utmp.h,
 375         [AC_DEFINE(HAVE_ID_IN_UTMP) AC_MSG_RESULT(yes); ],
 376         [AC_MSG_RESULT(no)]
 377 )
 378 AC_MSG_CHECKING([whether utmp.h has ut_addr field])
 379 AC_EGREP_HEADER(ut_addr, utmp.h,
 380         [AC_DEFINE(HAVE_ADDR_IN_UTMP) AC_MSG_RESULT(yes); ],
 381         [AC_MSG_RESULT(no)]
 382 )
 383 AC_MSG_CHECKING([whether utmpx.h has ut_addr field])
 384 AC_EGREP_HEADER(ut_addr, utmpx.h,
 385         [AC_DEFINE(HAVE_ADDR_IN_UTMPX) AC_MSG_RESULT(yes); ],
 386         [AC_MSG_RESULT(no)]
 387 )
 388 AC_MSG_CHECKING([whether utmp.h has ut_addr_v6 field])
 389 AC_EGREP_HEADER(ut_addr_v6, utmp.h,
 390         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMP) AC_MSG_RESULT(yes); ],
 391         [AC_MSG_RESULT(no)]
 392 )
 393 AC_MSG_CHECKING([whether utmpx.h has ut_addr_v6 field])
 394 AC_EGREP_HEADER(ut_addr_v6, utmpx.h,
 395         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMPX) AC_MSG_RESULT(yes); ],
 396         [AC_MSG_RESULT(no)]
 397 )
 398
 399 AC_MSG_CHECKING([whether struct sockaddr_storage has ss_family field])
 400 AC_TRY_COMPILE(
 401         [
 402                 #include <sys/types.h>
 403                 #include <sys/socket.h>
 404         ],
 405         [struct sockaddr_storage s; s.ss_family = 1;],
 406         [
 407                 AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 408                 AC_MSG_RESULT(yes)
 409         ],
 410         [AC_MSG_RESULT(no)]
 411 )
 412 AC_MSG_CHECKING([whether struct sockaddr_storage has __ss_family field])
 413 AC_TRY_COMPILE(
 414         [
 415                 #include <sys/types.h>
 416                 #include <sys/socket.h>
 417         ],
 418         [struct sockaddr_storage s; s.__ss_family = 1;],
 419         [
 420                 AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 421                 AC_MSG_RESULT(yes)
 422         ],
 423         [AC_MSG_RESULT(no)]
 424 )
 425
 426 AC_MSG_CHECKING([whether libc defines __progname])
 427 AC_TRY_LINK([],
 428         [extern char *__progname; printf("%s", __progname);],
 429         [
 430                 AC_DEFINE(HAVE___PROGNAME)
 431                 AC_MSG_RESULT(yes)
 432         ],
 433         [
 434                 AC_MSG_RESULT(no)
 435         ]
 436 )
 437
 438 # Looking for programs, paths and files
 439 AC_ARG_WITH(rsh,
 440         [  --with-rsh=PATH         Specify path to remote shell program ],
 441         [
 442                 if test "x$withval" != "$xno" ; then
 443                         AC_DEFINE_UNQUOTED(RSH_PATH, "$withval")
 444                 fi
 445         ],
 446         [
 447                 AC_PATH_PROG(rsh_path, rsh)
 448         ]
 449 )
 450
 451 AC_ARG_WITH(xauth,
 452         [  --with-xauth=PATH       Specify path to xauth program ],
 453         [
 454                 if test "x$withval" != "$xno" ; then
 455                         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$withval")
 456                 fi
 457         ],
 458         [
 459                 AC_PATH_PROG(xauth_path, xauth)
 460                 if test ! -z "$xauth_path" -a -x "/usr/openwin/bin/xauth" ; then
 461                         xauth_path="/usr/openwin/bin/xauth"
 462                 fi
 463         ]
 464 )
 465
 466 if test ! -z "$xauth_path" ; then
 467         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
 468 fi
 469 if test ! -z "$rsh_path" ; then
 470         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
 471 fi
 472
 473 # Check for mail directory (last resort if we cannot get it from headers)
 474 if test ! -z "$MAIL" ; then
 475         maildir=`dirname $MAIL`
 476         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
 477 fi
 478
 479 # Look for lastlog location
 480 AC_ARG_WITH(lastlog,
 481         [  --with-lastlog=FILE     Location of lastlog file],
 482         [
 483                 if test "x$withval" = "xno" ; then
 484                         AC_DEFINE(DISABLE_LASTLOG)
 485                 else
 486                         AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$withval")
 487                 fi
 488         ],
 489         [
 490                 AC_MSG_CHECKING([location of lastlog file])
 491                 for lastlog in /var/log/lastlog /var/adm/lastlog /usr/adm/lastlog  /etc/security/lastlog ; do
 492                         if test -f $lastlog ; then
 493                                 gotlastlog="file"
 494                                 break
 495                         fi
 496                         if test -d $lastlog ; then
 497                                 gotlastlog="dir"
 498                                 break
 499                         fi
 500                 done
 501                 if test -z "$gotlastlog" ; then
 502                         AC_MSG_RESULT(not found)
 503                         nolastlog=1
 504                 else
 505                         if test "x$gotlastlog" = "xdir" ; then
 506                                 AC_MSG_RESULT(${lastlog}/)
 507                                 AC_DEFINE(LASTLOG_IS_DIR)
 508                         else
 509                                 AC_MSG_RESULT($lastlog)
 510                                 AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$lastlog")
 511                         fi
 512                 fi
 513         ]
 514 )
 515
 516 if test ! -z "$nolastlog" ; then
 517         AC_MSG_WARN([*** Disabling lastlog support *** ])
 518         AC_DEFINE(DISABLE_LASTLOG)
 519 fi
 520
 521 if test -z "$no_dev_ptmx" ; then
 522         AC_CHECK_FILE("/dev/ptmx",
 523                 [
 524                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
 525                         have_dev_ptmx=1
 526                 ]
 527         )
 528 fi
 529 AC_CHECK_FILE("/dev/ptc",
 530         [
 531                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
 532                 have_dev_ptc=1
 533         ]
 534 )
 535
 536 # Some systems (defined in platform-specific code above) automagically remove
 537 # Unix98 ptys when they are closed
 538 if test "x$ac_cv_func_openpty" = "xyes" -o "x$have_dev_ptmx" = "x1" -o "x$have_dev_ptc" = "x1" ; then
 539         if test "x$need_pty_removed_on_close" = "x1" ; then
 540                 AC_DEFINE(PTY_REMOVED_ON_CLOSE)
 541         fi
 542 fi
 543
 544 # Options from here on. Some of these are preset by platform above
 545
 546 # Check whether user wants GNOME ssh-askpass
 547 AC_MSG_CHECKING([whether to build GNOME ssh-askpass])
 548 AC_ARG_WITH(gnome-askpass,
 549         [  --with-gnome-askpass    Build the GNOME passphrase requester (default=no)],
 550         [
 551                 if test x$withval = xno ; then
 552                         GNOME_ASKPASS="";
 553                 else
 554                         GNOME_ASKPASS="gnome-ssh-askpass";
 555                 fi
 556         ])
 557 AC_SUBST(GNOME_ASKPASS)
 558
 559 if test -z "$GNOME_ASKPASS" ; then
 560         AC_MSG_RESULT(no)
 561 else
 562         AC_MSG_RESULT(yes)
 563 fi
 564
 565 # Check for user-specified random device, otherwise check /dev/urandom
 566 AC_ARG_WITH(random,
 567         [  --with-random=FILE      read randomness from FILE (default=/dev/urandom)],
 568         [
 569                 RANDOM_POOL="$withval";
 570                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 571         ],
 572         [
 573                 # Check for random device
 574                 AC_CHECK_FILE("/dev/urandom",
 575                         [
 576                                 RANDOM_POOL="/dev/urandom";
 577                                 AC_SUBST(RANDOM_POOL)
 578                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 579                         ]
 580                 )
 581         ]
 582 )
 583
 584 # Check for EGD pool file
 585 AC_ARG_WITH(egd-pool,
 586         [  --with-egd-pool=FILE    read randomness from EGD pool FILE (default none)],
 587         [
 588                 RANDOM_POOL="$withval";
 589                 AC_DEFINE(HAVE_EGD)
 590                 AC_SUBST(RANDOM_POOL)
 591                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 592         ]
 593 )
 594
 595 # Make sure we have some random number support
 596 if test -z "$RANDOM_POOL" -a -z "$EGD_POOL"; then
 597         AC_MSG_ERROR([No random device found, and no EGD random pool specified])
 598 fi
 599
 600 AC_ARG_WITH(catman,
 601         [  --with-catman=man|cat   Install preformatted manpages[no]],
 602         [
 603                 MANTYPE='$(CATMAN)'
 604                 if test x"$withval" != x"yes" ; then
 605                    mansubdir=$withval
 606                 else
 607                    mansubdir=cat
 608                 fi
 609         ], [
 610                 if test -z "$MANTYPE" ; then
 611                         MANTYPE='$(TROFFMAN)'
 612                         mansubdir=man
 613                 fi
 614         ]
 615 )
 616 AC_SUBST(MANTYPE)
 617 AC_SUBST(mansubdir)
 618
 619 # Check whether user wants Kerberos support
 620 AC_ARG_WITH(kerberos4,
 621         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
 622         [
 623                 if test "x$withval" != "$xno" ; then
 624
 625                         if test "x$withval" != "$xyes" ; then
 626                                 CFLAGS="$CFLAGS -I${withval}/include"
 627                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 628                         else
 629                                 if test -d /usr/include/kerberosIV ; then
 630                                         CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 631                                 fi
 632                         fi
 633
 634                         AC_CHECK_HEADERS(krb.h)
 635                         AC_CHECK_LIB(krb, main)
 636                         if test "$ac_cv_header_krb_h" != yes; then
 637                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
 638                         fi
 639                         if test "$ac_cv_lib_krb_main" != yes; then
 640                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
 641                         fi
 642
 643                         KLIBS="-lkrb -ldes"
 644                         AC_CHECK_LIB(resolv, dn_expand, , )
 645                         KRB4=yes
 646                         AC_DEFINE(KRB4)
 647                 fi
 648         ]
 649 )
 650
 651 # Check whether user wants AFS support
 652 AC_ARG_WITH(afs,
 653         [  --with-afs=PATH         Enable AFS support],
 654         [
 655                 if test "x$withval" != "$xno" ; then
 656
 657                         if test "x$withval" != "$xyes" ; then
 658                                 CFLAGS="$CFLAGS -I${withval}/include"
 659                                 LFLAGS="$LFLAGS -L${withval}/lib"
 660                         fi
 661
 662                         if test -z "$KRB4" ; then
 663                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
 664                         fi
 665
 666                         LIBS="$LIBS -lkafs"
 667                         if test ! -z "$AFS_LIBS" ; then
 668                                 LIBS="$LIBS $AFS_LIBS"
 669                         fi
 670                         AC_DEFINE(AFS)
 671                 fi
 672         ]
 673 )
 674 LIBS="$LIBS $KLIBS"
 675
 676 # Check whether user wants S/Key support
 677 AC_ARG_WITH(skey,
 678         [  --with-skey             Enable S/Key support],
 679         [
 680                 if test "x$withval" != "$xno" ; then
 681                         AC_DEFINE(SKEY)
 682                         LIBS="$LIBS -lskey"
 683                 fi
 684         ]
 685 )
 686
 687 # Check whether user wants TCP wrappers support
 688 AC_ARG_WITH(tcp-wrappers,
 689         [  --with-tcp-wrappers     Enable tcpwrappers support],
 690         [
 691                 if test "x$withval" != "$xno" ; then
 692                         AC_DEFINE(LIBWRAP)
 693                         LIBS="$LIBS -lwrap"
 694                 fi
 695         ]
 696 )
 697
 698 # Check whether to enable MD5 passwords
 699 AC_ARG_WITH(md5-passwords,
 700         [  --with-md5-passwords    Enable use of MD5 passwords],
 701         [
 702                 if test "x$withval" != "$xno" ; then
 703                         AC_DEFINE(HAVE_MD5_PASSWORDS)
 704                 fi
 705         ]
 706 )
 707
 708 # Check whether to enable utmpx support
 709 AC_ARG_WITH(utmpx,
 710         [  --with-utmpx            Enable utmpx support],
 711         [
 712                 if test "x$withval" != "xno" ; then
 713                         AC_DEFINE(USE_UTMPX)
 714                 fi
 715         ]
 716 )
 717
 718 # Whether to disable shadow password support
 719 AC_ARG_WITH(shadow,
 720         [  --without-shadow        Disable shadow password support],
 721         [
 722                 if test "x$withval" = "xno" ; then
 723                         AC_DEFINE(DISABLE_SHADOW)
 724                 fi
 725         ]
 726 )
 727
 728 # Use ip address instead of hostname in $DISPLAY
 729 AC_ARG_WITH(ipaddr-display,
 730         [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
 731         [
 732                 if test "x$withval" = "xno" ; then
 733                         AC_DEFINE(IPADDR_IN_DISPLAY)
 734                 fi
 735         ]
 736 )
 737
 738 # Whether to mess with the default path
 739 AC_ARG_WITH(default-path,
 740         [  --with-default-path=PATH Specify default \$PATH environment for server],
 741         [
 742                 if test "x$withval" != "xno" ; then
 743                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
 744                 fi
 745         ]
 746 )
 747
 748 # Whether to force IPv4 by default (needed on broken glibc Linux)
 749 AC_ARG_WITH(ipv4-default,
 750         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
 751         [
 752                 if test "x$withval" != "xno" ; then
 753                         AC_DEFINE(IPV4_DEFAULT)
 754                 fi
 755         ]
 756 )
 757
 758 # Where to place sshd.pid
 759 piddir=/var/run
 760 AC_ARG_WITH(pid-dir,
 761         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
 762         [
 763                 if test "x$withval" != "xno" ; then
 764                         piddir=$withval
 765                 fi
 766         ]
 767 )
 768 AC_DEFINE_UNQUOTED(PIDDIR, "$piddir")
 769 AC_SUBST(piddir)
 770
 771 AC_OUTPUT(Makefile)