configure.in

   1 AC_INIT(ssh.c)
   2
   3 AC_CONFIG_HEADER(config.h)
   4 AC_PROG_CC
   5 AC_CANONICAL_HOST
   6
   7 # Checks for programs.
   8 AC_PROG_CPP
   9 AC_PROG_RANLIB
  10 AC_PROG_INSTALL
  11 AC_CHECK_PROG(AR, ar, ar)
  12 AC_PATH_PROG(PERL, perl)
  13 AC_SUBST(PERL)
  14
  15 if test -z "$LD" ; then
  16         LD=$CC
  17 fi
  18 AC_SUBST(LD)
  19
  20 # C Compiler features
  21 AC_C_INLINE
  22 if test "$GCC" = "yes"; then
  23         CFLAGS="$CFLAGS -Wall"
  24 fi
  25
  26 # Check for some target-specific stuff
  27 case "$host" in
  28 *-*-aix*)
  29         AFS_LIBS="-lld"
  30         CFLAGS="$CFLAGS -I/usr/local/include"
  31         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  32         if test "$LD" != "gcc" -a -z "$blibpath"; then
  33                 blibpath="/usr/lib:/lib:/usr/local/lib"
  34         fi
  35         AC_DEFINE(BROKEN_GETADDRINFO)
  36         ;;
  37 *-*-hpux10*)
  38         if test -z "$GCC"; then
  39                 CFLAGS="$CFLAGS -Aa"
  40         fi
  41         CFLAGS="$CFLAGS -D_HPUX_SOURCE"
  42         CFLAGS="$CFLAGS -I/usr/local/include"
  43         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  44         AC_DEFINE(IPADDR_IN_DISPLAY)
  45         AC_DEFINE(USE_UTMPX)
  46         AC_MSG_CHECKING(for HPUX trusted system password database)
  47         if test -f /tcb/files/auth/system/default; then
  48                 AC_MSG_RESULT(yes)
  49                 AC_DEFINE(HAVE_HPUX_TRUSTED_SYSTEM_PW)
  50                 LIBS="$LIBS -lsec"
  51                 AC_MSG_WARN([This configuration is untested])
  52         else
  53                 AC_MSG_RESULT(no)
  54                 AC_DEFINE(DISABLE_SHADOW)
  55         fi
  56         MANTYPE='$(CATMAN)'
  57         mansubdir=cat
  58         ;;
  59 *-*-irix5*)
  60         CFLAGS="$CFLAGS -I/usr/local/include"
  61         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  62         MANTYPE='$(CATMAN)'
  63         no_libsocket=1
  64         no_libnsl=1
  65         ;;
  66 *-*-irix6*)
  67         CFLAGS="$CFLAGS -I/usr/local/include"
  68         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  69         MANTYPE='$(CATMAN)'
  70         AC_MSG_WARN([*** Irix 6.x is not tested, please report you experiences *** ])
  71         no_libsocket=1
  72         no_libnsl=1
  73         ;;
  74 *-*-linux*)
  75         no_dev_ptmx=1
  76         AC_DEFINE(DONT_TRY_OTHER_AF)
  77         inet6_default_4in6=yes
  78         ;;
  79 *-*-netbsd*)
  80         need_dash_r=1
  81         ;;
  82 *-*-solaris*)
  83         CFLAGS="$CFLAGS -I/usr/local/include"
  84         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib -L/usr/ucblib -R/usr/ucblib"
  85         need_dash_r=1
  86         AC_DEFINE(USE_UTMPX)
  87         ;;
  88 *-*-sysv*)
  89         CFLAGS="$CFLAGS -I/usr/local/include"
  90         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  91         AC_DEFINE(USE_UTMPX)
  92         MANTYPE='$(CATMAN)'
  93         mansubdir=cat
  94         LIBS="$LIBS -lgen -lsocket"
  95         ;;
  96 esac
  97
  98 # Checks for libraries.
  99 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first ***]))
 100 AC_CHECK_LIB(util, login, AC_DEFINE(HAVE_LIBUTIL_LOGIN) LIBS="$LIBS -lutil")
 101
 102 if test -z "$no_libsocket" ; then
 103         AC_CHECK_LIB(nsl, yp_match, , )
 104 fi
 105 if test -z "$no_libnsl" ; then
 106         AC_CHECK_LIB(socket, main, , )
 107 fi
 108
 109 # Checks for header files.
 110 AC_CHECK_HEADERS(bstring.h endian.h lastlog.h login.h maillock.h netdb.h netgroup.h paths.h poll.h pty.h shadow.h security/pam_appl.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h sys/poll.h sys/select.h sys/stropts.h sys/sysmacros.h sys/time.h sys/ttcompat.h stddef.h util.h utmp.h utmpx.h)
 111
 112 # Checks for library functions.
 113 AC_CHECK_FUNCS(arc4random bindresvport_af freeaddrinfo gai_strerror getaddrinfo getnameinfo innetgr md5_crypt mkdtemp openpty rresvport_af setenv seteuid setlogin setproctitle setreuid snprintf strlcat strlcpy updwtmpx vsnprintf _getpty)
 114
 115 AC_CHECK_FUNC(login,
 116         [AC_DEFINE(HAVE_LOGIN)],
 117         [AC_CHECK_LIB(bsd, login, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_LOGIN)])]
 118 )
 119
 120 AC_CHECK_FUNC(daemon,
 121         [AC_DEFINE(HAVE_DAEMON)],
 122         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 123 )
 124
 125 AC_CHECK_FUNC(getpagesize,
 126         [AC_DEFINE(HAVE_GETPAGESIZE)],
 127         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 128 )
 129
 130 AC_ARG_WITH(pam,
 131         [  --without-pam           Disable PAM support ],
 132         [
 133                 if test "x$withval" = "xno" ; then
 134                         no_pam=1
 135                         AC_DEFINE(DISABLE_PAM)
 136                 fi
 137         ]
 138 )
 139 if test -z "$no_pam" -a "x$ac_cv_header_security_pam_appl_h" = "xyes" ; then
 140         AC_CHECK_LIB(dl, dlopen, , )
 141         LIBS="$LIBS -lpam"
 142
 143         # Check PAM strerror arguments (old PAM)
 144         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 145         AC_TRY_COMPILE(
 146                 [
 147                         #include <stdlib.h>
 148                         #include <security/pam_appl.h>
 149                 ],
 150                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 151                 [AC_MSG_RESULT(no)],
 152                 [
 153                         AC_DEFINE(HAVE_OLD_PAM)
 154                         AC_MSG_RESULT(yes)
 155                 ]
 156         )
 157 fi
 158
 159 # The big search for OpenSSL
 160 AC_ARG_WITH(ssl-dir,
 161         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 162         [
 163                 if test "x$withval" != "$xno" ; then
 164                         tryssldir=$withval
 165                 fi
 166         ]
 167 )
 168
 169 saved_LIBS="$LIBS"
 170 saved_LDFLAGS="$LDFLAGS"
 171 saved_CFLAGS="$CFLAGS"
 172 if test "x$prefix" != "xNONE" ; then
 173         tryssldir="$tryssldir $prefix"
 174 fi
 175 AC_MSG_CHECKING([for OpenSSL/SSLeay directory])
 176 for ssldir in "" $tryssldir /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 177         if test ! -z "$ssldir" ; then
 178                 LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 179                 CFLAGS="$saved_CFLAGS -I$ssldir/include"
 180                 if test ! -z "$need_dash_r" ; then
 181                         LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 182                 fi
 183         else
 184                 LDFLAGS="$saved_LDFLAGS"
 185         fi
 186
 187         for WANTS_RSAREF in "" 1 ; do
 188
 189                 if test -z "$WANTS_RSAREF" ; then
 190                         LIBS="$saved_LIBS -lcrypto"
 191                 else
 192                         LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 193                 fi
 194
 195                 AC_TRY_RUN(
 196                         [
 197                                 #include <openssl/rsa.h>
 198                                 #include <openssl/bn.h>
 199                                 #include <openssl/sha.h>
 200                                 int main(void)
 201                                 {RSA *key; char seed[2048];memset(seed, 0, sizeof(seed));
 202                                 RAND_seed(seed, sizeof(seed));key=RSA_generate_key(32,3,NULL,NULL);
 203                                 return(key==NULL);}
 204                         ],
 205                         [
 206                                 AC_DEFINE(HAVE_OPENSSL)
 207                                 found_crypto=1
 208                                 break;
 209                         ], []
 210                 )
 211                 AC_TRY_RUN(
 212                         [
 213                                 #include <ssl/rsa.h>
 214                                 #include <ssl/bn.h>
 215                                 #include <ssl/sha.h>
 216                                 int main(void)
 217                                 {RSA *key; char seed[2048];memset(seed, 0, sizeof(seed));
 218                                 RAND_seed(seed, sizeof(seed));key=RSA_generate_key(32,3,NULL,NULL);
 219                                 return(key==NULL);}
 220                         ],
 221                         [
 222                                 AC_DEFINE(HAVE_SSL)
 223                                 found_crypto=1
 224                                 break;
 225                         ], []
 226                 )
 227         done
 228
 229         if test ! -z "$found_crypto" ; then
 230                 break;
 231         fi
 232 done
 233
 234 if test -z "$found_crypto" ; then
 235         AC_MSG_ERROR([Could not find working SSLeay / OpenSSL libraries, please install])
 236 fi
 237 if test -z "$ssldir" ; then
 238         ssldir="(system)"
 239 else
 240         CFLAGS="$saved_CFLAGS -I$ssldir/include"
 241         LDFLAGS="$saved_LDFLAGS -L$ssldir/lib -L$ssldir"
 242         if test ! -z "$need_dash_r" ; then
 243                 LDFLAGS="$LDFLAGS -R$ssldir/lib -R$ssldir"
 244         fi
 245         if test ! -z "$blibpath" ; then
 246                 blibpath="$blibpath:$ssldir:$ssldir/lib"
 247         fi
 248 fi
 249 if test -z "$WANTS_RSAREF" ; then
 250         LIBS="$saved_LIBS -lcrypto"
 251 else
 252         LIBS="$saved_LIBS -lcrypto -lRSAglue -lrsaref"
 253 fi
 254 AC_MSG_RESULT($ssldir)
 255
 256 # Checks for data types
 257 AC_CHECK_SIZEOF(char, 1)
 258 AC_CHECK_SIZEOF(short int, 2)
 259 AC_CHECK_SIZEOF(int, 4)
 260 AC_CHECK_SIZEOF(long int, 4)
 261 AC_CHECK_SIZEOF(long long int, 8)
 262
 263 # More checks for data types
 264 AC_MSG_CHECKING([for intXX_t types])
 265 AC_TRY_COMPILE(
 266         [#include <sys/types.h>],
 267         [int8_t a; int16_t b; int32_t c; int64_t d; a = b = c = d = 1;],
 268         [
 269                 AC_DEFINE(HAVE_INTXX_T)
 270                 AC_MSG_RESULT(yes)
 271                 have_intxx_t=1
 272         ],
 273         [AC_MSG_RESULT(no)]
 274 )
 275
 276 AC_MSG_CHECKING([for u_intXX_t types])
 277 AC_TRY_COMPILE(
 278         [#include <sys/types.h>],
 279         [u_int8_t a; u_int16_t b; u_int32_t c; u_int64_t d; a = b = c = d = 1;],
 280         [
 281                 AC_DEFINE(HAVE_U_INTXX_T)
 282                 AC_MSG_RESULT(yes)
 283                 have_u_intxx_t=1
 284         ],
 285         [AC_MSG_RESULT(no)]
 286 )
 287
 288 if test -z "$have_u_intxx_t" -o -z "$have_intxx_t" -a \
 289            "x$ac_cv_header_sys_bitypes_h" = "xyes"
 290 then
 291         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
 292         AC_TRY_COMPILE(
 293                 [#include <sys/bitypes.h>],
 294                 [
 295                         int8_t a; int16_t b; int32_t c; int64_t d;
 296                         u_int8_t e; u_int16_t f; u_int32_t g; u_int64_t h;
 297                         a = b = c = d = e = f = g = h = 1;
 298                 ],
 299                 [
 300                         AC_DEFINE(HAVE_U_INTXX_T)
 301                         AC_DEFINE(HAVE_INTXX_T)
 302                         AC_MSG_RESULT(yes)
 303                 ],
 304                 [AC_MSG_RESULT(no)]
 305         )
 306 fi
 307
 308 if test -z "$have_u_intxx_t" ; then
 309         AC_MSG_CHECKING([for uintXX_t types])
 310         AC_TRY_COMPILE(
 311                 [#include <sys/types.h>],
 312                 [uint8_t a; uint16_t b; uint32_t c; uint64_t d; a = b = c = d = 1;],
 313                 [
 314                         AC_DEFINE(HAVE_UINTXX_T)
 315                         AC_MSG_RESULT(yes)
 316                 ],
 317                 [AC_MSG_RESULT(no)]
 318         )
 319 fi
 320
 321 AC_MSG_CHECKING([for socklen_t])
 322 AC_TRY_COMPILE(
 323         [
 324                 #include <sys/types.h>
 325                 #include <sys/socket.h>
 326         ],
 327         [socklen_t foo; foo = 1235;],
 328         [
 329                 AC_DEFINE(HAVE_SOCKLEN_T)
 330                 AC_MSG_RESULT(yes)
 331         ],
 332         [AC_MSG_RESULT(no)]
 333 )
 334
 335 AC_MSG_CHECKING([for size_t])
 336 AC_TRY_COMPILE(
 337         [#include <sys/types.h>],
 338         [size_t foo; foo = 1235;],
 339         [
 340                 AC_DEFINE(HAVE_SIZE_T)
 341                 AC_MSG_RESULT(yes)
 342         ],
 343         [AC_MSG_RESULT(no)]
 344 )
 345
 346 AC_MSG_CHECKING([for struct sockaddr_storage])
 347 AC_TRY_COMPILE(
 348         [
 349                 #include <sys/types.h>
 350                 #include <sys/socket.h>
 351         ],
 352         [struct sockaddr_storage s;],
 353         [
 354                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
 355                 AC_MSG_RESULT(yes)
 356         ],
 357         [AC_MSG_RESULT(no)]
 358 )
 359
 360 AC_MSG_CHECKING([for struct sockaddr_in6])
 361 AC_TRY_COMPILE(
 362         [#include <netinet/in.h>],
 363         [struct sockaddr_in6 s; s.sin6_family = 0;],
 364         [
 365                 AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
 366                 AC_MSG_RESULT(yes)
 367         ],
 368         [AC_MSG_RESULT(no)]
 369 )
 370
 371 AC_MSG_CHECKING([for struct in6_addr])
 372 AC_TRY_COMPILE(
 373         [#include <netinet/in.h>],
 374         [struct in6_addr s; s.s6_addr[0] = 0;],
 375         [
 376                 AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
 377                 AC_MSG_RESULT(yes)
 378         ],
 379         [AC_MSG_RESULT(no)]
 380 )
 381
 382 AC_MSG_CHECKING([for struct addrinfo])
 383 AC_TRY_COMPILE(
 384         [
 385                 #include <sys/types.h>
 386                 #include <sys/socket.h>
 387                 #include <netdb.h>
 388         ],
 389         [struct addrinfo s; s.ai_flags = AI_PASSIVE;],
 390         [
 391                 AC_DEFINE(HAVE_STRUCT_ADDRINFO)
 392                 AC_MSG_RESULT(yes)
 393         ],
 394         [AC_MSG_RESULT(no)]
 395 )
 396
 397 # Checks for structure members
 398 AC_MSG_CHECKING([whether utmp.h has ut_host field])
 399 AC_EGREP_HEADER(ut_host, utmp.h,
 400         [AC_DEFINE(HAVE_HOST_IN_UTMP) AC_MSG_RESULT(yes); ],
 401         [AC_MSG_RESULT(no)]
 402 )
 403 AC_MSG_CHECKING([whether utmpx.h has ut_host field])
 404 AC_EGREP_HEADER(ut_host, utmpx.h,
 405         [AC_DEFINE(HAVE_HOST_IN_UTMPX) AC_MSG_RESULT(yes); ],
 406         [AC_MSG_RESULT(no)]
 407 )
 408 AC_MSG_CHECKING([whether utmpx.h has syslen field])
 409 AC_EGREP_HEADER(syslen, utmpx.h,
 410         [AC_DEFINE(HAVE_SYSLEN_IN_UTMPX) AC_MSG_RESULT(yes); ],
 411         [AC_MSG_RESULT(no)]
 412 )
 413 AC_MSG_CHECKING([whether utmp.h has ut_pid field])
 414 AC_EGREP_HEADER(ut_pid, utmp.h,
 415         [AC_DEFINE(HAVE_PID_IN_UTMP) AC_MSG_RESULT(yes); ],
 416         [AC_MSG_RESULT(no)]
 417 )
 418 AC_MSG_CHECKING([whether utmp.h has ut_type field])
 419 AC_EGREP_HEADER(ut_type, utmp.h,
 420         [AC_DEFINE(HAVE_TYPE_IN_UTMP) AC_MSG_RESULT(yes); ],
 421         [AC_MSG_RESULT(no)]
 422 )
 423 AC_MSG_CHECKING([whether utmp.h has ut_tv field])
 424 AC_EGREP_HEADER(ut_tv, utmp.h,
 425         [AC_DEFINE(HAVE_TV_IN_UTMP) AC_MSG_RESULT(yes); ],
 426         [AC_MSG_RESULT(no)]
 427 )
 428 AC_MSG_CHECKING([whether utmp.h has ut_id field])
 429 AC_EGREP_HEADER(ut_id, utmp.h,
 430         [AC_DEFINE(HAVE_ID_IN_UTMP) AC_MSG_RESULT(yes); ],
 431         [AC_MSG_RESULT(no)]
 432 )
 433 AC_MSG_CHECKING([whether utmp.h has ut_addr field])
 434 AC_EGREP_HEADER(ut_addr, utmp.h,
 435         [AC_DEFINE(HAVE_ADDR_IN_UTMP) AC_MSG_RESULT(yes); ],
 436         [AC_MSG_RESULT(no)]
 437 )
 438 AC_MSG_CHECKING([whether utmpx.h has ut_addr field])
 439 AC_EGREP_HEADER(ut_addr, utmpx.h,
 440         [AC_DEFINE(HAVE_ADDR_IN_UTMPX) AC_MSG_RESULT(yes); ],
 441         [AC_MSG_RESULT(no)]
 442 )
 443 AC_MSG_CHECKING([whether utmp.h has ut_addr_v6 field])
 444 AC_EGREP_HEADER(ut_addr_v6, utmp.h,
 445         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMP) AC_MSG_RESULT(yes); ],
 446         [AC_MSG_RESULT(no)]
 447 )
 448 AC_MSG_CHECKING([whether utmpx.h has ut_addr_v6 field])
 449 AC_EGREP_HEADER(ut_addr_v6, utmpx.h,
 450         [AC_DEFINE(HAVE_ADDR_V6_IN_UTMPX) AC_MSG_RESULT(yes); ],
 451         [AC_MSG_RESULT(no)]
 452 )
 453
 454 AC_MSG_CHECKING([whether struct sockaddr_storage has ss_family field])
 455 AC_TRY_COMPILE(
 456         [
 457                 #include <sys/types.h>
 458                 #include <sys/socket.h>
 459         ],
 460         [struct sockaddr_storage s; s.ss_family = 1;],
 461         [
 462                 AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
 463                 AC_MSG_RESULT(yes)
 464         ],
 465         [AC_MSG_RESULT(no)]
 466 )
 467 AC_MSG_CHECKING([whether struct sockaddr_storage has __ss_family field])
 468 AC_TRY_COMPILE(
 469         [
 470                 #include <sys/types.h>
 471                 #include <sys/socket.h>
 472         ],
 473         [struct sockaddr_storage s; s.__ss_family = 1;],
 474         [
 475                 AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
 476                 AC_MSG_RESULT(yes)
 477         ],
 478         [AC_MSG_RESULT(no)]
 479 )
 480
 481 AC_MSG_CHECKING([whether libc defines __progname])
 482 AC_TRY_LINK([],
 483         [extern char *__progname; printf("%s", __progname);],
 484         [
 485                 AC_DEFINE(HAVE___PROGNAME)
 486                 AC_MSG_RESULT(yes)
 487         ],
 488         [
 489                 AC_MSG_RESULT(no)
 490         ]
 491 )
 492
 493 # Looking for programs, paths and files
 494 AC_ARG_WITH(rsh,
 495         [  --with-rsh=PATH         Specify path to remote shell program ],
 496         [
 497                 if test "x$withval" != "$no" ; then
 498                         AC_DEFINE_UNQUOTED(RSH_PATH, "$withval")
 499                 fi
 500         ],
 501         [
 502                 AC_PATH_PROG(rsh_path, rsh)
 503         ]
 504 )
 505
 506 AC_ARG_WITH(xauth,
 507         [  --with-xauth=PATH       Specify path to xauth program ],
 508         [
 509                 if test "x$withval" != "$xno" ; then
 510                         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$withval")
 511                 fi
 512         ],
 513         [
 514                 AC_PATH_PROG(xauth_path, xauth)
 515                 if test ! -z "$xauth_path" -a -x "/usr/openwin/bin/xauth" ; then
 516                         xauth_path="/usr/openwin/bin/xauth"
 517                 fi
 518         ]
 519 )
 520
 521 if test ! -z "$xauth_path" ; then
 522         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
 523 fi
 524 if test ! -z "$rsh_path" ; then
 525         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
 526 fi
 527
 528 # Check for mail directory (last resort if we cannot get it from headers)
 529 if test ! -z "$MAIL" ; then
 530         maildir=`dirname $MAIL`
 531         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
 532 fi
 533
 534 # Look for lastlog location
 535 AC_ARG_WITH(lastlog,
 536         [  --with-lastlog=FILE     Location of lastlog file],
 537         [
 538                 if test "x$withval" = "xno" ; then
 539                         AC_DEFINE(DISABLE_LASTLOG)
 540                 else
 541                         AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$withval")
 542                 fi
 543         ],
 544         [
 545                 AC_MSG_CHECKING([location of lastlog file])
 546                 for lastlog in /var/log/lastlog /var/adm/lastlog /usr/adm/lastlog  /etc/security/lastlog ; do
 547                         if test -f $lastlog ; then
 548                                 gotlastlog="file"
 549                                 break
 550                         fi
 551                         if test -d $lastlog ; then
 552                                 gotlastlog="dir"
 553                                 break
 554                         fi
 555                 done
 556                 if test -z "$gotlastlog" ; then
 557                         AC_MSG_RESULT(not found)
 558                         nolastlog=1
 559                 else
 560                         if test "x$gotlastlog" = "xdir" ; then
 561                                 AC_MSG_RESULT(${lastlog}/)
 562                                 AC_DEFINE(LASTLOG_IS_DIR)
 563                         else
 564                                 AC_MSG_RESULT($lastlog)
 565                                 AC_DEFINE_UNQUOTED(LASTLOG_LOCATION, "$lastlog")
 566                         fi
 567                 fi
 568         ]
 569 )
 570
 571 if test ! -z "$nolastlog" ; then
 572         AC_MSG_WARN([*** Disabling lastlog support *** ])
 573         AC_DEFINE(DISABLE_LASTLOG)
 574 fi
 575
 576 if test -z "$no_dev_ptmx" ; then
 577         AC_CHECK_FILE("/dev/ptmx",
 578                 [
 579                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
 580                         have_dev_ptmx=1
 581                 ]
 582         )
 583 fi
 584 AC_CHECK_FILE("/dev/ptc",
 585         [
 586                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
 587                 have_dev_ptc=1
 588         ]
 589 )
 590
 591 # Options from here on. Some of these are preset by platform above
 592
 593 # Check for user-specified random device, otherwise check /dev/urandom
 594 AC_ARG_WITH(random,
 595         [  --with-random=FILE      read randomness from FILE (default=/dev/urandom)],
 596         [
 597                 RANDOM_POOL="$withval";
 598                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 599         ],
 600         [
 601                 # Check for random device
 602                 AC_CHECK_FILE("/dev/urandom",
 603                         [
 604                                 RANDOM_POOL="/dev/urandom";
 605                                 AC_SUBST(RANDOM_POOL)
 606                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 607                         ]
 608                 )
 609         ]
 610 )
 611
 612 # Check for EGD pool file
 613 AC_ARG_WITH(egd-pool,
 614         [  --with-egd-pool=FILE    read randomness from EGD pool FILE (default none)],
 615         [
 616                 RANDOM_POOL="$withval";
 617                 AC_DEFINE(HAVE_EGD)
 618                 AC_SUBST(RANDOM_POOL)
 619                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
 620         ]
 621 )
 622
 623 # Make sure we have some random number support
 624 if test -z "$RANDOM_POOL" -a -z "$EGD_POOL"; then
 625         AC_MSG_ERROR([No random device found, and no EGD random pool specified])
 626 fi
 627
 628 AC_ARG_WITH(catman,
 629         [  --with-catman=man|cat   Install preformatted manpages[no]],
 630         [
 631                 MANTYPE='$(CATMAN)'
 632                 if test x"$withval" != x"yes" ; then
 633                    mansubdir=$withval
 634                 else
 635                    mansubdir=cat
 636                 fi
 637         ], [
 638                 if test -z "$MANTYPE" ; then
 639                         MANTYPE='$(TROFFMAN)'
 640                         mansubdir=man
 641                 fi
 642         ]
 643 )
 644 AC_SUBST(MANTYPE)
 645 AC_SUBST(mansubdir)
 646
 647 # Check whether user wants Kerberos support
 648 AC_ARG_WITH(kerberos4,
 649         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
 650         [
 651                 if test "x$withval" != "xno" ; then
 652
 653                         if test "x$withval" != "$xyes" ; then
 654                                 CFLAGS="$CFLAGS -I${withval}/include"
 655                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 656                                 if test ! -z "$need_dash_r" ; then
 657                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
 658                                 fi
 659                                 if test ! -z "$blibpath" ; then
 660                                         blibpath="$blibpath:${withval}/lib"
 661                                 fi
 662                         else
 663                                 if test -d /usr/include/kerberosIV ; then
 664                                         CFLAGS="$CFLAGS -I/usr/include/kerberosIV"
 665                                 fi
 666                         fi
 667
 668                         AC_CHECK_HEADERS(krb.h)
 669                         AC_CHECK_LIB(krb, main)
 670                         if test "$ac_cv_header_krb_h" != yes; then
 671                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
 672                         fi
 673                         if test "$ac_cv_lib_krb_main" != yes; then
 674                                 AC_MSG_WARN([Cannot find libkrb, build may fail])
 675                         fi
 676
 677                         KLIBS="-lkrb -ldes"
 678                         AC_CHECK_LIB(resolv, dn_expand, , )
 679                         KRB4=yes
 680                         AC_DEFINE(KRB4)
 681                 fi
 682         ]
 683 )
 684
 685 # Check whether user wants AFS support
 686 AC_ARG_WITH(afs,
 687         [  --with-afs=PATH         Enable AFS support],
 688         [
 689                 if test "x$withval" != "xno" ; then
 690
 691                         if test "x$withval" != "$xyes" ; then
 692                                 CFLAGS="$CFLAGS -I${withval}/include"
 693                                 LFLAGS="$LFLAGS -L${withval}/lib"
 694                         fi
 695
 696                         if test -z "$KRB4" ; then
 697                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
 698                         fi
 699
 700                         LIBS="$LIBS -lkafs"
 701                         if test ! -z "$AFS_LIBS" ; then
 702                                 LIBS="$LIBS $AFS_LIBS"
 703                         fi
 704                         AC_DEFINE(AFS)
 705                 fi
 706         ]
 707 )
 708 LIBS="$LIBS $KLIBS"
 709
 710 # Check whether user wants S/Key support
 711 AC_ARG_WITH(skey,
 712         [  --with-skey             Enable S/Key support],
 713         [
 714                 if test "x$withval" != "xno" ; then
 715                         AC_DEFINE(SKEY)
 716                         LIBS="$LIBS -lskey"
 717                 fi
 718         ]
 719 )
 720
 721 # Check whether user wants TCP wrappers support
 722 AC_ARG_WITH(tcp-wrappers,
 723         [  --with-tcp-wrappers     Enable tcpwrappers support],
 724         [
 725                 if test "x$withval" != "xno" ; then
 726                         saved_LIBS="$LIBS"
 727                         LIBS="$LIBS -lwrap"
 728                         AC_MSG_CHECKING(for libwrap)
 729                         AC_TRY_LINK(
 730                                 [
 731                                         #include <tcpd.h>
 732                                         int deny_severity = 0, allow_severity = 0;
 733                                 ],
 734                                 [hosts_access(0);],
 735                                 [
 736                                         AC_MSG_RESULT(yes)
 737                                         AC_DEFINE(LIBWRAP)
 738                                 ],
 739                                 [
 740                                         AC_MSG_RESULT(no)
 741                                         AC_MSG_WARN([*** libwrap missing - tcpwrapper support disabled ***])
 742                                         LIBS="$saved_LIBS"
 743                                 ]
 744                         )
 745                 fi
 746         ]
 747 )
 748
 749 # Check whether to enable MD5 passwords
 750 AC_ARG_WITH(md5-passwords,
 751         [  --with-md5-passwords    Enable use of MD5 passwords],
 752         [
 753                 if test "x$withval" != "xno" ; then
 754                         AC_DEFINE(HAVE_MD5_PASSWORDS)
 755                 fi
 756         ]
 757 )
 758
 759 # Check whether to enable utmpx support
 760 AC_ARG_WITH(utmpx,
 761         [  --with-utmpx            Enable utmpx support],
 762         [
 763                 if test "x$withval" != "xno" ; then
 764                         AC_DEFINE(USE_UTMPX)
 765                 fi
 766         ]
 767 )
 768
 769 # Whether to disable shadow password support
 770 AC_ARG_WITH(shadow,
 771         [  --without-shadow        Disable shadow password support],
 772         [
 773                 if test "x$withval" = "xno" ; then
 774                         AC_DEFINE(DISABLE_SHADOW)
 775                 fi
 776         ]
 777 )
 778
 779 # Use ip address instead of hostname in $DISPLAY
 780 AC_ARG_WITH(ipaddr-display,
 781         [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
 782         [
 783                 if test "x$withval" = "xno" ; then
 784                         AC_DEFINE(IPADDR_IN_DISPLAY)
 785                 fi
 786         ]
 787 )
 788
 789 # Whether to mess with the default path
 790 AC_ARG_WITH(default-path,
 791         [  --with-default-path=PATH Specify default \$PATH environment for server],
 792         [
 793                 if test "x$withval" != "xno" ; then
 794                         AC_DEFINE_UNQUOTED(USER_PATH, "$withval")
 795                 fi
 796         ]
 797 )
 798
 799 # Whether to force IPv4 by default (needed on broken glibc Linux)
 800 AC_ARG_WITH(ipv4-default,
 801         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
 802         [
 803                 if test "x$withval" != "xno" ; then
 804                         AC_DEFINE(IPV4_DEFAULT)
 805                 fi
 806         ]
 807 )
 808
 809 AC_MSG_CHECKING([to convert IPv4 in IPv6-mapped addresses])
 810 AC_ARG_WITH(4in6,
 811         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
 812         [
 813                 if test "x$withval" != "xno" ; then
 814                         AC_MSG_RESULT(yes)
 815                         AC_DEFINE(IPV4_IN_IPV6)
 816                 else
 817                         AC_MSG_RESULT(no)
 818                 fi
 819         ],[
 820                 if test "x$inet6_default_4in6" = "xyes"; then
 821                         AC_MSG_RESULT([yes (default)])
 822                         AC_DEFINE(IPV4_IN_IPV6)
 823                 else
 824                         AC_MSG_RESULT([no (default)])
 825                 fi
 826         ]
 827 )
 828
 829 # Where to place sshd.pid
 830 piddir=/var/run
 831 AC_ARG_WITH(pid-dir,
 832         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
 833         [
 834                 if test "x$withval" != "xno" ; then
 835                         piddir=$withval
 836                 fi
 837         ]
 838 )
 839 AC_DEFINE_UNQUOTED(PIDDIR, "$piddir")
 840 AC_SUBST(piddir)
 841
 842 if test ! -z "$blibpath" ; then
 843         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
 844         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
 845 fi
 846
 847 AC_OUTPUT(Makefile)