configure.in

   1 # $Id$
   2
   3 AC_INIT(ssh.c)
   4
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PROG_CC
   7 AC_CANONICAL_HOST
   8 AC_C_BIGENDIAN
   9
  10 # Checks for programs.
  11 AC_PROG_CPP
  12 AC_PROG_RANLIB
  13 AC_PROG_INSTALL
  14 AC_PATH_PROG(AR, ar)
  15 AC_PATH_PROGS(PERL, perl5 perl)
  16 AC_SUBST(PERL)
  17 AC_PATH_PROG(ENT, ent)
  18 AC_SUBST(ENT)
  19 AC_PATH_PROGS(FILEPRIV, filepriv, true, /sbin:/usr/sbin)
  20 AC_PATH_PROG(TEST_MINUS_S_SH, bash)
  21 AC_PATH_PROG(TEST_MINUS_S_SH, ksh)
  22 AC_PATH_PROG(TEST_MINUS_S_SH, sh)
  23
  24 if test -z "$AR" ; then
  25         AC_MSG_ERROR([*** 'ar' missing, please install or fix your \$PATH ***])
  26 fi
  27
  28 # Use LOGIN_PROGRAM from environment if possible
  29 if test ! -z "$LOGIN_PROGRAM" ; then
  30         AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM")
  31 else
  32         # Search for login
  33         AC_PATH_PROG(LOGIN_PROGRAM_FALLBACK, login)
  34         if test ! -z "$LOGIN_PROGRAM_FALLBACK" ; then
  35                 AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM_FALLBACK")
  36         fi
  37 fi
  38
  39 if test -z "$LD" ; then
  40         LD=$CC
  41 fi
  42 AC_SUBST(LD)
  43
  44 AC_C_INLINE
  45 if test "$GCC" = "yes" || test "$GCC" = "egcs"; then
  46         CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wno-uninitialized"
  47 fi
  48
  49 # Check for some target-specific stuff
  50 case "$host" in
  51 *-*-aix*)
  52         AFS_LIBS="-lld"
  53         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
  54         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  55         if (test "$LD" != "gcc" && test -z "$blibpath"); then
  56                 blibpath="/usr/lib:/lib:/usr/local/lib"
  57         fi
  58         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)])
  59         AC_DEFINE(BROKEN_GETADDRINFO)
  60         dnl AIX handles lastlog as part of its login message
  61         AC_DEFINE(DISABLE_LASTLOG)
  62         ;;
  63 *-*-cygwin*)
  64         LIBS="$LIBS -lregex /usr/lib/textmode.o"
  65         AC_DEFINE(HAVE_CYGWIN)
  66         AC_DEFINE(USE_PIPES)
  67         AC_DEFINE(DISABLE_SHADOW)
  68         AC_DEFINE(IPV4_DEFAULT)
  69         AC_DEFINE(IP_TOS_IS_BROKEN)
  70         AC_DEFINE(NO_X11_UNIX_SOCKETS)
  71         no_libsocket=1
  72         no_libnsl=1
  73         ;;
  74 *-*-dgux*)
  75         AC_DEFINE(IP_TOS_IS_BROKEN)
  76         ;;
  77 *-*-darwin*)
  78         AC_DEFINE(BROKEN_GETADDRINFO)
  79         ;;
  80 *-*-hpux10*)
  81         if test -z "$GCC"; then
  82                 CFLAGS="$CFLAGS -Ae"
  83         fi
  84         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
  85         IPADDR_IN_DISPLAY=yes
  86         AC_DEFINE(USE_PIPES)
  87         AC_DEFINE(DISABLE_SHADOW)
  88         AC_DEFINE(DISABLE_UTMP)
  89         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
  90         LIBS="$LIBS -lxnet -lsec"
  91         ;;
  92 *-*-hpux11*)
  93         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
  94         IPADDR_IN_DISPLAY=yes
  95         AC_DEFINE(PAM_SUN_CODEBASE)
  96         AC_DEFINE(USE_PIPES)
  97         AC_DEFINE(DISABLE_SHADOW)
  98         AC_DEFINE(DISABLE_UTMP)
  99         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 100         LIBS="$LIBS -lxnet -lsec"
 101         ;;
 102 *-*-irix5*)
 103         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 104         LDFLAGS="$LDFLAGS"
 105         PATH="$PATH:/usr/etc"
 106         no_libsocket=1
 107         no_libnsl=1
 108         AC_DEFINE(BROKEN_INET_NTOA)
 109         ;;
 110 *-*-irix6*)
 111         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 112         LDFLAGS="$LDFLAGS"
 113         PATH="$PATH:/usr/etc"
 114         AC_DEFINE(WITH_IRIX_ARRAY)
 115         AC_DEFINE(WITH_IRIX_PROJECT)
 116         AC_DEFINE(WITH_IRIX_AUDIT)
 117         AC_CHECK_FUNC(jlimit_startjob, [AC_DEFINE(WITH_IRIX_JOBS)])
 118         no_libsocket=1
 119         no_libnsl=1
 120         AC_DEFINE(BROKEN_INET_NTOA)
 121         ;;
 122 *-*-linux*)
 123         no_dev_ptmx=1
 124         check_for_libcrypt_later=1
 125         AC_DEFINE(DONT_TRY_OTHER_AF)
 126         AC_DEFINE(PAM_TTY_KLUDGE)
 127         inet6_default_4in6=yes
 128         ;;
 129 mips-sony-bsd|mips-sony-newsos4)
 130         AC_DEFINE(HAVE_NEWS4)
 131         SONY=1
 132         AC_CHECK_LIB(iberty, xatexit, AC_DEFINE(HAVE_XATEXIT),
 133                 AC_MSG_ERROR([*** libiberty missing - please install first or check config.log ***])
 134         )
 135         ;;
 136 *-*-netbsd*)
 137         need_dash_r=1
 138         ;;
 139 *-*-freebsd*)
 140         check_for_libcrypt_later=1
 141         ;;
 142 *-next-*)
 143         conf_lastlog_location="/usr/adm/lastlog"
 144         conf_utmp_location=/etc/utmp
 145         conf_wtmp_location=/usr/adm/wtmp
 146         MAIL=/usr/spool/mail
 147         AC_DEFINE(HAVE_NEXT)
 148         AC_DEFINE(BROKEN_REALPATH)
 149         AC_DEFINE(USE_PIPES)
 150         AC_DEFINE(BROKEN_SAVED_UIDS)
 151         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 152         CFLAGS="$CFLAGS"
 153         ;;
 154 *-*-solaris*)
 155         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 156         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib"
 157         need_dash_r=1
 158         AC_DEFINE(PAM_SUN_CODEBASE)
 159         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 160         AC_DEFINE(LOGIN_NEEDS_TERM)
 161         # hardwire lastlog location (can't detect it on some versions)
 162         conf_lastlog_location="/var/adm/lastlog"
 163         AC_MSG_CHECKING(for obsolete utmp and wtmp in solaris2.x)
 164         sol2ver=`echo "$host"| sed -e 's/.*[[0-9]]\.//'`
 165         if test "$sol2ver" -ge 8; then
 166                 AC_MSG_RESULT(yes)
 167                 AC_DEFINE(DISABLE_UTMP)
 168                 AC_DEFINE(DISABLE_WTMP)
 169         else
 170                 AC_MSG_RESULT(no)
 171         fi
 172         ;;
 173 *-*-sunos4*)
 174         CPPFLAGS="$CPPFLAGS -DSUNOS4"
 175         AC_CHECK_FUNCS(getpwanam)
 176         AC_DEFINE(PAM_SUN_CODEBASE)
 177         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 178         conf_utmp_location=/etc/utmp
 179         conf_wtmp_location=/var/adm/wtmp
 180         conf_lastlog_location=/var/adm/lastlog
 181         AC_DEFINE(USE_PIPES)
 182         ;;
 183 *-ncr-sysv*)
 184         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 185         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 186         LIBS="$LIBS -lc89 -lnsl -lgen -lsocket"
 187         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 188         ;;
 189 *-sni-sysv*)
 190         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 191         LDFLAGS="$LDFLAGS -L/usr/local/lib -L/usr/ucblib"
 192         IPADDR_IN_DISPLAY=yes
 193         AC_DEFINE(USE_PIPES)
 194         AC_DEFINE(IP_TOS_IS_BROKEN)
 195         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 196         LIBS="$LIBS -lgen -lnsl -lucb"
 197         ;;
 198 *-*-sysv4.2*)
 199         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 200         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 201         enable_suid_ssh=no
 202         AC_DEFINE(USE_PIPES)
 203         ;;
 204 *-*-sysv5*)
 205         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 206         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 207         enable_suid_ssh=no
 208         AC_DEFINE(USE_PIPES)
 209         ;;
 210 *-*-sysv*)
 211         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 212         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 213         LIBS="$LIBS -lgen -lsocket"
 214         ;;
 215 *-*-sco3.2v4*)
 216         CPPFLAGS="$CPPFLAGS -Dftruncate=chsize -I/usr/local/include"
 217         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 218         LIBS="$LIBS -lgen -lsocket -los -lprot -lx -ltinfo -lm"
 219         rsh_path="/usr/bin/rcmd"
 220         RANLIB=true
 221         no_dev_ptmx=1
 222         AC_DEFINE(BROKEN_SYS_TERMIO_H)
 223         AC_DEFINE(USE_PIPES)
 224         AC_DEFINE(HAVE_SCO_PROTECTED_PW)
 225         AC_DEFINE(DISABLE_SHADOW)
 226         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 227         AC_DEFINE(BROKEN_SAVED_UIDS)
 228         AC_CHECK_FUNCS(getluid setluid)
 229         MANTYPE=man
 230         ;;
 231 *-*-sco3.2v5*)
 232         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 233         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 234         LIBS="$LIBS -lprot -lx -ltinfo -lm"
 235         no_dev_ptmx=1
 236         rsh_path="/usr/bin/rcmd"
 237         AC_DEFINE(USE_PIPES)
 238         AC_DEFINE(HAVE_SCO_PROTECTED_PW)
 239         AC_DEFINE(DISABLE_SHADOW)
 240         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 241         AC_CHECK_FUNCS(getluid setluid)
 242         MANTYPE=man
 243         ;;
 244 *-*-unicos*)
 245         no_libsocket=1
 246         no_libnsl=1
 247         AC_DEFINE(USE_PIPES)
 248         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 249         LIBS="$LIBS -lgen -lrsc"
 250         ;;
 251 *-dec-osf*)
 252         AC_MSG_CHECKING(for Digital Unix SIA)
 253         no_osfsia=""
 254         AC_ARG_WITH(osfsia,
 255                 [  --with-osfsia           Enable Digital Unix SIA],
 256                 [
 257                         if test "x$withval" = "xno" ; then
 258                                 AC_MSG_RESULT(disabled)
 259                                 no_osfsia=1
 260                         fi
 261                 ],
 262         )
 263         if test -z "$no_osfsia" ; then
 264                 if test -f /etc/sia/matrix.conf; then
 265                         AC_MSG_RESULT(yes)
 266                         AC_DEFINE(HAVE_OSF_SIA)
 267                         AC_DEFINE(DISABLE_LOGIN)
 268                         LIBS="$LIBS -lsecurity -ldb -lm -laud"
 269                 else
 270                         AC_MSG_RESULT(no)
 271                 fi
 272         fi
 273         ;;
 274 esac
 275
 276 # Allow user to specify flags
 277 AC_ARG_WITH(cflags,
 278         [  --with-cflags           Specify additional flags to pass to compiler],
 279         [
 280                 if test "x$withval" != "xno" ; then
 281                         CFLAGS="$CFLAGS $withval"
 282                 fi
 283         ]
 284 )
 285 AC_ARG_WITH(cppflags,
 286         [  --with-cppflags         Specify additional flags to pass to preprocessor] ,
 287         [
 288                 if test "x$withval" != "xno"; then
 289                         CPPFLAGS="$CPPFLAGS $withval"
 290                 fi
 291         ]
 292 )
 293 AC_ARG_WITH(ldflags,
 294         [  --with-ldflags          Specify additional flags to pass to linker],
 295         [
 296                 if test "x$withval" != "xno" ; then
 297                         LDFLAGS="$LDFLAGS $withval"
 298                 fi
 299         ]
 300 )
 301 AC_ARG_WITH(libs,
 302         [  --with-libs             Specify additional libraries to link with],
 303         [
 304                 if test "x$withval" != "xno" ; then
 305                         LIBS="$LIBS $withval"
 306                 fi
 307         ]
 308 )
 309
 310 AC_ARG_WITH(pcre,
 311         [  --with-pcre             Override built in regex library with pcre],
 312         [
 313
 314                 AC_CHECK_LIB(pcre, pcre_info,
 315                         [
 316                                 AC_DEFINE(HAVE_LIBPCRE)
 317                                 LIBS="$LIBS -lpcreposix -lpcre"
 318                                 no_comp_check="yes"
 319                         ],
 320                         [ AC_MSG_ERROR([*** Can not locate pcre libraries.]) ]
 321                 )
 322         ]
 323 )
 324
 325 # Checks for libraries.
 326 if test -z "$no_libnsl" ; then
 327         AC_CHECK_LIB(nsl, yp_match, , )
 328 fi
 329 if test -z "$no_libsocket" ; then
 330         AC_CHECK_LIB(socket, main, , )
 331 fi
 332
 333 dnl SCO OS3 needs this for libwrap
 334 AC_CHECK_LIB(rpc, innetgr, LIBS="-lrpc -lyp -lrpc $LIBS" , , -lyp -lrpc)
 335
 336 AC_CHECK_LIB(gen, getspnam, LIBS="$LIBS -lgen")
 337 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first or check config.log ***]))
 338 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
 339
 340 # We don't want to check if we did an pcre override.
 341 if test -z "$no_comp_check" ; then
 342         AC_CHECK_FUNC(regcomp,
 343                 [ AC_DEFINE(HAVE_REGCOMP)],
 344                 [
 345                         AC_CHECK_LIB(pcre, pcre_info,
 346                         [
 347                                 AC_DEFINE(HAVE_LIBPCRE)
 348                                 LIBS="$LIBS -lpcreposix -lpcre"
 349                         ],
 350                         [
 351                                 AC_MSG_ERROR([*** No regex library found.])
 352                         ])
 353                 ]
 354         )
 355 fi
 356
 357 dnl UnixWare 2.x
 358 AC_CHECK_FUNC(strcasecmp,
 359         [], [ AC_CHECK_LIB(resolv, strcasecmp, LIBS="$LIBS -lresolv") ]
 360 )
 361 AC_CHECK_FUNC(utimes,
 362         [], [ AC_CHECK_LIB(c89, utimes, LIBS="$LIBS -lc89") ]
 363 )
 364
 365 AC_FUNC_STRFTIME
 366
 367 # Checks for header files.
 368 AC_CHECK_HEADERS(bstring.h crypt.h endian.h floatingpoint.h getopt.h glob.h lastlog.h libgen.h limits.h login.h login_cap.h maillock.h netdb.h netgroup.h netinet/in_systm.h paths.h poll.h pty.h regex.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/queue.h sys/select.h sys/stat.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h sys/un.h stddef.h time.h ttyent.h usersec.h util.h utime.h utmp.h utmpx.h vis.h)
 369
 370 # Check for ALTDIRFUNC glob() extension
 371 AC_MSG_CHECKING(for GLOB_ALTDIRFUNC support)
 372 AC_EGREP_CPP(FOUNDIT,
 373         [
 374                 #include <glob.h>
 375                 #ifdef GLOB_ALTDIRFUNC
 376                 FOUNDIT
 377                 #endif
 378         ],
 379         [
 380                 AC_DEFINE(GLOB_HAS_ALTDIRFUNC)
 381                 AC_MSG_RESULT(yes)
 382         ],
 383         [
 384                 AC_MSG_RESULT(no)
 385         ]
 386 )
 387
 388 # Check for g.gl_matchc glob() extension
 389 AC_MSG_CHECKING(for gl_matchc field in glob_t)
 390 AC_EGREP_CPP(FOUNDIT,
 391         [
 392                 #include <glob.h>
 393                 int main(void){glob_t g; g.gl_matchc = 1;}
 394         ],
 395         [
 396                 AC_DEFINE(GLOB_HAS_GL_MATCHC)
 397                 AC_MSG_RESULT(yes)
 398         ],
 399         [
 400                 AC_MSG_RESULT(no)
 401         ]
 402 )
 403
 404 AC_MSG_CHECKING([whether struct dirent allocates space for d_name])
 405 AC_TRY_RUN(
 406         [
 407 #include <sys/types.h>
 408 #include <dirent.h>
 409 int main(void){struct dirent d;return(sizeof(d.d_name)<=sizeof(char));}
 410         ],
 411         [AC_MSG_RESULT(yes)],
 412         [
 413                 AC_MSG_RESULT(no)
 414                 AC_DEFINE(BROKEN_ONE_BYTE_DIRENT_D_NAME)
 415         ]
 416 )
 417
 418 # Check whether user wants S/Key support
 419 SKEY_MSG="no"
 420 AC_ARG_WITH(skey,
 421         [  --with-skey=PATH         Enable S/Key support],
 422         [
 423                 if test "x$withval" != "xno" ; then
 424
 425                         if test "x$withval" != "xyes" ; then
 426                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 427                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 428                         fi
 429
 430                         AC_DEFINE(SKEY)
 431                         LIBS="-lskey $LIBS"
 432                         SKEY_MSG="yes"
 433
 434                         AC_CHECK_FUNC(skey_keyinfo,
 435                                 [],
 436                                 [
 437                                         AC_MSG_ERROR([** Incomplete or missing s/key libraries.])
 438                                 ])
 439                 fi
 440         ]
 441 )
 442
 443 # Check whether user wants TCP wrappers support
 444 TCPW_MSG="no"
 445 AC_ARG_WITH(tcp-wrappers,
 446         [  --with-tcp-wrappers     Enable tcpwrappers support],
 447         [
 448                 if test "x$withval" != "xno" ; then
 449                         saved_LIBS="$LIBS"
 450                         LIBS="-lwrap $LIBS"
 451                         AC_MSG_CHECKING(for libwrap)
 452                         AC_TRY_LINK(
 453                                 [
 454 #include <tcpd.h>
 455                                         int deny_severity = 0, allow_severity = 0;
 456                                 ],
 457                                 [hosts_access(0);],
 458                                 [
 459                                         AC_MSG_RESULT(yes)
 460                                         AC_DEFINE(LIBWRAP)
 461                                         TCPW_MSG="yes"
 462                                 ],
 463                                 [
 464                                         AC_MSG_ERROR([*** libwrap missing])
 465                                 ]
 466                         )
 467                 fi
 468         ]
 469 )
 470
 471 dnl    Checks for library functions.
 472 AC_CHECK_FUNCS(arc4random atexit b64_ntop bcopy bindresvport_sa clock dirname fchown fchmod freeaddrinfo futimes gai_strerror getcwd getaddrinfo getgrouplist getopt getnameinfo getrlimit getrusage getttyent glob inet_aton inet_ntoa innetgr login_getcapbool md5_crypt memmove mkdtemp on_exit openpty readpassphrase realpath rresvport_af setdtablesize setenv setegid seteuid setlogin setproctitle setresgid setreuid setrlimit setsid setvbuf sigaction sigvec snprintf strerror strlcat strlcpy strmode strsep sysconf tcgetpgrp utimes vsnprintf vhangup vis waitpid _getpty __b64_ntop)
 473 dnl    Checks for time functions
 474 AC_CHECK_FUNCS(gettimeofday time)
 475 dnl    Checks for libutil functions
 476 AC_CHECK_HEADERS(libutil.h)
 477 AC_CHECK_FUNCS(login logout updwtmp logwtmp)
 478 dnl    Checks for utmp functions
 479 AC_CHECK_FUNCS(endutent getutent getutid getutline pututline setutent)
 480 AC_CHECK_FUNCS(utmpname)
 481 dnl    Checks for utmpx functions
 482 AC_CHECK_FUNCS(endutxent getutxent getutxid getutxline pututxline )
 483 AC_CHECK_FUNCS(setutxent utmpxname)
 484
 485 AC_CHECK_FUNC(getuserattr,
 486         [AC_DEFINE(HAVE_GETUSERATTR)],
 487         [AC_CHECK_LIB(s, getuserattr, [LIBS="$LIBS -ls"; AC_DEFINE(HAVE_GETUSERATTR)])]
 488 )
 489
 490 AC_CHECK_FUNC(login,
 491         [AC_DEFINE(HAVE_LOGIN)],
 492         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 493 )
 494
 495 AC_CHECK_FUNC(daemon,
 496         [AC_DEFINE(HAVE_DAEMON)],
 497         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 498 )
 499
 500 AC_CHECK_FUNC(getpagesize,
 501         [AC_DEFINE(HAVE_GETPAGESIZE)],
 502         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 503 )
 504
 505 # Check for broken snprintf
 506 if test "x$ac_cv_func_snprintf" = "xyes" ; then
 507         AC_MSG_CHECKING([whether snprintf correctly terminates long strings])
 508         AC_TRY_RUN(
 509                 [
 510 #include <stdio.h>
 511 int main(void){char b[5];snprintf(b,5,"123456789");return(b[4]!='\0');}
 512                 ],
 513                 [AC_MSG_RESULT(yes)],
 514                 [
 515                         AC_MSG_RESULT(no)
 516                         AC_DEFINE(BROKEN_SNPRINTF)
 517                         AC_MSG_WARN([****** Your snprintf() function is broken, complain to your vendor])
 518                 ]
 519         )
 520 fi
 521
 522 AC_FUNC_GETPGRP
 523
 524 # Check for PAM libs
 525 PAM_MSG="no"
 526 AC_ARG_WITH(pam,
 527         [  --with-pam              Enable PAM support ],
 528         [
 529                 if test "x$withval" != "xno" ; then
 530                         if test "x$ac_cv_header_security_pam_appl_h" != "xyes" ; then
 531                                 AC_MSG_ERROR([PAM headers not found])
 532                         fi
 533
 534                         AC_CHECK_LIB(dl, dlopen, , )
 535                         AC_CHECK_LIB(pam, pam_set_item, , AC_MSG_ERROR([*** libpam missing]))
 536                         AC_CHECK_FUNCS(pam_getenvlist)
 537
 538                         disable_shadow=yes
 539                         PAM_MSG="yes"
 540
 541                         AC_DEFINE(USE_PAM)
 542                 fi
 543         ]
 544 )
 545
 546 # Check for older PAM
 547 if test "x$PAM_MSG" = "xyes" ; then
 548         # Check PAM strerror arguments (old PAM)
 549         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 550         AC_TRY_COMPILE(
 551                 [
 552 #include <stdlib.h>
 553 #include <security/pam_appl.h>
 554                 ],
 555                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 556                 [AC_MSG_RESULT(no)],
 557                 [
 558                         AC_DEFINE(HAVE_OLD_PAM)
 559                         AC_MSG_RESULT(yes)
 560                         PAM_MSG="yes (old library)"
 561                 ]
 562         )
 563 fi
 564
 565 # The big search for OpenSSL
 566 AC_ARG_WITH(ssl-dir,
 567         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 568         [
 569                 if test "x$withval" != "xno" ; then
 570                         tryssldir=$withval
 571                 fi
 572         ]
 573 )
 574
 575 saved_LIBS="$LIBS"
 576 saved_LDFLAGS="$LDFLAGS"
 577 saved_CPPFLAGS="$CPPFLAGS"
 578 if test "x$prefix" != "xNONE" ; then
 579         tryssldir="$tryssldir $prefix"
 580 fi
 581 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 582         for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 583                 CPPFLAGS="$saved_CPPFLAGS"
 584                 LDFLAGS="$saved_LDFLAGS"
 585                 LIBS="$saved_LIBS -lcrypto"
 586
 587                 # Skip directories if they don't exist
 588                 if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 589                         continue;
 590                 fi
 591                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 592                         # Try to use $ssldir/lib if it exists, otherwise
 593                         # $ssldir
 594                         if test -d "$ssldir/lib" ; then
 595                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 596                                 if test ! -z "$need_dash_r" ; then
 597                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 598                                 fi
 599                         else
 600                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 601                                 if test ! -z "$need_dash_r" ; then
 602                                         LDFLAGS="-R$ssldir $LDFLAGS"
 603                                 fi
 604                         fi
 605                         # Try to use $ssldir/include if it exists, otherwise
 606                         # $ssldir
 607                         if test -d "$ssldir/include" ; then
 608                                 CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 609                         else
 610                                 CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 611                         fi
 612                 fi
 613
 614                 # Basic test to check for compatible version and correct linking
 615                 # *does not* test for RSA - that comes later.
 616                 AC_TRY_RUN(
 617                         [
 618 #include <string.h>
 619 #include <openssl/rand.h>
 620 int main(void)
 621 {
 622         char a[2048];
 623         memset(a, 0, sizeof(a));
 624         RAND_add(a, sizeof(a), sizeof(a));
 625         return(RAND_status() <= 0);
 626 }
 627                         ],
 628                         [
 629                                 found_crypto=1
 630                                 break;
 631                         ], []
 632                 )
 633
 634                 if test ! -z "$found_crypto" ; then
 635                         break;
 636                 fi
 637         done
 638
 639         if test -z "$found_crypto" ; then
 640                 AC_MSG_ERROR([Could not find working OpenSSL library, please install or check config.log])
 641         fi
 642         if test -z "$ssldir" ; then
 643                 ssldir="(system)"
 644         fi
 645
 646         ac_cv_openssldir=$ssldir
 647 ])
 648
 649 if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ; then
 650         AC_DEFINE(HAVE_OPENSSL)
 651         dnl Need to recover ssldir - test above runs in subshell
 652         ssldir=$ac_cv_openssldir
 653         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 654                 # Try to use $ssldir/lib if it exists, otherwise
 655                 # $ssldir
 656                 if test -d "$ssldir/lib" ; then
 657                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 658                         if test ! -z "$need_dash_r" ; then
 659                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 660                         fi
 661                 else
 662                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 663                         if test ! -z "$need_dash_r" ; then
 664                                 LDFLAGS="-R$ssldir $LDFLAGS"
 665                         fi
 666                 fi
 667                 # Try to use $ssldir/include if it exists, otherwise
 668                 # $ssldir
 669                 if test -d "$ssldir/include" ; then
 670                         CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 671                 else
 672                         CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 673                 fi
 674         fi
 675 fi
 676 LIBS="$saved_LIBS -lcrypto"
 677
 678 # Now test RSA support
 679 saved_LIBS="$LIBS"
 680 AC_MSG_CHECKING([for RSA support])
 681 for WANTS_RSAREF in "" 1 ; do
 682         if test -z "$WANTS_RSAREF" ; then
 683                 LIBS="$saved_LIBS"
 684         else
 685                 LIBS="$saved_LIBS -lRSAglue -lrsaref"
 686         fi
 687         AC_TRY_RUN([
 688 #include <string.h>
 689 #include <openssl/rand.h>
 690 #include <openssl/rsa.h>
 691 #include <openssl/bn.h>
 692 #include <openssl/sha.h>
 693 int main(void)
 694 {
 695         int num; RSA *key; static unsigned char p_in[] = "blahblah";
 696         unsigned char c[256], p[256];
 697         memset(c, 0, sizeof(c)); RAND_add(c, sizeof(c), sizeof(c));
 698         if ((key=RSA_generate_key(512, 3, NULL, NULL))==NULL) return(1);
 699         num = RSA_public_encrypt(sizeof(p_in) - 1, p_in, c, key, RSA_PKCS1_PADDING);
 700         return(-1 == RSA_private_decrypt(num, c, p, key, RSA_PKCS1_PADDING));
 701 }
 702         ],
 703         [
 704                 rsa_works=1
 705                 break;
 706         ], [])
 707 done
 708 LIBS="$saved_LIBS"
 709
 710 if test ! -z "$no_rsa" ; then
 711         AC_MSG_RESULT(disabled)
 712         RSA_MSG="disabled"
 713 else
 714         if test -z "$rsa_works" ; then
 715                 AC_MSG_WARN([*** No RSA support found *** ])
 716                 RSA_MSG="no"
 717         else
 718                 if test -z "$WANTS_RSAREF" ; then
 719                         AC_MSG_RESULT(yes)
 720                         RSA_MSG="yes"
 721                 else
 722                         RSA_MSG="yes (using RSAref)"
 723                         AC_MSG_RESULT(using RSAref)
 724                         LIBS="$LIBS -lcrypto -lRSAglue -lrsaref"
 725                 fi
 726         fi
 727 fi
 728
 729 # Some Linux systems (Slackware) need crypt() from libcrypt, *not* the
 730 # version in OpenSSL. Skip this for PAM
 731 if test "x$PAM_MSG" = "xno" -a "x$check_for_libcrypt_later" = "x1"; then
 732         AC_CHECK_LIB(crypt, crypt, LIBS="$LIBS -lcrypt")
 733 fi
 734
 735 # Cheap hack to ensure NEWS-OS libraries are arranged right.
 736 if test ! -z "$SONY" ; then
 737   LIBS="$LIBS -liberty";
 738 fi
 739
 740 # Checks for data types
 741 AC_CHECK_SIZEOF(char, 1)
 742 AC_CHECK_SIZEOF(short int, 2)
 743 AC_CHECK_SIZEOF(int, 4)
 744 AC_CHECK_SIZEOF(long int, 4)
 745 AC_CHECK_SIZEOF(long long int, 8)
 746
 747 # More checks for data types
 748 AC_CACHE_CHECK([for u_int type], ac_cv_have_u_int, [
 749         AC_TRY_COMPILE(
 750                 [ #include <sys/types.h> ],
 751                 [ u_int a; a = 1;],
 752                 [ ac_cv_have_u_int="yes" ],
 753                 [ ac_cv_have_u_int="no" ]
 754         )
 755 ])
 756 if test "x$ac_cv_have_u_int" = "xyes" ; then
 757         AC_DEFINE(HAVE_U_INT)
 758         have_u_int=1
 759 fi
 760
 761 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
 762         AC_TRY_COMPILE(
 763                 [ #include <sys/types.h> ],
 764                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
 765                 [ ac_cv_have_intxx_t="yes" ],
 766                 [ ac_cv_have_intxx_t="no" ]
 767         )
 768 ])
 769 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
 770         AC_DEFINE(HAVE_INTXX_T)
 771         have_intxx_t=1
 772 fi
 773
 774 AC_CACHE_CHECK([for int64_t type], ac_cv_have_int64_t, [
 775         AC_TRY_COMPILE(
 776                 [ #include <sys/types.h> ],
 777                 [ int64_t a; a = 1;],
 778                 [ ac_cv_have_int64_t="yes" ],
 779                 [ ac_cv_have_int64_t="no" ]
 780         )
 781 ])
 782 if test "x$ac_cv_have_int64_t" = "xyes" ; then
 783         AC_DEFINE(HAVE_INT64_T)
 784         have_int64_t=1
 785 fi
 786
 787 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
 788         AC_TRY_COMPILE(
 789                 [ #include <sys/types.h> ],
 790                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
 791                 [ ac_cv_have_u_intxx_t="yes" ],
 792                 [ ac_cv_have_u_intxx_t="no" ]
 793         )
 794 ])
 795 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
 796         AC_DEFINE(HAVE_U_INTXX_T)
 797         have_u_intxx_t=1
 798 fi
 799
 800 AC_CACHE_CHECK([for u_int64_t types], ac_cv_have_u_int64_t, [
 801         AC_TRY_COMPILE(
 802                 [ #include <sys/types.h> ],
 803                 [ u_int64_t a; a = 1;],
 804                 [ ac_cv_have_u_int64_t="yes" ],
 805                 [ ac_cv_have_u_int64_t="no" ]
 806         )
 807 ])
 808 if test "x$ac_cv_have_u_int64_t" = "xyes" ; then
 809         AC_DEFINE(HAVE_U_INT64_T)
 810         have_u_int64_t=1
 811 fi
 812
 813 if (test -z "$have_u_intxx_t" || test -z "$have_intxx_t" && \
 814            test "x$ac_cv_header_sys_bitypes_h" = "xyes")
 815 then
 816         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 817         AC_TRY_COMPILE(
 818                 [
 819 #include <sys/bitypes.h>
 820                 ],
 821                 [
 822                         int8_t a; int16_t b; int32_t c;
 823                         u_int8_t e; u_int16_t f; u_int32_t g;
 824                         a = b = c = e = f = g = 1;
 825                 ],
 826                 [
 827                         AC_DEFINE(HAVE_U_INTXX_T)
 828                         AC_DEFINE(HAVE_INTXX_T)
 829                         AC_MSG_RESULT(yes)
 830                 ],
 831                 [AC_MSG_RESULT(no)]
 832         )
 833 fi
 834
 835 if test -z "$have_u_intxx_t" ; then
 836         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
 837                 AC_TRY_COMPILE(
 838                         [
 839 #include <sys/types.h>
 840                         ],
 841                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
 842                         [ ac_cv_have_uintxx_t="yes" ],
 843                         [ ac_cv_have_uintxx_t="no" ]
 844                 )
 845         ])
 846         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
 847                 AC_DEFINE(HAVE_UINTXX_T)
 848         fi
 849 fi
 850
 851 AC_CACHE_CHECK([for socklen_t], ac_cv_have_socklen_t, [
 852         AC_TRY_COMPILE(
 853                 [
 854 #include <sys/types.h>
 855 #include <sys/socket.h>
 856                 ],
 857                 [socklen_t foo; foo = 1235;],
 858                 [ ac_cv_have_socklen_t="yes" ],
 859                 [ ac_cv_have_socklen_t="no" ]
 860         )
 861 ])
 862 if test "x$ac_cv_have_socklen_t" = "xyes" ; then
 863         AC_DEFINE(HAVE_SOCKLEN_T)
 864 fi
 865
 866 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
 867         AC_TRY_COMPILE(
 868                 [
 869 #include <sys/types.h>
 870                 ],
 871                 [ size_t foo; foo = 1235; ],
 872                 [ ac_cv_have_size_t="yes" ],
 873                 [ ac_cv_have_size_t="no" ]
 874         )
 875 ])
 876 if test "x$ac_cv_have_size_t" = "xyes" ; then
 877         AC_DEFINE(HAVE_SIZE_T)
 878 fi
 879
 880 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
 881         AC_TRY_COMPILE(
 882                 [
 883 #include <sys/types.h>
 884                 ],
 885                 [ ssize_t foo; foo = 1235; ],
 886                 [ ac_cv_have_ssize_t="yes" ],
 887                 [ ac_cv_have_ssize_t="no" ]
 888         )
 889 ])
 890 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
 891         AC_DEFINE(HAVE_SSIZE_T)
 892 fi
 893
 894 AC_CACHE_CHECK([for clock_t], ac_cv_have_clock_t, [
 895         AC_TRY_COMPILE(
 896                 [
 897 #include <time.h>
 898                 ],
 899                 [ clock_t foo; foo = 1235; ],
 900                 [ ac_cv_have_clock_t="yes" ],
 901                 [ ac_cv_have_clock_t="no" ]
 902         )
 903 ])
 904 if test "x$ac_cv_have_clock_t" = "xyes" ; then
 905         AC_DEFINE(HAVE_CLOCK_T)
 906 fi
 907
 908 AC_CACHE_CHECK([for sa_family_t], ac_cv_have_sa_family_t, [
 909         AC_TRY_COMPILE(
 910                 [
 911 #include <sys/types.h>
 912 #include <sys/socket.h>
 913                 ],
 914                 [ sa_family_t foo; foo = 1235; ],
 915                 [ ac_cv_have_sa_family_t="yes" ],
 916                 [ AC_TRY_COMPILE(
 917                   [
 918 #include <sys/types.h>
 919 #include <sys/socket.h>
 920 #include <netinet/in.h>
 921                 ],
 922                 [ sa_family_t foo; foo = 1235; ],
 923                 [ ac_cv_have_sa_family_t="yes" ],
 924
 925                 [ ac_cv_have_sa_family_t="no" ]
 926         )]
 927         )
 928 ])
 929 if test "x$ac_cv_have_sa_family_t" = "xyes" ; then
 930         AC_DEFINE(HAVE_SA_FAMILY_T)
 931 fi
 932
 933 AC_CACHE_CHECK([for pid_t], ac_cv_have_pid_t, [
 934         AC_TRY_COMPILE(
 935                 [
 936 #include <sys/types.h>
 937                 ],
 938                 [ pid_t foo; foo = 1235; ],
 939                 [ ac_cv_have_pid_t="yes" ],
 940                 [ ac_cv_have_pid_t="no" ]
 941         )
 942 ])
 943 if test "x$ac_cv_have_pid_t" = "xyes" ; then
 944         AC_DEFINE(HAVE_PID_T)
 945 fi
 946
 947 AC_CACHE_CHECK([for mode_t], ac_cv_have_mode_t, [
 948         AC_TRY_COMPILE(
 949                 [
 950 #include <sys/types.h>
 951                 ],
 952                 [ mode_t foo; foo = 1235; ],
 953                 [ ac_cv_have_mode_t="yes" ],
 954                 [ ac_cv_have_mode_t="no" ]
 955         )
 956 ])
 957 if test "x$ac_cv_have_mode_t" = "xyes" ; then
 958         AC_DEFINE(HAVE_MODE_T)
 959 fi
 960
 961
 962 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
 963         AC_TRY_COMPILE(
 964                 [
 965 #include <sys/types.h>
 966 #include <sys/socket.h>
 967                 ],
 968                 [ struct sockaddr_storage s; ],
 969                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
 970                 [ ac_cv_have_struct_sockaddr_storage="no" ]
 971         )
 972 ])
 973 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
 974         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 975 fi
 976
 977 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
 978         AC_TRY_COMPILE(
 979                 [
 980 #include <sys/types.h>
 981 #include <netinet/in.h>
 982                 ],
 983                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
 984                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
 985                 [ ac_cv_have_struct_sockaddr_in6="no" ]
 986         )
 987 ])
 988 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
 989         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 990 fi
 991
 992 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
 993         AC_TRY_COMPILE(
 994                 [
 995 #include <sys/types.h>
 996 #include <netinet/in.h>
 997                 ],
 998                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
 999                 [ ac_cv_have_struct_in6_addr="yes" ],
1000                 [ ac_cv_have_struct_in6_addr="no" ]
1001         )
1002 ])
1003 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
1004         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
1005 fi
1006
1007 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
1008         AC_TRY_COMPILE(
1009                 [
1010 #include <sys/types.h>
1011 #include <sys/socket.h>
1012 #include <netdb.h>
1013                 ],
1014                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
1015                 [ ac_cv_have_struct_addrinfo="yes" ],
1016                 [ ac_cv_have_struct_addrinfo="no" ]
1017         )
1018 ])
1019 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
1020         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
1021 fi
1022
1023 AC_CACHE_CHECK([for struct timeval], ac_cv_have_struct_timeval, [
1024         AC_TRY_COMPILE(
1025                 [ #include <sys/time.h> ],
1026                 [ struct timeval tv; tv.tv_sec = 1;],
1027                 [ ac_cv_have_struct_timeval="yes" ],
1028                 [ ac_cv_have_struct_timeval="no" ]
1029         )
1030 ])
1031 if test "x$ac_cv_have_struct_timeval" = "xyes" ; then
1032         AC_DEFINE(HAVE_STRUCT_TIMEVAL)
1033         have_struct_timeval=1
1034 fi
1035
1036 # If we don't have int64_t then we can't compile sftp-server.  So don't
1037 # even attempt to do it.
1038 if test "x$ac_cv_have_int64_t" = "xno" -a \
1039         "x$ac_cv_sizeof_long_int" != "x8" -a \
1040         "x$ac_cv_sizeof_long_long_int" = "x0" ; then
1041         NO_SFTP='#'
1042 else
1043 dnl test snprintf (broken on SCO w/gcc)
1044         AC_TRY_RUN(
1045                 [
1046 #include <stdio.h>
1047 #include <string.h>
1048 #ifdef HAVE_SNPRINTF
1049 main()
1050 {
1051         char buf[50];
1052         char expected_out[50];
1053         int mazsize = 50 ;
1054 #if (SIZEOF_LONG_INT == 8)
1055         long int num = 0x7fffffffffffffff;
1056 #else
1057         long long num = 0x7fffffffffffffffll;
1058 #endif
1059         strcpy(expected_out, "9223372036854775807");
1060         snprintf(buf, mazsize, "%lld", num);
1061         if(strcmp(buf, expected_out) != 0)
1062                 exit(1);
1063         exit(0);
1064 }
1065 #else
1066 main() { exit(0); }
1067 #endif
1068                 ], [ true ], [ AC_DEFINE(BROKEN_SNPRINTF) ]
1069         )
1070 fi
1071 AC_SUBST(NO_SFTP)
1072
1073 dnl Checks for structure members
1074 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
1075 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
1076 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
1077 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
1078 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
1079 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
1080 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
1081 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
1082 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmpx.h, HAVE_ID_IN_UTMPX)
1083 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
1084 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
1085 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
1086 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
1087 OSSH_CHECK_HEADER_FOR_FIELD(ut_exit, utmp.h, HAVE_EXIT_IN_UTMP)
1088 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmp.h, HAVE_TIME_IN_UTMP)
1089 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmpx.h, HAVE_TIME_IN_UTMPX)
1090 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmpx.h, HAVE_TV_IN_UTMPX)
1091 AC_STRUCT_ST_BLKSIZE
1092
1093 AC_CACHE_CHECK([for sun_len field in struct sockaddr_un],
1094                 ac_cv_have_sun_len_in_struct_sockaddr_un, [
1095         AC_TRY_COMPILE(
1096                 [
1097 #include <sys/types.h>
1098 #include <sys/socket.h>
1099                 ],
1100                 [ struct sockaddr_un s; s.sun_len = 1; ],
1101                 [ ac_cv_have_sun_len_in_struct_sockaddr_un="yes" ],
1102                 [ ac_cv_have_sun_len_in_struct_sockaddr_un="no" ],
1103         )
1104 ])
1105 if test "x$ac_cv_have_sun_len_in_struct_sockaddr_un" = "xyes" ; then
1106         AC_DEFINE(HAVE_SUN_LEN_IN_SOCKADDR_UN)
1107 fi
1108
1109 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
1110                 ac_cv_have_ss_family_in_struct_ss, [
1111         AC_TRY_COMPILE(
1112                 [
1113 #include <sys/types.h>
1114 #include <sys/socket.h>
1115                 ],
1116                 [ struct sockaddr_storage s; s.ss_family = 1; ],
1117                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
1118                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
1119         )
1120 ])
1121 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
1122         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
1123 fi
1124
1125 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
1126                 ac_cv_have___ss_family_in_struct_ss, [
1127         AC_TRY_COMPILE(
1128                 [
1129 #include <sys/types.h>
1130 #include <sys/socket.h>
1131                 ],
1132                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
1133                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
1134                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
1135         )
1136 ])
1137 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
1138         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
1139 fi
1140
1141 AC_CACHE_CHECK([for pw_class field in struct passwd],
1142                 ac_cv_have_pw_class_in_struct_passwd, [
1143         AC_TRY_COMPILE(
1144                 [
1145 #include <pwd.h>
1146                 ],
1147                 [ struct passwd p; p.pw_class = 0; ],
1148                 [ ac_cv_have_pw_class_in_struct_passwd="yes" ],
1149                 [ ac_cv_have_pw_class_in_struct_passwd="no" ]
1150         )
1151 ])
1152 if test "x$ac_cv_have_pw_class_in_struct_passwd" = "xyes" ; then
1153         AC_DEFINE(HAVE_PW_CLASS_IN_PASSWD)
1154 fi
1155
1156 AC_CACHE_CHECK([for pw_expire field in struct passwd],
1157                 ac_cv_have_pw_expire_in_struct_passwd, [
1158         AC_TRY_COMPILE(
1159                 [
1160 #include <pwd.h>
1161                 ],
1162                 [ struct passwd p; p.pw_expire = 0; ],
1163                 [ ac_cv_have_pw_expire_in_struct_passwd="yes" ],
1164                 [ ac_cv_have_pw_expire_in_struct_passwd="no" ]
1165         )
1166 ])
1167 if test "x$ac_cv_have_pw_expire_in_struct_passwd" = "xyes" ; then
1168         AC_DEFINE(HAVE_PW_EXPIRE_IN_PASSWD)
1169 fi
1170
1171 AC_CACHE_CHECK([for pw_change field in struct passwd],
1172                 ac_cv_have_pw_change_in_struct_passwd, [
1173         AC_TRY_COMPILE(
1174                 [
1175 #include <pwd.h>
1176                 ],
1177                 [ struct passwd p; p.pw_change = 0; ],
1178                 [ ac_cv_have_pw_change_in_struct_passwd="yes" ],
1179                 [ ac_cv_have_pw_change_in_struct_passwd="no" ]
1180         )
1181 ])
1182 if test "x$ac_cv_have_pw_change_in_struct_passwd" = "xyes" ; then
1183         AC_DEFINE(HAVE_PW_CHANGE_IN_PASSWD)
1184 fi
1185
1186 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
1187         AC_TRY_LINK([],
1188                 [ extern char *__progname; printf("%s", __progname); ],
1189                 [ ac_cv_libc_defines___progname="yes" ],
1190                 [ ac_cv_libc_defines___progname="no" ]
1191         )
1192 ])
1193 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
1194         AC_DEFINE(HAVE___PROGNAME)
1195 fi
1196
1197 AC_CACHE_CHECK([whether getopt has optreset support],
1198                 ac_cv_have_getopt_optreset, [
1199         AC_TRY_LINK(
1200                 [
1201 #include <getopt.h>
1202                 ],
1203                 [ extern int optreset; optreset = 0; ],
1204                 [ ac_cv_have_getopt_optreset="yes" ],
1205                 [ ac_cv_have_getopt_optreset="no" ]
1206         )
1207 ])
1208 if test "x$ac_cv_have_getopt_optreset" = "xyes" ; then
1209         AC_DEFINE(HAVE_GETOPT_OPTRESET)
1210 fi
1211
1212 AC_CACHE_CHECK([if libc defines sys_errlist], ac_cv_libc_defines_sys_errlist, [
1213         AC_TRY_LINK([],
1214                 [ extern const char *const sys_errlist[]; printf("%s", sys_errlist[0]);],
1215                 [ ac_cv_libc_defines_sys_errlist="yes" ],
1216                 [ ac_cv_libc_defines_sys_errlist="no" ]
1217         )
1218 ])
1219 if test "x$ac_cv_libc_defines_sys_errlist" = "xyes" ; then
1220         AC_DEFINE(HAVE_SYS_ERRLIST)
1221 fi
1222
1223
1224 AC_CACHE_CHECK([if libc defines sys_nerr], ac_cv_libc_defines_sys_nerr, [
1225         AC_TRY_LINK([],
1226                 [ extern int sys_nerr; printf("%i", sys_nerr);],
1227                 [ ac_cv_libc_defines_sys_nerr="yes" ],
1228                 [ ac_cv_libc_defines_sys_nerr="no" ]
1229         )
1230 ])
1231 if test "x$ac_cv_libc_defines_sys_nerr" = "xyes" ; then
1232         AC_DEFINE(HAVE_SYS_NERR)
1233 fi
1234
1235
1236 # Check whether user wants Kerberos support
1237 KRB4_MSG="no"
1238 AC_ARG_WITH(kerberos4,
1239         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
1240         [
1241                 if test "x$withval" != "xno" ; then
1242
1243                         if test "x$withval" != "xyes" ; then
1244                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1245                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1246                                 if test ! -z "$need_dash_r" ; then
1247                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
1248                                 fi
1249                                 if test ! -z "$blibpath" ; then
1250                                         blibpath="$blibpath:${withval}/lib"
1251                                 fi
1252                         else
1253                                 if test -d /usr/include/kerberosIV ; then
1254                                         CPPFLAGS="$CPPFLAGS -I/usr/include/kerberosIV"
1255                                 fi
1256                         fi
1257
1258                         AC_CHECK_HEADERS(krb.h)
1259                         if test "$ac_cv_header_krb_h" != yes; then
1260                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
1261                         fi
1262                         AC_CHECK_LIB(krb, main)
1263                         if test "$ac_cv_lib_krb_main" != yes; then
1264                                 AC_CHECK_LIB(krb4, main)
1265                                 if test "$ac_cv_lib_krb4_main" != yes; then
1266                                         AC_MSG_WARN([Cannot find libkrb nor libkrb4, build may fail])
1267                                 else
1268                                         KLIBS="-lkrb4"
1269                                 fi
1270                         else
1271                                 KLIBS="-lkrb"
1272                         fi
1273                         AC_CHECK_LIB(des, des_cbc_encrypt)
1274                         if test "$ac_cv_lib_des_des_cbc_encrypt" != yes; then
1275                                 AC_CHECK_LIB(des425, des_cbc_encrypt)
1276                                 if test "$ac_cv_lib_des425_des_cbc_encrypt" != yes; then
1277                                         AC_MSG_WARN([Cannot find libdes nor libdes425, build may fail])
1278                                 else
1279                                         KLIBS="-ldes425"
1280                                 fi
1281                         else
1282                                 KLIBS="-ldes"
1283                         fi
1284                         AC_CHECK_LIB(resolv, dn_expand, , )
1285                         KRB4=yes
1286                         KRB4_MSG="yes"
1287                         AC_DEFINE(KRB4)
1288                 fi
1289         ]
1290 )
1291
1292 # Check whether user wants AFS support
1293 AFS_MSG="no"
1294 AC_ARG_WITH(afs,
1295         [  --with-afs=PATH         Enable AFS support],
1296         [
1297                 if test "x$withval" != "xno" ; then
1298
1299                         if test "x$withval" != "xyes" ; then
1300                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1301                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1302                         fi
1303
1304                         if test -z "$KRB4" ; then
1305                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
1306                         fi
1307
1308                         LIBS="-lkafs $LIBS"
1309                         if test ! -z "$AFS_LIBS" ; then
1310                                 LIBS="$LIBS $AFS_LIBS"
1311                         fi
1312                         AC_DEFINE(AFS)
1313                         AFS_MSG="yes"
1314                 fi
1315         ]
1316 )
1317 LIBS="$LIBS $KLIBS"
1318
1319 # Looking for programs, paths and files
1320 AC_ARG_WITH(rsh,
1321         [  --with-rsh=PATH         Specify path to remote shell program ],
1322         [
1323                 if test "x$withval" != "$no" ; then
1324                         rsh_path=$withval
1325                 fi
1326         ],
1327         [
1328                 AC_PATH_PROG(rsh_path, rsh)
1329         ]
1330 )
1331
1332 AC_ARG_WITH(xauth,
1333         [  --with-xauth=PATH       Specify path to xauth program ],
1334         [
1335                 if test "x$withval" != "xno" ; then
1336                         xauth_path=$withval
1337                 fi
1338         ],
1339         [
1340                 AC_PATH_PROG(xauth_path, xauth,,$PATH:/usr/X/bin:/usr/bin/X11:/usr/X11R6/bin:/usr/openwin/bin)
1341                 if (test ! -z "$xauth_path" && test -x "/usr/openwin/bin/xauth") ; then
1342                         xauth_path="/usr/openwin/bin/xauth"
1343                 fi
1344         ]
1345 )
1346
1347 if test -z "$xauth_path" ; then
1348         XAUTH_PATH="undefined"
1349         AC_SUBST(XAUTH_PATH)
1350 else
1351         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
1352         XAUTH_PATH=$xauth_path
1353         AC_SUBST(XAUTH_PATH)
1354 fi
1355 if test ! -z "$rsh_path" ; then
1356         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
1357 fi
1358
1359 # Check for mail directory (last resort if we cannot get it from headers)
1360 if test ! -z "$MAIL" ; then
1361         maildir=`dirname $MAIL`
1362         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
1363 fi
1364
1365 if test -z "$no_dev_ptmx" ; then
1366         AC_CHECK_FILE("/dev/ptmx",
1367                 [
1368                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
1369                         have_dev_ptmx=1
1370                 ]
1371         )
1372 fi
1373 AC_CHECK_FILE("/dev/ptc",
1374         [
1375                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
1376                 have_dev_ptc=1
1377         ]
1378 )
1379
1380 # Options from here on. Some of these are preset by platform above
1381
1382 # Check for user-specified random device, otherwise check /dev/urandom
1383 AC_ARG_WITH(random,
1384         [  --with-random=FILE      read entropy from FILE (default=/dev/urandom)],
1385         [
1386                 if test "x$withval" != "xno" ; then
1387                         RANDOM_POOL="$withval";
1388                         AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
1389                 fi
1390         ],
1391         [
1392                 # Check for random device
1393                 AC_CHECK_FILE("/dev/urandom",
1394                         [
1395                                 RANDOM_POOL="/dev/urandom";
1396                                 AC_SUBST(RANDOM_POOL)
1397                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
1398                         ]
1399                 )
1400         ]
1401 )
1402
1403 # Check for PRNGD/EGD pool file
1404 AC_ARG_WITH(prngd-port,
1405         [  --with-prngd-port=PORT  read entropy from PRNGD/EGD localhost:PORT],
1406         [
1407                 if test ! -z "$withval" -a "x$withval" != "xno" ; then
1408                         PRNGD_PORT="$withval"
1409                         AC_DEFINE_UNQUOTED(PRNGD_PORT, $PRNGD_PORT)
1410                 fi
1411         ]
1412 )
1413
1414 # Check for PRNGD/EGD pool file
1415 AC_ARG_WITH(prngd-socket,
1416         [  --with-prngd-socket=FILE read entropy from PRNGD/EGD socket FILE (default=/var/run/egd-pool)],
1417         [
1418                 if test "x$withval" != "xno" ; then
1419                         PRNGD_SOCKET="$withval"
1420                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1421                 fi
1422         ],
1423         [
1424                 # Check for existing socket only if we don't have a random device already
1425                 if test -z "$RANDOM_POOL" ; then
1426                         AC_MSG_CHECKING(for PRNGD/EGD socket)
1427                         # Insert other locations here
1428                         for sock in /var/run/egd-pool /dev/egd-pool /etc/entropy; do
1429                                 if test -r $sock && $TEST_MINUS_S_SH -c "test -S $sock -o -p $sock" ; then
1430                                         PRNGD_SOCKET="$sock"
1431                                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1432                                         break;
1433                                 fi
1434                         done
1435                         if test ! -z "$PRNGD_SOCKET" ; then
1436                                 AC_MSG_RESULT($PRNGD_SOCKET)
1437                         else
1438                                 AC_MSG_RESULT(not found)
1439                         fi
1440                 fi
1441         ]
1442 )
1443
1444
1445 # detect pathnames for entropy gathering commands, if we need them
1446 INSTALL_SSH_PRNG_CMDS=""
1447 rm -f prng_commands
1448 if (test -z "$RANDOM_POOL" && test -z "$PRNGD") ; then
1449         # Use these commands to collect entropy
1450         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1451         OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
1452         OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
1453         OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
1454         OSSH_PATH_ENTROPY_PROG(PROG_JSTAT, jstat)
1455         OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
1456         OSSH_PATH_ENTROPY_PROG(PROG_SAR, sar)
1457         OSSH_PATH_ENTROPY_PROG(PROG_W, w)
1458         OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
1459         OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
1460         OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
1461         OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
1462         OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
1463         OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
1464         OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
1465         OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
1466
1467         INSTALL_SSH_PRNG_CMDS="yes"
1468 fi
1469 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
1470
1471
1472 AC_ARG_WITH(mantype,
1473         [  --with-mantype=man|cat|doc  Set man page type],
1474         [
1475                 case "$withval" in
1476                 man|cat|doc)
1477                         MANTYPE=$withval
1478                         ;;
1479                 *)
1480                         AC_MSG_ERROR(invalid man type: $withval)
1481                         ;;
1482                 esac
1483         ]
1484 )
1485 if test -z "$MANTYPE"; then
1486         AC_PATH_PROGS(NROFF, nroff awf, /bin/false, /usr/bin:/usr/ucb)
1487         if ${NROFF} -mdoc ${srcdir}/ssh.1 >/dev/null 2>&1; then
1488                 MANTYPE=doc
1489         elif ${NROFF} -man ${srcdir}/ssh.1 >/dev/null 2>&1; then
1490                 MANTYPE=man
1491         else
1492                 MANTYPE=cat
1493         fi
1494 fi
1495 AC_SUBST(MANTYPE)
1496 if test "$MANTYPE" = "doc"; then
1497         mansubdir=man;
1498 else
1499         mansubdir=$MANTYPE;
1500 fi
1501 AC_SUBST(mansubdir)
1502
1503 # Check whether to enable MD5 passwords
1504 MD5_MSG="no"
1505 AC_ARG_WITH(md5-passwords,
1506         [  --with-md5-passwords    Enable use of MD5 passwords],
1507         [
1508                 if test "x$withval" != "xno" ; then
1509                         AC_DEFINE(HAVE_MD5_PASSWORDS)
1510                         MD5_MSG="yes"
1511                 fi
1512         ]
1513 )
1514
1515 # Whether to disable shadow password support
1516 AC_ARG_WITH(shadow,
1517         [  --without-shadow        Disable shadow password support],
1518         [
1519                 if test "x$withval" = "xno" ; then
1520                         AC_DEFINE(DISABLE_SHADOW)
1521                         disable_shadow=yes
1522                 fi
1523         ]
1524 )
1525
1526 if test -z "$disable_shadow" ; then
1527         AC_MSG_CHECKING([if the systems has expire shadow information])
1528         AC_TRY_COMPILE(
1529         [
1530 #include <sys/types.h>
1531 #include <shadow.h>
1532         struct spwd sp;
1533         ],[ sp.sp_expire = sp.sp_lstchg = sp.sp_inact = 0; ],
1534         [ sp_expire_available=yes ], []
1535         )
1536
1537         if test "x$sp_expire_available" = "xyes" ; then
1538                 AC_MSG_RESULT(yes)
1539                 AC_DEFINE(HAS_SHADOW_EXPIRE)
1540         else
1541                 AC_MSG_RESULT(no)
1542         fi
1543 fi
1544
1545 # Use ip address instead of hostname in $DISPLAY
1546 if test ! -z "$IPADDR_IN_DISPLAY" ; then
1547         DISPLAY_HACK_MSG="yes"
1548         AC_DEFINE(IPADDR_IN_DISPLAY)
1549 else
1550         DISPLAY_HACK_MSG="no"
1551         AC_ARG_WITH(ipaddr-display,
1552                 [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
1553                 [
1554                         if test "x$withval" != "xno" ; then
1555                                 AC_DEFINE(IPADDR_IN_DISPLAY)
1556                                 DISPLAY_HACK_MSG="yes"
1557                         fi
1558                 ]
1559         )
1560 fi
1561
1562 # Whether to mess with the default path
1563 SERVER_PATH_MSG="(default)"
1564 AC_ARG_WITH(default-path,
1565         [  --with-default-path=PATH Specify default \$PATH environment for server],
1566         [
1567                 if test "x$withval" != "xno" ; then
1568                         user_path="$withval"
1569                         SERVER_PATH_MSG="$withval"
1570                 fi
1571         ],
1572         [
1573         AC_TRY_RUN(
1574                 [
1575 /* find out what STDPATH is */
1576 #include <stdio.h>
1577 #ifdef HAVE_PATHS_H
1578 # include <paths.h>
1579 #endif
1580 #ifndef _PATH_STDPATH
1581 # define _PATH_STDPATH "/usr/bin:/bin:/usr/sbin:/sbin"
1582 #endif
1583 #include <sys/types.h>
1584 #include <sys/stat.h>
1585 #include <fcntl.h>
1586 #define DATA "conftest.stdpath"
1587
1588 main()
1589 {
1590         FILE *fd;
1591         int rc;
1592
1593         fd = fopen(DATA,"w");
1594         if(fd == NULL)
1595                 exit(1);
1596
1597         if ((rc = fprintf(fd,"%s", _PATH_STDPATH)) < 0)
1598                 exit(1);
1599
1600         exit(0);
1601 }
1602                 ], [ user_path=`cat conftest.stdpath` ],
1603                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ],
1604                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ]
1605         )
1606 # make sure $bindir is in USER_PATH so scp will work
1607                 t_bindir=`eval echo ${bindir}`
1608                 case $t_bindir in
1609                         NONE/*) t_bindir=`echo $t_bindir | sed "s~NONE~$prefix~"` ;;
1610                 esac
1611                 case $t_bindir in
1612                         NONE/*) t_bindir=`echo $t_bindir | sed "s~NONE~$ac_default_prefix~"` ;;
1613                 esac
1614                 echo $user_path | grep ":$t_bindir"  > /dev/null 2>&1
1615                 if test $? -ne 0  ; then
1616                         echo $user_path | grep "^$t_bindir"  > /dev/null 2>&1
1617                         if test $? -ne 0  ; then
1618                                 user_path=$user_path:$t_bindir
1619                                 AC_MSG_RESULT(Adding $t_bindir to USER_PATH so scp will work)
1620                         fi
1621                 fi
1622         ]
1623 )
1624 AC_DEFINE_UNQUOTED(USER_PATH, "$user_path")
1625 AC_SUBST(user_path)
1626
1627 # Whether to force IPv4 by default (needed on broken glibc Linux)
1628 IPV4_HACK_MSG="no"
1629 AC_ARG_WITH(ipv4-default,
1630         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
1631         [
1632                 if test "x$withval" != "xno" ; then
1633                         AC_DEFINE(IPV4_DEFAULT)
1634                         IPV4_HACK_MSG="yes"
1635                 fi
1636         ]
1637 )
1638
1639 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
1640 IPV4_IN6_HACK_MSG="no"
1641 AC_ARG_WITH(4in6,
1642         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
1643         [
1644                 if test "x$withval" != "xno" ; then
1645                         AC_MSG_RESULT(yes)
1646                         AC_DEFINE(IPV4_IN_IPV6)
1647                         IPV4_IN6_HACK_MSG="yes"
1648                 else
1649                         AC_MSG_RESULT(no)
1650                 fi
1651         ],[
1652                 if test "x$inet6_default_4in6" = "xyes"; then
1653                         AC_MSG_RESULT([yes (default)])
1654                         AC_DEFINE(IPV4_IN_IPV6)
1655                         IPV4_IN6_HACK_MSG="yes"
1656                 else
1657                         AC_MSG_RESULT([no (default)])
1658                 fi
1659         ]
1660 )
1661
1662 # Whether to enable BSD auth support
1663 AC_ARG_WITH(bsd-auth,
1664         [  --with-bsd-auth         Enable BSD auth support],
1665         [
1666                 if test "x$withval" != "xno" ; then
1667                         AC_DEFINE(BSD_AUTH)
1668                         bsd_auth=yes
1669                 fi
1670         ]
1671 )
1672
1673 AC_MSG_CHECKING(whether to install ssh as suid root)
1674 AC_ARG_ENABLE(suid-ssh,
1675 [  --enable-suid-ssh       Install ssh as suid root (default)
1676   --disable-suid-ssh      Install ssh without suid bit],
1677 [ case "$enableval" in
1678   no)
1679        AC_MSG_RESULT(no)
1680        SSHMODE=0711
1681        ;;
1682   *)   AC_MSG_RESULT(yes)
1683        SSHMODE=4711
1684        ;;
1685   esac ],
1686   AC_MSG_RESULT(yes)
1687   SSHMODE=4711
1688 )
1689 AC_SUBST(SSHMODE)
1690
1691
1692 # Where to place sshd.pid
1693 piddir=/var/run
1694 AC_ARG_WITH(pid-dir,
1695         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
1696         [
1697                 if test "x$withval" != "xno" ; then
1698                         piddir=$withval
1699                 fi
1700         ]
1701 )
1702
1703 # make sure the directory exists
1704 if test ! -d $piddir ; then
1705         piddir=`eval echo ${sysconfdir}`
1706         case $piddir in
1707                 NONE/*) piddir=`echo $piddir | sed "s~NONE~$ac_default_prefix~"` ;;
1708         esac
1709 fi
1710
1711 AC_DEFINE_UNQUOTED(_PATH_SSH_PIDDIR, "$piddir")
1712 AC_SUBST(piddir)
1713
1714 dnl allow user to disable some login recording features
1715 AC_ARG_ENABLE(lastlog,
1716         [  --disable-lastlog       disable use of lastlog even if detected [no]],
1717         [ AC_DEFINE(DISABLE_LASTLOG) ]
1718 )
1719 AC_ARG_ENABLE(utmp,
1720         [  --disable-utmp          disable use of utmp even if detected [no]],
1721         [ AC_DEFINE(DISABLE_UTMP) ]
1722 )
1723 AC_ARG_ENABLE(utmpx,
1724         [  --disable-utmpx         disable use of utmpx even if detected [no]],
1725         [ AC_DEFINE(DISABLE_UTMPX) ]
1726 )
1727 AC_ARG_ENABLE(wtmp,
1728         [  --disable-wtmp          disable use of wtmp even if detected [no]],
1729         [ AC_DEFINE(DISABLE_WTMP) ]
1730 )
1731 AC_ARG_ENABLE(wtmpx,
1732         [  --disable-wtmpx         disable use of wtmpx even if detected [no]],
1733         [ AC_DEFINE(DISABLE_WTMPX) ]
1734 )
1735 AC_ARG_ENABLE(libutil,
1736         [  --disable-libutil       disable use of libutil (login() etc.) [no]],
1737         [ AC_DEFINE(DISABLE_LOGIN) ]
1738 )
1739 AC_ARG_ENABLE(pututline,
1740         [  --disable-pututline     disable use of pututline() etc. ([uw]tmp) [no]],
1741         [ AC_DEFINE(DISABLE_PUTUTLINE) ]
1742 )
1743 AC_ARG_ENABLE(pututxline,
1744         [  --disable-pututxline    disable use of pututxline() etc. ([uw]tmpx) [no]],
1745         [ AC_DEFINE(DISABLE_PUTUTXLINE) ]
1746 )
1747 AC_ARG_WITH(lastlog,
1748   [  --with-lastlog=FILE|DIR specify lastlog location [common locations]],
1749         [
1750                 if test "x$withval" = "xno" ; then
1751                         AC_DEFINE(DISABLE_LASTLOG)
1752                 else
1753                         conf_lastlog_location=$withval
1754                 fi
1755         ]
1756 )
1757
1758 dnl lastlog, [uw]tmpx? detection
1759 dnl  NOTE: set the paths in the platform section to avoid the
1760 dnl   need for command-line parameters
1761 dnl lastlog and [uw]tmp are subject to a file search if all else fails
1762
1763 dnl lastlog detection
1764 dnl  NOTE: the code itself will detect if lastlog is a directory
1765 AC_MSG_CHECKING([if your system defines LASTLOG_FILE])
1766 AC_TRY_COMPILE([
1767 #include <sys/types.h>
1768 #include <utmp.h>
1769 #ifdef HAVE_LASTLOG_H
1770 #  include <lastlog.h>
1771 #endif
1772 #ifdef HAVE_PATHS_H
1773 #  include <paths.h>
1774 #endif
1775         ],
1776         [ char *lastlog = LASTLOG_FILE; ],
1777         [ AC_MSG_RESULT(yes) ],
1778         [
1779                 AC_MSG_RESULT(no)
1780                 AC_MSG_CHECKING([if your system defines _PATH_LASTLOG])
1781                 AC_TRY_COMPILE([
1782 #include <sys/types.h>
1783 #include <utmp.h>
1784 #ifdef HAVE_LASTLOG_H
1785 #  include <lastlog.h>
1786 #endif
1787 #ifdef HAVE_PATHS_H
1788 #  include <paths.h>
1789 #endif
1790                 ],
1791                 [ char *lastlog = _PATH_LASTLOG; ],
1792                 [ AC_MSG_RESULT(yes) ],
1793                 [
1794                         AC_MSG_RESULT(no)
1795                         system_lastlog_path=no
1796                 ])
1797         ]
1798 )
1799
1800 if test -z "$conf_lastlog_location"; then
1801         if test x"$system_lastlog_path" = x"no" ; then
1802                 for f in /var/log/lastlog /usr/adm/lastlog /var/adm/lastlog /etc/security/lastlog ; do
1803                                 if (test -d "$f" || test -f "$f") ; then
1804                                         conf_lastlog_location=$f
1805                                 fi
1806                 done
1807                 if test -z "$conf_lastlog_location"; then
1808                         AC_MSG_WARN([** Cannot find lastlog **])
1809                         dnl Don't define DISABLE_LASTLOG - that means we don't try wtmp/wtmpx
1810                 fi
1811         fi
1812 fi
1813
1814 if test -n "$conf_lastlog_location"; then
1815         AC_DEFINE_UNQUOTED(CONF_LASTLOG_FILE, "$conf_lastlog_location")
1816 fi
1817
1818 dnl utmp detection
1819 AC_MSG_CHECKING([if your system defines UTMP_FILE])
1820 AC_TRY_COMPILE([
1821 #include <sys/types.h>
1822 #include <utmp.h>
1823 #ifdef HAVE_PATHS_H
1824 #  include <paths.h>
1825 #endif
1826         ],
1827         [ char *utmp = UTMP_FILE; ],
1828         [ AC_MSG_RESULT(yes) ],
1829         [ AC_MSG_RESULT(no)
1830           system_utmp_path=no ]
1831 )
1832 if test -z "$conf_utmp_location"; then
1833         if test x"$system_utmp_path" = x"no" ; then
1834                 for f in /etc/utmp /usr/adm/utmp /var/run/utmp; do
1835                         if test -f $f ; then
1836                                 conf_utmp_location=$f
1837                         fi
1838                 done
1839                 if test -z "$conf_utmp_location"; then
1840                         AC_DEFINE(DISABLE_UTMP)
1841                 fi
1842         fi
1843 fi
1844 if test -n "$conf_utmp_location"; then
1845         AC_DEFINE_UNQUOTED(CONF_UTMP_FILE, "$conf_utmp_location")
1846 fi
1847
1848 dnl wtmp detection
1849 AC_MSG_CHECKING([if your system defines WTMP_FILE])
1850 AC_TRY_COMPILE([
1851 #include <sys/types.h>
1852 #include <utmp.h>
1853 #ifdef HAVE_PATHS_H
1854 #  include <paths.h>
1855 #endif
1856         ],
1857         [ char *wtmp = WTMP_FILE; ],
1858         [ AC_MSG_RESULT(yes) ],
1859         [ AC_MSG_RESULT(no)
1860           system_wtmp_path=no ]
1861 )
1862 if test -z "$conf_wtmp_location"; then
1863         if test x"$system_wtmp_path" = x"no" ; then
1864                 for f in /usr/adm/wtmp /var/log/wtmp; do
1865                         if test -f $f ; then
1866                                 conf_wtmp_location=$f
1867                         fi
1868                 done
1869                 if test -z "$conf_wtmp_location"; then
1870                         AC_DEFINE(DISABLE_WTMP)
1871                 fi
1872         fi
1873 fi
1874 if test -n "$conf_wtmp_location"; then
1875         AC_DEFINE_UNQUOTED(CONF_WTMP_FILE, "$conf_wtmp_location")
1876 fi
1877
1878
1879 dnl utmpx detection - I don't know any system so perverse as to require
1880 dnl  utmpx, but not define UTMPX_FILE (ditto wtmpx.) No doubt it's out
1881 dnl  there, though.
1882 AC_MSG_CHECKING([if your system defines UTMPX_FILE])
1883 AC_TRY_COMPILE([
1884 #include <sys/types.h>
1885 #include <utmp.h>
1886 #ifdef HAVE_UTMPX_H
1887 #include <utmpx.h>
1888 #endif
1889 #ifdef HAVE_PATHS_H
1890 #  include <paths.h>
1891 #endif
1892         ],
1893         [ char *utmpx = UTMPX_FILE; ],
1894         [ AC_MSG_RESULT(yes) ],
1895         [ AC_MSG_RESULT(no)
1896           system_utmpx_path=no ]
1897 )
1898 if test -z "$conf_utmpx_location"; then
1899         if test x"$system_utmpx_path" = x"no" ; then
1900                 AC_DEFINE(DISABLE_UTMPX)
1901         fi
1902 else
1903         AC_DEFINE_UNQUOTED(CONF_UTMPX_FILE, "$conf_utmpx_location")
1904 fi
1905
1906 dnl wtmpx detection
1907 AC_MSG_CHECKING([if your system defines WTMPX_FILE])
1908 AC_TRY_COMPILE([
1909 #include <sys/types.h>
1910 #include <utmp.h>
1911 #ifdef HAVE_UTMPX_H
1912 #include <utmpx.h>
1913 #endif
1914 #ifdef HAVE_PATHS_H
1915 #  include <paths.h>
1916 #endif
1917         ],
1918         [ char *wtmpx = WTMPX_FILE; ],
1919         [ AC_MSG_RESULT(yes) ],
1920         [ AC_MSG_RESULT(no)
1921           system_wtmpx_path=no ]
1922 )
1923 if test -z "$conf_wtmpx_location"; then
1924         if test x"$system_wtmpx_path" = x"no" ; then
1925                 AC_DEFINE(DISABLE_WTMPX)
1926         fi
1927 else
1928         AC_DEFINE_UNQUOTED(CONF_WTMPX_FILE, "$conf_wtmpx_location")
1929 fi
1930
1931
1932 # Change default command timeout for builtin PRNG
1933 entropy_timeout=200
1934 AC_ARG_WITH(entropy-timeout,
1935         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
1936         [
1937                 if test "x$withval" != "xno" ; then
1938                         entropy_timeout=$withval
1939                 fi
1940         ]
1941 )
1942 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
1943
1944
1945 if test ! -z "$blibpath" ; then
1946         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
1947         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
1948 fi
1949
1950 AC_EXEEXT
1951
1952 AC_OUTPUT(Makefile openbsd-compat/Makefile ssh_prng_cmds)
1953
1954 # Print summary of options
1955
1956 if test ! -z "$RANDOM_POOL" ; then
1957         RAND_MSG="Device ($RANDOM_POOL)"
1958 else
1959         if test ! -z "$PRNGD_PORT" ; then
1960                 RAND_MSG="PRNGD/EGD (port localhost:$PRNGD_PORT)"
1961         elif test ! -z "$PRNGD_SOCKET" ; then
1962                 RAND_MSG="PRNGD/EGD (socket $PRNGD_SOCKET)"
1963         else
1964                 RAND_MSG="Builtin (timeout $entropy_timeout)"
1965                 BUILTIN_RNG=1
1966         fi
1967 fi
1968
1969 # Someone please show me a better way :)
1970 A=`eval echo ${prefix}` ; A=`eval echo ${A}`
1971 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
1972 C=`eval echo ${sbindir}` ; C=`eval echo ${C}`
1973 D=`eval echo ${sysconfdir}` ; D=`eval echo ${D}`
1974 E=`eval echo ${libexecdir}/ssh-askpass` ; E=`eval echo ${E}`
1975 F=`eval echo ${mandir}/${mansubdir}X` ; F=`eval echo ${F}`
1976 G=`eval echo ${piddir}` ; G=`eval echo ${G}`
1977 H=`eval echo ${user_path}` ; H=`eval echo ${H}`
1978
1979 echo ""
1980 echo "OpenSSH has been configured with the following options:"
1981 echo "                 User binaries: $B"
1982 echo "               System binaries: $C"
1983 echo "           Configuration files: $D"
1984 echo "               Askpass program: $E"
1985 echo "                  Manual pages: $F"
1986 echo "                      PID file: $G"
1987 echo "        sshd default user PATH: $H"
1988 echo "      Random number collection: $RAND_MSG"
1989 echo "                Manpage format: $MANTYPE"
1990 echo "                   PAM support: ${PAM_MSG}"
1991 echo "            KerberosIV support: $KRB4_MSG"
1992 echo "                   AFS support: $AFS_MSG"
1993 echo "                 S/KEY support: $SKEY_MSG"
1994 echo "          TCP Wrappers support: $TCPW_MSG"
1995 echo "          MD5 password support: $MD5_MSG"
1996 echo "   IP address in \$DISPLAY hack: $DISPLAY_HACK_MSG"
1997 echo "      Use IPv4 by default hack: $IPV4_HACK_MSG"
1998 echo "       Translate v4 in v6 hack: $IPV4_IN6_HACK_MSG"
1999
2000 if test ! -z "$bsd_auth"; then
2001         echo "              BSD Auth support: yes"
2002 fi
2003
2004 echo ""
2005
2006 echo "              Host: ${host}"
2007 echo "          Compiler: ${CC}"
2008 echo "    Compiler flags: ${CFLAGS}"
2009 echo "Preprocessor flags: ${CPPFLAGS}"
2010 echo "      Linker flags: ${LDFLAGS}"
2011 echo "         Libraries: ${LIBS}"
2012
2013 echo ""
2014
2015 if test "x$PAM_MSG" = "xyes" ; then
2016         echo "PAM is enabled. You may need to install a PAM control file for sshd,"
2017         echo "otherwise password authentication may fail. Example PAM control files"
2018         echo "can be found in the contrib/ subdirectory"
2019         echo ""
2020 fi
2021
2022 if test ! -z "$BUILTIN_RNG" ; then
2023         echo "WARNING: you are using the builtin random number collection service."
2024         echo "Please read WARNING.RNG and request that your OS vendor includes"
2025         echo "/dev/random in future versions of their OS."
2026         echo ""
2027 fi
2028
2029 if test ! -z "$NO_SFTP"; then
2030         echo "sftp-server will be disabled.  Your compiler does not support"
2031         echo "64bit integers."
2032         echo ""
2033 fi
2034