openssh/configure.ac

   1 # $Id$
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([ssh.c])
   5
   6 AC_CONFIG_HEADER(config.h)
   7 AC_PROG_CC
   8 AC_CANONICAL_HOST
   9 AC_C_BIGENDIAN
  10
  11 # Checks for programs.
  12 AC_PROG_CPP
  13 AC_PROG_RANLIB
  14 AC_PROG_INSTALL
  15 AC_PATH_PROG(AR, ar)
  16 AC_PATH_PROGS(PERL, perl5 perl)
  17 AC_SUBST(PERL)
  18 AC_PATH_PROG(ENT, ent)
  19 AC_SUBST(ENT)
  20 AC_PATH_PROGS(FILEPRIV, filepriv, true, /sbin:/usr/sbin)
  21 AC_PATH_PROG(TEST_MINUS_S_SH, bash)
  22 AC_PATH_PROG(TEST_MINUS_S_SH, ksh)
  23 AC_PATH_PROG(TEST_MINUS_S_SH, sh)
  24
  25 # System features
  26 AC_SYS_LARGEFILE
  27
  28 if test -z "$AR" ; then
  29         AC_MSG_ERROR([*** 'ar' missing, please install or fix your \$PATH ***])
  30 fi
  31
  32 # Use LOGIN_PROGRAM from environment if possible
  33 if test ! -z "$LOGIN_PROGRAM" ; then
  34         AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM")
  35 else
  36         # Search for login
  37         AC_PATH_PROG(LOGIN_PROGRAM_FALLBACK, login)
  38         if test ! -z "$LOGIN_PROGRAM_FALLBACK" ; then
  39                 AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM_FALLBACK")
  40         fi
  41 fi
  42
  43 if test -z "$LD" ; then
  44         LD=$CC
  45 fi
  46 AC_SUBST(LD)
  47
  48 AC_C_INLINE
  49 if test "$GCC" = "yes" || test "$GCC" = "egcs"; then
  50         CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wno-uninitialized"
  51 fi
  52
  53 # Check for some target-specific stuff
  54 case "$host" in
  55 *-*-aix*)
  56         AFS_LIBS="-lld"
  57         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
  58         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  59         if (test "$LD" != "gcc" && test -z "$blibpath"); then
  60                 blibpath="/usr/lib:/lib:/usr/local/lib"
  61         fi
  62         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)])
  63         AC_DEFINE(BROKEN_GETADDRINFO)
  64         dnl AIX handles lastlog as part of its login message
  65         AC_DEFINE(DISABLE_LASTLOG)
  66         ;;
  67 *-*-cygwin*)
  68         LIBS="$LIBS -lregex /usr/lib/textmode.o"
  69         AC_DEFINE(HAVE_CYGWIN)
  70         AC_DEFINE(USE_PIPES)
  71         AC_DEFINE(DISABLE_SHADOW)
  72         AC_DEFINE(IPV4_DEFAULT)
  73         AC_DEFINE(IP_TOS_IS_BROKEN)
  74         AC_DEFINE(NO_X11_UNIX_SOCKETS)
  75         ;;
  76 *-*-dgux*)
  77         AC_DEFINE(IP_TOS_IS_BROKEN)
  78         ;;
  79 *-*-darwin*)
  80         AC_DEFINE(BROKEN_GETADDRINFO)
  81         ;;
  82 *-*-hpux10*)
  83         if test -z "$GCC"; then
  84                 CFLAGS="$CFLAGS -Ae"
  85         fi
  86         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
  87         IPADDR_IN_DISPLAY=yes
  88         AC_DEFINE(USE_PIPES)
  89         AC_DEFINE(DISABLE_SHADOW)
  90         AC_DEFINE(DISABLE_UTMP)
  91         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
  92         LIBS="$LIBS -lxnet -lsec"
  93         ;;
  94 *-*-hpux11*)
  95         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
  96         IPADDR_IN_DISPLAY=yes
  97         AC_DEFINE(PAM_SUN_CODEBASE)
  98         AC_DEFINE(USE_PIPES)
  99         AC_DEFINE(DISABLE_SHADOW)
 100         AC_DEFINE(DISABLE_UTMP)
 101         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 102         LIBS="$LIBS -lxnet -lsec"
 103         ;;
 104 *-*-irix5*)
 105         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 106         LDFLAGS="$LDFLAGS"
 107         PATH="$PATH:/usr/etc"
 108         AC_DEFINE(BROKEN_INET_NTOA)
 109         ;;
 110 *-*-irix6*)
 111         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 112         LDFLAGS="$LDFLAGS"
 113         PATH="$PATH:/usr/etc"
 114         AC_DEFINE(WITH_IRIX_ARRAY)
 115         AC_DEFINE(WITH_IRIX_PROJECT)
 116         AC_DEFINE(WITH_IRIX_AUDIT)
 117         AC_CHECK_FUNC(jlimit_startjob, [AC_DEFINE(WITH_IRIX_JOBS)])
 118         AC_DEFINE(BROKEN_INET_NTOA)
 119         ;;
 120 *-*-linux*)
 121         no_dev_ptmx=1
 122         check_for_libcrypt_later=1
 123         AC_DEFINE(DONT_TRY_OTHER_AF)
 124         AC_DEFINE(PAM_TTY_KLUDGE)
 125         inet6_default_4in6=yes
 126         ;;
 127 mips-sony-bsd|mips-sony-newsos4)
 128         AC_DEFINE(HAVE_NEWS4)
 129         SONY=1
 130         AC_CHECK_LIB(iberty, xatexit, AC_DEFINE(HAVE_XATEXIT),
 131                 AC_MSG_ERROR([*** libiberty missing - please install first or check config.log ***])
 132         )
 133         ;;
 134 *-*-netbsd*)
 135         need_dash_r=1
 136         ;;
 137 *-*-freebsd*)
 138         check_for_libcrypt_later=1
 139         ;;
 140 *-next-*)
 141         conf_lastlog_location="/usr/adm/lastlog"
 142         conf_utmp_location=/etc/utmp
 143         conf_wtmp_location=/usr/adm/wtmp
 144         MAIL=/usr/spool/mail
 145         AC_DEFINE(HAVE_NEXT)
 146         AC_DEFINE(BROKEN_REALPATH)
 147         AC_DEFINE(USE_PIPES)
 148         AC_DEFINE(BROKEN_SAVED_UIDS)
 149         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 150         CFLAGS="$CFLAGS"
 151         ;;
 152 *-*-solaris*)
 153         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 154         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib"
 155         need_dash_r=1
 156         AC_DEFINE(PAM_SUN_CODEBASE)
 157         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 158         AC_DEFINE(LOGIN_NEEDS_TERM)
 159         AC_DEFINE(PAM_TTY_KLUDGE)
 160         # hardwire lastlog location (can't detect it on some versions)
 161         conf_lastlog_location="/var/adm/lastlog"
 162         AC_MSG_CHECKING(for obsolete utmp and wtmp in solaris2.x)
 163         sol2ver=`echo "$host"| sed -e 's/.*[[0-9]]\.//'`
 164         if test "$sol2ver" -ge 8; then
 165                 AC_MSG_RESULT(yes)
 166                 AC_DEFINE(DISABLE_UTMP)
 167                 AC_DEFINE(DISABLE_WTMP)
 168         else
 169                 AC_MSG_RESULT(no)
 170         fi
 171         ;;
 172 *-*-sunos4*)
 173         CPPFLAGS="$CPPFLAGS -DSUNOS4"
 174         AC_CHECK_FUNCS(getpwanam)
 175         AC_DEFINE(PAM_SUN_CODEBASE)
 176         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 177         conf_utmp_location=/etc/utmp
 178         conf_wtmp_location=/var/adm/wtmp
 179         conf_lastlog_location=/var/adm/lastlog
 180         AC_DEFINE(USE_PIPES)
 181         ;;
 182 *-ncr-sysv*)
 183         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 184         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 185         LIBS="$LIBS -lc89"
 186         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 187         ;;
 188 *-sni-sysv*)
 189         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 190         # /usr/ucblib MUST NOT be searched on ReliantUNIX
 191         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 192         IPADDR_IN_DISPLAY=yes
 193         AC_DEFINE(USE_PIPES)
 194         AC_DEFINE(IP_TOS_IS_BROKEN)
 195         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 196         # /usr/ucblib/libucb.a no longer needed on ReliantUNIX
 197         # Attention: always take care to bind libsocket and libnsl before libc,
 198         # otherwise you will find lots of "SIOCGPGRP errno 22" on syslog
 199         ;;
 200 *-*-sysv4.2*)
 201         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 202         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 203 #       enable_suid_ssh=no
 204         AC_DEFINE(USE_PIPES)
 205         ;;
 206 *-*-sysv5*)
 207         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 208         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 209 #       enable_suid_ssh=no
 210         AC_DEFINE(USE_PIPES)
 211         ;;
 212 *-*-sysv*)
 213         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 214         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 215         ;;
 216 *-*-sco3.2v4*)
 217         CPPFLAGS="$CPPFLAGS -Dftruncate=chsize -I/usr/local/include"
 218         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 219         LIBS="$LIBS -los -lprot -lx -ltinfo -lm"
 220         rsh_path="/usr/bin/rcmd"
 221         RANLIB=true
 222         no_dev_ptmx=1
 223         AC_DEFINE(BROKEN_SYS_TERMIO_H)
 224         AC_DEFINE(USE_PIPES)
 225         AC_DEFINE(HAVE_SCO_PROTECTED_PW)
 226         AC_DEFINE(DISABLE_SHADOW)
 227         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 228         AC_DEFINE(BROKEN_SAVED_UIDS)
 229         AC_CHECK_FUNCS(getluid setluid)
 230         MANTYPE=man
 231         do_sco3_extra_lib_check=yes
 232         ;;
 233 *-*-sco3.2v5*)
 234         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 235         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 236         LIBS="$LIBS -lprot -lx -ltinfo -lm"
 237         no_dev_ptmx=1
 238         rsh_path="/usr/bin/rcmd"
 239         AC_DEFINE(USE_PIPES)
 240         AC_DEFINE(HAVE_SCO_PROTECTED_PW)
 241         AC_DEFINE(DISABLE_SHADOW)
 242         AC_DEFINE(HAVE_BOGUS_SYS_QUEUE_H)
 243         AC_CHECK_FUNCS(getluid setluid)
 244         MANTYPE=man
 245         ;;
 246 *-*-unicos*)
 247         no_libsocket=1
 248         no_libnsl=1
 249         AC_DEFINE(USE_PIPES)
 250         LDFLAGS="$LDFLAGS -Wl,-Dmsglevel=334:fatal,-L/usr/local/lib"
 251         LIBS="$LIBS -lgen -lrsc"
 252         ;;
 253 *-dec-osf*)
 254         AC_MSG_CHECKING(for Digital Unix SIA)
 255         no_osfsia=""
 256         AC_ARG_WITH(osfsia,
 257                 [  --with-osfsia           Enable Digital Unix SIA],
 258                 [
 259                         if test "x$withval" = "xno" ; then
 260                                 AC_MSG_RESULT(disabled)
 261                                 no_osfsia=1
 262                         fi
 263                 ],
 264         )
 265         if test -z "$no_osfsia" ; then
 266                 if test -f /etc/sia/matrix.conf; then
 267                         AC_MSG_RESULT(yes)
 268                         AC_DEFINE(HAVE_OSF_SIA)
 269                         AC_DEFINE(DISABLE_LOGIN)
 270                         LIBS="$LIBS -lsecurity -ldb -lm -laud"
 271                 else
 272                         AC_MSG_RESULT(no)
 273                 fi
 274         fi
 275         ;;
 276
 277 *-*-nto-qnx)
 278         AC_DEFINE(USE_PIPES)
 279         AC_DEFINE(NO_X11_UNIX_SOCKETS)
 280         AC_DEFINE(MISSING_NFDBITS)
 281         AC_DEFINE(MISSING_HOWMANY)
 282         AC_DEFINE(MISSING_FD_MASK)
 283         ;;
 284 esac
 285
 286 # Allow user to specify flags
 287 AC_ARG_WITH(cflags,
 288         [  --with-cflags           Specify additional flags to pass to compiler],
 289         [
 290                 if test "x$withval" != "xno" ; then
 291                         CFLAGS="$CFLAGS $withval"
 292                 fi
 293         ]
 294 )
 295 AC_ARG_WITH(cppflags,
 296         [  --with-cppflags         Specify additional flags to pass to preprocessor] ,
 297         [
 298                 if test "x$withval" != "xno"; then
 299                         CPPFLAGS="$CPPFLAGS $withval"
 300                 fi
 301         ]
 302 )
 303 AC_ARG_WITH(ldflags,
 304         [  --with-ldflags          Specify additional flags to pass to linker],
 305         [
 306                 if test "x$withval" != "xno" ; then
 307                         LDFLAGS="$LDFLAGS $withval"
 308                 fi
 309         ]
 310 )
 311 AC_ARG_WITH(libs,
 312         [  --with-libs             Specify additional libraries to link with],
 313         [
 314                 if test "x$withval" != "xno" ; then
 315                         LIBS="$LIBS $withval"
 316                 fi
 317         ]
 318 )
 319
 320 AC_ARG_WITH(pcre,
 321         [  --with-pcre[[=PATH]]      Override built in regex library with pcre
 322                             (optionally in PATH)],
 323         [
 324                 case "$withval" in
 325                 no) ;;
 326                 *)
 327                         if test "x$withval" != "xyes"; then
 328                                 if test -d "$withval/lib"; then
 329                                         if test -n "${need_dash_r}"; then
 330                                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 331                                         else
 332                                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 333                                         fi
 334                                 else
 335                                         if test -n "${need_dash_r}"; then
 336                                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 337                                         else
 338                                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 339                                         fi
 340                                 fi
 341                                 if test -d "$withval/include"; then
 342                                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 343                                 else
 344                                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 345                                 fi
 346                         fi
 347
 348                         AC_CHECK_HEADER(pcreposix.h,
 349                                 AC_CHECK_LIB(pcre, pcre_info,[
 350                                         AC_DEFINE(HAVE_LIBPCRE)
 351                                         LIBS="$LIBS -lpcreposix -lpcre"
 352                                         no_comp_check=yes],
 353                                         AC_MSG_ERROR([*** unable to locate pcre library ***])),
 354                                 AC_MSG_ERROR([*** unable to locate pcreposix.h include file ***]))
 355                         ;;
 356                 esac
 357         ]
 358 )
 359
 360 # Checks for libraries.
 361 AC_CHECK_FUNC(yp_match, , AC_CHECK_LIB(nsl, yp_match))
 362 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 363
 364 dnl SCO OS3 needs this for libwrap
 365 if test "x$with_tcp_wrappers" != "xno" ; then
 366     if test "x$do_sco3_extra_lib_check" = "xyes" ; then
 367         AC_CHECK_LIB(rpc, innetgr, LIBS="-lrpc -lyp -lrpc $LIBS" , , -lyp -lrpc)
 368     fi
 369 fi
 370
 371 AC_CHECK_FUNC(getspnam, ,
 372         AC_CHECK_LIB(gen, getspnam, LIBS="$LIBS -lgen"))
 373
 374 dnl zlib is required
 375 AC_ARG_WITH(zlib,
 376         [  --with-zlib=PATH        Use zlib in PATH],
 377         [
 378                 if test -d "$withval/lib"; then
 379                         if test -n "${need_dash_r}"; then
 380                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 381                         else
 382                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 383                         fi
 384                 else
 385                         if test -n "${need_dash_r}"; then
 386                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 387                         else
 388                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 389                         fi
 390                 fi
 391                 if test -d "$withval/include"; then
 392                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 393                 else
 394                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 395                 fi
 396         ]
 397 )
 398
 399 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first or check config.log ***]))
 400
 401 # We don't want to check if we did an pcre override.
 402 if test -z "$no_comp_check" ; then
 403         AC_CHECK_FUNC(regcomp,
 404                 [ AC_DEFINE(HAVE_REGCOMP)],
 405                 [
 406                         AC_CHECK_LIB(pcre, pcre_info,
 407                         [
 408                                 AC_DEFINE(HAVE_LIBPCRE)
 409                                 LIBS="$LIBS -lpcreposix -lpcre"
 410                         ],
 411                         [
 412                                 AC_MSG_ERROR([*** No regex library found.])
 413                         ])
 414                 ]
 415         )
 416 fi
 417
 418 dnl UnixWare 2.x
 419 AC_CHECK_FUNC(strcasecmp,
 420         [], [ AC_CHECK_LIB(resolv, strcasecmp, LIBS="$LIBS -lresolv") ]
 421 )
 422 AC_CHECK_FUNC(utimes,
 423         [], [ AC_CHECK_LIB(c89, utimes, LIBS="$LIBS -lc89") ]
 424 )
 425
 426 dnl    Checks for libutil functions
 427 AC_CHECK_HEADERS(libutil.h)
 428 AC_SEARCH_LIBS(login, util bsd, [AC_DEFINE(HAVE_LOGIN)])
 429 AC_CHECK_FUNCS(logout updwtmp logwtmp)
 430
 431 AC_FUNC_STRFTIME
 432
 433 # Checks for header files.
 434 AC_CHECK_HEADERS(bstring.h crypt.h endian.h floatingpoint.h \
 435         getopt.h glob.h lastlog.h limits.h login.h \
 436         login_cap.h maillock.h netdb.h netgroup.h \
 437         netinet/in_systm.h paths.h poll.h pty.h regex.h \
 438         security/pam_appl.h shadow.h stddef.h stdint.h \
 439         strings.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h \
 440         sys/poll.h sys/queue.h sys/select.h sys/stat.h \
 441         sys/stropts.h sys/sysmacros.h sys/time.h \
 442         sys/ttcompat.h sys/un.h time.h ttyent.h usersec.h \
 443         util.h utime.h utmp.h utmpx.h)
 444
 445 # Check for ALTDIRFUNC glob() extension
 446 AC_MSG_CHECKING(for GLOB_ALTDIRFUNC support)
 447 AC_EGREP_CPP(FOUNDIT,
 448         [
 449                 #include <glob.h>
 450                 #ifdef GLOB_ALTDIRFUNC
 451                 FOUNDIT
 452                 #endif
 453         ],
 454         [
 455                 AC_DEFINE(GLOB_HAS_ALTDIRFUNC)
 456                 AC_MSG_RESULT(yes)
 457         ],
 458         [
 459                 AC_MSG_RESULT(no)
 460         ]
 461 )
 462
 463 # Check for g.gl_matchc glob() extension
 464 AC_MSG_CHECKING(for gl_matchc field in glob_t)
 465 AC_EGREP_CPP(FOUNDIT,
 466         [
 467                 #include <glob.h>
 468                 int main(void){glob_t g; g.gl_matchc = 1;}
 469         ],
 470         [
 471                 AC_DEFINE(GLOB_HAS_GL_MATCHC)
 472                 AC_MSG_RESULT(yes)
 473         ],
 474         [
 475                 AC_MSG_RESULT(no)
 476         ]
 477 )
 478
 479 AC_MSG_CHECKING([whether struct dirent allocates space for d_name])
 480 AC_TRY_RUN(
 481         [
 482 #include <sys/types.h>
 483 #include <dirent.h>
 484 int main(void){struct dirent d;return(sizeof(d.d_name)<=sizeof(char));}
 485         ],
 486         [AC_MSG_RESULT(yes)],
 487         [
 488                 AC_MSG_RESULT(no)
 489                 AC_DEFINE(BROKEN_ONE_BYTE_DIRENT_D_NAME)
 490         ]
 491 )
 492
 493 # Check whether user wants S/Key support
 494 SKEY_MSG="no"
 495 AC_ARG_WITH(skey,
 496         [  --with-skey[[=PATH]]      Enable S/Key support
 497                             (optionally in PATH)],
 498         [
 499                 if test "x$withval" != "xno" ; then
 500
 501                         if test "x$withval" != "xyes" ; then
 502                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 503                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 504                         fi
 505
 506                         AC_DEFINE(SKEY)
 507                         LIBS="-lskey $LIBS"
 508                         SKEY_MSG="yes"
 509
 510                         AC_CHECK_FUNC(skey_keyinfo,
 511                                 [],
 512                                 [
 513                                         AC_MSG_ERROR([** Incomplete or missing s/key libraries.])
 514                                 ])
 515                 fi
 516         ]
 517 )
 518
 519 # Check whether user wants TCP wrappers support
 520 TCPW_MSG="no"
 521 AC_ARG_WITH(tcp-wrappers,
 522         [  --with-tcp-wrappers[[=PATH]]      Enable tcpwrappers support
 523                             (optionally in PATH)],
 524         [
 525                 if test "x$withval" != "xno" ; then
 526                         saved_LIBS="$LIBS"
 527                         saved_LDFLAGS="$LDFLAGS"
 528                         saved_CPPFLAGS="$CPPFLAGS"
 529                         if test -n "${withval}" -a "${withval}" != "yes"; then
 530                                 if test -d "${withval}/lib"; then
 531                                         if test -n "${need_dash_r}"; then
 532                                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 533                                         else
 534                                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 535                                         fi
 536                                 else
 537                                         if test -n "${need_dash_r}"; then
 538                                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 539                                         else
 540                                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 541                                         fi
 542                                 fi
 543                                 if test -d "${withval}/include"; then
 544                                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 545                                 else
 546                                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 547                                 fi
 548                         fi
 549                         LIBS="-lwrap $LIBS"
 550                         AC_MSG_CHECKING(for libwrap)
 551                         AC_TRY_LINK(
 552                                 [
 553 #include <tcpd.h>
 554                                         int deny_severity = 0, allow_severity = 0;
 555                                 ],
 556                                 [hosts_access(0);],
 557                                 [
 558                                         AC_MSG_RESULT(yes)
 559                                         AC_DEFINE(LIBWRAP)
 560                                         TCPW_MSG="yes"
 561                                 ],
 562                                 [
 563                                         AC_MSG_ERROR([*** libwrap missing])
 564                                 ]
 565                         )
 566                 fi
 567         ]
 568 )
 569
 570 dnl    Checks for library functions.
 571 AC_CHECK_FUNCS(arc4random atexit b64_ntop bcopy bindresvport_sa \
 572         clock fchmod fchown freeaddrinfo futimes gai_strerror \
 573         getaddrinfo getcwd getgrouplist getnameinfo getopt \
 574         getrlimit getrusage getttyent glob inet_aton inet_ntoa \
 575         inet_ntop innetgr login_getcapbool md5_crypt memmove \
 576         mkdtemp on_exit openpty readpassphrase realpath \
 577         rresvport_af setdtablesize setegid setenv seteuid \
 578         setlogin setproctitle setresgid setreuid setrlimit \
 579         setsid setvbuf sigaction sigvec snprintf strerror \
 580         strlcat strlcpy strmode strsep sysconf tcgetpgrp utimes \
 581         vhangup vsnprintf waitpid __b64_ntop _getpty)
 582
 583 dnl IRIX and Solaris 2.5.1 have dirname() in libgen
 584 AC_CHECK_FUNCS(dirname, [AC_CHECK_HEADERS(libgen.h)] ,[
 585         AC_CHECK_LIB(gen, dirname,[
 586                 AC_CACHE_CHECK([for broken dirname],
 587                         ac_cv_have_broken_dirname, [
 588                         save_LIBS="$LIBS"
 589                         LIBS="$LIBS -lgen"
 590                         AC_TRY_RUN(
 591                                 [
 592 #include <libgen.h>
 593 #include <string.h>
 594
 595 int main(int argc, char **argv) {
 596     char *s, buf[32];
 597
 598     strncpy(buf,"/etc", 32);
 599     s = dirname(buf);
 600     if (!s || strncmp(s, "/", 32) != 0) {
 601         exit(1);
 602     } else {
 603         exit(0);
 604     }
 605 }
 606                                 ],
 607                                 [ ac_cv_have_broken_dirname="no" ],
 608                                 [ ac_cv_have_broken_dirname="yes" ]
 609                         )
 610                         LIBS="$save_LIBS"
 611                 ])
 612                 if test "x$ac_cv_have_broken_dirname" = "xno" ; then
 613                         LIBS="$LIBS -lgen"
 614                         AC_DEFINE(HAVE_DIRNAME)
 615                         AC_CHECK_HEADERS(libgen.h)
 616                 fi
 617         ])
 618 ])
 619
 620 dnl    Checks for time functions
 621 AC_CHECK_FUNCS(gettimeofday time)
 622 dnl    Checks for utmp functions
 623 AC_CHECK_FUNCS(endutent getutent getutid getutline pututline setutent)
 624 AC_CHECK_FUNCS(utmpname)
 625 dnl    Checks for utmpx functions
 626 AC_CHECK_FUNCS(endutxent getutxent getutxid getutxline pututxline )
 627 AC_CHECK_FUNCS(setutxent utmpxname)
 628
 629 AC_CHECK_FUNC(getuserattr,
 630         [AC_DEFINE(HAVE_GETUSERATTR)],
 631         [AC_CHECK_LIB(s, getuserattr, [LIBS="$LIBS -ls"; AC_DEFINE(HAVE_GETUSERATTR)])]
 632 )
 633
 634 AC_CHECK_FUNC(daemon,
 635         [AC_DEFINE(HAVE_DAEMON)],
 636         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 637 )
 638
 639 AC_CHECK_FUNC(getpagesize,
 640         [AC_DEFINE(HAVE_GETPAGESIZE)],
 641         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 642 )
 643
 644 # Check for broken snprintf
 645 if test "x$ac_cv_func_snprintf" = "xyes" ; then
 646         AC_MSG_CHECKING([whether snprintf correctly terminates long strings])
 647         AC_TRY_RUN(
 648                 [
 649 #include <stdio.h>
 650 int main(void){char b[5];snprintf(b,5,"123456789");return(b[4]!='\0');}
 651                 ],
 652                 [AC_MSG_RESULT(yes)],
 653                 [
 654                         AC_MSG_RESULT(no)
 655                         AC_DEFINE(BROKEN_SNPRINTF)
 656                         AC_MSG_WARN([****** Your snprintf() function is broken, complain to your vendor])
 657                 ]
 658         )
 659 fi
 660
 661 AC_FUNC_GETPGRP
 662
 663 # Check for PAM libs
 664 PAM_MSG="no"
 665 AC_ARG_WITH(pam,
 666         [  --with-pam              Enable PAM support ],
 667         [
 668                 if test "x$withval" != "xno" ; then
 669                         if test "x$ac_cv_header_security_pam_appl_h" != "xyes" ; then
 670                                 AC_MSG_ERROR([PAM headers not found])
 671                         fi
 672
 673                         AC_CHECK_LIB(dl, dlopen, , )
 674                         AC_CHECK_LIB(pam, pam_set_item, , AC_MSG_ERROR([*** libpam missing]))
 675                         AC_CHECK_FUNCS(pam_getenvlist)
 676
 677                         disable_shadow=yes
 678                         PAM_MSG="yes"
 679
 680                         AC_DEFINE(USE_PAM)
 681                 fi
 682         ]
 683 )
 684
 685 # Check for older PAM
 686 if test "x$PAM_MSG" = "xyes" ; then
 687         # Check PAM strerror arguments (old PAM)
 688         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 689         AC_TRY_COMPILE(
 690                 [
 691 #include <stdlib.h>
 692 #include <security/pam_appl.h>
 693                 ],
 694                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 695                 [AC_MSG_RESULT(no)],
 696                 [
 697                         AC_DEFINE(HAVE_OLD_PAM)
 698                         AC_MSG_RESULT(yes)
 699                         PAM_MSG="yes (old library)"
 700                 ]
 701         )
 702 fi
 703
 704 # The big search for OpenSSL
 705 AC_ARG_WITH(ssl-dir,
 706         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 707         [
 708                 if test "x$withval" != "xno" ; then
 709                         tryssldir=$withval
 710                 fi
 711         ]
 712 )
 713
 714 saved_LIBS="$LIBS"
 715 saved_LDFLAGS="$LDFLAGS"
 716 saved_CPPFLAGS="$CPPFLAGS"
 717 if test "x$prefix" != "xNONE" ; then
 718         tryssldir="$tryssldir $prefix"
 719 fi
 720 AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
 721         for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 722                 CPPFLAGS="$saved_CPPFLAGS"
 723                 LDFLAGS="$saved_LDFLAGS"
 724                 LIBS="$saved_LIBS -lcrypto"
 725
 726                 # Skip directories if they don't exist
 727                 if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 728                         continue;
 729                 fi
 730                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 731                         # Try to use $ssldir/lib if it exists, otherwise
 732                         # $ssldir
 733                         if test -d "$ssldir/lib" ; then
 734                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 735                                 if test ! -z "$need_dash_r" ; then
 736                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 737                                 fi
 738                         else
 739                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 740                                 if test ! -z "$need_dash_r" ; then
 741                                         LDFLAGS="-R$ssldir $LDFLAGS"
 742                                 fi
 743                         fi
 744                         # Try to use $ssldir/include if it exists, otherwise
 745                         # $ssldir
 746                         if test -d "$ssldir/include" ; then
 747                                 CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 748                         else
 749                                 CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 750                         fi
 751                 fi
 752
 753                 # Basic test to check for compatible version and correct linking
 754                 # *does not* test for RSA - that comes later.
 755                 AC_TRY_RUN(
 756                         [
 757 #include <string.h>
 758 #include <openssl/rand.h>
 759 int main(void)
 760 {
 761         char a[2048];
 762         memset(a, 0, sizeof(a));
 763         RAND_add(a, sizeof(a), sizeof(a));
 764         return(RAND_status() <= 0);
 765 }
 766                         ],
 767                         [
 768                                 found_crypto=1
 769                                 break;
 770                         ], []
 771                 )
 772
 773                 if test ! -z "$found_crypto" ; then
 774                         break;
 775                 fi
 776         done
 777
 778         if test -z "$found_crypto" ; then
 779                 AC_MSG_ERROR([Could not find working OpenSSL library, please install or check config.log])
 780         fi
 781         if test -z "$ssldir" ; then
 782                 ssldir="(system)"
 783         fi
 784
 785         ac_cv_openssldir=$ssldir
 786 ])
 787
 788 if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ; then
 789         AC_DEFINE(HAVE_OPENSSL)
 790         dnl Need to recover ssldir - test above runs in subshell
 791         ssldir=$ac_cv_openssldir
 792         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 793                 # Try to use $ssldir/lib if it exists, otherwise
 794                 # $ssldir
 795                 if test -d "$ssldir/lib" ; then
 796                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 797                         if test ! -z "$need_dash_r" ; then
 798                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 799                         fi
 800                 else
 801                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 802                         if test ! -z "$need_dash_r" ; then
 803                                 LDFLAGS="-R$ssldir $LDFLAGS"
 804                         fi
 805                 fi
 806                 # Try to use $ssldir/include if it exists, otherwise
 807                 # $ssldir
 808                 if test -d "$ssldir/include" ; then
 809                         CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
 810                 else
 811                         CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
 812                 fi
 813         fi
 814 fi
 815 LIBS="$saved_LIBS -lcrypto"
 816
 817 # Now test RSA support
 818 saved_LIBS="$LIBS"
 819 AC_MSG_CHECKING([for RSA support])
 820 for WANTS_RSAREF in "" 1 ; do
 821         if test -z "$WANTS_RSAREF" ; then
 822                 LIBS="$saved_LIBS"
 823         else
 824                 LIBS="$saved_LIBS -lRSAglue -lrsaref"
 825         fi
 826         AC_TRY_RUN([
 827 #include <string.h>
 828 #include <openssl/rand.h>
 829 #include <openssl/rsa.h>
 830 #include <openssl/bn.h>
 831 #include <openssl/sha.h>
 832 int main(void)
 833 {
 834         int num; RSA *key; static unsigned char p_in[] = "blahblah";
 835         unsigned char c[256], p[256];
 836         memset(c, 0, sizeof(c)); RAND_add(c, sizeof(c), sizeof(c));
 837         if ((key=RSA_generate_key(512, 3, NULL, NULL))==NULL) return(1);
 838         num = RSA_public_encrypt(sizeof(p_in) - 1, p_in, c, key, RSA_PKCS1_PADDING);
 839         return(-1 == RSA_private_decrypt(num, c, p, key, RSA_PKCS1_PADDING));
 840 }
 841         ],
 842         [
 843                 rsa_works=1
 844                 break;
 845         ], [])
 846 done
 847 LIBS="$saved_LIBS"
 848
 849 if test ! -z "$no_rsa" ; then
 850         AC_MSG_RESULT(disabled)
 851         RSA_MSG="disabled"
 852 else
 853         if test -z "$rsa_works" ; then
 854                 AC_MSG_WARN([*** No RSA support found *** ])
 855                 RSA_MSG="no"
 856         else
 857                 if test -z "$WANTS_RSAREF" ; then
 858                         AC_MSG_RESULT(yes)
 859                         RSA_MSG="yes"
 860                 else
 861                         RSA_MSG="yes (using RSAref)"
 862                         AC_MSG_RESULT(using RSAref)
 863                         LIBS="$LIBS -lcrypto -lRSAglue -lrsaref"
 864                 fi
 865         fi
 866 fi
 867
 868 # Some Linux systems (Slackware) need crypt() from libcrypt, *not* the
 869 # version in OpenSSL. Skip this for PAM
 870 if test "x$PAM_MSG" = "xno" -a "x$check_for_libcrypt_later" = "x1"; then
 871         AC_CHECK_LIB(crypt, crypt, LIBS="$LIBS -lcrypt")
 872 fi
 873
 874 # Cheap hack to ensure NEWS-OS libraries are arranged right.
 875 if test ! -z "$SONY" ; then
 876   LIBS="$LIBS -liberty";
 877 fi
 878
 879 # Checks for data types
 880 AC_CHECK_SIZEOF(char, 1)
 881 AC_CHECK_SIZEOF(short int, 2)
 882 AC_CHECK_SIZEOF(int, 4)
 883 AC_CHECK_SIZEOF(long int, 4)
 884 AC_CHECK_SIZEOF(long long int, 8)
 885
 886 # More checks for data types
 887 AC_CACHE_CHECK([for u_int type], ac_cv_have_u_int, [
 888         AC_TRY_COMPILE(
 889                 [ #include <sys/types.h> ],
 890                 [ u_int a; a = 1;],
 891                 [ ac_cv_have_u_int="yes" ],
 892                 [ ac_cv_have_u_int="no" ]
 893         )
 894 ])
 895 if test "x$ac_cv_have_u_int" = "xyes" ; then
 896         AC_DEFINE(HAVE_U_INT)
 897         have_u_int=1
 898 fi
 899
 900 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
 901         AC_TRY_COMPILE(
 902                 [ #include <sys/types.h> ],
 903                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
 904                 [ ac_cv_have_intxx_t="yes" ],
 905                 [ ac_cv_have_intxx_t="no" ]
 906         )
 907 ])
 908 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
 909         AC_DEFINE(HAVE_INTXX_T)
 910         have_intxx_t=1
 911 fi
 912
 913 if (test -z "$have_intxx_t" && \
 914            test "x$ac_cv_header_stdint_h" = "xyes")
 915 then
 916     AC_MSG_CHECKING([for intXX_t types in stdint.h])
 917         AC_TRY_COMPILE(
 918                 [ #include <stdint.h> ],
 919                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
 920                 [
 921                         AC_DEFINE(HAVE_INTXX_T)
 922                         AC_MSG_RESULT(yes)
 923                 ],
 924                 [ AC_MSG_RESULT(no) ]
 925         )
 926 fi
 927
 928 AC_CACHE_CHECK([for int64_t type], ac_cv_have_int64_t, [
 929         AC_TRY_COMPILE(
 930                 [ #include <sys/types.h> ],
 931                 [ int64_t a; a = 1;],
 932                 [ ac_cv_have_int64_t="yes" ],
 933                 [ ac_cv_have_int64_t="no" ]
 934         )
 935 ])
 936 if test "x$ac_cv_have_int64_t" = "xyes" ; then
 937         AC_DEFINE(HAVE_INT64_T)
 938         have_int64_t=1
 939 fi
 940
 941 if test -z "$have_int64_t" ; then
 942     AC_MSG_CHECKING([for int64_t type in sys/socket.h])
 943         AC_TRY_COMPILE(
 944                 [ #include <sys/socket.h> ],
 945                 [ int64_t a; a = 1],
 946                 [
 947                         AC_DEFINE(HAVE_INT64_T)
 948                         AC_MSG_RESULT(yes)
 949                 ],
 950                 [ AC_MSG_RESULT(no) ]
 951         )
 952 fi
 953
 954 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
 955         AC_TRY_COMPILE(
 956                 [ #include <sys/types.h> ],
 957                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
 958                 [ ac_cv_have_u_intxx_t="yes" ],
 959                 [ ac_cv_have_u_intxx_t="no" ]
 960         )
 961 ])
 962 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
 963         AC_DEFINE(HAVE_U_INTXX_T)
 964         have_u_intxx_t=1
 965 fi
 966
 967 if test -z "$have_u_intxx_t" ; then
 968     AC_MSG_CHECKING([for u_intXX_t types in sys/socket.h])
 969         AC_TRY_COMPILE(
 970                 [ #include <sys/socket.h> ],
 971                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
 972                 [
 973                         AC_DEFINE(HAVE_U_INTXX_T)
 974                         AC_MSG_RESULT(yes)
 975                 ],
 976                 [ AC_MSG_RESULT(no) ]
 977         )
 978 fi
 979
 980 AC_CACHE_CHECK([for u_int64_t types], ac_cv_have_u_int64_t, [
 981         AC_TRY_COMPILE(
 982                 [ #include <sys/types.h> ],
 983                 [ u_int64_t a; a = 1;],
 984                 [ ac_cv_have_u_int64_t="yes" ],
 985                 [ ac_cv_have_u_int64_t="no" ]
 986         )
 987 ])
 988 if test "x$ac_cv_have_u_int64_t" = "xyes" ; then
 989         AC_DEFINE(HAVE_U_INT64_T)
 990         have_u_int64_t=1
 991 fi
 992
 993 if test -z "$have_u_intxx_t" ; then
 994         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
 995                 AC_TRY_COMPILE(
 996                         [
 997 #include <sys/types.h>
 998                         ],
 999                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
1000                         [ ac_cv_have_uintxx_t="yes" ],
1001                         [ ac_cv_have_uintxx_t="no" ]
1002                 )
1003         ])
1004         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
1005                 AC_DEFINE(HAVE_UINTXX_T)
1006         fi
1007 fi
1008
1009 if test -z "$have_uintxx_t" ; then
1010     AC_MSG_CHECKING([for uintXX_t types in stdint.h])
1011         AC_TRY_COMPILE(
1012                 [ #include <stdint.h> ],
1013                 [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1;],
1014                 [
1015                         AC_DEFINE(HAVE_UINTXX_T)
1016                         AC_MSG_RESULT(yes)
1017                 ],
1018                 [ AC_MSG_RESULT(no) ]
1019         )
1020 fi
1021
1022 if (test -z "$have_u_intxx_t" || test -z "$have_intxx_t" && \
1023            test "x$ac_cv_header_sys_bitypes_h" = "xyes")
1024 then
1025         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
1026         AC_TRY_COMPILE(
1027                 [
1028 #include <sys/bitypes.h>
1029                 ],
1030                 [
1031                         int8_t a; int16_t b; int32_t c;
1032                         u_int8_t e; u_int16_t f; u_int32_t g;
1033                         a = b = c = e = f = g = 1;
1034                 ],
1035                 [
1036                         AC_DEFINE(HAVE_U_INTXX_T)
1037                         AC_DEFINE(HAVE_INTXX_T)
1038                         AC_MSG_RESULT(yes)
1039                 ],
1040                 [AC_MSG_RESULT(no)]
1041         )
1042 fi
1043
1044
1045 AC_CACHE_CHECK([for u_char], ac_cv_have_u_char, [
1046         AC_TRY_COMPILE(
1047                 [
1048 #include <sys/types.h>
1049                 ],
1050                 [ u_char foo; foo = 125; ],
1051                 [ ac_cv_have_u_char="yes" ],
1052                 [ ac_cv_have_u_char="no" ]
1053         )
1054 ])
1055 if test "x$ac_cv_have_u_char" = "xyes" ; then
1056         AC_DEFINE(HAVE_U_CHAR)
1057 fi
1058
1059 TYPE_SOCKLEN_T
1060
1061 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
1062         AC_TRY_COMPILE(
1063                 [
1064 #include <sys/types.h>
1065                 ],
1066                 [ size_t foo; foo = 1235; ],
1067                 [ ac_cv_have_size_t="yes" ],
1068                 [ ac_cv_have_size_t="no" ]
1069         )
1070 ])
1071 if test "x$ac_cv_have_size_t" = "xyes" ; then
1072         AC_DEFINE(HAVE_SIZE_T)
1073 fi
1074
1075 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
1076         AC_TRY_COMPILE(
1077                 [
1078 #include <sys/types.h>
1079                 ],
1080                 [ ssize_t foo; foo = 1235; ],
1081                 [ ac_cv_have_ssize_t="yes" ],
1082                 [ ac_cv_have_ssize_t="no" ]
1083         )
1084 ])
1085 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
1086         AC_DEFINE(HAVE_SSIZE_T)
1087 fi
1088
1089 AC_CACHE_CHECK([for clock_t], ac_cv_have_clock_t, [
1090         AC_TRY_COMPILE(
1091                 [
1092 #include <time.h>
1093                 ],
1094                 [ clock_t foo; foo = 1235; ],
1095                 [ ac_cv_have_clock_t="yes" ],
1096                 [ ac_cv_have_clock_t="no" ]
1097         )
1098 ])
1099 if test "x$ac_cv_have_clock_t" = "xyes" ; then
1100         AC_DEFINE(HAVE_CLOCK_T)
1101 fi
1102
1103 AC_CACHE_CHECK([for sa_family_t], ac_cv_have_sa_family_t, [
1104         AC_TRY_COMPILE(
1105                 [
1106 #include <sys/types.h>
1107 #include <sys/socket.h>
1108                 ],
1109                 [ sa_family_t foo; foo = 1235; ],
1110                 [ ac_cv_have_sa_family_t="yes" ],
1111                 [ AC_TRY_COMPILE(
1112                   [
1113 #include <sys/types.h>
1114 #include <sys/socket.h>
1115 #include <netinet/in.h>
1116                 ],
1117                 [ sa_family_t foo; foo = 1235; ],
1118                 [ ac_cv_have_sa_family_t="yes" ],
1119
1120                 [ ac_cv_have_sa_family_t="no" ]
1121         )]
1122         )
1123 ])
1124 if test "x$ac_cv_have_sa_family_t" = "xyes" ; then
1125         AC_DEFINE(HAVE_SA_FAMILY_T)
1126 fi
1127
1128 AC_CACHE_CHECK([for pid_t], ac_cv_have_pid_t, [
1129         AC_TRY_COMPILE(
1130                 [
1131 #include <sys/types.h>
1132                 ],
1133                 [ pid_t foo; foo = 1235; ],
1134                 [ ac_cv_have_pid_t="yes" ],
1135                 [ ac_cv_have_pid_t="no" ]
1136         )
1137 ])
1138 if test "x$ac_cv_have_pid_t" = "xyes" ; then
1139         AC_DEFINE(HAVE_PID_T)
1140 fi
1141
1142 AC_CACHE_CHECK([for mode_t], ac_cv_have_mode_t, [
1143         AC_TRY_COMPILE(
1144                 [
1145 #include <sys/types.h>
1146                 ],
1147                 [ mode_t foo; foo = 1235; ],
1148                 [ ac_cv_have_mode_t="yes" ],
1149                 [ ac_cv_have_mode_t="no" ]
1150         )
1151 ])
1152 if test "x$ac_cv_have_mode_t" = "xyes" ; then
1153         AC_DEFINE(HAVE_MODE_T)
1154 fi
1155
1156
1157 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
1158         AC_TRY_COMPILE(
1159                 [
1160 #include <sys/types.h>
1161 #include <sys/socket.h>
1162                 ],
1163                 [ struct sockaddr_storage s; ],
1164                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
1165                 [ ac_cv_have_struct_sockaddr_storage="no" ]
1166         )
1167 ])
1168 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
1169         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
1170 fi
1171
1172 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
1173         AC_TRY_COMPILE(
1174                 [
1175 #include <sys/types.h>
1176 #include <netinet/in.h>
1177                 ],
1178                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
1179                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
1180                 [ ac_cv_have_struct_sockaddr_in6="no" ]
1181         )
1182 ])
1183 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
1184         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
1185 fi
1186
1187 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
1188         AC_TRY_COMPILE(
1189                 [
1190 #include <sys/types.h>
1191 #include <netinet/in.h>
1192                 ],
1193                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
1194                 [ ac_cv_have_struct_in6_addr="yes" ],
1195                 [ ac_cv_have_struct_in6_addr="no" ]
1196         )
1197 ])
1198 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
1199         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
1200 fi
1201
1202 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
1203         AC_TRY_COMPILE(
1204                 [
1205 #include <sys/types.h>
1206 #include <sys/socket.h>
1207 #include <netdb.h>
1208                 ],
1209                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
1210                 [ ac_cv_have_struct_addrinfo="yes" ],
1211                 [ ac_cv_have_struct_addrinfo="no" ]
1212         )
1213 ])
1214 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
1215         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
1216 fi
1217
1218 AC_CACHE_CHECK([for struct timeval], ac_cv_have_struct_timeval, [
1219         AC_TRY_COMPILE(
1220                 [ #include <sys/time.h> ],
1221                 [ struct timeval tv; tv.tv_sec = 1;],
1222                 [ ac_cv_have_struct_timeval="yes" ],
1223                 [ ac_cv_have_struct_timeval="no" ]
1224         )
1225 ])
1226 if test "x$ac_cv_have_struct_timeval" = "xyes" ; then
1227         AC_DEFINE(HAVE_STRUCT_TIMEVAL)
1228         have_struct_timeval=1
1229 fi
1230
1231 # If we don't have int64_t then we can't compile sftp-server.  So don't
1232 # even attempt to do it.
1233 if test "x$ac_cv_have_int64_t" = "xno" -a \
1234         "x$ac_cv_sizeof_long_int" != "x8" -a \
1235         "x$ac_cv_sizeof_long_long_int" = "x0" ; then
1236         NO_SFTP='#'
1237 else
1238 dnl test snprintf (broken on SCO w/gcc)
1239         AC_TRY_RUN(
1240                 [
1241 #include <stdio.h>
1242 #include <string.h>
1243 #ifdef HAVE_SNPRINTF
1244 main()
1245 {
1246         char buf[50];
1247         char expected_out[50];
1248         int mazsize = 50 ;
1249 #if (SIZEOF_LONG_INT == 8)
1250         long int num = 0x7fffffffffffffff;
1251 #else
1252         long long num = 0x7fffffffffffffffll;
1253 #endif
1254         strcpy(expected_out, "9223372036854775807");
1255         snprintf(buf, mazsize, "%lld", num);
1256         if(strcmp(buf, expected_out) != 0)
1257                 exit(1);
1258         exit(0);
1259 }
1260 #else
1261 main() { exit(0); }
1262 #endif
1263                 ], [ true ], [ AC_DEFINE(BROKEN_SNPRINTF) ]
1264         )
1265 fi
1266 AC_SUBST(NO_SFTP)
1267
1268 dnl Checks for structure members
1269 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
1270 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
1271 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
1272 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
1273 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
1274 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
1275 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
1276 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
1277 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmpx.h, HAVE_ID_IN_UTMPX)
1278 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
1279 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
1280 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
1281 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
1282 OSSH_CHECK_HEADER_FOR_FIELD(ut_exit, utmp.h, HAVE_EXIT_IN_UTMP)
1283 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmp.h, HAVE_TIME_IN_UTMP)
1284 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmpx.h, HAVE_TIME_IN_UTMPX)
1285 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmpx.h, HAVE_TV_IN_UTMPX)
1286
1287 AC_CHECK_MEMBERS([struct stat.st_blksize])
1288
1289 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
1290                 ac_cv_have_ss_family_in_struct_ss, [
1291         AC_TRY_COMPILE(
1292                 [
1293 #include <sys/types.h>
1294 #include <sys/socket.h>
1295                 ],
1296                 [ struct sockaddr_storage s; s.ss_family = 1; ],
1297                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
1298                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
1299         )
1300 ])
1301 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
1302         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
1303 fi
1304
1305 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
1306                 ac_cv_have___ss_family_in_struct_ss, [
1307         AC_TRY_COMPILE(
1308                 [
1309 #include <sys/types.h>
1310 #include <sys/socket.h>
1311                 ],
1312                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
1313                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
1314                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
1315         )
1316 ])
1317 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
1318         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
1319 fi
1320
1321 AC_CACHE_CHECK([for pw_class field in struct passwd],
1322                 ac_cv_have_pw_class_in_struct_passwd, [
1323         AC_TRY_COMPILE(
1324                 [
1325 #include <pwd.h>
1326                 ],
1327                 [ struct passwd p; p.pw_class = 0; ],
1328                 [ ac_cv_have_pw_class_in_struct_passwd="yes" ],
1329                 [ ac_cv_have_pw_class_in_struct_passwd="no" ]
1330         )
1331 ])
1332 if test "x$ac_cv_have_pw_class_in_struct_passwd" = "xyes" ; then
1333         AC_DEFINE(HAVE_PW_CLASS_IN_PASSWD)
1334 fi
1335
1336 AC_CACHE_CHECK([for pw_expire field in struct passwd],
1337                 ac_cv_have_pw_expire_in_struct_passwd, [
1338         AC_TRY_COMPILE(
1339                 [
1340 #include <pwd.h>
1341                 ],
1342                 [ struct passwd p; p.pw_expire = 0; ],
1343                 [ ac_cv_have_pw_expire_in_struct_passwd="yes" ],
1344                 [ ac_cv_have_pw_expire_in_struct_passwd="no" ]
1345         )
1346 ])
1347 if test "x$ac_cv_have_pw_expire_in_struct_passwd" = "xyes" ; then
1348         AC_DEFINE(HAVE_PW_EXPIRE_IN_PASSWD)
1349 fi
1350
1351 AC_CACHE_CHECK([for pw_change field in struct passwd],
1352                 ac_cv_have_pw_change_in_struct_passwd, [
1353         AC_TRY_COMPILE(
1354                 [
1355 #include <pwd.h>
1356                 ],
1357                 [ struct passwd p; p.pw_change = 0; ],
1358                 [ ac_cv_have_pw_change_in_struct_passwd="yes" ],
1359                 [ ac_cv_have_pw_change_in_struct_passwd="no" ]
1360         )
1361 ])
1362 if test "x$ac_cv_have_pw_change_in_struct_passwd" = "xyes" ; then
1363         AC_DEFINE(HAVE_PW_CHANGE_IN_PASSWD)
1364 fi
1365
1366 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
1367         AC_TRY_LINK([],
1368                 [ extern char *__progname; printf("%s", __progname); ],
1369                 [ ac_cv_libc_defines___progname="yes" ],
1370                 [ ac_cv_libc_defines___progname="no" ]
1371         )
1372 ])
1373 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
1374         AC_DEFINE(HAVE___PROGNAME)
1375 fi
1376
1377 AC_CACHE_CHECK([whether getopt has optreset support],
1378                 ac_cv_have_getopt_optreset, [
1379         AC_TRY_LINK(
1380                 [
1381 #include <getopt.h>
1382                 ],
1383                 [ extern int optreset; optreset = 0; ],
1384                 [ ac_cv_have_getopt_optreset="yes" ],
1385                 [ ac_cv_have_getopt_optreset="no" ]
1386         )
1387 ])
1388 if test "x$ac_cv_have_getopt_optreset" = "xyes" ; then
1389         AC_DEFINE(HAVE_GETOPT_OPTRESET)
1390 fi
1391
1392 AC_CACHE_CHECK([if libc defines sys_errlist], ac_cv_libc_defines_sys_errlist, [
1393         AC_TRY_LINK([],
1394                 [ extern const char *const sys_errlist[]; printf("%s", sys_errlist[0]);],
1395                 [ ac_cv_libc_defines_sys_errlist="yes" ],
1396                 [ ac_cv_libc_defines_sys_errlist="no" ]
1397         )
1398 ])
1399 if test "x$ac_cv_libc_defines_sys_errlist" = "xyes" ; then
1400         AC_DEFINE(HAVE_SYS_ERRLIST)
1401 fi
1402
1403
1404 AC_CACHE_CHECK([if libc defines sys_nerr], ac_cv_libc_defines_sys_nerr, [
1405         AC_TRY_LINK([],
1406                 [ extern int sys_nerr; printf("%i", sys_nerr);],
1407                 [ ac_cv_libc_defines_sys_nerr="yes" ],
1408                 [ ac_cv_libc_defines_sys_nerr="no" ]
1409         )
1410 ])
1411 if test "x$ac_cv_libc_defines_sys_nerr" = "xyes" ; then
1412         AC_DEFINE(HAVE_SYS_NERR)
1413 fi
1414
1415
1416 # Check whether user wants Kerberos support
1417 SCARD_MSG="no"
1418 AC_ARG_WITH(smartcard,
1419         [  --with-smartcard        Enable smartcard support],
1420         [
1421                 if test "x$withval" != "xno" ; then
1422                         if test "x$withval" != "xyes" ; then
1423                                 CPPFLAGS="$CPPFLAGS -I${withval}"
1424                                 LDFLAGS="$LDFLAGS -L${withval}"
1425                                 if test ! -z "$need_dash_r" ; then
1426                                         LDFLAGS="$LDFLAGS -R${withval}"
1427                                 fi
1428                                 if test ! -z "$blibpath" ; then
1429                                         blibpath="$blibpath:${withval}"
1430                                 fi
1431                         fi
1432                         AC_CHECK_HEADERS(sectok.h)
1433                         if test "$ac_cv_header_sectok_h" != yes; then
1434                                 AC_MSG_ERROR(Can't find sectok.h)
1435                         fi
1436                         AC_CHECK_LIB(sectok, sectok_open)
1437                         if test "$ac_cv_lib_sectok_sectok_open" != yes; then
1438                                 AC_MSG_ERROR(Can't find libsectok)
1439                         fi
1440                         AC_DEFINE(SMARTCARD)
1441                         SCARD_MSG="yes"
1442                 fi
1443         ]
1444 )
1445
1446 # Check whether user wants Kerberos 5 support
1447 AC_ARG_WITH(kerberos5,
1448         [  --with-kerberos5=PATH   Enable Kerberos 5 support],
1449         [
1450                 if test "x$withval" != "xno" ; then
1451                         if test "x$withval" = "xyes" ; then
1452                                 KRB5ROOT="/usr/local"
1453                         else
1454                                 KRB5ROOT=${withval}
1455                         fi
1456                         CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include"
1457                         LDFLAGS="$LDFLAGS -L${KRB5ROOT}/lib"
1458                         AC_DEFINE(KRB5)
1459                         AC_MSG_CHECKING(whether we are using Heimdal)
1460                         AC_TRY_COMPILE([ #include <krb5.h> ],
1461                                        [ char *tmp = heimdal_version; ],
1462                                        [ AC_MSG_RESULT(yes)
1463                                          AC_DEFINE(HEIMDAL)
1464                                          K5LIBS="-lkrb5 -ldes -lcom_err -lasn1 -lroken"
1465                                        ],
1466                                        [ AC_MSG_RESULT(no)
1467                                          K5LIBS="-lkrb5 -lk5crypto -lcom_err"
1468                                        ]
1469                         )
1470                         if test ! -z "$need_dash_r" ; then
1471                                 LDFLAGS="$LDFLAGS -R${KRB5ROOT}/lib"
1472                         fi
1473                         if test ! -z "$blibpath" ; then
1474                                 blibpath="$blibpath:${KRB5ROOT}/lib"
1475                         fi
1476                         AC_CHECK_LIB(resolv, dn_expand, , )
1477
1478                         KRB5=yes
1479                 fi
1480         ]
1481 )
1482 # Check whether user wants Kerberos 4 support
1483 KRB4_MSG="no"
1484 AC_ARG_WITH(kerberos4,
1485         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
1486         [
1487                 if test "x$withval" != "xno" ; then
1488                         if test "x$withval" != "xyes" ; then
1489                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1490                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1491                                 if test ! -z "$need_dash_r" ; then
1492                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
1493                                 fi
1494                                 if test ! -z "$blibpath" ; then
1495                                         blibpath="$blibpath:${withval}/lib"
1496                                 fi
1497                         else
1498                                 if test -d /usr/include/kerberosIV ; then
1499                                         CPPFLAGS="$CPPFLAGS -I/usr/include/kerberosIV"
1500                                 fi
1501                         fi
1502
1503                         AC_CHECK_HEADERS(krb.h)
1504                         if test "$ac_cv_header_krb_h" != yes; then
1505                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
1506                         fi
1507                         AC_CHECK_LIB(krb, main)
1508                         if test "$ac_cv_lib_krb_main" != yes; then
1509                                 AC_CHECK_LIB(krb4, main)
1510                                 if test "$ac_cv_lib_krb4_main" != yes; then
1511                                         AC_MSG_WARN([Cannot find libkrb nor libkrb4, build may fail])
1512                                 else
1513                                         KLIBS="-lkrb4"
1514                                 fi
1515                         else
1516                                 KLIBS="-lkrb"
1517                         fi
1518                         AC_CHECK_LIB(des, des_cbc_encrypt)
1519                         if test "$ac_cv_lib_des_des_cbc_encrypt" != yes; then
1520                                 AC_CHECK_LIB(des425, des_cbc_encrypt)
1521                                 if test "$ac_cv_lib_des425_des_cbc_encrypt" != yes; then
1522                                         AC_MSG_WARN([Cannot find libdes nor libdes425, build may fail])
1523                                 else
1524                                         KLIBS="-ldes425"
1525                                 fi
1526                         else
1527                                 KLIBS="-ldes"
1528                         fi
1529                         AC_CHECK_LIB(resolv, dn_expand, , )
1530                         KRB4=yes
1531                         KRB4_MSG="yes"
1532                         AC_DEFINE(KRB4)
1533                 fi
1534         ]
1535 )
1536
1537 # Check whether user wants AFS support
1538 AFS_MSG="no"
1539 AC_ARG_WITH(afs,
1540         [  --with-afs=PATH         Enable AFS support],
1541         [
1542                 if test "x$withval" != "xno" ; then
1543
1544                         if test "x$withval" != "xyes" ; then
1545                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
1546                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
1547                         fi
1548
1549                         if test -z "$KRB4" ; then
1550                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
1551                         fi
1552
1553                         LIBS="-lkafs $LIBS"
1554                         if test ! -z "$AFS_LIBS" ; then
1555                                 LIBS="$LIBS $AFS_LIBS"
1556                         fi
1557                         AC_DEFINE(AFS)
1558                         AFS_MSG="yes"
1559                 fi
1560         ]
1561 )
1562 LIBS="$LIBS $KLIBS $K5LIBS"
1563
1564 # Looking for programs, paths and files
1565 AC_ARG_WITH(rsh,
1566         [  --with-rsh=PATH         Specify path to remote shell program ],
1567         [
1568                 if test "x$withval" != "$no" ; then
1569                         rsh_path=$withval
1570                 fi
1571         ],
1572         [
1573                 AC_PATH_PROG(rsh_path, rsh)
1574         ]
1575 )
1576
1577 AC_ARG_WITH(xauth,
1578         [  --with-xauth=PATH       Specify path to xauth program ],
1579         [
1580                 if test "x$withval" != "xno" ; then
1581                         xauth_path=$withval
1582                 fi
1583         ],
1584         [
1585                 AC_PATH_PROG(xauth_path, xauth,,$PATH:/usr/X/bin:/usr/bin/X11:/usr/X11R6/bin:/usr/openwin/bin)
1586                 if (test ! -z "$xauth_path" && test -x "/usr/openwin/bin/xauth") ; then
1587                         xauth_path="/usr/openwin/bin/xauth"
1588                 fi
1589         ]
1590 )
1591
1592 if test -z "$xauth_path" ; then
1593         XAUTH_PATH="undefined"
1594         AC_SUBST(XAUTH_PATH)
1595 else
1596         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
1597         XAUTH_PATH=$xauth_path
1598         AC_SUBST(XAUTH_PATH)
1599 fi
1600 if test ! -z "$rsh_path" ; then
1601         AC_DEFINE_UNQUOTED(RSH_PATH, "$rsh_path")
1602 fi
1603
1604 # Check for mail directory (last resort if we cannot get it from headers)
1605 if test ! -z "$MAIL" ; then
1606         maildir=`dirname $MAIL`
1607         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
1608 fi
1609
1610 if test -z "$no_dev_ptmx" ; then
1611         AC_CHECK_FILE("/dev/ptmx",
1612                 [
1613                         AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
1614                         have_dev_ptmx=1
1615                 ]
1616         )
1617 fi
1618 AC_CHECK_FILE("/dev/ptc",
1619         [
1620                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
1621                 have_dev_ptc=1
1622         ]
1623 )
1624
1625 # Options from here on. Some of these are preset by platform above
1626
1627 # Check for user-specified random device, otherwise check /dev/urandom
1628 AC_ARG_WITH(random,
1629         [  --with-random=FILE      read entropy from FILE (default=/dev/urandom)],
1630         [
1631                 if test "x$withval" != "xno" ; then
1632                         RANDOM_POOL="$withval";
1633                         AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
1634                 fi
1635         ],
1636         [
1637                 # Check for random device
1638                 AC_CHECK_FILE("/dev/urandom",
1639                         [
1640                                 RANDOM_POOL="/dev/urandom";
1641                                 AC_SUBST(RANDOM_POOL)
1642                                 AC_DEFINE_UNQUOTED(RANDOM_POOL, "$RANDOM_POOL")
1643                         ]
1644                 )
1645         ]
1646 )
1647
1648 # Check for PRNGD/EGD pool file
1649 AC_ARG_WITH(prngd-port,
1650         [  --with-prngd-port=PORT  read entropy from PRNGD/EGD localhost:PORT],
1651         [
1652                 if test ! -z "$withval" -a "x$withval" != "xno" ; then
1653                         PRNGD_PORT="$withval"
1654                         AC_DEFINE_UNQUOTED(PRNGD_PORT, $PRNGD_PORT)
1655                 fi
1656         ]
1657 )
1658
1659 # Check for PRNGD/EGD pool file
1660 AC_ARG_WITH(prngd-socket,
1661         [  --with-prngd-socket=FILE read entropy from PRNGD/EGD socket FILE (default=/var/run/egd-pool)],
1662         [
1663                 if test "x$withval" != "xno" ; then
1664                         PRNGD_SOCKET="$withval"
1665                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1666                 fi
1667         ],
1668         [
1669                 # Check for existing socket only if we don't have a random device already
1670                 if test -z "$RANDOM_POOL" ; then
1671                         AC_MSG_CHECKING(for PRNGD/EGD socket)
1672                         # Insert other locations here
1673                         for sock in /var/run/egd-pool /dev/egd-pool /etc/entropy; do
1674                                 if test -r $sock && $TEST_MINUS_S_SH -c "test -S $sock -o -p $sock" ; then
1675                                         PRNGD_SOCKET="$sock"
1676                                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1677                                         break;
1678                                 fi
1679                         done
1680                         if test ! -z "$PRNGD_SOCKET" ; then
1681                                 AC_MSG_RESULT($PRNGD_SOCKET)
1682                         else
1683                                 AC_MSG_RESULT(not found)
1684                         fi
1685                 fi
1686         ]
1687 )
1688
1689
1690 # detect pathnames for entropy gathering commands, if we need them
1691 INSTALL_SSH_PRNG_CMDS=""
1692 rm -f prng_commands
1693 if (test -z "$RANDOM_POOL" && test -z "$PRNGD") ; then
1694         # Use these commands to collect entropy
1695         OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1696         OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
1697         OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
1698         OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
1699         OSSH_PATH_ENTROPY_PROG(PROG_JSTAT, jstat)
1700         OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
1701         OSSH_PATH_ENTROPY_PROG(PROG_SAR, sar)
1702         OSSH_PATH_ENTROPY_PROG(PROG_W, w)
1703         OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
1704         OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
1705         OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
1706         OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
1707         OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
1708         OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
1709         OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
1710         OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
1711
1712         INSTALL_SSH_PRNG_CMDS="yes"
1713 fi
1714 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
1715
1716
1717 AC_ARG_WITH(mantype,
1718         [  --with-mantype=man|cat|doc  Set man page type],
1719         [
1720                 case "$withval" in
1721                 man|cat|doc)
1722                         MANTYPE=$withval
1723                         ;;
1724                 *)
1725                         AC_MSG_ERROR(invalid man type: $withval)
1726                         ;;
1727                 esac
1728         ]
1729 )
1730 if test -z "$MANTYPE"; then
1731         AC_PATH_PROGS(NROFF, nroff awf, /bin/false, /usr/bin:/usr/ucb)
1732         if ${NROFF} -mdoc ${srcdir}/ssh.1 >/dev/null 2>&1; then
1733                 MANTYPE=doc
1734         elif ${NROFF} -man ${srcdir}/ssh.1 >/dev/null 2>&1; then
1735                 MANTYPE=man
1736         else
1737                 MANTYPE=cat
1738         fi
1739 fi
1740 AC_SUBST(MANTYPE)
1741 if test "$MANTYPE" = "doc"; then
1742         mansubdir=man;
1743 else
1744         mansubdir=$MANTYPE;
1745 fi
1746 AC_SUBST(mansubdir)
1747
1748 # Check whether to enable MD5 passwords
1749 MD5_MSG="no"
1750 AC_ARG_WITH(md5-passwords,
1751         [  --with-md5-passwords    Enable use of MD5 passwords],
1752         [
1753                 if test "x$withval" != "xno" ; then
1754                         AC_DEFINE(HAVE_MD5_PASSWORDS)
1755                         MD5_MSG="yes"
1756                 fi
1757         ]
1758 )
1759
1760 # Whether to disable shadow password support
1761 AC_ARG_WITH(shadow,
1762         [  --without-shadow        Disable shadow password support],
1763         [
1764                 if test "x$withval" = "xno" ; then
1765                         AC_DEFINE(DISABLE_SHADOW)
1766                         disable_shadow=yes
1767                 fi
1768         ]
1769 )
1770
1771 if test -z "$disable_shadow" ; then
1772         AC_MSG_CHECKING([if the systems has expire shadow information])
1773         AC_TRY_COMPILE(
1774         [
1775 #include <sys/types.h>
1776 #include <shadow.h>
1777         struct spwd sp;
1778         ],[ sp.sp_expire = sp.sp_lstchg = sp.sp_inact = 0; ],
1779         [ sp_expire_available=yes ], []
1780         )
1781
1782         if test "x$sp_expire_available" = "xyes" ; then
1783                 AC_MSG_RESULT(yes)
1784                 AC_DEFINE(HAS_SHADOW_EXPIRE)
1785         else
1786                 AC_MSG_RESULT(no)
1787         fi
1788 fi
1789
1790 # Use ip address instead of hostname in $DISPLAY
1791 if test ! -z "$IPADDR_IN_DISPLAY" ; then
1792         DISPLAY_HACK_MSG="yes"
1793         AC_DEFINE(IPADDR_IN_DISPLAY)
1794 else
1795         DISPLAY_HACK_MSG="no"
1796         AC_ARG_WITH(ipaddr-display,
1797                 [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
1798                 [
1799                         if test "x$withval" != "xno" ; then
1800                                 AC_DEFINE(IPADDR_IN_DISPLAY)
1801                                 DISPLAY_HACK_MSG="yes"
1802                         fi
1803                 ]
1804         )
1805 fi
1806
1807 # Whether to mess with the default path
1808 SERVER_PATH_MSG="(default)"
1809 AC_ARG_WITH(default-path,
1810         [  --with-default-path=PATH Specify default \$PATH environment for server],
1811         [
1812                 if test "x$withval" != "xno" ; then
1813                         user_path="$withval"
1814                         SERVER_PATH_MSG="$withval"
1815                 fi
1816         ],
1817         [
1818         AC_TRY_RUN(
1819                 [
1820 /* find out what STDPATH is */
1821 #include <stdio.h>
1822 #ifdef HAVE_PATHS_H
1823 # include <paths.h>
1824 #endif
1825 #ifndef _PATH_STDPATH
1826 # define _PATH_STDPATH "/usr/bin:/bin:/usr/sbin:/sbin"
1827 #endif
1828 #include <sys/types.h>
1829 #include <sys/stat.h>
1830 #include <fcntl.h>
1831 #define DATA "conftest.stdpath"
1832
1833 main()
1834 {
1835         FILE *fd;
1836         int rc;
1837
1838         fd = fopen(DATA,"w");
1839         if(fd == NULL)
1840                 exit(1);
1841
1842         if ((rc = fprintf(fd,"%s", _PATH_STDPATH)) < 0)
1843                 exit(1);
1844
1845         exit(0);
1846 }
1847                 ], [ user_path=`cat conftest.stdpath` ],
1848                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ],
1849                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ]
1850         )
1851 # make sure $bindir is in USER_PATH so scp will work
1852                 t_bindir=`eval echo ${bindir}`
1853                 case $t_bindir in
1854                         NONE/*) t_bindir=`echo $t_bindir | sed "s~NONE~$prefix~"` ;;
1855                 esac
1856                 case $t_bindir in
1857                         NONE/*) t_bindir=`echo $t_bindir | sed "s~NONE~$ac_default_prefix~"` ;;
1858                 esac
1859                 echo $user_path | grep ":$t_bindir"  > /dev/null 2>&1
1860                 if test $? -ne 0  ; then
1861                         echo $user_path | grep "^$t_bindir"  > /dev/null 2>&1
1862                         if test $? -ne 0  ; then
1863                                 user_path=$user_path:$t_bindir
1864                                 AC_MSG_RESULT(Adding $t_bindir to USER_PATH so scp will work)
1865                         fi
1866                 fi
1867         ]
1868 )
1869 AC_DEFINE_UNQUOTED(USER_PATH, "$user_path")
1870 AC_SUBST(user_path)
1871
1872 # Whether to force IPv4 by default (needed on broken glibc Linux)
1873 IPV4_HACK_MSG="no"
1874 AC_ARG_WITH(ipv4-default,
1875         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
1876         [
1877                 if test "x$withval" != "xno" ; then
1878                         AC_DEFINE(IPV4_DEFAULT)
1879                         IPV4_HACK_MSG="yes"
1880                 fi
1881         ]
1882 )
1883
1884 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
1885 IPV4_IN6_HACK_MSG="no"
1886 AC_ARG_WITH(4in6,
1887         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
1888         [
1889                 if test "x$withval" != "xno" ; then
1890                         AC_MSG_RESULT(yes)
1891                         AC_DEFINE(IPV4_IN_IPV6)
1892                         IPV4_IN6_HACK_MSG="yes"
1893                 else
1894                         AC_MSG_RESULT(no)
1895                 fi
1896         ],[
1897                 if test "x$inet6_default_4in6" = "xyes"; then
1898                         AC_MSG_RESULT([yes (default)])
1899                         AC_DEFINE(IPV4_IN_IPV6)
1900                         IPV4_IN6_HACK_MSG="yes"
1901                 else
1902                         AC_MSG_RESULT([no (default)])
1903                 fi
1904         ]
1905 )
1906
1907 # Whether to enable BSD auth support
1908 AC_ARG_WITH(bsd-auth,
1909         [  --with-bsd-auth         Enable BSD auth support],
1910         [
1911                 if test "x$withval" != "xno" ; then
1912                         AC_DEFINE(BSD_AUTH)
1913                         bsd_auth=yes
1914                 fi
1915         ]
1916 )
1917
1918 AC_MSG_CHECKING(whether to install ssh as suid root)
1919 AC_ARG_ENABLE(suid-ssh,
1920 [  --enable-suid-ssh       Install ssh as suid root (default)
1921   --disable-suid-ssh      Install ssh without suid bit],
1922 [ case "$enableval" in
1923   no)
1924        AC_MSG_RESULT(no)
1925        SSHMODE=0711
1926        ;;
1927   *)   AC_MSG_RESULT(yes)
1928        SSHMODE=4711
1929        ;;
1930   esac ],
1931   AC_MSG_RESULT(yes)
1932   SSHMODE=4711
1933 )
1934 AC_SUBST(SSHMODE)
1935
1936
1937 # Where to place sshd.pid
1938 piddir=/var/run
1939 AC_ARG_WITH(pid-dir,
1940         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
1941         [
1942                 if test "x$withval" != "xno" ; then
1943                         piddir=$withval
1944                 fi
1945         ]
1946 )
1947
1948 # make sure the directory exists
1949 if test ! -d $piddir ; then
1950         piddir=`eval echo ${sysconfdir}`
1951         case $piddir in
1952                 NONE/*) piddir=`echo $piddir | sed "s~NONE~$ac_default_prefix~"` ;;
1953         esac
1954 fi
1955
1956 AC_DEFINE_UNQUOTED(_PATH_SSH_PIDDIR, "$piddir")
1957 AC_SUBST(piddir)
1958
1959 dnl allow user to disable some login recording features
1960 AC_ARG_ENABLE(lastlog,
1961         [  --disable-lastlog       disable use of lastlog even if detected [no]],
1962         [ AC_DEFINE(DISABLE_LASTLOG) ]
1963 )
1964 AC_ARG_ENABLE(utmp,
1965         [  --disable-utmp          disable use of utmp even if detected [no]],
1966         [ AC_DEFINE(DISABLE_UTMP) ]
1967 )
1968 AC_ARG_ENABLE(utmpx,
1969         [  --disable-utmpx         disable use of utmpx even if detected [no]],
1970         [ AC_DEFINE(DISABLE_UTMPX) ]
1971 )
1972 AC_ARG_ENABLE(wtmp,
1973         [  --disable-wtmp          disable use of wtmp even if detected [no]],
1974         [ AC_DEFINE(DISABLE_WTMP) ]
1975 )
1976 AC_ARG_ENABLE(wtmpx,
1977         [  --disable-wtmpx         disable use of wtmpx even if detected [no]],
1978         [ AC_DEFINE(DISABLE_WTMPX) ]
1979 )
1980 AC_ARG_ENABLE(libutil,
1981         [  --disable-libutil       disable use of libutil (login() etc.) [no]],
1982         [ AC_DEFINE(DISABLE_LOGIN) ]
1983 )
1984 AC_ARG_ENABLE(pututline,
1985         [  --disable-pututline     disable use of pututline() etc. ([uw]tmp) [no]],
1986         [ AC_DEFINE(DISABLE_PUTUTLINE) ]
1987 )
1988 AC_ARG_ENABLE(pututxline,
1989         [  --disable-pututxline    disable use of pututxline() etc. ([uw]tmpx) [no]],
1990         [ AC_DEFINE(DISABLE_PUTUTXLINE) ]
1991 )
1992 AC_ARG_WITH(lastlog,
1993   [  --with-lastlog=FILE|DIR specify lastlog location [common locations]],
1994         [
1995                 if test "x$withval" = "xno" ; then
1996                         AC_DEFINE(DISABLE_LASTLOG)
1997                 else
1998                         conf_lastlog_location=$withval
1999                 fi
2000         ]
2001 )
2002
2003 dnl lastlog, [uw]tmpx? detection
2004 dnl  NOTE: set the paths in the platform section to avoid the
2005 dnl   need for command-line parameters
2006 dnl lastlog and [uw]tmp are subject to a file search if all else fails
2007
2008 dnl lastlog detection
2009 dnl  NOTE: the code itself will detect if lastlog is a directory
2010 AC_MSG_CHECKING([if your system defines LASTLOG_FILE])
2011 AC_TRY_COMPILE([
2012 #include <sys/types.h>
2013 #include <utmp.h>
2014 #ifdef HAVE_LASTLOG_H
2015 #  include <lastlog.h>
2016 #endif
2017 #ifdef HAVE_PATHS_H
2018 #  include <paths.h>
2019 #endif
2020 #ifdef HAVE_LOGIN_H
2021 # include <login.h>
2022 #endif
2023         ],
2024         [ char *lastlog = LASTLOG_FILE; ],
2025         [ AC_MSG_RESULT(yes) ],
2026         [
2027                 AC_MSG_RESULT(no)
2028                 AC_MSG_CHECKING([if your system defines _PATH_LASTLOG])
2029                 AC_TRY_COMPILE([
2030 #include <sys/types.h>
2031 #include <utmp.h>
2032 #ifdef HAVE_LASTLOG_H
2033 #  include <lastlog.h>
2034 #endif
2035 #ifdef HAVE_PATHS_H
2036 #  include <paths.h>
2037 #endif
2038                 ],
2039                 [ char *lastlog = _PATH_LASTLOG; ],
2040                 [ AC_MSG_RESULT(yes) ],
2041                 [
2042                         AC_MSG_RESULT(no)
2043                         system_lastlog_path=no
2044                 ])
2045         ]
2046 )
2047
2048 if test -z "$conf_lastlog_location"; then
2049         if test x"$system_lastlog_path" = x"no" ; then
2050                 for f in /var/log/lastlog /usr/adm/lastlog /var/adm/lastlog /etc/security/lastlog ; do
2051                                 if (test -d "$f" || test -f "$f") ; then
2052                                         conf_lastlog_location=$f
2053                                 fi
2054                 done
2055                 if test -z "$conf_lastlog_location"; then
2056                         AC_MSG_WARN([** Cannot find lastlog **])
2057                         dnl Don't define DISABLE_LASTLOG - that means we don't try wtmp/wtmpx
2058                 fi
2059         fi
2060 fi
2061
2062 if test -n "$conf_lastlog_location"; then
2063         AC_DEFINE_UNQUOTED(CONF_LASTLOG_FILE, "$conf_lastlog_location")
2064 fi
2065
2066 dnl utmp detection
2067 AC_MSG_CHECKING([if your system defines UTMP_FILE])
2068 AC_TRY_COMPILE([
2069 #include <sys/types.h>
2070 #include <utmp.h>
2071 #ifdef HAVE_PATHS_H
2072 #  include <paths.h>
2073 #endif
2074         ],
2075         [ char *utmp = UTMP_FILE; ],
2076         [ AC_MSG_RESULT(yes) ],
2077         [ AC_MSG_RESULT(no)
2078           system_utmp_path=no ]
2079 )
2080 if test -z "$conf_utmp_location"; then
2081         if test x"$system_utmp_path" = x"no" ; then
2082                 for f in /etc/utmp /usr/adm/utmp /var/run/utmp; do
2083                         if test -f $f ; then
2084                                 conf_utmp_location=$f
2085                         fi
2086                 done
2087                 if test -z "$conf_utmp_location"; then
2088                         AC_DEFINE(DISABLE_UTMP)
2089                 fi
2090         fi
2091 fi
2092 if test -n "$conf_utmp_location"; then
2093         AC_DEFINE_UNQUOTED(CONF_UTMP_FILE, "$conf_utmp_location")
2094 fi
2095
2096 dnl wtmp detection
2097 AC_MSG_CHECKING([if your system defines WTMP_FILE])
2098 AC_TRY_COMPILE([
2099 #include <sys/types.h>
2100 #include <utmp.h>
2101 #ifdef HAVE_PATHS_H
2102 #  include <paths.h>
2103 #endif
2104         ],
2105         [ char *wtmp = WTMP_FILE; ],
2106         [ AC_MSG_RESULT(yes) ],
2107         [ AC_MSG_RESULT(no)
2108           system_wtmp_path=no ]
2109 )
2110 if test -z "$conf_wtmp_location"; then
2111         if test x"$system_wtmp_path" = x"no" ; then
2112                 for f in /usr/adm/wtmp /var/log/wtmp; do
2113                         if test -f $f ; then
2114                                 conf_wtmp_location=$f
2115                         fi
2116                 done
2117                 if test -z "$conf_wtmp_location"; then
2118                         AC_DEFINE(DISABLE_WTMP)
2119                 fi
2120         fi
2121 fi
2122 if test -n "$conf_wtmp_location"; then
2123         AC_DEFINE_UNQUOTED(CONF_WTMP_FILE, "$conf_wtmp_location")
2124 fi
2125
2126
2127 dnl utmpx detection - I don't know any system so perverse as to require
2128 dnl  utmpx, but not define UTMPX_FILE (ditto wtmpx.) No doubt it's out
2129 dnl  there, though.
2130 AC_MSG_CHECKING([if your system defines UTMPX_FILE])
2131 AC_TRY_COMPILE([
2132 #include <sys/types.h>
2133 #include <utmp.h>
2134 #ifdef HAVE_UTMPX_H
2135 #include <utmpx.h>
2136 #endif
2137 #ifdef HAVE_PATHS_H
2138 #  include <paths.h>
2139 #endif
2140         ],
2141         [ char *utmpx = UTMPX_FILE; ],
2142         [ AC_MSG_RESULT(yes) ],
2143         [ AC_MSG_RESULT(no)
2144           system_utmpx_path=no ]
2145 )
2146 if test -z "$conf_utmpx_location"; then
2147         if test x"$system_utmpx_path" = x"no" ; then
2148                 AC_DEFINE(DISABLE_UTMPX)
2149         fi
2150 else
2151         AC_DEFINE_UNQUOTED(CONF_UTMPX_FILE, "$conf_utmpx_location")
2152 fi
2153
2154 dnl wtmpx detection
2155 AC_MSG_CHECKING([if your system defines WTMPX_FILE])
2156 AC_TRY_COMPILE([
2157 #include <sys/types.h>
2158 #include <utmp.h>
2159 #ifdef HAVE_UTMPX_H
2160 #include <utmpx.h>
2161 #endif
2162 #ifdef HAVE_PATHS_H
2163 #  include <paths.h>
2164 #endif
2165         ],
2166         [ char *wtmpx = WTMPX_FILE; ],
2167         [ AC_MSG_RESULT(yes) ],
2168         [ AC_MSG_RESULT(no)
2169           system_wtmpx_path=no ]
2170 )
2171 if test -z "$conf_wtmpx_location"; then
2172         if test x"$system_wtmpx_path" = x"no" ; then
2173                 AC_DEFINE(DISABLE_WTMPX)
2174         fi
2175 else
2176         AC_DEFINE_UNQUOTED(CONF_WTMPX_FILE, "$conf_wtmpx_location")
2177 fi
2178
2179
2180 # Change default command timeout for builtin PRNG
2181 entropy_timeout=200
2182 AC_ARG_WITH(entropy-timeout,
2183         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
2184         [
2185                 if test "x$withval" != "xno" ; then
2186                         entropy_timeout=$withval
2187                 fi
2188         ]
2189 )
2190 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
2191
2192
2193 if test ! -z "$blibpath" ; then
2194         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
2195         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
2196 fi
2197
2198 AC_EXEEXT
2199
2200 AC_CONFIG_FILES([Makefile openbsd-compat/Makefile scard/Makefile ssh_prng_cmds])
2201 AC_OUTPUT
2202
2203 # Print summary of options
2204
2205 if test ! -z "$RANDOM_POOL" ; then
2206         RAND_MSG="Device ($RANDOM_POOL)"
2207 else
2208         if test ! -z "$PRNGD_PORT" ; then
2209                 RAND_MSG="PRNGD/EGD (port localhost:$PRNGD_PORT)"
2210         elif test ! -z "$PRNGD_SOCKET" ; then
2211                 RAND_MSG="PRNGD/EGD (socket $PRNGD_SOCKET)"
2212         else
2213                 RAND_MSG="Builtin (timeout $entropy_timeout)"
2214                 BUILTIN_RNG=1
2215         fi
2216 fi
2217
2218 # Someone please show me a better way :)
2219 A=`eval echo ${prefix}` ; A=`eval echo ${A}`
2220 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
2221 C=`eval echo ${sbindir}` ; C=`eval echo ${C}`
2222 D=`eval echo ${sysconfdir}` ; D=`eval echo ${D}`
2223 E=`eval echo ${libexecdir}/ssh-askpass` ; E=`eval echo ${E}`
2224 F=`eval echo ${mandir}/${mansubdir}X` ; F=`eval echo ${F}`
2225 G=`eval echo ${piddir}` ; G=`eval echo ${G}`
2226 H=`eval echo ${user_path}` ; H=`eval echo ${H}`
2227
2228 echo ""
2229 echo "OpenSSH has been configured with the following options:"
2230 echo "                 User binaries: $B"
2231 echo "               System binaries: $C"
2232 echo "           Configuration files: $D"
2233 echo "               Askpass program: $E"
2234 echo "                  Manual pages: $F"
2235 echo "                      PID file: $G"
2236 echo "        sshd default user PATH: $H"
2237 echo "      Random number collection: $RAND_MSG"
2238 echo "                Manpage format: $MANTYPE"
2239 echo "                   PAM support: ${PAM_MSG}"
2240 echo "            KerberosIV support: $KRB4_MSG"
2241 echo "             Smartcard support: $SCARD_MSG"
2242 echo "                   AFS support: $AFS_MSG"
2243 echo "                 S/KEY support: $SKEY_MSG"
2244 echo "          TCP Wrappers support: $TCPW_MSG"
2245 echo "          MD5 password support: $MD5_MSG"
2246 echo "   IP address in \$DISPLAY hack: $DISPLAY_HACK_MSG"
2247 echo "      Use IPv4 by default hack: $IPV4_HACK_MSG"
2248 echo "       Translate v4 in v6 hack: $IPV4_IN6_HACK_MSG"
2249
2250 if test ! -z "$bsd_auth"; then
2251         echo "              BSD Auth support: yes"
2252 fi
2253
2254 echo ""
2255
2256 echo "              Host: ${host}"
2257 echo "          Compiler: ${CC}"
2258 echo "    Compiler flags: ${CFLAGS}"
2259 echo "Preprocessor flags: ${CPPFLAGS}"
2260 echo "      Linker flags: ${LDFLAGS}"
2261 echo "         Libraries: ${LIBS}"
2262
2263 echo ""
2264
2265 if test "x$PAM_MSG" = "xyes" ; then
2266         echo "PAM is enabled. You may need to install a PAM control file for sshd,"
2267         echo "otherwise password authentication may fail. Example PAM control files"
2268         echo "can be found in the contrib/ subdirectory"
2269         echo ""
2270 fi
2271
2272 if test ! -z "$BUILTIN_RNG" ; then
2273         echo "WARNING: you are using the builtin random number collection service."
2274         echo "Please read WARNING.RNG and request that your OS vendor includes"
2275         echo "/dev/random in future versions of their OS."
2276         echo ""
2277 fi
2278
2279 if test ! -z "$NO_SFTP"; then
2280         echo "sftp-server will be disabled.  Your compiler does not support"
2281         echo "64bit integers."
2282         echo ""
2283 fi
2284