configure.in

   1 AC_INIT(patchlevel.h)
   2
   3 dnl On Athena at least, many of the packages (krb, zephyr, hesiod, etc)
   4 dnl will all be in /usr/athena... this hack lets us not end up with 10
   5 dnl copies of -I/usr/athena/include -L/usr/athena/lib in our command lines
   6 AC_DEFUN(MR_EXTEND, [
   7     case $$1 in
   8         *$2*) ;;
   9         *) $1=$2\ $$1 ;;
  10     esac
  11 ])
  12
  13 dnl Define for both C and Pro*C
  14 AC_DEFUN(MR_DEFINE, [
  15     AC_DEFINE($1)
  16     MR_EXTEND(PRO_C_DEFS, DEFINE=$1)
  17 ])
  18
  19 dnl Add to include path for both C and Pro*C
  20 AC_DEFUN(MR_INCLUDE, [
  21     MR_EXTEND(CPPFLAGS, -I$1)
  22     MR_EXTEND(PRO_C_INCLUDES, INCLUDE=$1)
  23 ])
  24
  25 dnl Add to lib path
  26 AC_DEFUN(MR_LIBS, [MR_EXTEND(LIBPATH, -L$1)])
  27
  28 AC_PROG_CC
  29 AC_PROG_INSTALL
  30 AC_PROG_RANLIB
  31 AC_PROG_MAKE_SET
  32
  33 if test "$athena" = true; then
  34     enable_athena=yes
  35     with_readline=/mit/gnu
  36     unset with_com_err
  37     prefix=/afs/athena.mit.edu/system/moira
  38     bindir=$prefix/arch/$ATHENA_SYS/bin
  39     sbindir=$bindir
  40 fi
  41
  42 # We currently just don't support changing this
  43 mrbindir=/moira/bin
  44 AC_SUBST(mrbindir)
  45
  46 # Athena-local policy decisions
  47 AC_MSG_CHECKING(for Athena)
  48 AC_ARG_ENABLE(athena,
  49     [  --enable-athena         Enable Athena-specific policy decisions],
  50     , [if test "$athena" = true; then
  51            enableval=yes
  52        else
  53            enableval=no
  54        fi])
  55 AC_MSG_RESULT($enableval)
  56 if test "$enableval" = yes; then
  57     MR_DEFINE(ATHENA)
  58 fi
  59
  60 # Networking libraries
  61 AC_CHECKING(network libraries...)
  62 AC_CHECK_FUNC(gethostbyname, :,
  63               AC_CHECK_LIB(nsl, gethostbyname, ,
  64                            AC_CHECK_LIB(resolv, gethostbyname)))
  65 AC_CHECK_FUNC(socket, :,
  66               AC_CHECK_LIB(socket, socket, ,
  67                            AC_CHECK_LIB(socket, socket,
  68                                         LIBS="-lsocket -lnsl $LIBS", :,
  69                                         -lnsl)))
  70
  71 # com_err (required, but can be built)
  72 AC_MSG_CHECKING(for com_err)
  73 AC_ARG_WITH(com_err,
  74     [  --with-com_err=PREFIX   Specify location of com_err],
  75     [AC_MSG_RESULT($withval)
  76      if test $withval = "no"; then
  77          AC_MSG_ERROR(com_err is required for Moira)
  78      fi
  79      if test $withval != "yes"; then
  80          MR_INCLUDE($withval/include)
  81          MR_LIBS($withval/lib)
  82      fi
  83      COMPILE_ET=compile_et],
  84     [AC_MSG_RESULT(util/et)
  85      COM_ERR_SUBDIR=util/et;
  86      MR_INCLUDE(`pwd`/util/et)
  87      MR_LIBS(`pwd`/util/et)
  88      COMPILE_ET=`pwd`/util/et/compile_et
  89      AC_CONFIG_SUBDIRS($COM_ERR_SUBDIR)])
  90 AC_SUBST(COM_ERR_SUBDIR)
  91 AC_SUBST(COMPILE_ET)
  92
  93 # Kerberos (required)
  94 AC_MSG_CHECKING(for Kerberos 4)
  95 AC_ARG_WITH(krb4,
  96     [  --with-krb4=PREFIX      Specify location of krb4],
  97     [krb4="$withval"], [krb4=no])
  98 AC_MSG_RESULT($krb4)
  99 if test $krb4 = "no"; then
 100     AC_MSG_ERROR(Kerberos is required for Moira)
 101 fi
 102 if test "$krb4" != yes; then
 103     MR_INCLUDE($krb4/include)
 104     if test -d "$krb4/include/kerberosIV"; then
 105         MR_INCLUDE($krb4/include/kerberosIV)
 106     fi
 107     MR_LIBS($krb4/lib)
 108 elif test -d /usr/include/kerberosIV; then
 109     MR_INCLUDE(/usr/include/kerberosIV)
 110 fi
 111 AC_CHECK_LIB(krb4, krb_rd_req,
 112              [KRB4_LIBS="-lkrb4 -ldes425 -lkrb5 -lcrypto"],
 113              [AC_CHECK_LIB(krb, krb_rd_req,
 114                            [KRB4_LIBS="-lkrb -ldes"],
 115                            [AC_MSG_ERROR(Kerberos 4 libraries not found)],
 116                            $LIBPATH -ldes)],
 117              $LIBPATH -ldes425 -lkrb5 -lcrypto)
 118
 119 # Hesiod support
 120 AC_MSG_CHECKING(for Hesiod)
 121 AC_ARG_WITH(hesiod,
 122     [  --with-hesiod=PREFIX    Specify location of Hesiod],
 123     [hesiod="$withval"], [hesiod=no])
 124 AC_MSG_RESULT($hesiod)
 125 if test "$hesiod" != no; then
 126     if test "$hesiod" != yes; then
 127         MR_INCLUDE($hesiod/include)
 128         MR_LIBS($hesiod/lib)
 129     fi
 130     AC_CHECK_FUNC(res_send, :,
 131                   AC_CHECK_LIB(resolv, res_send))
 132     AC_CHECK_LIB(hesiod, hes_resolve, :,
 133                  [AC_MSG_ERROR(Hesiod library not found)],
 134                  $LIBPATH $LIBS)
 135     MR_DEFINE(HAVE_HESIOD)
 136 fi
 137
 138 # Zephyr support
 139 AC_MSG_CHECKING(for Zephyr)
 140 AC_ARG_WITH(zephyr,
 141     [  --with-zephyr=PREFIX    Specify location of Zephyr],
 142     [zephyr="$withval"], [zephyr=no])
 143 AC_MSG_RESULT($zephyr)
 144 if test "$zephyr" != no; then
 145     if test "$zephyr" != yes; then
 146         MR_INCLUDE($zephyr/include)
 147         MR_LIBS($zephyr/lib)
 148     fi
 149     AC_CHECK_LIB(zephyr, ZInitialize, :,
 150                  [AC_MSG_ERROR(Zephyr library not found)],
 151                  $LIBPATH $KRB4_LIBS -lcom_err)
 152     MR_DEFINE(HAVE_ZEPHYR)
 153 fi
 154
 155 # GDSS support (default: build util/gdss if present)
 156 AC_MSG_CHECKING(for GDSS)
 157 AC_ARG_WITH(gdss,
 158     [  --with-gdss=PREFIX      Specify location of GDSS],
 159     [gdss="$withval"
 160      GDSS_CPPFLAGS="-I$gdss/include"
 161      GDSS_LIBS="-L$gdss/lib -lgdss"],
 162     [if test -d $srcdir/util/gdss; then
 163          gdss=$srcdir/util/gdss
 164          GDSS_SUBDIR=util/gdss
 165          GDSS_OUTPUT_FILES="util/gdss/Makefile util/gdss/lib/Makefile \
 166              util/gdss/lib/crypto/Makefile util/gdss/lib/crypto/bignum/Makefile \
 167              util/gdss/lib/crypto/algorithm/Makefile"
 168          # autoconf can't deal with creating util/gdss if util doesn't exist
 169          if test ! -d util; then
 170              mkdir util
 171          fi
 172          GDSS_CPPFLAGS='-I$(SRCTOP)/util/gdss/include'
 173          GDSS_LIBS='-L$(BUILDTOP)/util/gdss/lib -lgdss'
 174      else
 175          gdss=no
 176      fi])
 177 AC_MSG_RESULT($gdss)
 178 if test "$gdss" != no; then
 179     GDSS_OBJS='$(GDSS_OBJS)'
 180     GDSS_CFILES='$(GDSS_CFILES)'
 181     GDSS_TARGET='$(GDSS_TARGET)'
 182     MR_DEFINE(HAVE_GDSS)
 183 fi
 184 AC_SUBST(GDSS_CPPFLAGS)
 185 AC_SUBST(GDSS_LIBS)
 186 AC_SUBST(GDSS_SUBDIR)
 187 AC_SUBST(GDSS_OBJS)
 188 AC_SUBST(GDSS_CFILES)
 189 AC_SUBST(GDSS_TARGET)
 190
 191 # Oracle (default: yes, if $ORACLE_HOME is set)
 192 AC_MSG_CHECKING(for Oracle)
 193 AC_ARG_WITH(oracle,
 194     [  --with-oracle=PREFIX    Specify location of Oracle (for server)],
 195     [oracle="$withval"],
 196     [if test -n "$ORACLE_HOME" -a -d "$ORACLE_HOME"; then
 197          oracle=$ORACLE_HOME
 198      else
 199          oracle=no
 200      fi])
 201 AC_MSG_RESULT($oracle)
 202 if test "$oracle" != no; then
 203     SQL_LIBS="-L$oracle/lib -lsql $oracle/lib/osntab.o -lsqlnet -lora -lsqlnet -lnlsrtl -lcv6 -lcore -lnlsrtl -lcore -lm"
 204     SVRSUBDIRS='$(SVRDIRS)'
 205     SERVER_OUTPUT_FILES="db/Makefile server/Makefile afssync/Makefile backup/Makefile dbck/Makefile dcm/Makefile gen/Makefile incremental/Makefile reg_svr/Makefile regtape/Makefile"
 206     PRO_C=$oracle/bin/proc
 207     PRO_C_OPTS=CODE=ANSI_C
 208 fi
 209 AC_SUBST(PRO_C)
 210 AC_SUBST(PRO_C_DEFS)
 211 AC_SUBST(PRO_C_INCLUDES)
 212 AC_SUBST(PRO_C_OPTS)
 213 AC_SUBST(SQL_LIBS)
 214 AC_SUBST(SVRSUBDIRS)
 215
 216 # AFS support
 217 AC_MSG_CHECKING(for AFS)
 218 AC_ARG_WITH(afs,
 219     [  --with-afs=PREFIX       Specify location of AFS libs (for server)],
 220     [afs="$withval"], [afs=no])
 221 AC_MSG_RESULT($afs)
 222 if test "$afs" != no -a "$oracle" != no; then
 223     if test "$afs" != yes; then
 224         AFS_CPPFLAGS="-I$afs/include -I$afs/include/afs -I$afs/include/rx"
 225         AFS_PRO_C_INCLUDES="INCLUDE=$afs/include INCLUDE=$afs/include/afs INCLUDE=$afs/include/rx"
 226         AFS_LIBS="-L$afs/lib -L$afs/lib/afs"
 227         AFS_DIR=$afs
 228     fi
 229     AC_CHECK_FUNC(insque, :, AC_CHECK_LIB(compat, insque,
 230                                           AFS_EXTRA_LIBS="-lcompat",
 231                                           AC_MSG_ERROR(insque not found)))
 232     AC_CHECK_FUNC(sigvec, :, AC_CHECK_LIB(ucb, sigvec,
 233                                           AFS_EXTRA_LIBS="$AFS_EXTRA_LIBS -L/usr/ucblib -lc -lucb",
 234                                           :, -L/usr/ucblib))
 235     AC_CHECK_LIB(sys, pioctl, :,
 236                  [AC_MSG_ERROR(AFS libraries not found)],
 237                  $AFS_LIBS -lrx -llwp -lsys $AFS_EXTRA_LIBS)
 238     MR_DEFINE(HAVE_AFS)
 239 fi
 240 AC_SUBST(AFS_CPPFLAGS)
 241 AC_SUBST(AFS_PRO_C_INCLUDES)
 242 AC_SUBST(AFS_LIBS)
 243 AC_SUBST(AFS_EXTRA_LIBS)
 244 AC_SUBST(AFS_DIR)
 245
 246 # GNU readline
 247 AC_CHECKING(for GNU readline...)
 248 AC_ARG_WITH(readline,
 249     [  --with-readline=PREFIX  Specify location of GNU readline],
 250     [readline="$withval"],
 251     [AC_CHECK_LIB(readline, readline, [readline=yes], :, -ltermcap)])
 252 if test "$readline" != no; then
 253     if test "$readline" != yes; then
 254         READLINE_CPPFLAGS="-I$readline/include/readline -DHAVE_READLINE"
 255         READLINE_LIBS="-L$readline/lib -lreadline -ltermcap"
 256     fi
 257 fi
 258 AC_SUBST(READLINE_CPPFLAGS)
 259 AC_SUBST(READLINE_LIBS)
 260
 261 # Curses
 262 curses=curses
 263 AC_CHECKING(for curses)
 264 AC_CHECK_LIB(curses, main, :, AC_CHECK_LIB(ncurses, main, curses=ncurses))
 265 if test -n "$curses"; then
 266     OLDLIBS=$LIBS
 267     LIBS=-l$curses
 268     AC_CHECKING(if curses needs termcap)
 269     dnl we need to use AC_TRY_RUN because under NetBSD, the program will
 270     dnl link with just -lcurses, but then fail with a runtime linker error
 271     dnl because you didn't use -ltermcap
 272     AC_TRY_RUN([#include <curses.h>
 273                 main(int argc, char **argv)
 274                 {
 275                     initscr();
 276                     endwin();
 277                     return 0;
 278                 }], [CURSES_LIBS="-l$curses"],
 279                 LIBS="-l$curses -ltermcap"
 280                 AC_TRY_RUN([#include <curses.h>
 281                             main(int argc, char **argv)
 282                             {
 283                                 initscr();
 284                                 endwin();
 285                                 return 0;
 286                             }], [CURSES_LIBS="-l$curses -ltermcap"],
 287                             :, :),
 288                 :)
 289     LIBS=$OLDLIBS
 290 fi
 291 if test -n "$CURSES_LIBS"; then
 292     OLDLIBS=$LIBS
 293     LIBS=$CURSES_LIBS
 294     AC_TRY_LINK([#include <curses.h>],[WINDOW *w; getmaxx(w);],
 295                 :,
 296                 AC_TRY_COMPILE([#include <curses.h>],[WINDOW *w; w->_maxx;],
 297                                [CURSES_CPPFLAGS="-D'getmaxx(w)=w->_maxx'"],
 298                                [CURSES_CPPFLAGS="-D'getmaxx(w)=w->maxx'"]))
 299     LIBS=$OLDLIBS
 300     CURSES_CPPFLAGS="-DHAVE_CURSES $CURSES_CPPFLAGS"
 301     CURSES_SUBDIRS='$(CURSES_SUBDIRS)'
 302 else
 303     AC_MSG_WARN(Couldn't find -lcurses)
 304 fi
 305 AC_SUBST(CURSES_CPPFLAGS)
 306 AC_SUBST(CURSES_LIBS)
 307 AC_SUBST(CURSES_SUBDIRS)
 308
 309
 310 AC_CHECK_FUNCS(getusershell)
 311
 312 AC_CHECK_HEADER(crypt.h, CRYPT_CPPFLAGS=-DHAVE_CRYPT_H)
 313 AC_CHECK_FUNC(crypt, :, AC_CHECK_LIB(crypt, crypt, CRYPT_LIBS=-lcrypt))
 314 AC_SUBST(CRYPT_CPPFLAGS)
 315 AC_SUBST(CRYPT_LIBS)
 316
 317 MR_EXTEND(PRO_C_INCLUDES, INCLUDE='$(srcdir)')
 318 MR_INCLUDE('$(SRCTOP)/include')
 319 MR_INCLUDE('$(SRCTOP)/lib')
 320 MR_INCLUDE('$(BUILDTOP)/lib')
 321 MR_INCLUDE('$(BUILDTOP)/db')
 322 MR_INCLUDE('$(srcdir)')
 323 LDFLAGS="$LDFLAGS -L\$(BUILDTOP)/lib $LIBPATH"
 324 KLIBS="-lzephyr $KRB4_LIBS -lcom_err -lhesiod $LIBS"
 325 LIBS="-lmoira $KLIBS"
 326 AC_SUBST(KLIBS)
 327
 328 AC_OUTPUT(Makefile lib/Makefile include/Makefile clients/Makefile \
 329           clients/addusr/Makefile clients/blanche/Makefile \
 330           clients/mailmaint/Makefile clients/moira/Makefile \
 331           clients/mrcheck/Makefile clients/mrtest/Makefile \
 332           clients/passwd/Makefile clients/userreg/Makefile \
 333           update/Makefile man/Makefile \
 334           $SERVER_OUTPUT_FILES $GDSS_OUTPUT_FILES)