backup/db2bkup.awk

   1 #       $Source$
   2 #       $Header$
   3 #
   4 #       This converts the file used to originally create the database
   5 #       into a program to back it up.
   6 #       This is not guaranteed to work for all data types; it may
   7 #       need to be extended.
   8
   9 BEGIN {
  10         print "/* This file automatically generated */";
  11         print "/* Do not edit */\n";
  12         print "#include <stdio.h>";
  13         print "EXEC SQL INCLUDE sqlca;";
  14         print "#include \"dump_db.h\"";
  15         print "#define dump_bin dump_str\n";
  16
  17         print "/* This file automatically generated */" > "bkup1.pc";
  18         print "/* Do not edit */\n" >> "bkup1.pc";
  19         print "#include <stdio.h>" >> "bkup1.pc";
  20         print "FILE *open_file();" >> "bkup1.pc";
  21         print "do_backups(prefix)\n\tchar *prefix;\n{" >> "bkup1.pc";
  22 }
  23
  24 $1=="#" { next; }
  25
  26 /^create/ {
  27         printf "dump_%s(f)\nFILE *f;\n{\n\tEXEC SQL BEGIN DECLARE SECTION;\n", $3;
  28         printf "\tdump_%s(open_file(prefix, \"%s\"));\n", $3, $3 >> "bkup1.pc";
  29
  30         tablename = $3;
  31         rangename = substr(tablename, 1, 1);
  32         count = 0;
  33         next;
  34 }
  35
  36 NF>=2 {
  37         vname[count] = $1;
  38         printf "/* %s */\n", $0;
  39         if ($2 ~ /INTEGER/ || $2 ~ /SMALLINT/ || $2 ~ /INTEGER1/) {
  40                 printf "\tint\tt_%s;\n", vname[count];
  41                 vtype[count]="int";
  42         } else if ($2 ~ /CHAR\([0-9]*\)/) {
  43                 t = split($2, temp, "(");
  44                 if (t != 2) printf "Can't parse %s\n", $2;
  45                 t = split(temp[2], temp2, ")");
  46                 if (t != 2) printf "Can't parse %s\n", temp[2];
  47                 printf "\tchar\tt_%s[%d];\n", vname[count], temp2[1]+1;
  48                 if ($1 == "signature") {
  49                         vtype[count]="bin";
  50                 } else {
  51                         vtype[count]="str";
  52                 }
  53                 vsize[count] = temp2[1]+1;
  54         } else if ($2 ~ /DATE/) {
  55                 printf "\tchar\tt_%s[26];\n", vname[count];
  56                 vtype[count]="date";
  57         } else printf "Unknown data type %s\n", $2;
  58         count++;
  59 }
  60
  61 /^\);$/ {
  62         printf "\tEXEC SQL END DECLARE SECTION;\n";
  63         printf "\tEXEC SQL DECLARE c_%s CURSOR FOR\n", tablename;
  64         printf "\t\tSELECT\n";
  65         for (i = 0; i < count; i++) {
  66                 if (i != 0) {
  67                         print ",";
  68                 }
  69                 if(vtype[i] ~ /date/) {
  70                         printf "\t\t\tTO_CHAR(%s, 'DD-mon-YYYY HH24:MI:SS')", vname[i];
  71                 } else printf "\t\t\t%s", vname[i];
  72         }
  73         printf " FROM %s;\n", tablename;
  74
  75         printf "\tEXEC SQL OPEN c_%s;\n", tablename;
  76         printf "\twhile(1) {\n\t\tEXEC SQL FETCH c_%s INTO\n", tablename;
  77         for (i = 0; i < count; i++) {
  78                 if (i != 0) printf ",\n";
  79                 printf "\t\t\t:t_%s", vname[i];
  80         }
  81         printf ";\n";
  82         printf "\t\tif(sqlca.sqlcode != 0) break;\n";
  83         for (i = 0; i < count; i++) {
  84                 if (i != 0) print "\t\tdump_sep(f);";
  85                 if (vtype[i] ~ /str/ || vtype[i] ~ /date/) {
  86                         printf "\t\tdump_str(f, strtrim(t_%s));\n", vname[i];
  87                 } else {
  88                         printf "\t\tdump_%s(f, t_%s);\n", vtype[i], vname[i];
  89                 }
  90         }
  91         printf "\t\tdump_nl(f);\n";
  92         printf "\t}\n";
  93         printf "\tEXEC SQL CLOSE c_%s;\n", tablename;
  94         printf "\tsafe_close(f);\n";
  95         printf "}\n\n";
  96 }
  97
  98 END {
  99         print "/* All done */";
 100         print "}" >> "bkup1.pc";
 101 }