openssh/configure.ac

   1 # $Id$
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([ssh.c])
   5
   6 AC_CONFIG_HEADER(config.h)
   7 AC_PROG_CC
   8 AC_CANONICAL_HOST
   9 AC_C_BIGENDIAN
  10
  11 # Checks for programs.
  12 AC_PROG_CPP
  13 AC_PROG_RANLIB
  14 AC_PROG_INSTALL
  15 AC_PATH_PROG(AR, ar)
  16 AC_PATH_PROGS(PERL, perl5 perl)
  17 AC_PATH_PROG(SED, sed)
  18 AC_SUBST(PERL)
  19 AC_PATH_PROG(ENT, ent)
  20 AC_SUBST(ENT)
  21 AC_PATH_PROG(TEST_MINUS_S_SH, bash)
  22 AC_PATH_PROG(TEST_MINUS_S_SH, ksh)
  23 AC_PATH_PROG(TEST_MINUS_S_SH, sh)
  24 AC_PATH_PROG(SH, sh)
  25
  26 # System features
  27 AC_SYS_LARGEFILE
  28
  29 if test -z "$AR" ; then
  30         AC_MSG_ERROR([*** 'ar' missing, please install or fix your \$PATH ***])
  31 fi
  32
  33 # Use LOGIN_PROGRAM from environment if possible
  34 if test ! -z "$LOGIN_PROGRAM" ; then
  35         AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM")
  36 else
  37         # Search for login
  38         AC_PATH_PROG(LOGIN_PROGRAM_FALLBACK, login)
  39         if test ! -z "$LOGIN_PROGRAM_FALLBACK" ; then
  40                 AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM_FALLBACK")
  41         fi
  42 fi
  43
  44 if test -z "$LD" ; then
  45         LD=$CC
  46 fi
  47 AC_SUBST(LD)
  48
  49 AC_C_INLINE
  50 if test "$GCC" = "yes" || test "$GCC" = "egcs"; then
  51         CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wno-uninitialized"
  52 fi
  53
  54 # Check for some target-specific stuff
  55 case "$host" in
  56 *-*-aix*)
  57         AFS_LIBS="-lld"
  58         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
  59         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  60         AC_MSG_CHECKING([how to specify blibpath for linker ($LD)])
  61         if (test -z "$blibpath"); then
  62                 blibpath="/usr/lib:/lib:/usr/local/lib"
  63         fi
  64         saved_LDFLAGS="$LDFLAGS"
  65         for tryflags in -blibpath: -Wl,-blibpath: -Wl,-rpath, ;do
  66                 if (test -z "$blibflags"); then
  67                         LDFLAGS="$saved_LDFLAGS $tryflags$blibpath"
  68                         AC_TRY_LINK([], [], [blibflags=$tryflags])
  69                 fi
  70         done
  71         if (test -z "$blibflags"); then
  72                 AC_MSG_RESULT(not found)
  73                 AC_MSG_ERROR([*** must be able to specify blibpath on AIX - check config.log])
  74         else
  75                 AC_MSG_RESULT($blibflags)
  76         fi
  77         LDFLAGS="$saved_LDFLAGS"
  78         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)],
  79                 [AC_CHECK_LIB(s,authenticate,
  80                         [ AC_DEFINE(WITH_AIXAUTHENTICATE)
  81                                 LIBS="$LIBS -ls"
  82                         ])
  83                 ])
  84         AC_DEFINE(BROKEN_GETADDRINFO)
  85         AC_DEFINE(BROKEN_REALPATH)
  86         dnl AIX handles lastlog as part of its login message
  87         AC_DEFINE(DISABLE_LASTLOG)
  88         AC_DEFINE(LOGIN_NEEDS_UTMPX)
  89         AC_DEFINE(SETPROCTITLE_STRATEGY,PS_USE_CLOBBER_ARGV)
  90         AC_DEFINE(SETPROCTITLE_PS_PADDING, '\0')
  91         ;;
  92 *-*-cygwin*)
  93         check_for_libcrypt_later=1
  94         LIBS="$LIBS /usr/lib/textmode.o"
  95         AC_DEFINE(HAVE_CYGWIN)
  96         AC_DEFINE(USE_PIPES)
  97         AC_DEFINE(DISABLE_SHADOW)
  98         AC_DEFINE(IPV4_DEFAULT)
  99         AC_DEFINE(IP_TOS_IS_BROKEN)
 100         AC_DEFINE(NO_X11_UNIX_SOCKETS)
 101         AC_DEFINE(NO_IPPORT_RESERVED_CONCEPT)
 102         AC_DEFINE(DISABLE_FD_PASSING)
 103         AC_DEFINE(SETGROUPS_NOOP)
 104         ;;
 105 *-*-dgux*)
 106         AC_DEFINE(IP_TOS_IS_BROKEN)
 107         ;;
 108 *-*-darwin*)
 109         AC_MSG_CHECKING(if we have working getaddrinfo)
 110         AC_TRY_RUN([#include <mach-o/dyld.h>
 111 main() { if (NSVersionOfRunTimeLibrary("System") >= (60 << 16))
 112                 exit(0);
 113         else
 114                 exit(1);
 115 }], [AC_MSG_RESULT(working)],
 116         [AC_MSG_RESULT(buggy)
 117         AC_DEFINE(BROKEN_GETADDRINFO)],
 118         [AC_MSG_RESULT(assume it is working)])
 119         ;;
 120 *-*-hpux10.26)
 121         if test -z "$GCC"; then
 122                 CFLAGS="$CFLAGS -Ae"
 123         fi
 124         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 125         IPADDR_IN_DISPLAY=yes
 126         AC_DEFINE(HAVE_SECUREWARE)
 127         AC_DEFINE(USE_PIPES)
 128         AC_DEFINE(LOGIN_NO_ENDOPT)
 129         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 130         AC_DEFINE(DISABLE_SHADOW)
 131         AC_DEFINE(DISABLE_UTMP)
 132         AC_DEFINE(SETPROCTITLE_STRATEGY,PS_USE_PSTAT)
 133         LIBS="$LIBS -lsec -lsecpw"
 134         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 135         disable_ptmx_check=yes
 136         ;;
 137 *-*-hpux10*)
 138         if test -z "$GCC"; then
 139                 CFLAGS="$CFLAGS -Ae"
 140         fi
 141         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 142         IPADDR_IN_DISPLAY=yes
 143         AC_DEFINE(USE_PIPES)
 144         AC_DEFINE(LOGIN_NO_ENDOPT)
 145         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 146         AC_DEFINE(DISABLE_SHADOW)
 147         AC_DEFINE(DISABLE_UTMP)
 148         AC_DEFINE(SETPROCTITLE_STRATEGY,PS_USE_PSTAT)
 149         LIBS="$LIBS -lsec"
 150         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 151         ;;
 152 *-*-hpux11*)
 153         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 154         IPADDR_IN_DISPLAY=yes
 155         AC_DEFINE(PAM_SUN_CODEBASE)
 156         AC_DEFINE(USE_PIPES)
 157         AC_DEFINE(LOGIN_NO_ENDOPT)
 158         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 159         AC_DEFINE(DISABLE_SHADOW)
 160         AC_DEFINE(DISABLE_UTMP)
 161         AC_DEFINE(SETPROCTITLE_STRATEGY,PS_USE_PSTAT)
 162         LIBS="$LIBS -lsec"
 163         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 164         ;;
 165 *-*-irix5*)
 166         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 167         LDFLAGS="$LDFLAGS"
 168         PATH="$PATH:/usr/etc"
 169         AC_DEFINE(BROKEN_INET_NTOA)
 170         AC_DEFINE(WITH_ABBREV_NO_TTY)
 171         ;;
 172 *-*-irix6*)
 173         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 174         LDFLAGS="$LDFLAGS"
 175         PATH="$PATH:/usr/etc"
 176         AC_DEFINE(WITH_IRIX_ARRAY)
 177         AC_DEFINE(WITH_IRIX_PROJECT)
 178         AC_DEFINE(WITH_IRIX_AUDIT)
 179         AC_CHECK_FUNC(jlimit_startjob, [AC_DEFINE(WITH_IRIX_JOBS)])
 180         AC_DEFINE(BROKEN_INET_NTOA)
 181         AC_DEFINE(WITH_ABBREV_NO_TTY)
 182         ;;
 183 *-*-linux*)
 184         no_dev_ptmx=1
 185         check_for_libcrypt_later=1
 186         AC_DEFINE(DONT_TRY_OTHER_AF)
 187         AC_DEFINE(PAM_TTY_KLUDGE)
 188         AC_DEFINE(SETPROCTITLE_STRATEGY,PS_USE_CLOBBER_ARGV)
 189         AC_DEFINE(SETPROCTITLE_PS_PADDING, '\0')
 190         inet6_default_4in6=yes
 191         ;;
 192 mips-sony-bsd|mips-sony-newsos4)
 193         AC_DEFINE(HAVE_NEWS4)
 194         SONY=1
 195         ;;
 196 *-*-netbsd*)
 197         check_for_libcrypt_before=1
 198         need_dash_r=1
 199         ;;
 200 *-*-freebsd*)
 201         check_for_libcrypt_later=1
 202         ;;
 203 *-next-*)
 204         conf_lastlog_location="/usr/adm/lastlog"
 205         conf_utmp_location=/etc/utmp
 206         conf_wtmp_location=/usr/adm/wtmp
 207         MAIL=/usr/spool/mail
 208         AC_DEFINE(HAVE_NEXT)
 209         AC_DEFINE(BROKEN_REALPATH)
 210         AC_DEFINE(USE_PIPES)
 211         AC_DEFINE(BROKEN_SAVED_UIDS)
 212         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 213         CFLAGS="$CFLAGS"
 214         ;;
 215 *-*-solaris*)
 216         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 217         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib"
 218         need_dash_r=1
 219         AC_DEFINE(PAM_SUN_CODEBASE)
 220         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 221         AC_DEFINE(LOGIN_NEEDS_TERM)
 222         AC_DEFINE(PAM_TTY_KLUDGE)
 223         AC_DEFINE(STREAMS_PUSH_ACQUIRES_CTTY)
 224         # hardwire lastlog location (can't detect it on some versions)
 225         conf_lastlog_location="/var/adm/lastlog"
 226         AC_MSG_CHECKING(for obsolete utmp and wtmp in solaris2.x)
 227         sol2ver=`echo "$host"| sed -e 's/.*[[0-9]]\.//'`
 228         if test "$sol2ver" -ge 8; then
 229                 AC_MSG_RESULT(yes)
 230                 AC_DEFINE(DISABLE_UTMP)
 231                 AC_DEFINE(DISABLE_WTMP)
 232         else
 233                 AC_MSG_RESULT(no)
 234         fi
 235         ;;
 236 *-*-sunos4*)
 237         CPPFLAGS="$CPPFLAGS -DSUNOS4"
 238         AC_CHECK_FUNCS(getpwanam)
 239         AC_DEFINE(PAM_SUN_CODEBASE)
 240         conf_utmp_location=/etc/utmp
 241         conf_wtmp_location=/var/adm/wtmp
 242         conf_lastlog_location=/var/adm/lastlog
 243         AC_DEFINE(USE_PIPES)
 244         ;;
 245 *-ncr-sysv*)
 246         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 247         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 248         LIBS="$LIBS -lc89"
 249         AC_DEFINE(USE_PIPES)
 250         ;;
 251 *-sni-sysv*)
 252         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 253         # /usr/ucblib MUST NOT be searched on ReliantUNIX
 254         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 255         IPADDR_IN_DISPLAY=yes
 256         AC_DEFINE(USE_PIPES)
 257         AC_DEFINE(IP_TOS_IS_BROKEN)
 258         # /usr/ucblib/libucb.a no longer needed on ReliantUNIX
 259         # Attention: always take care to bind libsocket and libnsl before libc,
 260         # otherwise you will find lots of "SIOCGPGRP errno 22" on syslog
 261         ;;
 262 *-*-sysv4.2*)
 263         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 264         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 265         AC_DEFINE(USE_PIPES)
 266         ;;
 267 *-*-sysv5*)
 268         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 269         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 270         AC_DEFINE(USE_PIPES)
 271         ;;
 272 *-*-sysv*)
 273         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 274         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 275         ;;
 276 *-*-sco3.2v4*)
 277         CPPFLAGS="$CPPFLAGS -Dftruncate=chsize -I/usr/local/include"
 278         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 279         LIBS="$LIBS -los -lprot -lx -ltinfo -lm"
 280         RANLIB=true
 281         no_dev_ptmx=1
 282         AC_DEFINE(BROKEN_SYS_TERMIO_H)
 283         AC_DEFINE(USE_PIPES)
 284         AC_DEFINE(HAVE_SECUREWARE)
 285         AC_DEFINE(DISABLE_SHADOW)
 286         AC_DEFINE(BROKEN_SAVED_UIDS)
 287         AC_CHECK_FUNCS(getluid setluid)
 288         MANTYPE=man
 289         do_sco3_extra_lib_check=yes
 290         ;;
 291 *-*-sco3.2v5*)
 292         if test -z "$GCC"; then
 293                 CFLAGS="$CFLAGS -belf"
 294         fi
 295         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 296         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 297         LIBS="$LIBS -lprot -lx -ltinfo -lm"
 298         no_dev_ptmx=1
 299         AC_DEFINE(USE_PIPES)
 300         AC_DEFINE(HAVE_SECUREWARE)
 301         AC_DEFINE(DISABLE_SHADOW)
 302         AC_DEFINE(DISABLE_FD_PASSING)
 303         AC_CHECK_FUNCS(getluid setluid)
 304         MANTYPE=man
 305         ;;
 306 *-*-unicosmk*)
 307         AC_DEFINE(USE_PIPES)
 308         AC_DEFINE(DISABLE_FD_PASSING)
 309         LDFLAGS="$LDFLAGS"
 310         LIBS="$LIBS -lgen -lrsc -lshare -luex -lacm"
 311         MANTYPE=cat
 312         ;;
 313 *-*-unicos*)
 314         AC_DEFINE(USE_PIPES)
 315         AC_DEFINE(DISABLE_FD_PASSING)
 316         AC_DEFINE(NO_SSH_LASTLOG)
 317         LDFLAGS="$LDFLAGS -Wl,-Dmsglevel=334:fatal"
 318         LIBS="$LIBS -lgen -lrsc -lshare -luex -lacm"
 319         MANTYPE=cat
 320         ;;
 321 *-dec-osf*)
 322         AC_MSG_CHECKING(for Digital Unix SIA)
 323         no_osfsia=""
 324         AC_ARG_WITH(osfsia,
 325                 [  --with-osfsia           Enable Digital Unix SIA],
 326                 [
 327                         if test "x$withval" = "xno" ; then
 328                                 AC_MSG_RESULT(disabled)
 329                                 no_osfsia=1
 330                         fi
 331                 ],
 332         )
 333         if test -z "$no_osfsia" ; then
 334                 if test -f /etc/sia/matrix.conf; then
 335                         AC_MSG_RESULT(yes)
 336                         AC_DEFINE(HAVE_OSF_SIA)
 337                         AC_DEFINE(DISABLE_LOGIN)
 338                         AC_DEFINE(DISABLE_FD_PASSING)
 339                         LIBS="$LIBS -lsecurity -ldb -lm -laud"
 340                 else
 341                         AC_MSG_RESULT(no)
 342                 fi
 343         fi
 344         AC_DEFINE(DISABLE_FD_PASSING)
 345         ;;
 346
 347 *-*-nto-qnx)
 348         AC_DEFINE(USE_PIPES)
 349         AC_DEFINE(NO_X11_UNIX_SOCKETS)
 350         AC_DEFINE(MISSING_NFDBITS)
 351         AC_DEFINE(MISSING_HOWMANY)
 352         AC_DEFINE(MISSING_FD_MASK)
 353         ;;
 354 esac
 355
 356 # Allow user to specify flags
 357 AC_ARG_WITH(cflags,
 358         [  --with-cflags           Specify additional flags to pass to compiler],
 359         [
 360                 if test "x$withval" != "xno" ; then
 361                         CFLAGS="$CFLAGS $withval"
 362                 fi
 363         ]
 364 )
 365 AC_ARG_WITH(cppflags,
 366         [  --with-cppflags         Specify additional flags to pass to preprocessor] ,
 367         [
 368                 if test "x$withval" != "xno"; then
 369                         CPPFLAGS="$CPPFLAGS $withval"
 370                 fi
 371         ]
 372 )
 373 AC_ARG_WITH(ldflags,
 374         [  --with-ldflags          Specify additional flags to pass to linker],
 375         [
 376                 if test "x$withval" != "xno" ; then
 377                         LDFLAGS="$LDFLAGS $withval"
 378                 fi
 379         ]
 380 )
 381 AC_ARG_WITH(libs,
 382         [  --with-libs             Specify additional libraries to link with],
 383         [
 384                 if test "x$withval" != "xno" ; then
 385                         LIBS="$LIBS $withval"
 386                 fi
 387         ]
 388 )
 389
 390 # Checks for header files.
 391 AC_CHECK_HEADERS(bstring.h crypt.h endian.h floatingpoint.h \
 392         getopt.h glob.h ia.h lastlog.h libgen.h limits.h login.h \
 393         login_cap.h maillock.h netdb.h netgroup.h \
 394         netinet/in_systm.h paths.h pty.h readpassphrase.h \
 395         rpc/types.h security/pam_appl.h shadow.h stddef.h stdint.h \
 396         strings.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h \
 397         sys/mman.h sys/pstat.h sys/select.h sys/stat.h \
 398         sys/stropts.h sys/sysmacros.h sys/time.h sys/timers.h \
 399         sys/un.h time.h tmpdir.h ttyent.h usersec.h \
 400         util.h utime.h utmp.h utmpx.h)
 401
 402 # Checks for libraries.
 403 AC_CHECK_FUNC(yp_match, , AC_CHECK_LIB(nsl, yp_match))
 404 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 405
 406 dnl SCO OS3 needs this for libwrap
 407 if test "x$with_tcp_wrappers" != "xno" ; then
 408     if test "x$do_sco3_extra_lib_check" = "xyes" ; then
 409         AC_CHECK_LIB(rpc, innetgr, LIBS="-lrpc -lyp -lrpc $LIBS" , , -lyp -lrpc)
 410     fi
 411 fi
 412
 413 AC_CHECK_FUNC(getspnam, ,
 414         AC_CHECK_LIB(gen, getspnam, LIBS="$LIBS -lgen"))
 415
 416 AC_ARG_WITH(rpath,
 417         [  --without-rpath         Disable auto-added -R linker paths],
 418         [
 419                 if test "x$withval" = "xno" ; then
 420                         need_dash_r=""
 421                 fi
 422                 if test "x$withval" = "xyes" ; then
 423                         need_dash_r=1
 424                 fi
 425         ]
 426 )
 427
 428 dnl zlib is required
 429 AC_ARG_WITH(zlib,
 430         [  --with-zlib=PATH        Use zlib in PATH],
 431         [
 432                 if test "x$withval" = "xno" ; then
 433                         AC_MSG_ERROR([*** zlib is required ***])
 434                 fi
 435                 if test -d "$withval/lib"; then
 436                         if test -n "${need_dash_r}"; then
 437                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 438                         else
 439                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 440                         fi
 441                 else
 442                         if test -n "${need_dash_r}"; then
 443                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 444                         else
 445                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 446                         fi
 447                 fi
 448                 if test -d "$withval/include"; then
 449                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 450                 else
 451                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 452                 fi
 453         ]
 454 )
 455
 456 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first or check config.log ***]))
 457
 458 dnl UnixWare 2.x
 459 AC_CHECK_FUNC(strcasecmp,
 460         [], [ AC_CHECK_LIB(resolv, strcasecmp, LIBS="$LIBS -lresolv") ]
 461 )
 462 AC_CHECK_FUNC(utimes,
 463         [], [ AC_CHECK_LIB(c89, utimes, [AC_DEFINE(HAVE_UTIMES)
 464                                         LIBS="$LIBS -lc89"]) ]
 465 )
 466
 467 dnl    Checks for libutil functions
 468 AC_CHECK_HEADERS(libutil.h)
 469 AC_SEARCH_LIBS(login, util bsd, [AC_DEFINE(HAVE_LOGIN)])
 470 AC_CHECK_FUNCS(logout updwtmp logwtmp)
 471
 472 AC_FUNC_STRFTIME
 473
 474 # Check for ALTDIRFUNC glob() extension
 475 AC_MSG_CHECKING(for GLOB_ALTDIRFUNC support)
 476 AC_EGREP_CPP(FOUNDIT,
 477         [
 478                 #include <glob.h>
 479                 #ifdef GLOB_ALTDIRFUNC
 480                 FOUNDIT
 481                 #endif
 482         ],
 483         [
 484                 AC_DEFINE(GLOB_HAS_ALTDIRFUNC)
 485                 AC_MSG_RESULT(yes)
 486         ],
 487         [
 488                 AC_MSG_RESULT(no)
 489         ]
 490 )
 491
 492 # Check for g.gl_matchc glob() extension
 493 AC_MSG_CHECKING(for gl_matchc field in glob_t)
 494 AC_EGREP_CPP(FOUNDIT,
 495         [
 496                 #include <glob.h>
 497                 int main(void){glob_t g; g.gl_matchc = 1;}
 498         ],
 499         [
 500                 AC_DEFINE(GLOB_HAS_GL_MATCHC)
 501                 AC_MSG_RESULT(yes)
 502         ],
 503         [
 504                 AC_MSG_RESULT(no)
 505         ]
 506 )
 507
 508 AC_MSG_CHECKING([whether struct dirent allocates space for d_name])
 509 AC_TRY_RUN(
 510         [
 511 #include <sys/types.h>
 512 #include <dirent.h>
 513 int main(void){struct dirent d;exit(sizeof(d.d_name)<=sizeof(char));}
 514         ],
 515         [AC_MSG_RESULT(yes)],
 516         [
 517                 AC_MSG_RESULT(no)
 518                 AC_DEFINE(BROKEN_ONE_BYTE_DIRENT_D_NAME)
 519         ]
 520 )
 521
 522 # Check whether the user wants GSSAPI mechglue support
 523 AC_ARG_WITH(mechglue,
 524         [  --with-mechglue=PATH    Build with GSSAPI mechglue library],
 525         [
 526                 AC_MSG_CHECKING(for mechglue library)
 527
 528                 if test -e ${withval}/libgssapi.a ; then
 529                     mechglue_lib=${withval}/libgssapi.a
 530                 elif test -e ${withval}/lib/libgssapi.a ; then
 531                     mechglue_lib=${withval}/lib/libgssapi.a
 532                 else
 533                     AC_MSG_ERROR("Can't find libgssapi in ${withval}");
 534                 fi
 535                 LIBS="$LIBS ${mechglue_lib}"
 536                 AC_MSG_RESULT(${mechglue_lib})
 537
 538                 AC_CHECK_LIB(dl, dlopen, , )
 539                 if test $ac_cv_lib_dl_dlopen = yes; then
 540                    LDFLAGS="$LDFLAGS -ldl -Wl,-Bsymbolic"
 541                 fi
 542
 543                 AC_DEFINE(GSSAPI)
 544                 AC_DEFINE(MECHGLUE)
 545                 GSSAPI="mechglue"
 546
 547         ]
 548 )
 549
 550
 551 # Check whether the user wants GSI (Globus) support
 552 gsi_path="no"
 553 AC_ARG_WITH(gsi,
 554         [  --with-gsi=PATH         Enable GSI/Globus authentication support],
 555         [
 556                 gsi_path="$withval"
 557         ]
 558 )
 559
 560 AC_ARG_WITH(globus,
 561         [  --with-globus=PATH      Enable GSI/Globus authentication support],
 562         [
 563                 gsi_path="$withval"
 564         ]
 565 )
 566
 567 # Check whether the user has a Globus flavor type
 568 globus_flavor_type="no"
 569 AC_ARG_WITH(globus-flavor,
 570         [  --with-globus-flavor=TYPE         Describe Globus flavor type (ex: gcc32dbg, etc.)],
 571         [
 572                 globus_flavor_type="$withval"
 573         ]
 574 )
 575
 576 if test "x$gsi_path" != "xno" ; then
 577         # Globus GSSAPI configuration
 578         AC_MSG_CHECKING(for Globus GSI)
 579         AC_DEFINE(GSI)
 580
 581         if test "$GSSAPI" -a "$GSSAPI" != "mechglue"; then
 582                 AC_MSG_ERROR([Previously configured GSSAPI library conflicts with Globus/GSI.])
 583         fi
 584         if test -z "$GSSAPI"; then
 585                 AC_DEFINE(GSSAPI)
 586                 GSSAPI="GSI"
 587         fi
 588
 589         if test "x$globus_install_dir" = "xyes" ; then
 590                 AC_MSG_ERROR(--with-globus=PATH must specify a path)
 591         fi
 592
 593         if test "x$globus_flavor_type" = "xno" ; then
 594                 AC_MSG_ERROR(--with-globus-flavor=TYPE must be specified)
 595         fi
 596         if test "x$globus_flavor_type" = "xyes" ; then
 597                 AC_MSG_ERROR(--with-globus-flavor=TYPE must specify a flavor type)
 598         fi
 599         AC_MSG_RESULT(yes)
 600
 601         AC_MSG_CHECKING(for Globus include path)
 602         GLOBUS_INCLUDE="${gsi_path}/include/${globus_flavor_type}"
 603         if test ! -d "$GLOBUS_INCLUDE" ; then
 604                 AC_MSG_ERROR(Cannot find Globus flavor-specific include directory: ${GLOBUS_INCLUDE})
 605         fi
 606         GSI_CPPFLAGS="-I${GLOBUS_INCLUDE}"
 607         AC_MSG_RESULT(yes)
 608
 609         AC_MSG_CHECKING(for Globus linkline)
 610         if test -x $GPT_LOCATION/sbin/gpt_build_config ; then
 611                 $GPT_LOCATION/sbin/gpt_build_config -f gcc32 -link static -src pkg_data_src.gpt
 612                 . ./gpt_build_temp.sh
 613                 GSI_LDFLAGS="-L${gsi_path}/lib"
 614                 GSI_LIBS="$GPT_CONFIG_PGM_LINKS"
 615         else
 616                 AC_MSG_ERROR(Cannot find gpt_build_config: GPT installation is incomplete)
 617         fi
 618         if test -z "$GSI_LIBS" ; then
 619                 AC_MSG_ERROR(gpt_build_config failed)
 620         fi
 621         AC_MSG_RESULT(yes)
 622
 623         LIBS="$LIBS $GSI_LIBS"
 624         LDFLAGS="$LDFLAGS $GSI_LDFLAGS"
 625         CPPFLAGS="$CPPFLAGS $GSI_CPPFLAGS"
 626
 627         AC_MSG_CHECKING(that Globus linkline works)
 628         # test that we got the libraries OK
 629         AC_TRY_LINK(
 630                 [],
 631                 [],
 632                 [
 633                         AC_MSG_RESULT(yes)
 634                 ],
 635                 [
 636                         AC_MSG_ERROR(link with Globus libraries failed)
 637                 ]
 638         )
 639         INSTALL_GSISSH="yes"
 640 else
 641         INSTALL_GSISSH=""
 642 fi
 643 # End Globus/GSI section
 644
 645 # Check whether user wants S/Key support
 646 SKEY_MSG="no"
 647 AC_ARG_WITH(skey,
 648         [  --with-skey[[=PATH]]      Enable S/Key support
 649                             (optionally in PATH)],
 650         [
 651                 if test "x$withval" != "xno" ; then
 652
 653                         if test "x$withval" != "xyes" ; then
 654                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 655                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 656                         fi
 657
 658                         AC_DEFINE(SKEY)
 659                         LIBS="-lskey $LIBS"
 660                         SKEY_MSG="yes"
 661
 662                         AC_MSG_CHECKING([for s/key support])
 663                         AC_TRY_RUN(
 664                                 [
 665 #include <stdio.h>
 666 #include <skey.h>
 667 int main() { char *ff = skey_keyinfo(""); ff=""; exit(0); }
 668                                 ],
 669                                 [AC_MSG_RESULT(yes)],
 670                                 [
 671                                         AC_MSG_RESULT(no)
 672                                         AC_MSG_ERROR([** Incomplete or missing s/key libraries.])
 673                                 ])
 674                 fi
 675         ]
 676 )
 677
 678 # Check whether user wants TCP wrappers support
 679 TCPW_MSG="no"
 680 AC_ARG_WITH(tcp-wrappers,
 681         [  --with-tcp-wrappers[[=PATH]]      Enable tcpwrappers support
 682                             (optionally in PATH)],
 683         [
 684                 if test "x$withval" != "xno" ; then
 685                         saved_LIBS="$LIBS"
 686                         saved_LDFLAGS="$LDFLAGS"
 687                         saved_CPPFLAGS="$CPPFLAGS"
 688                         if test -n "${withval}" -a "${withval}" != "yes"; then
 689                                 if test -d "${withval}/lib"; then
 690                                         if test -n "${need_dash_r}"; then
 691                                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 692                                         else
 693                                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 694                                         fi
 695                                 else
 696                                         if test -n "${need_dash_r}"; then
 697                                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 698                                         else
 699                                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 700                                         fi
 701                                 fi
 702                                 if test -d "${withval}/include"; then
 703                                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 704                                 else
 705                                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 706                                 fi
 707                         fi
 708                         LIBWRAP="-lwrap"
 709                         LIBS="$LIBWRAP $LIBS"
 710                         AC_MSG_CHECKING(for libwrap)
 711                         AC_TRY_LINK(
 712                                 [
 713 #include <tcpd.h>
 714                                         int deny_severity = 0, allow_severity = 0;
 715                                 ],
 716                                 [hosts_access(0);],
 717                                 [
 718                                         AC_MSG_RESULT(yes)
 719                                         AC_DEFINE(LIBWRAP)
 720                                         AC_SUBST(LIBWRAP)
 721                                         TCPW_MSG="yes"
 722                                 ],
 723                                 [
 724                                         AC_MSG_ERROR([*** libwrap missing])
 725                                 ]
 726                         )
 727                         LIBS="$saved_LIBS"
 728                 fi
 729         ]
 730 )
 731
 732 dnl    Checks for library functions. Please keep in alphabetical order
 733 AC_CHECK_FUNCS(\
 734         arc4random __b64_ntop b64_ntop __b64_pton b64_pton basename bcopy \
 735         bindresvport_sa clock fchmod fchown freeaddrinfo futimes \
 736         gai_strerror getaddrinfo getcwd getgrouplist getnameinfo getopt \
 737         getpeereid _getpty getrlimit getrusage getttyent glob inet_aton \
 738         inet_ntoa inet_ntop innetgr login_getcapbool md5_crypt memmove \
 739         mkdtemp mmap ngetaddrinfo nsleep ogetaddrinfo openpty pstat \
 740         readpassphrase realpath recvmsg rresvport_af sendmsg setdtablesize \
 741         setegid setenv seteuid setgroups setlogin setpcred setproctitle \
 742         setresgid setreuid setrlimit setsid setvbuf sigaction sigvec \
 743         snprintf socketpair strerror strlcat strlcpy strmode strnvis \
 744         sysconf tcgetpgrp truncate utimes vhangup vsnprintf waitpid \
 745 )
 746
 747 AC_SEARCH_LIBS(nanosleep, rt posix4, AC_DEFINE(HAVE_NANOSLEEP))
 748 AC_SEARCH_LIBS(basename, gen, AC_DEFINE(HAVE_BASENAME))
 749
 750 dnl IRIX has basename() in libgen
 751 AC_SEARCH_LIBS(basename, gen, AC_DEFINE(HAVE_BASENAME))
 752
 753 dnl Make sure strsep prototype is defined before defining HAVE_STRSEP
 754 AC_CHECK_DECL(strsep, [AC_CHECK_FUNCS(strsep)])
 755
 756 dnl IRIX and Solaris 2.5.1 have dirname() in libgen
 757 AC_CHECK_FUNCS(dirname, [AC_CHECK_HEADERS(libgen.h)] ,[
 758         AC_CHECK_LIB(gen, dirname,[
 759                 AC_CACHE_CHECK([for broken dirname],
 760                         ac_cv_have_broken_dirname, [
 761                         save_LIBS="$LIBS"
 762                         LIBS="$LIBS -lgen"
 763                         AC_TRY_RUN(
 764                                 [
 765 #include <libgen.h>
 766 #include <string.h>
 767
 768 int main(int argc, char **argv) {
 769     char *s, buf[32];
 770
 771     strncpy(buf,"/etc", 32);
 772     s = dirname(buf);
 773     if (!s || strncmp(s, "/", 32) != 0) {
 774         exit(1);
 775     } else {
 776         exit(0);
 777     }
 778 }
 779                                 ],
 780                                 [ ac_cv_have_broken_dirname="no" ],
 781                                 [ ac_cv_have_broken_dirname="yes" ]
 782                         )
 783                         LIBS="$save_LIBS"
 784                 ])
 785                 if test "x$ac_cv_have_broken_dirname" = "xno" ; then
 786                         LIBS="$LIBS -lgen"
 787                         AC_DEFINE(HAVE_DIRNAME)
 788                         AC_CHECK_HEADERS(libgen.h)
 789                 fi
 790         ])
 791 ])
 792
 793 dnl    Checks for time functions
 794 AC_CHECK_FUNCS(gettimeofday time)
 795 dnl    Checks for utmp functions
 796 AC_CHECK_FUNCS(endutent getutent getutid getutline pututline setutent)
 797 AC_CHECK_FUNCS(utmpname)
 798 dnl    Checks for utmpx functions
 799 AC_CHECK_FUNCS(endutxent getutxent getutxid getutxline pututxline )
 800 AC_CHECK_FUNCS(setutxent utmpxname)
 801
 802 AC_CHECK_FUNC(daemon,
 803         [AC_DEFINE(HAVE_DAEMON)],
 804         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 805 )
 806
 807 AC_CHECK_FUNC(getpagesize,
 808         [AC_DEFINE(HAVE_GETPAGESIZE)],
 809         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 810 )
 811
 812 # Check for broken snprintf
 813 if test "x$ac_cv_func_snprintf" = "xyes" ; then
 814         AC_MSG_CHECKING([whether snprintf correctly terminates long strings])
 815         AC_TRY_RUN(
 816                 [
 817 #include <stdio.h>
 818 int main(void){char b[5];snprintf(b,5,"123456789");exit(b[4]!='\0');}
 819                 ],
 820                 [AC_MSG_RESULT(yes)],
 821                 [
 822                         AC_MSG_RESULT(no)
 823                         AC_DEFINE(BROKEN_SNPRINTF)
 824                         AC_MSG_WARN([****** Your snprintf() function is broken, complain to your vendor])
 825                 ]
 826         )
 827 fi
 828
 829 dnl see whether mkstemp() requires XXXXXX
 830 if test "x$ac_cv_func_mkdtemp" = "xyes" ; then
 831 AC_MSG_CHECKING([for (overly) strict mkstemp])
 832 AC_TRY_RUN(
 833         [
 834 #include <stdlib.h>
 835 main() { char template[]="conftest.mkstemp-test";
 836 if (mkstemp(template) == -1)
 837         exit(1);
 838 unlink(template); exit(0);
 839 }
 840         ],
 841         [
 842                 AC_MSG_RESULT(no)
 843         ],
 844         [
 845                 AC_MSG_RESULT(yes)
 846                 AC_DEFINE(HAVE_STRICT_MKSTEMP)
 847         ],
 848         [
 849                 AC_MSG_RESULT(yes)
 850                 AC_DEFINE(HAVE_STRICT_MKSTEMP)
 851         ]
 852 )
 853 fi
 854
 855 AC_FUNC_GETPGRP
 856
 857 # Check for PAM libs
 858 PAM_MSG="no"
 859 AC_ARG_WITH(pam,
 860         [  --with-pam              Enable PAM support ],
 861         [
 862                 if test "x$withval" != "xno" ; then
 863                         if test "x$ac_cv_header_security_pam_appl_h" != "xyes" ; then
 864                                 AC_MSG_ERROR([PAM headers not found])
 865                         fi
 866
 867                         AC_CHECK_LIB(dl, dlopen, , )
 868                         AC_CHECK_LIB(pam, pam_set_item, , AC_MSG_ERROR([*** libpam missing]))
 869                         AC_CHECK_FUNCS(pam_getenvlist)
 870                         AC_CHECK_FUNCS(pam_putenv)
 871
 872                         disable_shadow=yes
 873                         PAM_MSG="yes"
 874
 875                         AC_DEFINE(USE_PAM)
 876                         if test $ac_cv_lib_dl_dlopen = yes; then
 877                                 LIBPAM="-lpam -ldl"
 878                         else
 879                                 LIBPAM="-lpam"
 880                         fi
 881
 882                         AC_SUBST(LIBPAM)
 883                 fi
 884         ]
 885 )
 886
 887 # Check for older PAM
 888 if test "x$PAM_MSG" = "xyes" ; then
 889         # Check PAM strerror arguments (old PAM)
 890         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 891         AC_TRY_COMPILE(
 892                 [
 893 #include <stdlib.h>
 894 #include <security/pam_appl.h>
 895                 ],
 896                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 897                 [AC_MSG_RESULT(no)],
 898                 [
 899                         AC_DEFINE(HAVE_OLD_PAM)
 900                         AC_MSG_RESULT(yes)
 901                         PAM_MSG="yes (old library)"
 902                 ]
 903         )
 904 fi
 905
 906 # Some systems want crypt() from libcrypt, *not* the version in OpenSSL,
 907 # because the system crypt() is more featureful.
 908 if test "x$check_for_libcrypt_before" = "x1"; then
 909         AC_CHECK_LIB(crypt, crypt)
 910 fi
 911
 912 # Search for OpenSSL
 913 saved_CPPFLAGS="$CPPFLAGS"
 914 saved_LDFLAGS="$LDFLAGS"
 915 AC_ARG_WITH(ssl-dir,
 916         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 917         [
 918                 if test "x$withval" != "xno" ; then
 919                         if test -d "$withval/lib"; then
 920                                 if test -n "${need_dash_r}"; then
 921                                         LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 922                                 else
 923                                         LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 924                                 fi
 925                         else
 926                                 if test -n "${need_dash_r}"; then
 927                                         LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 928                                 else
 929                                         LDFLAGS="-L${withval} ${LDFLAGS}"
 930                                 fi
 931                         fi
 932                         if test -d "$withval/include"; then
 933                                 CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 934                         else
 935                                 CPPFLAGS="-I${withval} ${CPPFLAGS}"
 936                         fi
 937                 fi
 938         ]
 939 )
 940
 941 if test -z "$GSI_LIBS" ; then
 942         LIBS="$LIBS -lcrypto"
 943 fi
 944
 945 AC_TRY_LINK_FUNC(RAND_add, AC_DEFINE(HAVE_OPENSSL),
 946         [
 947                 dnl Check default openssl install dir
 948                 if test -n "${need_dash_r}"; then
 949                         LDFLAGS="-L/usr/local/ssl/lib -R/usr/local/ssl/lib ${saved_LDFLAGS}"
 950                 else
 951                         LDFLAGS="-L/usr/local/ssl/lib ${saved_LDFLAGS}"
 952                 fi
 953                 CPPFLAGS="-I/usr/local/ssl/include ${saved_CPPFLAGS}"
 954                 AC_TRY_LINK_FUNC(RAND_add, AC_DEFINE(HAVE_OPENSSL),
 955                         [
 956                                 AC_MSG_ERROR([*** Can't find recent OpenSSL libcrypto (see config.log for details) ***])
 957                         ]
 958                 )
 959         ]
 960 )
 961
 962 # Determine OpenSSL header version
 963 AC_MSG_CHECKING([OpenSSL header version])
 964 AC_TRY_RUN(
 965         [
 966 #include <stdio.h>
 967 #include <string.h>
 968 #include <openssl/opensslv.h>
 969 #define DATA "conftest.sslincver"
 970 int main(void) {
 971         FILE *fd;
 972         int rc;
 973
 974         fd = fopen(DATA,"w");
 975         if(fd == NULL)
 976                 exit(1);
 977
 978         if ((rc = fprintf(fd ,"%x (%s)\n", OPENSSL_VERSION_NUMBER, OPENSSL_VERSION_TEXT)) <0)
 979                 exit(1);
 980
 981         exit(0);
 982 }
 983         ],
 984         [
 985                 ssl_header_ver=`cat conftest.sslincver`
 986                 AC_MSG_RESULT($ssl_header_ver)
 987         ],
 988         [
 989                 AC_MSG_RESULT(not found)
 990                 AC_MSG_ERROR(OpenSSL version header not found.)
 991         ]
 992 )
 993
 994 # Determine OpenSSL library version
 995 AC_MSG_CHECKING([OpenSSL library version])
 996 AC_TRY_RUN(
 997         [
 998 #include <stdio.h>
 999 #include <string.h>
1000 #include <openssl/opensslv.h>
1001 #include <openssl/crypto.h>
1002 #define DATA "conftest.ssllibver"
1003 int main(void) {
1004         FILE *fd;
1005         int rc;
1006
1007         fd = fopen(DATA,"w");
1008         if(fd == NULL)
1009                 exit(1);
1010
1011         if ((rc = fprintf(fd ,"%x (%s)\n", SSLeay(), SSLeay_version(SSLEAY_VERSION))) <0)
1012                 exit(1);
1013
1014         exit(0);
1015 }
1016         ],
1017         [
1018                 ssl_library_ver=`cat conftest.ssllibver`
1019                 AC_MSG_RESULT($ssl_library_ver)
1020         ],
1021         [
1022                 AC_MSG_RESULT(not found)
1023                 AC_MSG_ERROR(OpenSSL library not found.)
1024         ]
1025 )
1026
1027 # Sanity check OpenSSL headers
1028 AC_MSG_CHECKING([whether OpenSSL's headers match the library])
1029 AC_TRY_RUN(
1030         [
1031 #include <string.h>
1032 #include <openssl/opensslv.h>
1033 int main(void) { exit(SSLeay() == OPENSSL_VERSION_NUMBER ? 0 : 1); }
1034         ],
1035         [
1036                 AC_MSG_RESULT(yes)
1037         ],
1038         [
1039                 AC_MSG_RESULT(no)
1040                 AC_MSG_ERROR(Your OpenSSL headers do not match your library)
1041         ]
1042 )
1043
1044 # Some Linux systems (Slackware) need crypt() from libcrypt, *not* the
1045 # version in OpenSSL. Skip this for PAM
1046 if test "x$PAM_MSG" = "xno" -a "x$check_for_libcrypt_later" = "x1"; then
1047         AC_CHECK_LIB(crypt, crypt, LIBS="$LIBS -lcrypt")
1048 fi
1049
1050
1051 ### Configure cryptographic random number support
1052
1053 # Check wheter OpenSSL seeds itself
1054 AC_MSG_CHECKING([whether OpenSSL's PRNG is internally seeded])
1055 AC_TRY_RUN(
1056         [
1057 #include <string.h>
1058 #include <openssl/rand.h>
1059 int main(void) { exit(RAND_status() == 1 ? 0 : 1); }
1060         ],
1061         [
1062                 OPENSSL_SEEDS_ITSELF=yes
1063                 AC_MSG_RESULT(yes)
1064         ],
1065         [
1066                 AC_MSG_RESULT(no)
1067                 # Default to use of the rand helper if OpenSSL doesn't
1068                 # seed itself
1069                 USE_RAND_HELPER=yes
1070         ]
1071 )
1072
1073
1074 # Do we want to force the use of the rand helper?
1075 AC_ARG_WITH(rand-helper,
1076         [  --with-rand-helper      Use subprocess to gather strong randomness ],
1077         [
1078                 if test "x$withval" = "xno" ; then
1079                         # Force use of OpenSSL's internal RNG, even if
1080                         # the previous test showed it to be unseeded.
1081                         if test -z "$OPENSSL_SEEDS_ITSELF" ; then
1082                                 AC_MSG_WARN([*** Forcing use of OpenSSL's non-self-seeding PRNG])
1083                                 OPENSSL_SEEDS_ITSELF=yes
1084                                 USE_RAND_HELPER=""
1085                         fi
1086                 else
1087                         USE_RAND_HELPER=yes
1088                 fi
1089         ],
1090 )
1091
1092 # Which randomness source do we use?
1093 if test ! -z "$OPENSSL_SEEDS_ITSELF" -a -z "$USE_RAND_HELPER" ; then
1094         # OpenSSL only
1095         AC_DEFINE(OPENSSL_PRNG_ONLY)
1096         RAND_MSG="OpenSSL internal ONLY"
1097         INSTALL_SSH_RAND_HELPER=""
1098 elif test ! -z "$USE_RAND_HELPER" ; then
1099         # install rand helper
1100         RAND_MSG="ssh-rand-helper"
1101         INSTALL_SSH_RAND_HELPER="yes"
1102 fi
1103 AC_SUBST(INSTALL_SSH_RAND_HELPER)
1104
1105 ### Configuration of ssh-rand-helper
1106
1107 # PRNGD TCP socket
1108 AC_ARG_WITH(prngd-port,
1109         [  --with-prngd-port=PORT  read entropy from PRNGD/EGD TCP localhost:PORT],
1110         [
1111                 case "$withval" in
1112                 no)
1113                         withval=""
1114                         ;;
1115                 [[0-9]]*)
1116                         ;;
1117                 *)
1118                         AC_MSG_ERROR(You must specify a numeric port number for --with-prngd-port)
1119                         ;;
1120                 esac
1121                 if test ! -z "$withval" ; then
1122                         PRNGD_PORT="$withval"
1123                         AC_DEFINE_UNQUOTED(PRNGD_PORT, $PRNGD_PORT)
1124                 fi
1125         ]
1126 )
1127
1128 # PRNGD Unix domain socket
1129 AC_ARG_WITH(prngd-socket,
1130         [  --with-prngd-socket=FILE read entropy from PRNGD/EGD socket FILE (default=/var/run/egd-pool)],
1131         [
1132                 case "$withval" in
1133                 yes)
1134                         withval="/var/run/egd-pool"
1135                         ;;
1136                 no)
1137                         withval=""
1138                         ;;
1139                 /*)
1140                         ;;
1141                 *)
1142                         AC_MSG_ERROR(You must specify an absolute path to the entropy socket)
1143                         ;;
1144                 esac
1145
1146                 if test ! -z "$withval" ; then
1147                         if test ! -z "$PRNGD_PORT" ; then
1148                                 AC_MSG_ERROR(You may not specify both a PRNGD/EGD port and socket)
1149                         fi
1150                         if test ! -r "$withval" ; then
1151                                 AC_MSG_WARN(Entropy socket is not readable)
1152                         fi
1153                         PRNGD_SOCKET="$withval"
1154                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1155                 fi
1156         ],
1157         [
1158                 # Check for existing socket only if we don't have a random device already
1159                 if test "$USE_RAND_HELPER" = yes ; then
1160                         AC_MSG_CHECKING(for PRNGD/EGD socket)
1161                         # Insert other locations here
1162                         for sock in /var/run/egd-pool /dev/egd-pool /etc/entropy; do
1163                                 if test -r $sock && $TEST_MINUS_S_SH -c "test -S $sock -o -p $sock" ; then
1164                                         PRNGD_SOCKET="$sock"
1165                                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1166                                         break;
1167                                 fi
1168                         done
1169                         if test ! -z "$PRNGD_SOCKET" ; then
1170                                 AC_MSG_RESULT($PRNGD_SOCKET)
1171                         else
1172                                 AC_MSG_RESULT(not found)
1173                         fi
1174                 fi
1175         ]
1176 )
1177
1178 # Change default command timeout for hashing entropy source
1179 entropy_timeout=200
1180 AC_ARG_WITH(entropy-timeout,
1181         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
1182         [
1183                 if test "x$withval" != "xno" ; then
1184                         entropy_timeout=$withval
1185                 fi
1186         ]
1187 )
1188 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
1189
1190 SSH_PRIVSEP_USER=sshd
1191 AC_ARG_WITH(privsep-user,
1192         [  --with-privsep-user=user Specify non-privileged user for privilege separation],
1193         [
1194                 if test -n "$withval"; then
1195                         SSH_PRIVSEP_USER=$withval
1196                 fi
1197         ]
1198 )
1199 AC_DEFINE_UNQUOTED(SSH_PRIVSEP_USER, "$SSH_PRIVSEP_USER")
1200 AC_SUBST(SSH_PRIVSEP_USER)
1201
1202 # We do this little dance with the search path to insure
1203 # that programs that we select for use by installed programs
1204 # (which may be run by the super-user) come from trusted
1205 # locations before they come from the user's private area.
1206 # This should help avoid accidentally configuring some
1207 # random version of a program in someone's personal bin.
1208
1209 OPATH=$PATH
1210 PATH=/bin:/usr/bin
1211 test -h /bin 2> /dev/null && PATH=/usr/bin
1212 test -d /sbin && PATH=$PATH:/sbin
1213 test -d /usr/sbin && PATH=$PATH:/usr/sbin
1214 PATH=$PATH:/etc:$OPATH
1215
1216 # These programs are used by the command hashing source to gather entropy
1217 OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1218 OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
1219 OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
1220 OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
1221 OSSH_PATH_ENTROPY_PROG(PROG_JSTAT, jstat)
1222 OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
1223 OSSH_PATH_ENTROPY_PROG(PROG_SAR, sar)
1224 OSSH_PATH_ENTROPY_PROG(PROG_W, w)
1225 OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
1226 OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
1227 OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
1228 OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
1229 OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
1230 OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
1231 OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
1232 OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
1233 # restore PATH
1234 PATH=$OPATH
1235
1236 # Where does ssh-rand-helper get its randomness from?
1237 INSTALL_SSH_PRNG_CMDS=""
1238 if test ! -z "$INSTALL_SSH_RAND_HELPER" ; then
1239         if test ! -z "$PRNGD_PORT" ; then
1240                 RAND_HELPER_MSG="TCP localhost:$PRNGD_PORT"
1241         elif test ! -z "$PRNGD_SOCKET" ; then
1242                 RAND_HELPER_MSG="Unix domain socket \"$PRNGD_SOCKET\""
1243         else
1244                 RAND_HELPER_MSG="Command hashing (timeout $entropy_timeout)"
1245                 RAND_HELPER_CMDHASH=yes
1246                 INSTALL_SSH_PRNG_CMDS="yes"
1247         fi
1248 fi
1249 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
1250
1251
1252 # Cheap hack to ensure NEWS-OS libraries are arranged right.
1253 if test ! -z "$SONY" ; then
1254   LIBS="$LIBS -liberty";
1255 fi
1256
1257 # Checks for data types
1258 AC_CHECK_SIZEOF(char, 1)
1259 AC_CHECK_SIZEOF(short int, 2)
1260 AC_CHECK_SIZEOF(int, 4)
1261 AC_CHECK_SIZEOF(long int, 4)
1262 AC_CHECK_SIZEOF(long long int, 8)
1263
1264 # Sanity check long long for some platforms (AIX)
1265 if test "x$ac_cv_sizeof_long_long_int" = "x4" ; then
1266         ac_cv_sizeof_long_long_int=0
1267 fi
1268
1269 # More checks for data types
1270 AC_CACHE_CHECK([for u_int type], ac_cv_have_u_int, [
1271         AC_TRY_COMPILE(
1272                 [ #include <sys/types.h> ],
1273                 [ u_int a; a = 1;],
1274                 [ ac_cv_have_u_int="yes" ],
1275                 [ ac_cv_have_u_int="no" ]
1276         )
1277 ])
1278 if test "x$ac_cv_have_u_int" = "xyes" ; then
1279         AC_DEFINE(HAVE_U_INT)
1280         have_u_int=1
1281 fi
1282
1283 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
1284         AC_TRY_COMPILE(
1285                 [ #include <sys/types.h> ],
1286                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
1287                 [ ac_cv_have_intxx_t="yes" ],
1288                 [ ac_cv_have_intxx_t="no" ]
1289         )
1290 ])
1291 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
1292         AC_DEFINE(HAVE_INTXX_T)
1293         have_intxx_t=1
1294 fi
1295
1296 if (test -z "$have_intxx_t" && \
1297            test "x$ac_cv_header_stdint_h" = "xyes")
1298 then
1299     AC_MSG_CHECKING([for intXX_t types in stdint.h])
1300         AC_TRY_COMPILE(
1301                 [ #include <stdint.h> ],
1302                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
1303                 [
1304                         AC_DEFINE(HAVE_INTXX_T)
1305                         AC_MSG_RESULT(yes)
1306                 ],
1307                 [ AC_MSG_RESULT(no) ]
1308         )
1309 fi
1310
1311 AC_CACHE_CHECK([for int64_t type], ac_cv_have_int64_t, [
1312         AC_TRY_COMPILE(
1313                 [
1314 #include <sys/types.h>
1315 #ifdef HAVE_STDINT_H
1316 # include <stdint.h>
1317 #endif
1318 #include <sys/socket.h>
1319 #ifdef HAVE_SYS_BITYPES_H
1320 # include <sys/bitypes.h>
1321 #endif
1322                 ],
1323                 [ int64_t a; a = 1;],
1324                 [ ac_cv_have_int64_t="yes" ],
1325                 [ ac_cv_have_int64_t="no" ]
1326         )
1327 ])
1328 if test "x$ac_cv_have_int64_t" = "xyes" ; then
1329         AC_DEFINE(HAVE_INT64_T)
1330 fi
1331
1332 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
1333         AC_TRY_COMPILE(
1334                 [ #include <sys/types.h> ],
1335                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
1336                 [ ac_cv_have_u_intxx_t="yes" ],
1337                 [ ac_cv_have_u_intxx_t="no" ]
1338         )
1339 ])
1340 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
1341         AC_DEFINE(HAVE_U_INTXX_T)
1342         have_u_intxx_t=1
1343 fi
1344
1345 if test -z "$have_u_intxx_t" ; then
1346     AC_MSG_CHECKING([for u_intXX_t types in sys/socket.h])
1347         AC_TRY_COMPILE(
1348                 [ #include <sys/socket.h> ],
1349                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
1350                 [
1351                         AC_DEFINE(HAVE_U_INTXX_T)
1352                         AC_MSG_RESULT(yes)
1353                 ],
1354                 [ AC_MSG_RESULT(no) ]
1355         )
1356 fi
1357
1358 AC_CACHE_CHECK([for u_int64_t types], ac_cv_have_u_int64_t, [
1359         AC_TRY_COMPILE(
1360                 [ #include <sys/types.h> ],
1361                 [ u_int64_t a; a = 1;],
1362                 [ ac_cv_have_u_int64_t="yes" ],
1363                 [ ac_cv_have_u_int64_t="no" ]
1364         )
1365 ])
1366 if test "x$ac_cv_have_u_int64_t" = "xyes" ; then
1367         AC_DEFINE(HAVE_U_INT64_T)
1368         have_u_int64_t=1
1369 fi
1370
1371 if test -z "$have_u_int64_t" ; then
1372     AC_MSG_CHECKING([for u_int64_t type in sys/bitypes.h])
1373         AC_TRY_COMPILE(
1374                 [ #include <sys/bitypes.h> ],
1375                 [ u_int64_t a; a = 1],
1376                 [
1377                         AC_DEFINE(HAVE_U_INT64_T)
1378                         AC_MSG_RESULT(yes)
1379                 ],
1380                 [ AC_MSG_RESULT(no) ]
1381         )
1382 fi
1383
1384 if test -z "$have_u_intxx_t" ; then
1385         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
1386                 AC_TRY_COMPILE(
1387                         [
1388 #include <sys/types.h>
1389                         ],
1390                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
1391                         [ ac_cv_have_uintxx_t="yes" ],
1392                         [ ac_cv_have_uintxx_t="no" ]
1393                 )
1394         ])
1395         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
1396                 AC_DEFINE(HAVE_UINTXX_T)
1397         fi
1398 fi
1399
1400 if test -z "$have_uintxx_t" ; then
1401     AC_MSG_CHECKING([for uintXX_t types in stdint.h])
1402         AC_TRY_COMPILE(
1403                 [ #include <stdint.h> ],
1404                 [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1;],
1405                 [
1406                         AC_DEFINE(HAVE_UINTXX_T)
1407                         AC_MSG_RESULT(yes)
1408                 ],
1409                 [ AC_MSG_RESULT(no) ]
1410         )
1411 fi
1412
1413 if (test -z "$have_u_intxx_t" || test -z "$have_intxx_t" && \
1414            test "x$ac_cv_header_sys_bitypes_h" = "xyes")
1415 then
1416         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
1417         AC_TRY_COMPILE(
1418                 [
1419 #include <sys/bitypes.h>
1420                 ],
1421                 [
1422                         int8_t a; int16_t b; int32_t c;
1423                         u_int8_t e; u_int16_t f; u_int32_t g;
1424                         a = b = c = e = f = g = 1;
1425                 ],
1426                 [
1427                         AC_DEFINE(HAVE_U_INTXX_T)
1428                         AC_DEFINE(HAVE_INTXX_T)
1429                         AC_MSG_RESULT(yes)
1430                 ],
1431                 [AC_MSG_RESULT(no)]
1432         )
1433 fi
1434
1435
1436 AC_CACHE_CHECK([for u_char], ac_cv_have_u_char, [
1437         AC_TRY_COMPILE(
1438                 [
1439 #include <sys/types.h>
1440                 ],
1441                 [ u_char foo; foo = 125; ],
1442                 [ ac_cv_have_u_char="yes" ],
1443                 [ ac_cv_have_u_char="no" ]
1444         )
1445 ])
1446 if test "x$ac_cv_have_u_char" = "xyes" ; then
1447         AC_DEFINE(HAVE_U_CHAR)
1448 fi
1449
1450 TYPE_SOCKLEN_T
1451
1452 AC_CHECK_TYPES(sig_atomic_t,,,[#include <signal.h>])
1453
1454 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
1455         AC_TRY_COMPILE(
1456                 [
1457 #include <sys/types.h>
1458                 ],
1459                 [ size_t foo; foo = 1235; ],
1460                 [ ac_cv_have_size_t="yes" ],
1461                 [ ac_cv_have_size_t="no" ]
1462         )
1463 ])
1464 if test "x$ac_cv_have_size_t" = "xyes" ; then
1465         AC_DEFINE(HAVE_SIZE_T)
1466 fi
1467
1468 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
1469         AC_TRY_COMPILE(
1470                 [
1471 #include <sys/types.h>
1472                 ],
1473                 [ ssize_t foo; foo = 1235; ],
1474                 [ ac_cv_have_ssize_t="yes" ],
1475                 [ ac_cv_have_ssize_t="no" ]
1476         )
1477 ])
1478 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
1479         AC_DEFINE(HAVE_SSIZE_T)
1480 fi
1481
1482 AC_CACHE_CHECK([for clock_t], ac_cv_have_clock_t, [
1483         AC_TRY_COMPILE(
1484                 [
1485 #include <time.h>
1486                 ],
1487                 [ clock_t foo; foo = 1235; ],
1488                 [ ac_cv_have_clock_t="yes" ],
1489                 [ ac_cv_have_clock_t="no" ]
1490         )
1491 ])
1492 if test "x$ac_cv_have_clock_t" = "xyes" ; then
1493         AC_DEFINE(HAVE_CLOCK_T)
1494 fi
1495
1496 AC_CACHE_CHECK([for sa_family_t], ac_cv_have_sa_family_t, [
1497         AC_TRY_COMPILE(
1498                 [
1499 #include <sys/types.h>
1500 #include <sys/socket.h>
1501                 ],
1502                 [ sa_family_t foo; foo = 1235; ],
1503                 [ ac_cv_have_sa_family_t="yes" ],
1504                 [ AC_TRY_COMPILE(
1505                   [
1506 #include <sys/types.h>
1507 #include <sys/socket.h>
1508 #include <netinet/in.h>
1509                 ],
1510                 [ sa_family_t foo; foo = 1235; ],
1511                 [ ac_cv_have_sa_family_t="yes" ],
1512
1513                 [ ac_cv_have_sa_family_t="no" ]
1514         )]
1515         )
1516 ])
1517 if test "x$ac_cv_have_sa_family_t" = "xyes" ; then
1518         AC_DEFINE(HAVE_SA_FAMILY_T)
1519 fi
1520
1521 AC_CACHE_CHECK([for pid_t], ac_cv_have_pid_t, [
1522         AC_TRY_COMPILE(
1523                 [
1524 #include <sys/types.h>
1525                 ],
1526                 [ pid_t foo; foo = 1235; ],
1527                 [ ac_cv_have_pid_t="yes" ],
1528                 [ ac_cv_have_pid_t="no" ]
1529         )
1530 ])
1531 if test "x$ac_cv_have_pid_t" = "xyes" ; then
1532         AC_DEFINE(HAVE_PID_T)
1533 fi
1534
1535 AC_CACHE_CHECK([for mode_t], ac_cv_have_mode_t, [
1536         AC_TRY_COMPILE(
1537                 [
1538 #include <sys/types.h>
1539                 ],
1540                 [ mode_t foo; foo = 1235; ],
1541                 [ ac_cv_have_mode_t="yes" ],
1542                 [ ac_cv_have_mode_t="no" ]
1543         )
1544 ])
1545 if test "x$ac_cv_have_mode_t" = "xyes" ; then
1546         AC_DEFINE(HAVE_MODE_T)
1547 fi
1548
1549
1550 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
1551         AC_TRY_COMPILE(
1552                 [
1553 #include <sys/types.h>
1554 #include <sys/socket.h>
1555                 ],
1556                 [ struct sockaddr_storage s; ],
1557                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
1558                 [ ac_cv_have_struct_sockaddr_storage="no" ]
1559         )
1560 ])
1561 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
1562         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
1563 fi
1564
1565 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
1566         AC_TRY_COMPILE(
1567                 [
1568 #include <sys/types.h>
1569 #include <netinet/in.h>
1570                 ],
1571                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
1572                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
1573                 [ ac_cv_have_struct_sockaddr_in6="no" ]
1574         )
1575 ])
1576 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
1577         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
1578 fi
1579
1580 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
1581         AC_TRY_COMPILE(
1582                 [
1583 #include <sys/types.h>
1584 #include <netinet/in.h>
1585                 ],
1586                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
1587                 [ ac_cv_have_struct_in6_addr="yes" ],
1588                 [ ac_cv_have_struct_in6_addr="no" ]
1589         )
1590 ])
1591 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
1592         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
1593 fi
1594
1595 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
1596         AC_TRY_COMPILE(
1597                 [
1598 #include <sys/types.h>
1599 #include <sys/socket.h>
1600 #include <netdb.h>
1601                 ],
1602                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
1603                 [ ac_cv_have_struct_addrinfo="yes" ],
1604                 [ ac_cv_have_struct_addrinfo="no" ]
1605         )
1606 ])
1607 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
1608         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
1609 fi
1610
1611 AC_CACHE_CHECK([for struct timeval], ac_cv_have_struct_timeval, [
1612         AC_TRY_COMPILE(
1613                 [ #include <sys/time.h> ],
1614                 [ struct timeval tv; tv.tv_sec = 1;],
1615                 [ ac_cv_have_struct_timeval="yes" ],
1616                 [ ac_cv_have_struct_timeval="no" ]
1617         )
1618 ])
1619 if test "x$ac_cv_have_struct_timeval" = "xyes" ; then
1620         AC_DEFINE(HAVE_STRUCT_TIMEVAL)
1621         have_struct_timeval=1
1622 fi
1623
1624 AC_CHECK_TYPES(struct timespec)
1625
1626 # We need int64_t or else certian parts of the compile will fail.
1627 if test "x$ac_cv_have_int64_t" = "xno" -a \
1628         "x$ac_cv_sizeof_long_int" != "x8" -a \
1629         "x$ac_cv_sizeof_long_long_int" = "x0" ; then
1630         echo "OpenSSH requires int64_t support.  Contact your vendor or install"
1631         echo "an alternative compiler (I.E., GCC) before continuing."
1632         echo ""
1633         exit 1;
1634 else
1635 dnl test snprintf (broken on SCO w/gcc)
1636         AC_TRY_RUN(
1637                 [
1638 #include <stdio.h>
1639 #include <string.h>
1640 #ifdef HAVE_SNPRINTF
1641 main()
1642 {
1643         char buf[50];
1644         char expected_out[50];
1645         int mazsize = 50 ;
1646 #if (SIZEOF_LONG_INT == 8)
1647         long int num = 0x7fffffffffffffff;
1648 #else
1649         long long num = 0x7fffffffffffffffll;
1650 #endif
1651         strcpy(expected_out, "9223372036854775807");
1652         snprintf(buf, mazsize, "%lld", num);
1653         if(strcmp(buf, expected_out) != 0)
1654                 exit(1);
1655         exit(0);
1656 }
1657 #else
1658 main() { exit(0); }
1659 #endif
1660                 ], [ true ], [ AC_DEFINE(BROKEN_SNPRINTF) ]
1661         )
1662 fi
1663
1664 dnl Checks for structure members
1665 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
1666 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
1667 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
1668 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
1669 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
1670 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
1671 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
1672 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
1673 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmpx.h, HAVE_ID_IN_UTMPX)
1674 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
1675 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
1676 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
1677 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
1678 OSSH_CHECK_HEADER_FOR_FIELD(ut_exit, utmp.h, HAVE_EXIT_IN_UTMP)
1679 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmp.h, HAVE_TIME_IN_UTMP)
1680 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmpx.h, HAVE_TIME_IN_UTMPX)
1681 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmpx.h, HAVE_TV_IN_UTMPX)
1682
1683 AC_CHECK_MEMBERS([struct stat.st_blksize])
1684
1685 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
1686                 ac_cv_have_ss_family_in_struct_ss, [
1687         AC_TRY_COMPILE(
1688                 [
1689 #include <sys/types.h>
1690 #include <sys/socket.h>
1691                 ],
1692                 [ struct sockaddr_storage s; s.ss_family = 1; ],
1693                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
1694                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
1695         )
1696 ])
1697 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
1698         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
1699 fi
1700
1701 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
1702                 ac_cv_have___ss_family_in_struct_ss, [
1703         AC_TRY_COMPILE(
1704                 [
1705 #include <sys/types.h>
1706 #include <sys/socket.h>
1707                 ],
1708                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
1709                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
1710                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
1711         )
1712 ])
1713 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
1714         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
1715 fi
1716
1717 AC_CACHE_CHECK([for pw_class field in struct passwd],
1718                 ac_cv_have_pw_class_in_struct_passwd, [
1719         AC_TRY_COMPILE(
1720                 [
1721 #include <pwd.h>
1722                 ],
1723                 [ struct passwd p; p.pw_class = 0; ],
1724                 [ ac_cv_have_pw_class_in_struct_passwd="yes" ],
1725                 [ ac_cv_have_pw_class_in_struct_passwd="no" ]
1726         )
1727 ])
1728 if test "x$ac_cv_have_pw_class_in_struct_passwd" = "xyes" ; then
1729         AC_DEFINE(HAVE_PW_CLASS_IN_PASSWD)
1730 fi
1731
1732 AC_CACHE_CHECK([for pw_expire field in struct passwd],
1733                 ac_cv_have_pw_expire_in_struct_passwd, [
1734         AC_TRY_COMPILE(
1735                 [
1736 #include <pwd.h>
1737                 ],
1738                 [ struct passwd p; p.pw_expire = 0; ],
1739                 [ ac_cv_have_pw_expire_in_struct_passwd="yes" ],
1740                 [ ac_cv_have_pw_expire_in_struct_passwd="no" ]
1741         )
1742 ])
1743 if test "x$ac_cv_have_pw_expire_in_struct_passwd" = "xyes" ; then
1744         AC_DEFINE(HAVE_PW_EXPIRE_IN_PASSWD)
1745 fi
1746
1747 AC_CACHE_CHECK([for pw_change field in struct passwd],
1748                 ac_cv_have_pw_change_in_struct_passwd, [
1749         AC_TRY_COMPILE(
1750                 [
1751 #include <pwd.h>
1752                 ],
1753                 [ struct passwd p; p.pw_change = 0; ],
1754                 [ ac_cv_have_pw_change_in_struct_passwd="yes" ],
1755                 [ ac_cv_have_pw_change_in_struct_passwd="no" ]
1756         )
1757 ])
1758 if test "x$ac_cv_have_pw_change_in_struct_passwd" = "xyes" ; then
1759         AC_DEFINE(HAVE_PW_CHANGE_IN_PASSWD)
1760 fi
1761
1762 dnl make sure we're using the real structure members and not defines
1763 AC_CACHE_CHECK([for msg_accrights field in struct msghdr],
1764                 ac_cv_have_accrights_in_msghdr, [
1765         AC_TRY_RUN(
1766                 [
1767 #include <sys/types.h>
1768 #include <sys/socket.h>
1769 #include <sys/uio.h>
1770 int main() {
1771 #ifdef msg_accrights
1772 exit(1);
1773 #endif
1774 struct msghdr m;
1775 m.msg_accrights = 0;
1776 exit(0);
1777 }
1778                 ],
1779                 [ ac_cv_have_accrights_in_msghdr="yes" ],
1780                 [ ac_cv_have_accrights_in_msghdr="no" ]
1781         )
1782 ])
1783 if test "x$ac_cv_have_accrights_in_msghdr" = "xyes" ; then
1784         AC_DEFINE(HAVE_ACCRIGHTS_IN_MSGHDR)
1785 fi
1786
1787 AC_CACHE_CHECK([for msg_control field in struct msghdr],
1788                 ac_cv_have_control_in_msghdr, [
1789         AC_TRY_RUN(
1790                 [
1791 #include <sys/types.h>
1792 #include <sys/socket.h>
1793 #include <sys/uio.h>
1794 int main() {
1795 #ifdef msg_control
1796 exit(1);
1797 #endif
1798 struct msghdr m;
1799 m.msg_control = 0;
1800 exit(0);
1801 }
1802                 ],
1803                 [ ac_cv_have_control_in_msghdr="yes" ],
1804                 [ ac_cv_have_control_in_msghdr="no" ]
1805         )
1806 ])
1807 if test "x$ac_cv_have_control_in_msghdr" = "xyes" ; then
1808         AC_DEFINE(HAVE_CONTROL_IN_MSGHDR)
1809 fi
1810
1811 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
1812         AC_TRY_LINK([],
1813                 [ extern char *__progname; printf("%s", __progname); ],
1814                 [ ac_cv_libc_defines___progname="yes" ],
1815                 [ ac_cv_libc_defines___progname="no" ]
1816         )
1817 ])
1818 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
1819         AC_DEFINE(HAVE___PROGNAME)
1820 fi
1821
1822 AC_CACHE_CHECK([whether $CC implements __FUNCTION__], ac_cv_cc_implements___FUNCTION__, [
1823         AC_TRY_LINK([
1824 #include <stdio.h>
1825 ],
1826                 [ printf("%s", __FUNCTION__); ],
1827                 [ ac_cv_cc_implements___FUNCTION__="yes" ],
1828                 [ ac_cv_cc_implements___FUNCTION__="no" ]
1829         )
1830 ])
1831 if test "x$ac_cv_cc_implements___FUNCTION__" = "xyes" ; then
1832         AC_DEFINE(HAVE___FUNCTION__)
1833 fi
1834
1835 AC_CACHE_CHECK([whether $CC implements __func__], ac_cv_cc_implements___func__, [
1836         AC_TRY_LINK([
1837 #include <stdio.h>
1838 ],
1839                 [ printf("%s", __func__); ],
1840                 [ ac_cv_cc_implements___func__="yes" ],
1841                 [ ac_cv_cc_implements___func__="no" ]
1842         )
1843 ])
1844 if test "x$ac_cv_cc_implements___func__" = "xyes" ; then
1845         AC_DEFINE(HAVE___func__)
1846 fi
1847
1848 AC_CACHE_CHECK([whether getopt has optreset support],
1849                 ac_cv_have_getopt_optreset, [
1850         AC_TRY_LINK(
1851                 [
1852 #include <getopt.h>
1853                 ],
1854                 [ extern int optreset; optreset = 0; ],
1855                 [ ac_cv_have_getopt_optreset="yes" ],
1856                 [ ac_cv_have_getopt_optreset="no" ]
1857         )
1858 ])
1859 if test "x$ac_cv_have_getopt_optreset" = "xyes" ; then
1860         AC_DEFINE(HAVE_GETOPT_OPTRESET)
1861 fi
1862
1863 AC_CACHE_CHECK([if libc defines sys_errlist], ac_cv_libc_defines_sys_errlist, [
1864         AC_TRY_LINK([],
1865                 [ extern const char *const sys_errlist[]; printf("%s", sys_errlist[0]);],
1866                 [ ac_cv_libc_defines_sys_errlist="yes" ],
1867                 [ ac_cv_libc_defines_sys_errlist="no" ]
1868         )
1869 ])
1870 if test "x$ac_cv_libc_defines_sys_errlist" = "xyes" ; then
1871         AC_DEFINE(HAVE_SYS_ERRLIST)
1872 fi
1873
1874
1875 AC_CACHE_CHECK([if libc defines sys_nerr], ac_cv_libc_defines_sys_nerr, [
1876         AC_TRY_LINK([],
1877                 [ extern int sys_nerr; printf("%i", sys_nerr);],
1878                 [ ac_cv_libc_defines_sys_nerr="yes" ],
1879                 [ ac_cv_libc_defines_sys_nerr="no" ]
1880         )
1881 ])
1882 if test "x$ac_cv_libc_defines_sys_nerr" = "xyes" ; then
1883         AC_DEFINE(HAVE_SYS_NERR)
1884 fi
1885
1886 SCARD_MSG="no"
1887
1888 # Check whether user wants sectok support
1889 AC_ARG_WITH(sectok,
1890         [  --with-sectok           Enable smartcard support using libsectok],
1891         [
1892                 if test "x$withval" != "xno" ; then
1893                         if test "x$withval" != "xyes" ; then
1894                                 CPPFLAGS="$CPPFLAGS -I${withval}"
1895                                 LDFLAGS="$LDFLAGS -L${withval}"
1896                                 if test ! -z "$need_dash_r" ; then
1897                                         LDFLAGS="$LDFLAGS -R${withval}"
1898                                 fi
1899                                 if test ! -z "$blibpath" ; then
1900                                         blibpath="$blibpath:${withval}"
1901                                 fi
1902                         fi
1903                         AC_CHECK_HEADERS(sectok.h)
1904                         if test "$ac_cv_header_sectok_h" != yes; then
1905                                 AC_MSG_ERROR(Can't find sectok.h)
1906                         fi
1907                         AC_CHECK_LIB(sectok, sectok_open)
1908                         if test "$ac_cv_lib_sectok_sectok_open" != yes; then
1909                                 AC_MSG_ERROR(Can't find libsectok)
1910                         fi
1911                         AC_DEFINE(SMARTCARD)
1912                         AC_DEFINE(USE_SECTOK)
1913                         SCARD_MSG="yes, using sectok"
1914                 fi
1915         ]
1916 )
1917
1918 # Check whether user wants OpenSC support
1919 AC_ARG_WITH(opensc,
1920         AC_HELP_STRING([--with-opensc=PFX],
1921                        [Enable smartcard support using OpenSC]),
1922         opensc_config_prefix="$withval", opensc_config_prefix="")
1923 if test x$opensc_config_prefix != x ; then
1924   OPENSC_CONFIG=$opensc_config_prefix/bin/opensc-config
1925   AC_PATH_PROG(OPENSC_CONFIG, opensc-config, no)
1926   if test "$OPENSC_CONFIG" != "no"; then
1927     LIBOPENSC_CFLAGS=`$OPENSC_CONFIG --cflags`
1928     LIBOPENSC_LIBS=`$OPENSC_CONFIG --libs`
1929     CPPFLAGS="$CPPFLAGS $LIBOPENSC_CFLAGS"
1930     LDFLAGS="$LDFLAGS $LIBOPENSC_LIBS"
1931     AC_DEFINE(SMARTCARD)
1932     AC_DEFINE(USE_OPENSC)
1933     SCARD_MSG="yes, using OpenSC"
1934   fi
1935 fi
1936
1937 # Check whether user wants Kerberos 5 support
1938 KRB5_MSG="no"
1939 AC_ARG_WITH(kerberos5,
1940         [  --with-kerberos5=PATH   Enable Kerberos 5 support],
1941         [
1942                 if test "x$withval" != "xno" ; then
1943                         if test "x$withval" = "xyes" ; then
1944                                 KRB5ROOT="/usr/local"
1945                         else
1946                                 KRB5ROOT=${withval}
1947                         fi
1948                         CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include"
1949                         LDFLAGS="$LDFLAGS -L${KRB5ROOT}/lib"
1950                         AC_DEFINE(KRB5)
1951                         KRB5_MSG="yes"
1952                         AC_MSG_CHECKING(whether we are using Heimdal)
1953                         AC_TRY_COMPILE([ #include <krb5.h> ],
1954                                        [ char *tmp = heimdal_version; ],
1955                                        [ AC_MSG_RESULT(yes)
1956                                          AC_DEFINE(HEIMDAL)
1957                                          K5LIBS="-lkrb5 -ldes -lcom_err -lasn1 -lroken"
1958                                        ],
1959                                        [ AC_MSG_RESULT(no)
1960                                          K5LIBS="-lkrb5 -lk5crypto -lcom_err"
1961                                        ]
1962                         )
1963                         if test ! -z "$need_dash_r" ; then
1964                                 LDFLAGS="$LDFLAGS -R${KRB5ROOT}/lib"
1965                         fi
1966                         if test ! -z "$blibpath" ; then
1967                                 blibpath="$blibpath:${KRB5ROOT}/lib"
1968                         fi
1969                         AC_CHECK_LIB(resolv, dn_expand, , )
1970
1971                         # If we're using some other GSSAPI
1972                         if test "$GSSAPI" -a "$GSSAPI" != "mechglue"; then
1973                                 AC_MSG_ERROR([$GSSAPI GSSAPI library conflicts with Kerberos support.  Use mechglue instead.])
1974                         fi
1975                         AC_CHECK_LIB(gssapi,gss_init_sec_context,
1976                                 [ AC_DEFINE(GSSAPI)
1977                                   K5LIBS="-lgssapi $K5LIBS" ],
1978                                 [ AC_CHECK_LIB(gssapi_krb5,gss_init_sec_context,
1979                                         [ AC_DEFINE(GSSAPI)
1980                                           K5LIBS="-lgssapi_krb5 $K5LIBS" ],
1981                                         AC_MSG_WARN([Cannot find any suitable gss-api library - build may fail]),
1982                                         $K5LIBS)
1983                                 ],
1984                                 $K5LIBS)
1985
1986                         AC_CHECK_HEADER(gssapi.h, ,
1987                                 [ unset ac_cv_header_gssapi_h
1988                                   CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include/gssapi"
1989                                   AC_CHECK_HEADERS(gssapi.h, ,
1990                                         AC_MSG_WARN([Cannot find any suitable gss-api header - build may fail])
1991                                   )
1992                                 ]
1993                         )
1994
1995                         AC_CHECK_LIB(gssapi, gss_krb5_copy_ccache, /bin/true,
1996                                 [ K5LIBS="-lgssapi_krb5 $K5LIBS"
1997                                   AC_CHECK_LIB(gssapi_krb5, gss_krb5_copy_ccache, /bin/true,
1998                                         AC_MSG_WARN([Cannot find gss_krb5_copy_ccache -- build may fail]),
1999                                         $K5LIBS)
2000                                 ],
2001                                 $K5LIBS)
2002
2003                         oldCPP="$CPPFLAGS"
2004                         CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include/gssapi"
2005                         AC_CHECK_HEADER(gssapi_krb5.h, ,
2006                                         [ CPPFLAGS="$oldCPP" ])
2007
2008                         if test -z "$GSSAPI"; then
2009                                 GSSAPI="KRB5";
2010                         fi
2011
2012                         KRB5=yes
2013                 fi
2014         ]
2015 )
2016 # Check whether user wants Kerberos 4 support
2017 KRB4_MSG="no"
2018 AC_ARG_WITH(kerberos4,
2019         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
2020         [
2021                 if test "x$withval" != "xno" ; then
2022                         if test "x$withval" != "xyes" ; then
2023                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
2024                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
2025                                 if test ! -z "$need_dash_r" ; then
2026                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
2027                                 fi
2028                                 if test ! -z "$blibpath" ; then
2029                                         blibpath="$blibpath:${withval}/lib"
2030                                 fi
2031                         else
2032                                 if test -d /usr/include/kerberosIV ; then
2033                                         CPPFLAGS="$CPPFLAGS -I/usr/include/kerberosIV"
2034                                 fi
2035                         fi
2036
2037                         AC_CHECK_HEADERS(krb.h)
2038                         if test "$ac_cv_header_krb_h" != yes; then
2039                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
2040                         fi
2041                         AC_CHECK_LIB(krb, main)
2042                         if test "$ac_cv_lib_krb_main" != yes; then
2043                                 AC_CHECK_LIB(krb4, main)
2044                                 if test "$ac_cv_lib_krb4_main" != yes; then
2045                                         AC_MSG_WARN([Cannot find libkrb nor libkrb4, build may fail])
2046                                 else
2047                                         KLIBS="-lkrb4"
2048                                 fi
2049                         else
2050                                 KLIBS="-lkrb"
2051                         fi
2052                         AC_CHECK_LIB(des, des_cbc_encrypt)
2053                         if test "$ac_cv_lib_des_des_cbc_encrypt" != yes; then
2054                                 AC_CHECK_LIB(des425, des_cbc_encrypt)
2055                                 if test "$ac_cv_lib_des425_des_cbc_encrypt" != yes; then
2056                                         AC_MSG_WARN([Cannot find libdes nor libdes425, build may fail])
2057                                 else
2058                                         KLIBS="-ldes425"
2059                                 fi
2060                         else
2061                                 KLIBS="-ldes"
2062                         fi
2063                         AC_CHECK_LIB(resolv, dn_expand, , )
2064                         KRB4=yes
2065                         KRB4_MSG="yes"
2066                         AC_DEFINE(KRB4)
2067                 fi
2068         ]
2069 )
2070
2071 # Check whether user wants AFS_KRB5 support
2072 AFS_KRB5_MSG="no"
2073 AC_ARG_WITH(afs-krb5,
2074         [  --with-afs-krb5[[=AKLOG_PATH]]  Enable aklog to get token (default=/usr/bin/aklog).],
2075         [
2076                 if test "x$withval" != "xno" ; then
2077
2078                         if test "x$withval" != "xyes" ; then
2079                                 AC_DEFINE_UNQUOTED(AKLOG_PATH, "$withval")
2080                         else
2081                                 AC_DEFINE_UNQUOTED(AKLOG_PATH, "/usr/bin/aklog")
2082                         fi
2083
2084                         if test -z "$KRB5" ; then
2085                                 AC_MSG_WARN([AFS_KRB5 requires Kerberos 5 support, build may fail])
2086                         fi
2087
2088                         LIBS="-lkrbafs $LIBS"
2089                         if test ! -z "$AFS_LIBS" ; then
2090                                 LIBS="$LIBS $AFS_LIBS"
2091                         fi
2092                         AC_DEFINE(AFS_KRB5)
2093                         AFS_KRB5_MSG="yes"
2094                 fi
2095         ]
2096 )
2097
2098 # Check whether user wants AFS support
2099 AFS_MSG="no"
2100 AC_ARG_WITH(afs,
2101         [  --with-afs=PATH         Enable AFS support],
2102         [
2103                 if test "x$withval" != "xno" ; then
2104
2105                         if test "x$withval" != "xyes" ; then
2106                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
2107                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
2108                         fi
2109
2110                         if test -z "$KRB4" ; then
2111                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
2112                         fi
2113
2114                         LIBS="-lkafs $LIBS"
2115                         if test ! -z "$AFS_LIBS" ; then
2116                                 LIBS="$LIBS $AFS_LIBS"
2117                         fi
2118                         AC_DEFINE(AFS)
2119                         AFS_MSG="yes"
2120                 fi
2121         ]
2122 )
2123 LIBS="$LIBS $KLIBS $K5LIBS"
2124
2125 AC_ARG_WITH(session-hooks,
2126         [  --with-session-hooks    Enable hooks for executing external commands                                       before/after a session],
2127         [ AC_DEFINE(SESSION_HOOKS) ]
2128 )
2129
2130 # Looking for programs, paths and files
2131
2132 PRIVSEP_PATH=/var/empty
2133 AC_ARG_WITH(privsep-path,
2134         [  --with-privsep-path=xxx Path for privilege separation chroot (default=/var/empty)],
2135         [
2136                 if test "x$withval" != "$no" ; then
2137                         PRIVSEP_PATH=$withval
2138                 fi
2139         ]
2140 )
2141 AC_SUBST(PRIVSEP_PATH)
2142
2143 AC_ARG_WITH(xauth,
2144         [  --with-xauth=PATH       Specify path to xauth program ],
2145         [
2146                 if test "x$withval" != "xno" ; then
2147                         xauth_path=$withval
2148                 fi
2149         ],
2150         [
2151                 TestPath="$PATH"
2152                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/X/bin"
2153                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/bin/X11"
2154                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/X11R6/bin"
2155                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/openwin/bin"
2156                 AC_PATH_PROG(xauth_path, xauth, , $TestPath)
2157                 if (test ! -z "$xauth_path" && test -x "/usr/openwin/bin/xauth") ; then
2158                         xauth_path="/usr/openwin/bin/xauth"
2159                 fi
2160         ]
2161 )
2162
2163 STRIP_OPT=-s
2164 AC_ARG_ENABLE(strip,
2165         [  --disable-strip         Disable calling strip(1) on install],
2166         [
2167                 if test "x$enableval" = "xno" ; then
2168                         STRIP_OPT=
2169                 fi
2170         ]
2171 )
2172 AC_SUBST(STRIP_OPT)
2173
2174 if test -z "$xauth_path" ; then
2175         XAUTH_PATH="undefined"
2176         AC_SUBST(XAUTH_PATH)
2177 else
2178         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
2179         XAUTH_PATH=$xauth_path
2180         AC_SUBST(XAUTH_PATH)
2181 fi
2182
2183 # Check for mail directory (last resort if we cannot get it from headers)
2184 if test ! -z "$MAIL" ; then
2185         maildir=`dirname $MAIL`
2186         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
2187 fi
2188
2189 if test -z "$no_dev_ptmx" ; then
2190         if test "x$disable_ptmx_check" != "xyes" ; then
2191                 AC_CHECK_FILE("/dev/ptmx",
2192                         [
2193                                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
2194                                 have_dev_ptmx=1
2195                         ]
2196                 )
2197         fi
2198 fi
2199 AC_CHECK_FILE("/dev/ptc",
2200         [
2201                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
2202                 have_dev_ptc=1
2203         ]
2204 )
2205
2206 # Options from here on. Some of these are preset by platform above
2207 AC_ARG_WITH(mantype,
2208         [  --with-mantype=man|cat|doc  Set man page type],
2209         [
2210                 case "$withval" in
2211                 man|cat|doc)
2212                         MANTYPE=$withval
2213                         ;;
2214                 *)
2215                         AC_MSG_ERROR(invalid man type: $withval)
2216                         ;;
2217                 esac
2218         ]
2219 )
2220 if test -z "$MANTYPE"; then
2221         TestPath="/usr/bin${PATH_SEPARATOR}/usr/ucb"
2222         AC_PATH_PROGS(NROFF, nroff awf, /bin/false, $TestPath)
2223         if ${NROFF} -mdoc ${srcdir}/ssh.1 >/dev/null 2>&1; then
2224                 MANTYPE=doc
2225         elif ${NROFF} -man ${srcdir}/ssh.1 >/dev/null 2>&1; then
2226                 MANTYPE=man
2227         else
2228                 MANTYPE=cat
2229         fi
2230 fi
2231 AC_SUBST(MANTYPE)
2232 if test "$MANTYPE" = "doc"; then
2233         mansubdir=man;
2234 else
2235         mansubdir=$MANTYPE;
2236 fi
2237 AC_SUBST(mansubdir)
2238
2239 # Check whether to enable MD5 passwords
2240 MD5_MSG="no"
2241 AC_ARG_WITH(md5-passwords,
2242         [  --with-md5-passwords    Enable use of MD5 passwords],
2243         [
2244                 if test "x$withval" != "xno" ; then
2245                         AC_DEFINE(HAVE_MD5_PASSWORDS)
2246                         MD5_MSG="yes"
2247                 fi
2248         ]
2249 )
2250
2251 # Whether to disable shadow password support
2252 AC_ARG_WITH(shadow,
2253         [  --without-shadow        Disable shadow password support],
2254         [
2255                 if test "x$withval" = "xno" ; then
2256                         AC_DEFINE(DISABLE_SHADOW)
2257                         disable_shadow=yes
2258                 fi
2259         ]
2260 )
2261
2262 if test -z "$disable_shadow" ; then
2263         AC_MSG_CHECKING([if the systems has expire shadow information])
2264         AC_TRY_COMPILE(
2265         [
2266 #include <sys/types.h>
2267 #include <shadow.h>
2268         struct spwd sp;
2269         ],[ sp.sp_expire = sp.sp_lstchg = sp.sp_inact = 0; ],
2270         [ sp_expire_available=yes ], []
2271         )
2272
2273         if test "x$sp_expire_available" = "xyes" ; then
2274                 AC_MSG_RESULT(yes)
2275                 AC_DEFINE(HAS_SHADOW_EXPIRE)
2276         else
2277                 AC_MSG_RESULT(no)
2278         fi
2279 fi
2280
2281 # Use ip address instead of hostname in $DISPLAY
2282 if test ! -z "$IPADDR_IN_DISPLAY" ; then
2283         DISPLAY_HACK_MSG="yes"
2284         AC_DEFINE(IPADDR_IN_DISPLAY)
2285 else
2286         DISPLAY_HACK_MSG="no"
2287         AC_ARG_WITH(ipaddr-display,
2288                 [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
2289                 [
2290                         if test "x$withval" != "xno" ; then
2291                                 AC_DEFINE(IPADDR_IN_DISPLAY)
2292                                 DISPLAY_HACK_MSG="yes"
2293                         fi
2294                 ]
2295         )
2296 fi
2297
2298 dnl BSD systems use /etc/login.conf so --with-default-path= has no effect
2299 if test $ac_cv_func_login_getcapbool = "yes" -a \
2300         $ac_cv_header_login_cap_h = "yes" ; then
2301         USES_LOGIN_CONF=yes
2302 fi
2303 # Whether to mess with the default path
2304 SERVER_PATH_MSG="(default)"
2305 AC_ARG_WITH(default-path,
2306         [  --with-default-path=    Specify default \$PATH environment for server],
2307         [
2308                 if test "$USES_LOGIN_CONF" = "yes" ; then
2309                         AC_MSG_WARN([
2310 --with-default-path=PATH has no effect on this system.
2311 Edit /etc/login.conf instead.])
2312                 elif test "x$withval" != "xno" ; then
2313                         user_path="$withval"
2314                         SERVER_PATH_MSG="$withval"
2315                 fi
2316         ],
2317         [ if test "$USES_LOGIN_CONF" = "yes" ; then
2318         AC_MSG_WARN([Make sure the path to scp is in /etc/login.conf])
2319         else
2320         AC_TRY_RUN(
2321                 [
2322 /* find out what STDPATH is */
2323 #include <stdio.h>
2324 #ifdef HAVE_PATHS_H
2325 # include <paths.h>
2326 #endif
2327 #ifndef _PATH_STDPATH
2328 # ifdef _PATH_USERPATH  /* Irix */
2329 #  define _PATH_STDPATH _PATH_USERPATH
2330 # else
2331 #  define _PATH_STDPATH "/usr/bin:/bin:/usr/sbin:/sbin"
2332 # endif
2333 #endif
2334 #include <sys/types.h>
2335 #include <sys/stat.h>
2336 #include <fcntl.h>
2337 #define DATA "conftest.stdpath"
2338
2339 main()
2340 {
2341         FILE *fd;
2342         int rc;
2343
2344         fd = fopen(DATA,"w");
2345         if(fd == NULL)
2346                 exit(1);
2347
2348         if ((rc = fprintf(fd,"%s", _PATH_STDPATH)) < 0)
2349                 exit(1);
2350
2351         exit(0);
2352 }
2353                 ], [ user_path=`cat conftest.stdpath` ],
2354                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ],
2355                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ]
2356         )
2357         fi ]
2358 )
2359 if test "$USES_LOGIN_CONF" != "yes" ; then
2360         AC_DEFINE_UNQUOTED(USER_PATH, "$user_path")
2361         AC_SUBST(user_path)
2362 fi
2363
2364 # Set superuser path separately to user path
2365 AC_ARG_WITH(superuser-path,
2366         [  --with-superuser-path=  Specify different path for super-user],
2367         [
2368                 if test "x$withval" != "xno" ; then
2369                         AC_DEFINE_UNQUOTED(SUPERUSER_PATH, "$withval")
2370                         superuser_path=$withval
2371                 fi
2372         ]
2373 )
2374
2375
2376 # Whether to force IPv4 by default (needed on broken glibc Linux)
2377 IPV4_HACK_MSG="no"
2378 AC_ARG_WITH(ipv4-default,
2379         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
2380         [
2381                 if test "x$withval" != "xno" ; then
2382                         AC_DEFINE(IPV4_DEFAULT)
2383                         IPV4_HACK_MSG="yes"
2384                 fi
2385         ]
2386 )
2387
2388 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
2389 IPV4_IN6_HACK_MSG="no"
2390 AC_ARG_WITH(4in6,
2391         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
2392         [
2393                 if test "x$withval" != "xno" ; then
2394                         AC_MSG_RESULT(yes)
2395                         AC_DEFINE(IPV4_IN_IPV6)
2396                         IPV4_IN6_HACK_MSG="yes"
2397                 else
2398                         AC_MSG_RESULT(no)
2399                 fi
2400         ],[
2401                 if test "x$inet6_default_4in6" = "xyes"; then
2402                         AC_MSG_RESULT([yes (default)])
2403                         AC_DEFINE(IPV4_IN_IPV6)
2404                         IPV4_IN6_HACK_MSG="yes"
2405                 else
2406                         AC_MSG_RESULT([no (default)])
2407                 fi
2408         ]
2409 )
2410
2411 # Whether to enable BSD auth support
2412 BSD_AUTH_MSG=no
2413 AC_ARG_WITH(bsd-auth,
2414         [  --with-bsd-auth         Enable BSD auth support],
2415         [
2416                 if test "x$withval" != "xno" ; then
2417                         AC_DEFINE(BSD_AUTH)
2418                         BSD_AUTH_MSG=yes
2419                 fi
2420         ]
2421 )
2422
2423 dnl allow user to disable some login recording features
2424 AC_ARG_ENABLE(lastlog,
2425         [  --disable-lastlog       disable use of lastlog even if detected [no]],
2426         [ AC_DEFINE(DISABLE_LASTLOG) ]
2427 )
2428 AC_ARG_ENABLE(utmp,
2429         [  --disable-utmp          disable use of utmp even if detected [no]],
2430         [ AC_DEFINE(DISABLE_UTMP) ]
2431 )
2432 AC_ARG_ENABLE(utmpx,
2433         [  --disable-utmpx         disable use of utmpx even if detected [no]],
2434         [ AC_DEFINE(DISABLE_UTMPX) ]
2435 )
2436 AC_ARG_ENABLE(wtmp,
2437         [  --disable-wtmp          disable use of wtmp even if detected [no]],
2438         [ AC_DEFINE(DISABLE_WTMP) ]
2439 )
2440 AC_ARG_ENABLE(wtmpx,
2441         [  --disable-wtmpx         disable use of wtmpx even if detected [no]],
2442         [ AC_DEFINE(DISABLE_WTMPX) ]
2443 )
2444 AC_ARG_ENABLE(libutil,
2445         [  --disable-libutil       disable use of libutil (login() etc.) [no]],
2446         [ AC_DEFINE(DISABLE_LOGIN) ]
2447 )
2448 AC_ARG_ENABLE(pututline,
2449         [  --disable-pututline     disable use of pututline() etc. ([uw]tmp) [no]],
2450         [ AC_DEFINE(DISABLE_PUTUTLINE) ]
2451 )
2452 AC_ARG_ENABLE(pututxline,
2453         [  --disable-pututxline    disable use of pututxline() etc. ([uw]tmpx) [no]],
2454         [ AC_DEFINE(DISABLE_PUTUTXLINE) ]
2455 )
2456 AC_ARG_WITH(lastlog,
2457   [  --with-lastlog=FILE|DIR specify lastlog location [common locations]],
2458         [
2459                 if test "x$withval" = "xno" ; then
2460                         AC_DEFINE(DISABLE_LASTLOG)
2461                 else
2462                         conf_lastlog_location=$withval
2463                 fi
2464         ]
2465 )
2466
2467 dnl lastlog, [uw]tmpx? detection
2468 dnl  NOTE: set the paths in the platform section to avoid the
2469 dnl   need for command-line parameters
2470 dnl lastlog and [uw]tmp are subject to a file search if all else fails
2471
2472 dnl lastlog detection
2473 dnl  NOTE: the code itself will detect if lastlog is a directory
2474 AC_MSG_CHECKING([if your system defines LASTLOG_FILE])
2475 AC_TRY_COMPILE([
2476 #include <sys/types.h>
2477 #include <utmp.h>
2478 #ifdef HAVE_LASTLOG_H
2479 #  include <lastlog.h>
2480 #endif
2481 #ifdef HAVE_PATHS_H
2482 #  include <paths.h>
2483 #endif
2484 #ifdef HAVE_LOGIN_H
2485 # include <login.h>
2486 #endif
2487         ],
2488         [ char *lastlog = LASTLOG_FILE; ],
2489         [ AC_MSG_RESULT(yes) ],
2490         [
2491                 AC_MSG_RESULT(no)
2492                 AC_MSG_CHECKING([if your system defines _PATH_LASTLOG])
2493                 AC_TRY_COMPILE([
2494 #include <sys/types.h>
2495 #include <utmp.h>
2496 #ifdef HAVE_LASTLOG_H
2497 #  include <lastlog.h>
2498 #endif
2499 #ifdef HAVE_PATHS_H
2500 #  include <paths.h>
2501 #endif
2502                 ],
2503                 [ char *lastlog = _PATH_LASTLOG; ],
2504                 [ AC_MSG_RESULT(yes) ],
2505                 [
2506                         AC_MSG_RESULT(no)
2507                         system_lastlog_path=no
2508                 ])
2509         ]
2510 )
2511
2512 if test -z "$conf_lastlog_location"; then
2513         if test x"$system_lastlog_path" = x"no" ; then
2514                 for f in /var/log/lastlog /usr/adm/lastlog /var/adm/lastlog /etc/security/lastlog ; do
2515                                 if (test -d "$f" || test -f "$f") ; then
2516                                         conf_lastlog_location=$f
2517                                 fi
2518                 done
2519                 if test -z "$conf_lastlog_location"; then
2520                         AC_MSG_WARN([** Cannot find lastlog **])
2521                         dnl Don't define DISABLE_LASTLOG - that means we don't try wtmp/wtmpx
2522                 fi
2523         fi
2524 fi
2525
2526 if test -n "$conf_lastlog_location"; then
2527         AC_DEFINE_UNQUOTED(CONF_LASTLOG_FILE, "$conf_lastlog_location")
2528 fi
2529
2530 dnl utmp detection
2531 AC_MSG_CHECKING([if your system defines UTMP_FILE])
2532 AC_TRY_COMPILE([
2533 #include <sys/types.h>
2534 #include <utmp.h>
2535 #ifdef HAVE_PATHS_H
2536 #  include <paths.h>
2537 #endif
2538         ],
2539         [ char *utmp = UTMP_FILE; ],
2540         [ AC_MSG_RESULT(yes) ],
2541         [ AC_MSG_RESULT(no)
2542           system_utmp_path=no ]
2543 )
2544 if test -z "$conf_utmp_location"; then
2545         if test x"$system_utmp_path" = x"no" ; then
2546                 for f in /etc/utmp /usr/adm/utmp /var/run/utmp; do
2547                         if test -f $f ; then
2548                                 conf_utmp_location=$f
2549                         fi
2550                 done
2551                 if test -z "$conf_utmp_location"; then
2552                         AC_DEFINE(DISABLE_UTMP)
2553                 fi
2554         fi
2555 fi
2556 if test -n "$conf_utmp_location"; then
2557         AC_DEFINE_UNQUOTED(CONF_UTMP_FILE, "$conf_utmp_location")
2558 fi
2559
2560 dnl wtmp detection
2561 AC_MSG_CHECKING([if your system defines WTMP_FILE])
2562 AC_TRY_COMPILE([
2563 #include <sys/types.h>
2564 #include <utmp.h>
2565 #ifdef HAVE_PATHS_H
2566 #  include <paths.h>
2567 #endif
2568         ],
2569         [ char *wtmp = WTMP_FILE; ],
2570         [ AC_MSG_RESULT(yes) ],
2571         [ AC_MSG_RESULT(no)
2572           system_wtmp_path=no ]
2573 )
2574 if test -z "$conf_wtmp_location"; then
2575         if test x"$system_wtmp_path" = x"no" ; then
2576                 for f in /usr/adm/wtmp /var/log/wtmp; do
2577                         if test -f $f ; then
2578                                 conf_wtmp_location=$f
2579                         fi
2580                 done
2581                 if test -z "$conf_wtmp_location"; then
2582                         AC_DEFINE(DISABLE_WTMP)
2583                 fi
2584         fi
2585 fi
2586 if test -n "$conf_wtmp_location"; then
2587         AC_DEFINE_UNQUOTED(CONF_WTMP_FILE, "$conf_wtmp_location")
2588 fi
2589
2590
2591 dnl utmpx detection - I don't know any system so perverse as to require
2592 dnl  utmpx, but not define UTMPX_FILE (ditto wtmpx.) No doubt it's out
2593 dnl  there, though.
2594 AC_MSG_CHECKING([if your system defines UTMPX_FILE])
2595 AC_TRY_COMPILE([
2596 #include <sys/types.h>
2597 #include <utmp.h>
2598 #ifdef HAVE_UTMPX_H
2599 #include <utmpx.h>
2600 #endif
2601 #ifdef HAVE_PATHS_H
2602 #  include <paths.h>
2603 #endif
2604         ],
2605         [ char *utmpx = UTMPX_FILE; ],
2606         [ AC_MSG_RESULT(yes) ],
2607         [ AC_MSG_RESULT(no)
2608           system_utmpx_path=no ]
2609 )
2610 if test -z "$conf_utmpx_location"; then
2611         if test x"$system_utmpx_path" = x"no" ; then
2612                 AC_DEFINE(DISABLE_UTMPX)
2613         fi
2614 else
2615         AC_DEFINE_UNQUOTED(CONF_UTMPX_FILE, "$conf_utmpx_location")
2616 fi
2617
2618 dnl wtmpx detection
2619 AC_MSG_CHECKING([if your system defines WTMPX_FILE])
2620 AC_TRY_COMPILE([
2621 #include <sys/types.h>
2622 #include <utmp.h>
2623 #ifdef HAVE_UTMPX_H
2624 #include <utmpx.h>
2625 #endif
2626 #ifdef HAVE_PATHS_H
2627 #  include <paths.h>
2628 #endif
2629         ],
2630         [ char *wtmpx = WTMPX_FILE; ],
2631         [ AC_MSG_RESULT(yes) ],
2632         [ AC_MSG_RESULT(no)
2633           system_wtmpx_path=no ]
2634 )
2635 if test -z "$conf_wtmpx_location"; then
2636         if test x"$system_wtmpx_path" = x"no" ; then
2637                 AC_DEFINE(DISABLE_WTMPX)
2638         fi
2639 else
2640         AC_DEFINE_UNQUOTED(CONF_WTMPX_FILE, "$conf_wtmpx_location")
2641 fi
2642
2643
2644 if test ! -z "$blibpath" ; then
2645         LDFLAGS="$LDFLAGS $blibflags$blibpath"
2646         AC_MSG_WARN([Please check and edit blibpath in LDFLAGS in Makefile])
2647 fi
2648
2649 dnl remove pam and dl because they are in $LIBPAM
2650 if test "$PAM_MSG" = yes ; then
2651         LIBS=`echo $LIBS | sed 's/-lpam //'`
2652 fi
2653 if test "$ac_cv_lib_pam_pam_set_item" = yes ; then
2654         LIBS=`echo $LIBS | sed 's/-ldl //'`
2655 fi
2656
2657 AC_EXEEXT
2658 AC_CONFIG_FILES([Makefile openbsd-compat/Makefile scard/Makefile ssh_prng_cmds])
2659 AC_OUTPUT
2660
2661 # Print summary of options
2662
2663 # Someone please show me a better way :)
2664 A=`eval echo ${prefix}` ; A=`eval echo ${A}`
2665 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
2666 C=`eval echo ${sbindir}` ; C=`eval echo ${C}`
2667 D=`eval echo ${sysconfdir}` ; D=`eval echo ${D}`
2668 E=`eval echo ${libexecdir}/ssh-askpass` ; E=`eval echo ${E}`
2669 F=`eval echo ${mandir}/${mansubdir}X` ; F=`eval echo ${F}`
2670 H=`eval echo ${PRIVSEP_PATH}` ; H=`eval echo ${H}`
2671 I=`eval echo ${user_path}` ; I=`eval echo ${I}`
2672 J=`eval echo ${superuser_path}` ; J=`eval echo ${J}`
2673
2674 echo ""
2675 echo "OpenSSH has been configured with the following options:"
2676 echo "                     User binaries: $B"
2677 echo "                   System binaries: $C"
2678 echo "               Configuration files: $D"
2679 echo "                   Askpass program: $E"
2680 echo "                      Manual pages: $F"
2681 echo "  Privilege separation chroot path: $H"
2682 if test "$USES_LOGIN_CONF" = "yes" ; then
2683 echo "   At runtime, sshd will use the path defined in /etc/login.conf"
2684 else
2685 echo "            sshd default user PATH: $I"
2686 fi
2687 if test ! -z "$superuser_path" ; then
2688 echo "          sshd superuser user PATH: $J"
2689 fi
2690 echo "                    Manpage format: $MANTYPE"
2691 echo "                       PAM support: ${PAM_MSG}"
2692 echo "                KerberosIV support: $KRB4_MSG"
2693 echo "                 KerberosV support: $KRB5_MSG"
2694 echo "                 Smartcard support: $SCARD_MSG"
2695 echo "                       AFS support: $AFS_MSG"
2696 echo "                     S/KEY support: $SKEY_MSG"
2697 echo "              TCP Wrappers support: $TCPW_MSG"
2698 echo "              MD5 password support: $MD5_MSG"
2699 echo "       IP address in \$DISPLAY hack: $DISPLAY_HACK_MSG"
2700 echo "          Use IPv4 by default hack: $IPV4_HACK_MSG"
2701 echo "           Translate v4 in v6 hack: $IPV4_IN6_HACK_MSG"
2702 echo "                  BSD Auth support: $BSD_AUTH_MSG"
2703 echo "              Random number source: $RAND_MSG"
2704 if test ! -z "$USE_RAND_HELPER" ; then
2705 echo "     ssh-rand-helper collects from: $RAND_HELPER_MSG"
2706 fi
2707
2708 echo ""
2709
2710 echo "              Host: ${host}"
2711 echo "          Compiler: ${CC}"
2712 echo "    Compiler flags: ${CFLAGS}"
2713 echo "Preprocessor flags: ${CPPFLAGS}"
2714 echo "      Linker flags: ${LDFLAGS}"
2715 echo "         Libraries: ${LIBWRAP} ${LIBPAM} ${LIBS}"
2716
2717 echo ""
2718
2719 if test "x$PAM_MSG" = "xyes" ; then
2720         echo "PAM is enabled. You may need to install a PAM control file "
2721         echo "for sshd, otherwise password authentication may fail. "
2722         echo "Example PAM control files can be found in the contrib/ "
2723         echo "subdirectory"
2724         echo ""
2725 fi
2726
2727 if test ! -z "$RAND_HELPER_CMDHASH" ; then
2728         echo "WARNING: you are using the builtin random number collection "
2729         echo "service. Please read WARNING.RNG and request that your OS "
2730         echo "vendor includes kernel-based random number collection in "
2731         echo "future versions of your OS."
2732         echo ""
2733 fi
2734