openssh/configure.ac

   1 # $Id$
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([ssh.c])
   5
   6 AC_CONFIG_HEADER(config.h)
   7 AC_PROG_CC
   8 AC_CANONICAL_HOST
   9 AC_C_BIGENDIAN
  10
  11 # Checks for programs.
  12 AC_PROG_CPP
  13 AC_PROG_RANLIB
  14 AC_PROG_INSTALL
  15 AC_PATH_PROG(AR, ar)
  16 AC_PATH_PROGS(PERL, perl5 perl)
  17 AC_SUBST(PERL)
  18 AC_PATH_PROG(ENT, ent)
  19 AC_SUBST(ENT)
  20 AC_PATH_PROG(TEST_MINUS_S_SH, bash)
  21 AC_PATH_PROG(TEST_MINUS_S_SH, ksh)
  22 AC_PATH_PROG(TEST_MINUS_S_SH, sh)
  23 AC_PATH_PROG(SH, sh)
  24
  25 # System features
  26 AC_SYS_LARGEFILE
  27
  28 if test -z "$AR" ; then
  29         AC_MSG_ERROR([*** 'ar' missing, please install or fix your \$PATH ***])
  30 fi
  31
  32 # Use LOGIN_PROGRAM from environment if possible
  33 if test ! -z "$LOGIN_PROGRAM" ; then
  34         AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM")
  35 else
  36         # Search for login
  37         AC_PATH_PROG(LOGIN_PROGRAM_FALLBACK, login)
  38         if test ! -z "$LOGIN_PROGRAM_FALLBACK" ; then
  39                 AC_DEFINE_UNQUOTED(LOGIN_PROGRAM_FALLBACK, "$LOGIN_PROGRAM_FALLBACK")
  40         fi
  41 fi
  42
  43 if test -z "$LD" ; then
  44         LD=$CC
  45 fi
  46 AC_SUBST(LD)
  47
  48 AC_C_INLINE
  49 if test "$GCC" = "yes" || test "$GCC" = "egcs"; then
  50         CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wno-uninitialized"
  51 fi
  52
  53 # Check for some target-specific stuff
  54 case "$host" in
  55 *-*-aix*)
  56         AFS_LIBS="-lld"
  57         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
  58         LDFLAGS="$LDFLAGS -L/usr/local/lib"
  59         if (test "$LD" != "gcc" && test -z "$blibpath"); then
  60                 AC_MSG_CHECKING([if linkage editor ($LD) accepts -blibpath])
  61                 saved_LDFLAGS="$LDFLAGS"
  62                 LDFLAGS="$LDFLAGS -blibpath:/usr/lib:/lib:/usr/local/lib"
  63                 AC_TRY_LINK([],
  64                         [],
  65                         [
  66                                 AC_MSG_RESULT(yes)
  67                                 blibpath="/usr/lib:/lib:/usr/local/lib"
  68                         ],
  69                         [ AC_MSG_RESULT(no) ]
  70                 )
  71                 LDFLAGS="$saved_LDFLAGS"
  72         fi
  73         AC_CHECK_FUNC(authenticate, [AC_DEFINE(WITH_AIXAUTHENTICATE)],
  74                 [AC_CHECK_LIB(s,authenticate,
  75                         [ AC_DEFINE(WITH_AIXAUTHENTICATE)
  76                                 LIBS="$LIBS -ls"
  77                         ])
  78                 ])
  79         AC_DEFINE(BROKEN_GETADDRINFO)
  80         AC_DEFINE(BROKEN_REALPATH)
  81         dnl AIX handles lastlog as part of its login message
  82         AC_DEFINE(DISABLE_LASTLOG)
  83         AC_DEFINE(LOGIN_NEEDS_UTMPX)
  84         ;;
  85 *-*-cygwin*)
  86         LIBS="$LIBS /usr/lib/textmode.o"
  87         AC_DEFINE(HAVE_CYGWIN)
  88         AC_DEFINE(USE_PIPES)
  89         AC_DEFINE(DISABLE_SHADOW)
  90         AC_DEFINE(IPV4_DEFAULT)
  91         AC_DEFINE(IP_TOS_IS_BROKEN)
  92         AC_DEFINE(NO_X11_UNIX_SOCKETS)
  93         AC_DEFINE(NO_IPPORT_RESERVED_CONCEPT)
  94         AC_DEFINE(DISABLE_FD_PASSING)
  95         AC_DEFINE(SETGROUPS_NOOP)
  96         ;;
  97 *-*-dgux*)
  98         AC_DEFINE(IP_TOS_IS_BROKEN)
  99         ;;
 100 *-*-darwin*)
 101         AC_MSG_CHECKING(if we have working getaddrinfo)
 102         AC_TRY_RUN([#include <mach-o/dyld.h>
 103 main() { if (NSVersionOfRunTimeLibrary("System") >= (60 << 16))
 104                 exit(0);
 105         else
 106                 exit(1);
 107 }], [AC_MSG_RESULT(working)],
 108         [AC_MSG_RESULT(buggy)
 109         AC_DEFINE(BROKEN_GETADDRINFO)],
 110         [AC_MSG_RESULT(assume it is working)])
 111         ;;
 112 *-*-hpux10.26)
 113         if test -z "$GCC"; then
 114                 CFLAGS="$CFLAGS -Ae"
 115         fi
 116         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 117         IPADDR_IN_DISPLAY=yes
 118         AC_DEFINE(HAVE_SECUREWARE)
 119         AC_DEFINE(USE_PIPES)
 120         AC_DEFINE(LOGIN_NO_ENDOPT)
 121         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 122         AC_DEFINE(DISABLE_SHADOW)
 123         AC_DEFINE(DISABLE_UTMP)
 124         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 125         LIBS="$LIBS -lsec -lsecpw"
 126         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 127         disable_ptmx_check=yes
 128         ;;
 129 *-*-hpux10*)
 130         if test -z "$GCC"; then
 131                 CFLAGS="$CFLAGS -Ae"
 132         fi
 133         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 134         IPADDR_IN_DISPLAY=yes
 135         AC_DEFINE(USE_PIPES)
 136         AC_DEFINE(LOGIN_NO_ENDOPT)
 137         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 138         AC_DEFINE(DISABLE_SHADOW)
 139         AC_DEFINE(DISABLE_UTMP)
 140         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 141         LIBS="$LIBS -lsec"
 142         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 143         ;;
 144 *-*-hpux11*)
 145         CPPFLAGS="$CPPFLAGS -D_HPUX_SOURCE -D_XOPEN_SOURCE -D_XOPEN_SOURCE_EXTENDED=1"
 146         IPADDR_IN_DISPLAY=yes
 147         AC_DEFINE(PAM_SUN_CODEBASE)
 148         AC_DEFINE(USE_PIPES)
 149         AC_DEFINE(LOGIN_NO_ENDOPT)
 150         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 151         AC_DEFINE(DISABLE_SHADOW)
 152         AC_DEFINE(DISABLE_UTMP)
 153         AC_DEFINE(SPT_TYPE,SPT_PSTAT)
 154         LIBS="$LIBS -lsec"
 155         AC_CHECK_LIB(xnet, t_error, ,AC_MSG_ERROR([*** -lxnet needed on HP-UX - check config.log ***]))
 156         ;;
 157 *-*-irix5*)
 158         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 159         LDFLAGS="$LDFLAGS"
 160         PATH="$PATH:/usr/etc"
 161         AC_DEFINE(BROKEN_INET_NTOA)
 162         AC_DEFINE(WITH_ABBREV_NO_TTY)
 163         ;;
 164 *-*-irix6*)
 165         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 166         LDFLAGS="$LDFLAGS"
 167         PATH="$PATH:/usr/etc"
 168         AC_DEFINE(WITH_IRIX_ARRAY)
 169         AC_DEFINE(WITH_IRIX_PROJECT)
 170         AC_DEFINE(WITH_IRIX_AUDIT)
 171         AC_CHECK_FUNC(jlimit_startjob, [AC_DEFINE(WITH_IRIX_JOBS)])
 172         AC_DEFINE(BROKEN_INET_NTOA)
 173         AC_DEFINE(WITH_ABBREV_NO_TTY)
 174         ;;
 175 *-*-linux*)
 176         no_dev_ptmx=1
 177         check_for_libcrypt_later=1
 178         AC_DEFINE(DONT_TRY_OTHER_AF)
 179         AC_DEFINE(PAM_TTY_KLUDGE)
 180         inet6_default_4in6=yes
 181         ;;
 182 mips-sony-bsd|mips-sony-newsos4)
 183         AC_DEFINE(HAVE_NEWS4)
 184         SONY=1
 185         ;;
 186 *-*-netbsd*)
 187         check_for_libcrypt_before=1
 188         need_dash_r=1
 189         ;;
 190 *-*-freebsd*)
 191         check_for_libcrypt_later=1
 192         ;;
 193 *-next-*)
 194         conf_lastlog_location="/usr/adm/lastlog"
 195         conf_utmp_location=/etc/utmp
 196         conf_wtmp_location=/usr/adm/wtmp
 197         MAIL=/usr/spool/mail
 198         AC_DEFINE(HAVE_NEXT)
 199         AC_DEFINE(BROKEN_REALPATH)
 200         AC_DEFINE(USE_PIPES)
 201         AC_DEFINE(BROKEN_SAVED_UIDS)
 202         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 203         CFLAGS="$CFLAGS"
 204         ;;
 205 *-*-solaris*)
 206         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 207         LDFLAGS="$LDFLAGS -L/usr/local/lib -R/usr/local/lib"
 208         need_dash_r=1
 209         AC_DEFINE(PAM_SUN_CODEBASE)
 210         AC_DEFINE(LOGIN_NEEDS_UTMPX)
 211         AC_DEFINE(LOGIN_NEEDS_TERM)
 212         AC_DEFINE(PAM_TTY_KLUDGE)
 213         # hardwire lastlog location (can't detect it on some versions)
 214         conf_lastlog_location="/var/adm/lastlog"
 215         AC_MSG_CHECKING(for obsolete utmp and wtmp in solaris2.x)
 216         sol2ver=`echo "$host"| sed -e 's/.*[[0-9]]\.//'`
 217         if test "$sol2ver" -ge 8; then
 218                 AC_MSG_RESULT(yes)
 219                 AC_DEFINE(DISABLE_UTMP)
 220                 AC_DEFINE(DISABLE_WTMP)
 221         else
 222                 AC_MSG_RESULT(no)
 223         fi
 224         ;;
 225 *-*-sunos4*)
 226         CPPFLAGS="$CPPFLAGS -DSUNOS4"
 227         AC_CHECK_FUNCS(getpwanam)
 228         AC_DEFINE(PAM_SUN_CODEBASE)
 229         conf_utmp_location=/etc/utmp
 230         conf_wtmp_location=/var/adm/wtmp
 231         conf_lastlog_location=/var/adm/lastlog
 232         AC_DEFINE(USE_PIPES)
 233         ;;
 234 *-ncr-sysv*)
 235         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 236         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 237         LIBS="$LIBS -lc89"
 238         AC_DEFINE(USE_PIPES)
 239         ;;
 240 *-sni-sysv*)
 241         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 242         # /usr/ucblib MUST NOT be searched on ReliantUNIX
 243         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 244         IPADDR_IN_DISPLAY=yes
 245         AC_DEFINE(USE_PIPES)
 246         AC_DEFINE(IP_TOS_IS_BROKEN)
 247         # /usr/ucblib/libucb.a no longer needed on ReliantUNIX
 248         # Attention: always take care to bind libsocket and libnsl before libc,
 249         # otherwise you will find lots of "SIOCGPGRP errno 22" on syslog
 250         ;;
 251 *-*-sysv4.2*)
 252         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 253         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 254         AC_DEFINE(USE_PIPES)
 255         ;;
 256 *-*-sysv5*)
 257         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 258         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 259         AC_DEFINE(USE_PIPES)
 260         ;;
 261 *-*-sysv*)
 262         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 263         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 264         ;;
 265 *-*-sco3.2v4*)
 266         CPPFLAGS="$CPPFLAGS -Dftruncate=chsize -I/usr/local/include"
 267         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 268         LIBS="$LIBS -los -lprot -lx -ltinfo -lm"
 269         RANLIB=true
 270         no_dev_ptmx=1
 271         AC_DEFINE(BROKEN_SYS_TERMIO_H)
 272         AC_DEFINE(USE_PIPES)
 273         AC_DEFINE(HAVE_SECUREWARE)
 274         AC_DEFINE(DISABLE_SHADOW)
 275         AC_DEFINE(BROKEN_SAVED_UIDS)
 276         AC_CHECK_FUNCS(getluid setluid)
 277         MANTYPE=man
 278         do_sco3_extra_lib_check=yes
 279         ;;
 280 *-*-sco3.2v5*)
 281         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 282         LDFLAGS="$LDFLAGS -L/usr/local/lib"
 283         LIBS="$LIBS -lprot -lx -ltinfo -lm"
 284         no_dev_ptmx=1
 285         AC_DEFINE(USE_PIPES)
 286         AC_DEFINE(HAVE_SECUREWARE)
 287         AC_DEFINE(DISABLE_SHADOW)
 288         AC_DEFINE(DISABLE_FD_PASSING)
 289         AC_CHECK_FUNCS(getluid setluid)
 290         MANTYPE=man
 291         ;;
 292 *-*-unicosmk*)
 293         no_libsocket=1
 294         no_libnsl=1
 295         AC_DEFINE(USE_PIPES)
 296         AC_DEFINE(DISABLE_FD_PASSING)
 297         LDFLAGS="$LDFLAGS"
 298         LIBS="$LIBS -lgen -lrsc -lshare -luex -lacm"
 299         MANTYPE=cat
 300         ;;
 301 *-*-unicos*)
 302         no_libsocket=1
 303         no_libnsl=1
 304         AC_DEFINE(USE_PIPES)
 305         AC_DEFINE(DISABLE_FD_PASSING)
 306         AC_DEFINE(NO_SSH_LASTLOG)
 307         LDFLAGS="$LDFLAGS -Wl,-Dmsglevel=334:fatal"
 308         LIBS="$LIBS -lgen -lrsc -lshare -luex -lacm"
 309         MANTYPE=cat
 310         ;;
 311 *-dec-osf*)
 312         AC_MSG_CHECKING(for Digital Unix SIA)
 313         no_osfsia=""
 314         AC_ARG_WITH(osfsia,
 315                 [  --with-osfsia           Enable Digital Unix SIA],
 316                 [
 317                         if test "x$withval" = "xno" ; then
 318                                 AC_MSG_RESULT(disabled)
 319                                 no_osfsia=1
 320                         fi
 321                 ],
 322         )
 323         if test -z "$no_osfsia" ; then
 324                 if test -f /etc/sia/matrix.conf; then
 325                         AC_MSG_RESULT(yes)
 326                         AC_DEFINE(HAVE_OSF_SIA)
 327                         AC_DEFINE(DISABLE_LOGIN)
 328                         LIBS="$LIBS -lsecurity -ldb -lm -laud"
 329                 else
 330                         AC_MSG_RESULT(no)
 331                 fi
 332         fi
 333         ;;
 334
 335 *-*-nto-qnx)
 336         AC_DEFINE(USE_PIPES)
 337         AC_DEFINE(NO_X11_UNIX_SOCKETS)
 338         AC_DEFINE(MISSING_NFDBITS)
 339         AC_DEFINE(MISSING_HOWMANY)
 340         AC_DEFINE(MISSING_FD_MASK)
 341         ;;
 342 esac
 343
 344 # Allow user to specify flags
 345 AC_ARG_WITH(cflags,
 346         [  --with-cflags           Specify additional flags to pass to compiler],
 347         [
 348                 if test "x$withval" != "xno" ; then
 349                         CFLAGS="$CFLAGS $withval"
 350                 fi
 351         ]
 352 )
 353 AC_ARG_WITH(cppflags,
 354         [  --with-cppflags         Specify additional flags to pass to preprocessor] ,
 355         [
 356                 if test "x$withval" != "xno"; then
 357                         CPPFLAGS="$CPPFLAGS $withval"
 358                 fi
 359         ]
 360 )
 361 AC_ARG_WITH(ldflags,
 362         [  --with-ldflags          Specify additional flags to pass to linker],
 363         [
 364                 if test "x$withval" != "xno" ; then
 365                         LDFLAGS="$LDFLAGS $withval"
 366                 fi
 367         ]
 368 )
 369 AC_ARG_WITH(libs,
 370         [  --with-libs             Specify additional libraries to link with],
 371         [
 372                 if test "x$withval" != "xno" ; then
 373                         LIBS="$LIBS $withval"
 374                 fi
 375         ]
 376 )
 377
 378 # Checks for header files.
 379 AC_CHECK_HEADERS(bstring.h crypt.h endian.h floatingpoint.h \
 380         getopt.h glob.h ia.h lastlog.h limits.h login.h \
 381         login_cap.h maillock.h netdb.h netgroup.h \
 382         netinet/in_systm.h paths.h pty.h readpassphrase.h \
 383         rpc/types.h security/pam_appl.h shadow.h stddef.h stdint.h \
 384         strings.h sys/bitypes.h sys/bsdtty.h sys/cdefs.h \
 385         sys/mman.h sys/select.h sys/stat.h \
 386         sys/stropts.h sys/sysmacros.h sys/time.h \
 387         sys/un.h time.h tmpdir.h ttyent.h usersec.h \
 388         util.h utime.h utmp.h utmpx.h)
 389
 390 # Checks for libraries.
 391 AC_CHECK_FUNC(yp_match, , AC_CHECK_LIB(nsl, yp_match))
 392 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt))
 393
 394 dnl SCO OS3 needs this for libwrap
 395 if test "x$with_tcp_wrappers" != "xno" ; then
 396     if test "x$do_sco3_extra_lib_check" = "xyes" ; then
 397         AC_CHECK_LIB(rpc, innetgr, LIBS="-lrpc -lyp -lrpc $LIBS" , , -lyp -lrpc)
 398     fi
 399 fi
 400
 401 AC_CHECK_FUNC(getspnam, ,
 402         AC_CHECK_LIB(gen, getspnam, LIBS="$LIBS -lgen"))
 403
 404 AC_ARG_WITH(rpath,
 405         [  --without-rpath         Disable auto-added -R linker paths],
 406         [
 407                 if test "x$withval" = "xno" ; then
 408                         need_dash_r=""
 409                 fi
 410                 if test "x$withval" = "xyes" ; then
 411                         need_dash_r=1
 412                 fi
 413         ]
 414 )
 415
 416 dnl zlib is required
 417 AC_ARG_WITH(zlib,
 418         [  --with-zlib=PATH        Use zlib in PATH],
 419         [
 420                 if test "x$withval" = "xno" ; then
 421                         AC_MSG_ERROR([*** zlib is required ***])
 422                 fi
 423                 if test -d "$withval/lib"; then
 424                         if test -n "${need_dash_r}"; then
 425                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 426                         else
 427                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 428                         fi
 429                 else
 430                         if test -n "${need_dash_r}"; then
 431                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 432                         else
 433                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 434                         fi
 435                 fi
 436                 if test -d "$withval/include"; then
 437                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 438                 else
 439                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 440                 fi
 441         ]
 442 )
 443
 444 AC_CHECK_LIB(z, deflate, ,AC_MSG_ERROR([*** zlib missing - please install first or check config.log ***]))
 445
 446 dnl UnixWare 2.x
 447 AC_CHECK_FUNC(strcasecmp,
 448         [], [ AC_CHECK_LIB(resolv, strcasecmp, LIBS="$LIBS -lresolv") ]
 449 )
 450 AC_CHECK_FUNC(utimes,
 451         [], [ AC_CHECK_LIB(c89, utimes, [AC_DEFINE(HAVE_UTIMES)
 452                                         LIBS="$LIBS -lc89"]) ]
 453 )
 454
 455 dnl    Checks for libutil functions
 456 AC_CHECK_HEADERS(libutil.h)
 457 AC_SEARCH_LIBS(login, util bsd, [AC_DEFINE(HAVE_LOGIN)])
 458 AC_CHECK_FUNCS(logout updwtmp logwtmp)
 459
 460 AC_FUNC_STRFTIME
 461
 462 # Check for ALTDIRFUNC glob() extension
 463 AC_MSG_CHECKING(for GLOB_ALTDIRFUNC support)
 464 AC_EGREP_CPP(FOUNDIT,
 465         [
 466                 #include <glob.h>
 467                 #ifdef GLOB_ALTDIRFUNC
 468                 FOUNDIT
 469                 #endif
 470         ],
 471         [
 472                 AC_DEFINE(GLOB_HAS_ALTDIRFUNC)
 473                 AC_MSG_RESULT(yes)
 474         ],
 475         [
 476                 AC_MSG_RESULT(no)
 477         ]
 478 )
 479
 480 # Check for g.gl_matchc glob() extension
 481 AC_MSG_CHECKING(for gl_matchc field in glob_t)
 482 AC_EGREP_CPP(FOUNDIT,
 483         [
 484                 #include <glob.h>
 485                 int main(void){glob_t g; g.gl_matchc = 1;}
 486         ],
 487         [
 488                 AC_DEFINE(GLOB_HAS_GL_MATCHC)
 489                 AC_MSG_RESULT(yes)
 490         ],
 491         [
 492                 AC_MSG_RESULT(no)
 493         ]
 494 )
 495
 496 AC_MSG_CHECKING([whether struct dirent allocates space for d_name])
 497 AC_TRY_RUN(
 498         [
 499 #include <sys/types.h>
 500 #include <dirent.h>
 501 int main(void){struct dirent d;exit(sizeof(d.d_name)<=sizeof(char));}
 502         ],
 503         [AC_MSG_RESULT(yes)],
 504         [
 505                 AC_MSG_RESULT(no)
 506                 AC_DEFINE(BROKEN_ONE_BYTE_DIRENT_D_NAME)
 507         ]
 508 )
 509
 510 # Check whether the user wants GSSAPI mechglue support
 511 AC_ARG_WITH(mechglue,
 512         [  --with-mechglue=PATH    Build with GSSAPI mechglue library],
 513         [
 514                 AC_MSG_CHECKING(for mechglue library)
 515
 516                 if test -e ${withval}/libgssapi.a ; then
 517                     mechglue_lib=${withval}/libgssapi.a
 518                 elif test -e ${withval}/lib/libgssapi.a ; then
 519                     mechglue_lib=${withval}/lib/libgssapi.a
 520                 else
 521                     AC_MSG_ERROR("Can't find libgssapi in ${withval}");
 522                 fi
 523                 LIBS="$LIBS ${mechglue_lib}"
 524                 AC_MSG_RESULT(${mechglue_lib})
 525
 526 #               if test -e ${withval}/gssapi.h ; then
 527 #                   CPPFLAGS="$CPPFLAGS -I${withval}"
 528 #               elif test -e ${withval}/include/gssapi.h ; then
 529 #                   CPPFLAGS="$CPPFLAGS -I${withval}/include"
 530 #               else
 531 #                   AC_MSG_ERROR("Can't find gssapi.h in ${withval}");
 532 #               fi
 533
 534                 AC_CHECK_LIB(dl, dlopen, , )
 535                 if test $ac_cv_lib_dl_dlopen = yes; then
 536                    LDFLAGS="$LDFLAGS -ldl -Wl,-Bsymbolic"
 537                 fi
 538
 539                 AC_DEFINE(GSSAPI)
 540                 AC_DEFINE(MECHGLUE)
 541                 AC_DEFINE(HAVE_GSSAPI_EXT)
 542                 GSSAPI="mechglue"
 543
 544         ]
 545 )
 546
 547
 548 # Check whether the user wants GSI (Globus) support
 549 gsi_path="no"
 550 AC_ARG_WITH(gsi,
 551         [  --with-gsi=PATH         Enable GSI/Globus authentication support],
 552         [
 553                 gsi_path="$withval"
 554         ]
 555 )
 556
 557 AC_ARG_WITH(globus,
 558         [  --with-globus=PATH      Enable GSI/Globus authentication support],
 559         [
 560                 gsi_path="$withval"
 561         ]
 562 )
 563
 564 # Check whether the user has a Globus flavor type
 565 globus_flavor_type="no"
 566 AC_ARG_WITH(globus-flavor,
 567         [  --with-globus-flavor=TYPE         Describe Globus flavor type (ex: gcc32dbg, etc.)],
 568         [
 569                 globus_flavor_type="$withval"
 570         ]
 571 )
 572
 573 if test "x$gsi_path" != "xno" ; then
 574         # Globus GSSAPI configuration
 575         AC_DEFINE(GSI)
 576
 577         if test "$GSSAPI" -a "$GSSAPI" != "mechglue"; then
 578                 AC_MSG_ERROR([Previously configured GSSAPI library conflicts with Globus/GSI.])
 579         fi
 580         if test -z "$GSSAPI"; then
 581                 AC_DEFINE(GSSAPI)
 582                 GSSAPI="GSI"
 583         fi
 584
 585         # Find GLOBUS/GSI installation Directory
 586
 587         AC_MSG_CHECKING(for Globus installation)
 588         globus_dev_dir=$gsi_path
 589         if test "x$globus_dev_dir" = "xyes" ; then
 590                 AC_MSG_ERROR(Cannot find Globus installation -- a path must be specified!)
 591         fi
 592         AC_MSG_RESULT($globus_dev_dir)
 593
 594         # Find GLOBUS/GSI flavor Directory
 595
 596         AC_MSG_CHECKING(for Globus flavor)
 597         if test "x$globus_flavor_type" = "xno" ; then
 598                 AC_MSG_ERROR(No Globus flavor type specified)
 599         elif test "x$globus_flavor_type" = "xyes" ; then
 600                 AC_MSG_ERROR(No Globus flavor type specified)
 601         else
 602                 AC_DEFINE(HAVE_GSSAPI_EXT)
 603                 GLOBUS_FLAVOR_TYPE_INCL_DIR="${globus_dev_dir}/include/${globus_flavor_type}"
 604                 if test ! -d "$GLOBUS_FLAVOR_TYPE_INCL_DIR" ; then
 605                         AC_MSG_ERROR(Cannot find Globus flavor-specific include directory: ${GLOBUS_FLAVOR_TYPE_INCL_DIR})
 606                 fi
 607                 GSI_CPPFLAGS="-I${GLOBUS_FLAVOR_TYPE_INCL_DIR}"
 608         fi
 609         AC_MSG_RESULT($globus_flavor_type)
 610
 611         # Build possible libraries off of the flavor name
 612
 613         libglobus_gss_assist="${gsi_path}/lib/libglobus_gss_assist_${globus_flavor_type}.a"
 614         libglobus_gssapi_gsi="${gsi_path}/lib/libglobus_gssapi_gsi_${globus_flavor_type}.a"
 615
 616         # Test that the base gss_assist library is present
 617
 618         if test -r ${libglobus_gss_assist} ; then
 619                 LIBS="$LIBS ${libglobus_gss_assist}"
 620         else
 621                 AC_MSG_ERROR([*** libglobus_gss_assist missing])
 622         fi
 623
 624         AC_MSG_CHECKING(for libglobus_gss_assist)
 625         AC_TRY_LINK(
 626                 [],
 627                 [],
 628                 [
 629                         AC_MSG_RESULT(yes)
 630                 ],
 631                 [
 632                         AC_MSG_ERROR([*** libglobus_gss_assist missing])
 633                 ]
 634         )
 635
 636         # If we aren't using mechglue, test that gssapi_gsi is present
 637         if test "$GSSAPI" != "mechglue"; then
 638                 if test -r ${libglobus_gssapi_gsi} ; then
 639                         LIBS="$LIBS ${libglobus_gssapi_gsi}"
 640                 else
 641                         AC_MSG_ERROR([*** libglobus_gssapi_gsi missing])
 642                 fi
 643         fi
 644
 645         AC_MSG_CHECKING(for libglobus_gssapi_gsi)
 646         AC_TRY_LINK(
 647                 [],
 648                 [],
 649                 [
 650                         AC_MSG_RESULT(yes)
 651                 ],
 652                 [
 653                         AC_MSG_ERROR([*** libglobus_gssapi_gsi missing])
 654                 ]
 655         )
 656
 657         CPPFLAGS="$CPPFLAGS $GSI_CPPFLAGS"
 658 fi
 659 # End Globus/GSI section
 660
 661 # Check whether user wants S/Key support
 662 SKEY_MSG="no"
 663 AC_ARG_WITH(skey,
 664         [  --with-skey[[=PATH]]      Enable S/Key support
 665                             (optionally in PATH)],
 666         [
 667                 if test "x$withval" != "xno" ; then
 668
 669                         if test "x$withval" != "xyes" ; then
 670                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
 671                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
 672                         fi
 673
 674                         AC_DEFINE(SKEY)
 675                         LIBS="-lskey $LIBS"
 676                         SKEY_MSG="yes"
 677
 678                         AC_MSG_CHECKING([for s/key support])
 679                         AC_TRY_RUN(
 680                                 [
 681 #include <stdio.h>
 682 #include <skey.h>
 683 int main() { char *ff = skey_keyinfo(""); ff=""; exit(0); }
 684                                 ],
 685                                 [AC_MSG_RESULT(yes)],
 686                                 [
 687                                         AC_MSG_RESULT(no)
 688                                         AC_MSG_ERROR([** Incomplete or missing s/key libraries.])
 689                                 ])
 690                 fi
 691         ]
 692 )
 693
 694 # Check whether user wants TCP wrappers support
 695 TCPW_MSG="no"
 696 AC_ARG_WITH(tcp-wrappers,
 697         [  --with-tcp-wrappers[[=PATH]]      Enable tcpwrappers support
 698                             (optionally in PATH)],
 699         [
 700                 if test "x$withval" != "xno" ; then
 701                         saved_LIBS="$LIBS"
 702                         saved_LDFLAGS="$LDFLAGS"
 703                         saved_CPPFLAGS="$CPPFLAGS"
 704                         if test -n "${withval}" -a "${withval}" != "yes"; then
 705                                 if test -d "${withval}/lib"; then
 706                                         if test -n "${need_dash_r}"; then
 707                                                 LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 708                                         else
 709                                                 LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 710                                         fi
 711                                 else
 712                                         if test -n "${need_dash_r}"; then
 713                                                 LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 714                                         else
 715                                                 LDFLAGS="-L${withval} ${LDFLAGS}"
 716                                         fi
 717                                 fi
 718                                 if test -d "${withval}/include"; then
 719                                         CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 720                                 else
 721                                         CPPFLAGS="-I${withval} ${CPPFLAGS}"
 722                                 fi
 723                         fi
 724                         LIBWRAP="-lwrap"
 725                         LIBS="$LIBWRAP $LIBS"
 726                         AC_MSG_CHECKING(for libwrap)
 727                         AC_TRY_LINK(
 728                                 [
 729 #include <tcpd.h>
 730                                         int deny_severity = 0, allow_severity = 0;
 731                                 ],
 732                                 [hosts_access(0);],
 733                                 [
 734                                         AC_MSG_RESULT(yes)
 735                                         AC_DEFINE(LIBWRAP)
 736                                         AC_SUBST(LIBWRAP)
 737                                         TCPW_MSG="yes"
 738                                 ],
 739                                 [
 740                                         AC_MSG_ERROR([*** libwrap missing])
 741                                 ]
 742                         )
 743                         LIBS="$saved_LIBS"
 744                 fi
 745         ]
 746 )
 747
 748 dnl    Checks for library functions.
 749 AC_CHECK_FUNCS(arc4random b64_ntop bcopy bindresvport_sa \
 750         clock fchmod fchown freeaddrinfo futimes gai_strerror \
 751         getaddrinfo getcwd getgrouplist getnameinfo getopt getpeereid\
 752         getrlimit getrusage getttyent glob inet_aton inet_ntoa \
 753         inet_ntop innetgr login_getcapbool md5_crypt memmove \
 754         mkdtemp mmap ngetaddrinfo openpty ogetaddrinfo readpassphrase \
 755         realpath recvmsg rresvport_af sendmsg setdtablesize setegid \
 756         setenv seteuid setgroups setlogin setproctitle setresgid setreuid \
 757         setrlimit setsid setpcred setvbuf sigaction sigvec snprintf \
 758         socketpair strerror strlcat strlcpy strmode strsep sysconf tcgetpgrp \
 759         truncate utimes vhangup vsnprintf waitpid __b64_ntop _getpty)
 760
 761 dnl IRIX and Solaris 2.5.1 have dirname() in libgen
 762 AC_CHECK_FUNCS(dirname, [AC_CHECK_HEADERS(libgen.h)] ,[
 763         AC_CHECK_LIB(gen, dirname,[
 764                 AC_CACHE_CHECK([for broken dirname],
 765                         ac_cv_have_broken_dirname, [
 766                         save_LIBS="$LIBS"
 767                         LIBS="$LIBS -lgen"
 768                         AC_TRY_RUN(
 769                                 [
 770 #include <libgen.h>
 771 #include <string.h>
 772
 773 int main(int argc, char **argv) {
 774     char *s, buf[32];
 775
 776     strncpy(buf,"/etc", 32);
 777     s = dirname(buf);
 778     if (!s || strncmp(s, "/", 32) != 0) {
 779         exit(1);
 780     } else {
 781         exit(0);
 782     }
 783 }
 784                                 ],
 785                                 [ ac_cv_have_broken_dirname="no" ],
 786                                 [ ac_cv_have_broken_dirname="yes" ]
 787                         )
 788                         LIBS="$save_LIBS"
 789                 ])
 790                 if test "x$ac_cv_have_broken_dirname" = "xno" ; then
 791                         LIBS="$LIBS -lgen"
 792                         AC_DEFINE(HAVE_DIRNAME)
 793                         AC_CHECK_HEADERS(libgen.h)
 794                 fi
 795         ])
 796 ])
 797
 798 dnl    Checks for time functions
 799 AC_CHECK_FUNCS(gettimeofday time)
 800 dnl    Checks for utmp functions
 801 AC_CHECK_FUNCS(endutent getutent getutid getutline pututline setutent)
 802 AC_CHECK_FUNCS(utmpname)
 803 dnl    Checks for utmpx functions
 804 AC_CHECK_FUNCS(endutxent getutxent getutxid getutxline pututxline )
 805 AC_CHECK_FUNCS(setutxent utmpxname)
 806
 807 AC_CHECK_FUNC(daemon,
 808         [AC_DEFINE(HAVE_DAEMON)],
 809         [AC_CHECK_LIB(bsd, daemon, [LIBS="$LIBS -lbsd"; AC_DEFINE(HAVE_DAEMON)])]
 810 )
 811
 812 AC_CHECK_FUNC(getpagesize,
 813         [AC_DEFINE(HAVE_GETPAGESIZE)],
 814         [AC_CHECK_LIB(ucb, getpagesize, [LIBS="$LIBS -lucb"; AC_DEFINE(HAVE_GETPAGESIZE)])]
 815 )
 816
 817 # Check for broken snprintf
 818 if test "x$ac_cv_func_snprintf" = "xyes" ; then
 819         AC_MSG_CHECKING([whether snprintf correctly terminates long strings])
 820         AC_TRY_RUN(
 821                 [
 822 #include <stdio.h>
 823 int main(void){char b[5];snprintf(b,5,"123456789");exit(b[4]!='\0');}
 824                 ],
 825                 [AC_MSG_RESULT(yes)],
 826                 [
 827                         AC_MSG_RESULT(no)
 828                         AC_DEFINE(BROKEN_SNPRINTF)
 829                         AC_MSG_WARN([****** Your snprintf() function is broken, complain to your vendor])
 830                 ]
 831         )
 832 fi
 833
 834 AC_FUNC_GETPGRP
 835
 836 # Check for PAM libs
 837 PAM_MSG="no"
 838 AC_ARG_WITH(pam,
 839         [  --with-pam              Enable PAM support ],
 840         [
 841                 if test "x$withval" != "xno" ; then
 842                         if test "x$ac_cv_header_security_pam_appl_h" != "xyes" ; then
 843                                 AC_MSG_ERROR([PAM headers not found])
 844                         fi
 845
 846                         AC_CHECK_LIB(dl, dlopen, , )
 847                         AC_CHECK_LIB(pam, pam_set_item, , AC_MSG_ERROR([*** libpam missing]))
 848                         AC_CHECK_FUNCS(pam_getenvlist)
 849                         AC_CHECK_FUNCS(pam_putenv)
 850
 851                         disable_shadow=yes
 852                         PAM_MSG="yes"
 853
 854                         AC_DEFINE(USE_PAM)
 855                         if test $ac_cv_lib_dl_dlopen = yes; then
 856                                 LIBPAM="-lpam -ldl"
 857                         else
 858                                 LIBPAM="-lpam"
 859                         fi
 860
 861                         AC_SUBST(LIBPAM)
 862                 fi
 863         ]
 864 )
 865
 866 # Check for older PAM
 867 if test "x$PAM_MSG" = "xyes" ; then
 868         # Check PAM strerror arguments (old PAM)
 869         AC_MSG_CHECKING([whether pam_strerror takes only one argument])
 870         AC_TRY_COMPILE(
 871                 [
 872 #include <stdlib.h>
 873 #include <security/pam_appl.h>
 874                 ],
 875                 [(void)pam_strerror((pam_handle_t *)NULL, -1);],
 876                 [AC_MSG_RESULT(no)],
 877                 [
 878                         AC_DEFINE(HAVE_OLD_PAM)
 879                         AC_MSG_RESULT(yes)
 880                         PAM_MSG="yes (old library)"
 881                 ]
 882         )
 883 fi
 884
 885 # Some systems want crypt() from libcrypt, *not* the version in OpenSSL,
 886 # because the system crypt() is more featureful.
 887 if test "x$check_for_libcrypt_before" = "x1"; then
 888         AC_CHECK_LIB(crypt, crypt)
 889 fi
 890
 891 # Search for OpenSSL
 892 saved_CPPFLAGS="$CPPFLAGS"
 893 saved_LDFLAGS="$LDFLAGS"
 894 AC_ARG_WITH(ssl-dir,
 895         [  --with-ssl-dir=PATH     Specify path to OpenSSL installation ],
 896         [
 897                 if test "x$withval" != "xno" ; then
 898                         if test -d "$withval/lib"; then
 899                                 if test -n "${need_dash_r}"; then
 900                                         LDFLAGS="-L${withval}/lib -R${withval}/lib ${LDFLAGS}"
 901                                 else
 902                                         LDFLAGS="-L${withval}/lib ${LDFLAGS}"
 903                                 fi
 904                         else
 905                                 if test -n "${need_dash_r}"; then
 906                                         LDFLAGS="-L${withval} -R${withval} ${LDFLAGS}"
 907                                 else
 908                                         LDFLAGS="-L${withval} ${LDFLAGS}"
 909                                 fi
 910                         fi
 911                         if test -d "$withval/include"; then
 912                                 CPPFLAGS="-I${withval}/include ${CPPFLAGS}"
 913                         else
 914                                 CPPFLAGS="-I${withval} ${CPPFLAGS}"
 915                         fi
 916                 fi
 917         ]
 918 )
 919
 920 # Patch up SSL libraries for GSI authentication as needed
 921 if test "x$globus_flavor_type" != "xno" ; then
 922         #
 923         # For Globus 2, always link with the static libraries
 924         #
 925
 926         libssl_utils="${gsi_path}/lib/libglobus_ssl_utils_${globus_flavor_type}.a"
 927
 928         #
 929         # Trouble arrives at GT 2.1.3+ with the reorg of globus_ssl_utils.  Compensating for
 930         # the new library linking required here through file tests to see which libraries to
 931         # link against.
 932         #
 933
 934         libgsi_proxy_core="${gsi_path}/lib/libglobus_gsi_proxy_core_${globus_flavor_type}.a"
 935         libgsi_credential="${gsi_path}/lib/libglobus_gsi_credential_${globus_flavor_type}.a"
 936         libgsi_callback="${gsi_path}/lib/libglobus_gsi_callback_${globus_flavor_type}.a"
 937         liboldgaa="${gsi_path}/lib/libglobus_oldgaa_${globus_flavor_type}.a"
 938         libgsi_sysconfig="${gsi_path}/lib/libglobus_gsi_sysconfig_${globus_flavor_type}.a"
 939         libproxy_ssl="${gsi_path}/lib/libglobus_proxy_ssl_${globus_flavor_type}.a"
 940         libgsi_cert_utils="${gsi_path}/lib/libglobus_gsi_cert_utils_${globus_flavor_type}.a"
 941         libopenssl_error="${gsi_path}/lib/libglobus_openssl_error_${globus_flavor_type}.a"
 942         libopenssl="${gsi_path}/lib/libglobus_openssl_${globus_flavor_type}.a"
 943
 944         if test -r ${libgsi_proxy_core} \
 945              -a -r ${libgsi_credential} \
 946              -a -r ${libgsi_callback} \
 947              -a -r ${liboldgaa} \
 948              -a -r ${libgsi_sysconfig} \
 949              -a -r ${libproxy_ssl} \
 950              -a -r ${libgsi_cert_utils} \
 951              -a -r ${libopenssl_error} \
 952              -a -r ${libopenssl} ; then
 953                 LIBS="$LIBS ${libgsi_proxy_core}"
 954                 LIBS="$LIBS ${libgsi_credential}"
 955                 LIBS="$LIBS ${libgsi_callback}"
 956                 LIBS="$LIBS ${liboldgaa}"
 957                 LIBS="$LIBS ${libgsi_sysconfig}"
 958                 LIBS="$LIBS ${libproxy_ssl}"
 959                 LIBS="$LIBS ${libgsi_cert_utils}"
 960                 LIBS="$LIBS ${libopenssl_error}"
 961                 LIBS="$LIBS ${libopenssl}"
 962         elif test -r ${libssl_utils}; then
 963                 LIBS="$LIBS ${libssl_utils}"
 964         else
 965                 AC_MSG_ERROR([*** missing one or more Globus GSI libraries])
 966         fi
 967
 968         AC_MSG_CHECKING(for Globus GSI libraries)
 969         AC_TRY_LINK(
 970                 [],
 971                 [],
 972                 [
 973                         AC_MSG_RESULT(yes)
 974                 ],
 975                 [
 976                         AC_MSG_ERROR([*** missing one or more Globus GSI libraries])
 977                 ]
 978         )
 979
 980         #
 981         # Standard openssl libraries.  They need to appear near the end of the link line.
 982         #
 983
 984         LIBS="$LIBS ${gsi_path}/lib/libssl_${globus_flavor_type}.a"
 985         LIBS="$LIBS ${gsi_path}/lib/libcrypto_${globus_flavor_type}.a"
 986
 987         AC_MSG_CHECKING(for Globus OpenSSL libraries)
 988         AC_TRY_LINK(
 989                 [],
 990                 [],
 991                 [
 992                         AC_MSG_RESULT(yes)
 993                 ],
 994                 [
 995                         AC_MSG_ERROR([*** missing one or more Globus OpenSSL libraries])
 996                 ]
 997         )
 998
 999         #
1000         # Another "GT 2.1.3+"ism.
1001         #
1002
1003         libcommon_path="${gsi_path}/lib/libglobus_common_${globus_flavor_type}.a"
1004         if test -r ${libcommon_path}; then
1005                 LIBS="$LIBS ${libcommon_path}"
1006                 AC_MSG_CHECKING(for libglobus_common)
1007                 AC_TRY_LINK(
1008                         [],
1009                         [],
1010                         [
1011                                 AC_MSG_RESULT(yes)
1012                         ],
1013                         [
1014                                 AC_MSG_ERROR([*** libglobus_common missing])
1015                         ]
1016                 )
1017         fi
1018 else
1019         if test "x$gsi_path" != "xno" ; then
1020                 # Older GSI needs -lssl too
1021                 LIBS="$LIBS -lssl -lcrypto"
1022         else # if no GSI authentication (i.e., OpenSSL default)
1023                 LIBS="$LIBS -lcrypto"
1024         fi
1025 fi # globus_flavor_type
1026
1027 AC_TRY_LINK_FUNC(RAND_add, AC_DEFINE(HAVE_OPENSSL),
1028         [
1029                 dnl Check default openssl install dir
1030                 if test -n "${need_dash_r}"; then
1031                         LDFLAGS="-L/usr/local/ssl/lib -R/usr/local/ssl/lib ${saved_LDFLAGS}"
1032                 else
1033                         LDFLAGS="-L/usr/local/ssl/lib ${saved_LDFLAGS}"
1034                 fi
1035                 CPPFLAGS="-I/usr/local/ssl/include ${saved_CPPFLAGS}"
1036                 AC_TRY_LINK_FUNC(RAND_add, AC_DEFINE(HAVE_OPENSSL),
1037                         [
1038                                 AC_MSG_ERROR([*** Can't find recent OpenSSL libcrypto (see config.log for details) ***])
1039                         ]
1040                 )
1041         ]
1042 )
1043
1044 # Determine OpenSSL header version
1045 AC_MSG_CHECKING([OpenSSL header version])
1046 AC_TRY_RUN(
1047         [
1048 #include <stdio.h>
1049 #include <string.h>
1050 #include <openssl/opensslv.h>
1051 #define DATA "conftest.sslincver"
1052 int main(void) {
1053         FILE *fd;
1054         int rc;
1055
1056         fd = fopen(DATA,"w");
1057         if(fd == NULL)
1058                 exit(1);
1059
1060         if ((rc = fprintf(fd ,"%x (%s)\n", OPENSSL_VERSION_NUMBER, OPENSSL_VERSION_TEXT)) <0)
1061                 exit(1);
1062
1063         exit(0);
1064 }
1065         ],
1066         [
1067                 ssl_header_ver=`cat conftest.sslincver`
1068                 AC_MSG_RESULT($ssl_header_ver)
1069         ],
1070         [
1071                 AC_MSG_RESULT(not found)
1072                 AC_MSG_ERROR(OpenSSL version header not found.)
1073         ]
1074 )
1075
1076 # Determine OpenSSL library version
1077 AC_MSG_CHECKING([OpenSSL library version])
1078 AC_TRY_RUN(
1079         [
1080 #include <stdio.h>
1081 #include <string.h>
1082 #include <openssl/opensslv.h>
1083 #include <openssl/crypto.h>
1084 #define DATA "conftest.ssllibver"
1085 int main(void) {
1086         FILE *fd;
1087         int rc;
1088
1089         fd = fopen(DATA,"w");
1090         if(fd == NULL)
1091                 exit(1);
1092
1093         if ((rc = fprintf(fd ,"%x (%s)\n", SSLeay(), SSLeay_version(SSLEAY_VERSION))) <0)
1094                 exit(1);
1095
1096         exit(0);
1097 }
1098         ],
1099         [
1100                 ssl_library_ver=`cat conftest.ssllibver`
1101                 AC_MSG_RESULT($ssl_library_ver)
1102         ],
1103         [
1104                 AC_MSG_RESULT(not found)
1105                 AC_MSG_ERROR(OpenSSL library not found.)
1106         ]
1107 )
1108
1109 # Sanity check OpenSSL headers
1110 AC_MSG_CHECKING([whether OpenSSL's headers match the library])
1111 AC_TRY_RUN(
1112         [
1113 #include <string.h>
1114 #include <openssl/opensslv.h>
1115 int main(void) { exit(SSLeay() == OPENSSL_VERSION_NUMBER ? 0 : 1); }
1116         ],
1117         [
1118                 AC_MSG_RESULT(yes)
1119         ],
1120         [
1121                 AC_MSG_RESULT(no)
1122                 AC_MSG_ERROR(Your OpenSSL headers do not match your library)
1123         ]
1124 )
1125
1126 # Some Linux systems (Slackware) need crypt() from libcrypt, *not* the
1127 # version in OpenSSL. Skip this for PAM
1128 if test "x$PAM_MSG" = "xno" -a "x$check_for_libcrypt_later" = "x1"; then
1129         AC_CHECK_LIB(crypt, crypt, LIBS="$LIBS -lcrypt")
1130 fi
1131
1132
1133 ### Configure cryptographic random number support
1134
1135 # Check wheter OpenSSL seeds itself
1136 AC_MSG_CHECKING([whether OpenSSL's PRNG is internally seeded])
1137 AC_TRY_RUN(
1138         [
1139 #include <string.h>
1140 #include <openssl/rand.h>
1141 int main(void) { exit(RAND_status() == 1 ? 0 : 1); }
1142         ],
1143         [
1144                 OPENSSL_SEEDS_ITSELF=yes
1145                 AC_MSG_RESULT(yes)
1146         ],
1147         [
1148                 AC_MSG_RESULT(no)
1149                 # Default to use of the rand helper if OpenSSL doesn't
1150                 # seed itself
1151                 USE_RAND_HELPER=yes
1152         ]
1153 )
1154
1155
1156 # Do we want to force the use of the rand helper?
1157 AC_ARG_WITH(rand-helper,
1158         [  --with-rand-helper      Use subprocess to gather strong randomness ],
1159         [
1160                 if test "x$withval" = "xno" ; then
1161                         # Force use of OpenSSL's internal RNG, even if
1162                         # the previous test showed it to be unseeded.
1163                         if test -z "$OPENSSL_SEEDS_ITSELF" ; then
1164                                 AC_MSG_WARN([*** Forcing use of OpenSSL's non-self-seeding PRNG])
1165                                 OPENSSL_SEEDS_ITSELF=yes
1166                                 USE_RAND_HELPER=""
1167                         fi
1168                 else
1169                         USE_RAND_HELPER=yes
1170                 fi
1171         ],
1172 )
1173
1174 # Which randomness source do we use?
1175 if test ! -z "$OPENSSL_SEEDS_ITSELF" -a -z "$USE_RAND_HELPER" ; then
1176         # OpenSSL only
1177         AC_DEFINE(OPENSSL_PRNG_ONLY)
1178         RAND_MSG="OpenSSL internal ONLY"
1179         INSTALL_SSH_RAND_HELPER=""
1180 elif test ! -z "$USE_RAND_HELPER" ; then
1181         # install rand helper
1182         RAND_MSG="ssh-rand-helper"
1183         INSTALL_SSH_RAND_HELPER="yes"
1184 fi
1185 AC_SUBST(INSTALL_SSH_RAND_HELPER)
1186
1187 ### Configuration of ssh-rand-helper
1188
1189 # PRNGD TCP socket
1190 AC_ARG_WITH(prngd-port,
1191         [  --with-prngd-port=PORT  read entropy from PRNGD/EGD TCP localhost:PORT],
1192         [
1193                 case "$withval" in
1194                 no)
1195                         withval=""
1196                         ;;
1197                 [[0-9]]*)
1198                         ;;
1199                 *)
1200                         AC_MSG_ERROR(You must specify a numeric port number for --with-prngd-port)
1201                         ;;
1202                 esac
1203                 if test ! -z "$withval" ; then
1204                         PRNGD_PORT="$withval"
1205                         AC_DEFINE_UNQUOTED(PRNGD_PORT, $PRNGD_PORT)
1206                 fi
1207         ]
1208 )
1209
1210 # PRNGD Unix domain socket
1211 AC_ARG_WITH(prngd-socket,
1212         [  --with-prngd-socket=FILE read entropy from PRNGD/EGD socket FILE (default=/var/run/egd-pool)],
1213         [
1214                 case "$withval" in
1215                 yes)
1216                         withval="/var/run/egd-pool"
1217                         ;;
1218                 no)
1219                         withval=""
1220                         ;;
1221                 /*)
1222                         ;;
1223                 *)
1224                         AC_MSG_ERROR(You must specify an absolute path to the entropy socket)
1225                         ;;
1226                 esac
1227
1228                 if test ! -z "$withval" ; then
1229                         if test ! -z "$PRNGD_PORT" ; then
1230                                 AC_MSG_ERROR(You may not specify both a PRNGD/EGD port and socket)
1231                         fi
1232                         if test ! -r "$withval" ; then
1233                                 AC_MSG_WARN(Entropy socket is not readable)
1234                         fi
1235                         PRNGD_SOCKET="$withval"
1236                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1237                 fi
1238         ],
1239         [
1240                 # Check for existing socket only if we don't have a random device already
1241                 if test "$USE_RAND_HELPER" = yes ; then
1242                         AC_MSG_CHECKING(for PRNGD/EGD socket)
1243                         # Insert other locations here
1244                         for sock in /var/run/egd-pool /dev/egd-pool /etc/entropy; do
1245                                 if test -r $sock && $TEST_MINUS_S_SH -c "test -S $sock -o -p $sock" ; then
1246                                         PRNGD_SOCKET="$sock"
1247                                         AC_DEFINE_UNQUOTED(PRNGD_SOCKET, "$PRNGD_SOCKET")
1248                                         break;
1249                                 fi
1250                         done
1251                         if test ! -z "$PRNGD_SOCKET" ; then
1252                                 AC_MSG_RESULT($PRNGD_SOCKET)
1253                         else
1254                                 AC_MSG_RESULT(not found)
1255                         fi
1256                 fi
1257         ]
1258 )
1259
1260 # Change default command timeout for hashing entropy source
1261 entropy_timeout=200
1262 AC_ARG_WITH(entropy-timeout,
1263         [  --with-entropy-timeout  Specify entropy gathering command timeout (msec)],
1264         [
1265                 if test "x$withval" != "xno" ; then
1266                         entropy_timeout=$withval
1267                 fi
1268         ]
1269 )
1270 AC_DEFINE_UNQUOTED(ENTROPY_TIMEOUT_MSEC, $entropy_timeout)
1271
1272 SSH_PRIVSEP_USER=sshd
1273 AC_ARG_WITH(privsep-user,
1274         [  --with-privsep-user=user Specify non-privileged user for privilege separation],
1275         [
1276                 if test -n "$withval"; then
1277                         SSH_PRIVSEP_USER=$withval
1278                 fi
1279         ]
1280 )
1281 AC_DEFINE_UNQUOTED(SSH_PRIVSEP_USER, "$SSH_PRIVSEP_USER")
1282 AC_SUBST(SSH_PRIVSEP_USER)
1283
1284 # We do this little dance with the search path to insure
1285 # that programs that we select for use by installed programs
1286 # (which may be run by the super-user) come from trusted
1287 # locations before they come from the user's private area.
1288 # This should help avoid accidentally configuring some
1289 # random version of a program in someone's personal bin.
1290
1291 OPATH=$PATH
1292 PATH=/bin:/usr/bin
1293 test -h /bin 2> /dev/null && PATH=/usr/bin
1294 test -d /sbin && PATH=$PATH:/sbin
1295 test -d /usr/sbin && PATH=$PATH:/usr/sbin
1296 PATH=$PATH:/etc:$OPATH
1297
1298 # These programs are used by the command hashing source to gather entropy
1299 OSSH_PATH_ENTROPY_PROG(PROG_LS, ls)
1300 OSSH_PATH_ENTROPY_PROG(PROG_NETSTAT, netstat)
1301 OSSH_PATH_ENTROPY_PROG(PROG_ARP, arp)
1302 OSSH_PATH_ENTROPY_PROG(PROG_IFCONFIG, ifconfig)
1303 OSSH_PATH_ENTROPY_PROG(PROG_JSTAT, jstat)
1304 OSSH_PATH_ENTROPY_PROG(PROG_PS, ps)
1305 OSSH_PATH_ENTROPY_PROG(PROG_SAR, sar)
1306 OSSH_PATH_ENTROPY_PROG(PROG_W, w)
1307 OSSH_PATH_ENTROPY_PROG(PROG_WHO, who)
1308 OSSH_PATH_ENTROPY_PROG(PROG_LAST, last)
1309 OSSH_PATH_ENTROPY_PROG(PROG_LASTLOG, lastlog)
1310 OSSH_PATH_ENTROPY_PROG(PROG_DF, df)
1311 OSSH_PATH_ENTROPY_PROG(PROG_VMSTAT, vmstat)
1312 OSSH_PATH_ENTROPY_PROG(PROG_UPTIME, uptime)
1313 OSSH_PATH_ENTROPY_PROG(PROG_IPCS, ipcs)
1314 OSSH_PATH_ENTROPY_PROG(PROG_TAIL, tail)
1315 # restore PATH
1316 PATH=$OPATH
1317
1318 # Where does ssh-rand-helper get its randomness from?
1319 INSTALL_SSH_PRNG_CMDS=""
1320 if test ! -z "$INSTALL_SSH_RAND_HELPER" ; then
1321         if test ! -z "$PRNGD_PORT" ; then
1322                 RAND_HELPER_MSG="TCP localhost:$PRNGD_PORT"
1323         elif test ! -z "$PRNGD_SOCKET" ; then
1324                 RAND_HELPER_MSG="Unix domain socket \"$PRNGD_SOCKET\""
1325         else
1326                 RAND_HELPER_MSG="Command hashing (timeout $entropy_timeout)"
1327                 RAND_HELPER_CMDHASH=yes
1328                 INSTALL_SSH_PRNG_CMDS="yes"
1329         fi
1330 fi
1331 AC_SUBST(INSTALL_SSH_PRNG_CMDS)
1332
1333
1334 # Cheap hack to ensure NEWS-OS libraries are arranged right.
1335 if test ! -z "$SONY" ; then
1336   LIBS="$LIBS -liberty";
1337 fi
1338
1339 # Checks for data types
1340 AC_CHECK_SIZEOF(char, 1)
1341 AC_CHECK_SIZEOF(short int, 2)
1342 AC_CHECK_SIZEOF(int, 4)
1343 AC_CHECK_SIZEOF(long int, 4)
1344 AC_CHECK_SIZEOF(long long int, 8)
1345
1346 # Sanity check long long for some platforms (AIX)
1347 if test "x$ac_cv_sizeof_long_long_int" = "x4" ; then
1348         ac_cv_sizeof_long_long_int=0
1349 fi
1350
1351 # More checks for data types
1352 AC_CACHE_CHECK([for u_int type], ac_cv_have_u_int, [
1353         AC_TRY_COMPILE(
1354                 [ #include <sys/types.h> ],
1355                 [ u_int a; a = 1;],
1356                 [ ac_cv_have_u_int="yes" ],
1357                 [ ac_cv_have_u_int="no" ]
1358         )
1359 ])
1360 if test "x$ac_cv_have_u_int" = "xyes" ; then
1361         AC_DEFINE(HAVE_U_INT)
1362         have_u_int=1
1363 fi
1364
1365 AC_CACHE_CHECK([for intXX_t types], ac_cv_have_intxx_t, [
1366         AC_TRY_COMPILE(
1367                 [ #include <sys/types.h> ],
1368                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
1369                 [ ac_cv_have_intxx_t="yes" ],
1370                 [ ac_cv_have_intxx_t="no" ]
1371         )
1372 ])
1373 if test "x$ac_cv_have_intxx_t" = "xyes" ; then
1374         AC_DEFINE(HAVE_INTXX_T)
1375         have_intxx_t=1
1376 fi
1377
1378 if (test -z "$have_intxx_t" && \
1379            test "x$ac_cv_header_stdint_h" = "xyes")
1380 then
1381     AC_MSG_CHECKING([for intXX_t types in stdint.h])
1382         AC_TRY_COMPILE(
1383                 [ #include <stdint.h> ],
1384                 [ int8_t a; int16_t b; int32_t c; a = b = c = 1;],
1385                 [
1386                         AC_DEFINE(HAVE_INTXX_T)
1387                         AC_MSG_RESULT(yes)
1388                 ],
1389                 [ AC_MSG_RESULT(no) ]
1390         )
1391 fi
1392
1393 AC_CACHE_CHECK([for int64_t type], ac_cv_have_int64_t, [
1394         AC_TRY_COMPILE(
1395                 [
1396 #include <sys/types.h>
1397 #ifdef HAVE_STDINT_H
1398 # include <stdint.h>
1399 #endif
1400 #include <sys/socket.h>
1401 #ifdef HAVE_SYS_BITYPES_H
1402 # include <sys/bitypes.h>
1403 #endif
1404                 ],
1405                 [ int64_t a; a = 1;],
1406                 [ ac_cv_have_int64_t="yes" ],
1407                 [ ac_cv_have_int64_t="no" ]
1408         )
1409 ])
1410 if test "x$ac_cv_have_int64_t" = "xyes" ; then
1411         AC_DEFINE(HAVE_INT64_T)
1412 fi
1413
1414 AC_CACHE_CHECK([for u_intXX_t types], ac_cv_have_u_intxx_t, [
1415         AC_TRY_COMPILE(
1416                 [ #include <sys/types.h> ],
1417                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
1418                 [ ac_cv_have_u_intxx_t="yes" ],
1419                 [ ac_cv_have_u_intxx_t="no" ]
1420         )
1421 ])
1422 if test "x$ac_cv_have_u_intxx_t" = "xyes" ; then
1423         AC_DEFINE(HAVE_U_INTXX_T)
1424         have_u_intxx_t=1
1425 fi
1426
1427 if test -z "$have_u_intxx_t" ; then
1428     AC_MSG_CHECKING([for u_intXX_t types in sys/socket.h])
1429         AC_TRY_COMPILE(
1430                 [ #include <sys/socket.h> ],
1431                 [ u_int8_t a; u_int16_t b; u_int32_t c; a = b = c = 1;],
1432                 [
1433                         AC_DEFINE(HAVE_U_INTXX_T)
1434                         AC_MSG_RESULT(yes)
1435                 ],
1436                 [ AC_MSG_RESULT(no) ]
1437         )
1438 fi
1439
1440 AC_CACHE_CHECK([for u_int64_t types], ac_cv_have_u_int64_t, [
1441         AC_TRY_COMPILE(
1442                 [ #include <sys/types.h> ],
1443                 [ u_int64_t a; a = 1;],
1444                 [ ac_cv_have_u_int64_t="yes" ],
1445                 [ ac_cv_have_u_int64_t="no" ]
1446         )
1447 ])
1448 if test "x$ac_cv_have_u_int64_t" = "xyes" ; then
1449         AC_DEFINE(HAVE_U_INT64_T)
1450         have_u_int64_t=1
1451 fi
1452
1453 if test -z "$have_u_int64_t" ; then
1454     AC_MSG_CHECKING([for u_int64_t type in sys/bitypes.h])
1455         AC_TRY_COMPILE(
1456                 [ #include <sys/bitypes.h> ],
1457                 [ u_int64_t a; a = 1],
1458                 [
1459                         AC_DEFINE(HAVE_U_INT64_T)
1460                         AC_MSG_RESULT(yes)
1461                 ],
1462                 [ AC_MSG_RESULT(no) ]
1463         )
1464 fi
1465
1466 if test -z "$have_u_intxx_t" ; then
1467         AC_CACHE_CHECK([for uintXX_t types], ac_cv_have_uintxx_t, [
1468                 AC_TRY_COMPILE(
1469                         [
1470 #include <sys/types.h>
1471                         ],
1472                         [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1; ],
1473                         [ ac_cv_have_uintxx_t="yes" ],
1474                         [ ac_cv_have_uintxx_t="no" ]
1475                 )
1476         ])
1477         if test "x$ac_cv_have_uintxx_t" = "xyes" ; then
1478                 AC_DEFINE(HAVE_UINTXX_T)
1479         fi
1480 fi
1481
1482 if test -z "$have_uintxx_t" ; then
1483     AC_MSG_CHECKING([for uintXX_t types in stdint.h])
1484         AC_TRY_COMPILE(
1485                 [ #include <stdint.h> ],
1486                 [ uint8_t a; uint16_t b; uint32_t c; a = b = c = 1;],
1487                 [
1488                         AC_DEFINE(HAVE_UINTXX_T)
1489                         AC_MSG_RESULT(yes)
1490                 ],
1491                 [ AC_MSG_RESULT(no) ]
1492         )
1493 fi
1494
1495 if (test -z "$have_u_intxx_t" || test -z "$have_intxx_t" && \
1496            test "x$ac_cv_header_sys_bitypes_h" = "xyes")
1497 then
1498         AC_MSG_CHECKING([for intXX_t and u_intXX_t types in sys/bitypes.h])
1499         AC_TRY_COMPILE(
1500                 [
1501 #include <sys/bitypes.h>
1502                 ],
1503                 [
1504                         int8_t a; int16_t b; int32_t c;
1505                         u_int8_t e; u_int16_t f; u_int32_t g;
1506                         a = b = c = e = f = g = 1;
1507                 ],
1508                 [
1509                         AC_DEFINE(HAVE_U_INTXX_T)
1510                         AC_DEFINE(HAVE_INTXX_T)
1511                         AC_MSG_RESULT(yes)
1512                 ],
1513                 [AC_MSG_RESULT(no)]
1514         )
1515 fi
1516
1517
1518 AC_CACHE_CHECK([for u_char], ac_cv_have_u_char, [
1519         AC_TRY_COMPILE(
1520                 [
1521 #include <sys/types.h>
1522                 ],
1523                 [ u_char foo; foo = 125; ],
1524                 [ ac_cv_have_u_char="yes" ],
1525                 [ ac_cv_have_u_char="no" ]
1526         )
1527 ])
1528 if test "x$ac_cv_have_u_char" = "xyes" ; then
1529         AC_DEFINE(HAVE_U_CHAR)
1530 fi
1531
1532 TYPE_SOCKLEN_T
1533
1534 AC_CHECK_TYPES(sig_atomic_t,,,[#include <signal.h>])
1535
1536 AC_CACHE_CHECK([for size_t], ac_cv_have_size_t, [
1537         AC_TRY_COMPILE(
1538                 [
1539 #include <sys/types.h>
1540                 ],
1541                 [ size_t foo; foo = 1235; ],
1542                 [ ac_cv_have_size_t="yes" ],
1543                 [ ac_cv_have_size_t="no" ]
1544         )
1545 ])
1546 if test "x$ac_cv_have_size_t" = "xyes" ; then
1547         AC_DEFINE(HAVE_SIZE_T)
1548 fi
1549
1550 AC_CACHE_CHECK([for ssize_t], ac_cv_have_ssize_t, [
1551         AC_TRY_COMPILE(
1552                 [
1553 #include <sys/types.h>
1554                 ],
1555                 [ ssize_t foo; foo = 1235; ],
1556                 [ ac_cv_have_ssize_t="yes" ],
1557                 [ ac_cv_have_ssize_t="no" ]
1558         )
1559 ])
1560 if test "x$ac_cv_have_ssize_t" = "xyes" ; then
1561         AC_DEFINE(HAVE_SSIZE_T)
1562 fi
1563
1564 AC_CACHE_CHECK([for clock_t], ac_cv_have_clock_t, [
1565         AC_TRY_COMPILE(
1566                 [
1567 #include <time.h>
1568                 ],
1569                 [ clock_t foo; foo = 1235; ],
1570                 [ ac_cv_have_clock_t="yes" ],
1571                 [ ac_cv_have_clock_t="no" ]
1572         )
1573 ])
1574 if test "x$ac_cv_have_clock_t" = "xyes" ; then
1575         AC_DEFINE(HAVE_CLOCK_T)
1576 fi
1577
1578 AC_CACHE_CHECK([for sa_family_t], ac_cv_have_sa_family_t, [
1579         AC_TRY_COMPILE(
1580                 [
1581 #include <sys/types.h>
1582 #include <sys/socket.h>
1583                 ],
1584                 [ sa_family_t foo; foo = 1235; ],
1585                 [ ac_cv_have_sa_family_t="yes" ],
1586                 [ AC_TRY_COMPILE(
1587                   [
1588 #include <sys/types.h>
1589 #include <sys/socket.h>
1590 #include <netinet/in.h>
1591                 ],
1592                 [ sa_family_t foo; foo = 1235; ],
1593                 [ ac_cv_have_sa_family_t="yes" ],
1594
1595                 [ ac_cv_have_sa_family_t="no" ]
1596         )]
1597         )
1598 ])
1599 if test "x$ac_cv_have_sa_family_t" = "xyes" ; then
1600         AC_DEFINE(HAVE_SA_FAMILY_T)
1601 fi
1602
1603 AC_CACHE_CHECK([for pid_t], ac_cv_have_pid_t, [
1604         AC_TRY_COMPILE(
1605                 [
1606 #include <sys/types.h>
1607                 ],
1608                 [ pid_t foo; foo = 1235; ],
1609                 [ ac_cv_have_pid_t="yes" ],
1610                 [ ac_cv_have_pid_t="no" ]
1611         )
1612 ])
1613 if test "x$ac_cv_have_pid_t" = "xyes" ; then
1614         AC_DEFINE(HAVE_PID_T)
1615 fi
1616
1617 AC_CACHE_CHECK([for mode_t], ac_cv_have_mode_t, [
1618         AC_TRY_COMPILE(
1619                 [
1620 #include <sys/types.h>
1621                 ],
1622                 [ mode_t foo; foo = 1235; ],
1623                 [ ac_cv_have_mode_t="yes" ],
1624                 [ ac_cv_have_mode_t="no" ]
1625         )
1626 ])
1627 if test "x$ac_cv_have_mode_t" = "xyes" ; then
1628         AC_DEFINE(HAVE_MODE_T)
1629 fi
1630
1631
1632 AC_CACHE_CHECK([for struct sockaddr_storage], ac_cv_have_struct_sockaddr_storage, [
1633         AC_TRY_COMPILE(
1634                 [
1635 #include <sys/types.h>
1636 #include <sys/socket.h>
1637                 ],
1638                 [ struct sockaddr_storage s; ],
1639                 [ ac_cv_have_struct_sockaddr_storage="yes" ],
1640                 [ ac_cv_have_struct_sockaddr_storage="no" ]
1641         )
1642 ])
1643 if test "x$ac_cv_have_struct_sockaddr_storage" = "xyes" ; then
1644         AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE)
1645 fi
1646
1647 AC_CACHE_CHECK([for struct sockaddr_in6], ac_cv_have_struct_sockaddr_in6, [
1648         AC_TRY_COMPILE(
1649                 [
1650 #include <sys/types.h>
1651 #include <netinet/in.h>
1652                 ],
1653                 [ struct sockaddr_in6 s; s.sin6_family = 0; ],
1654                 [ ac_cv_have_struct_sockaddr_in6="yes" ],
1655                 [ ac_cv_have_struct_sockaddr_in6="no" ]
1656         )
1657 ])
1658 if test "x$ac_cv_have_struct_sockaddr_in6" = "xyes" ; then
1659         AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6)
1660 fi
1661
1662 AC_CACHE_CHECK([for struct in6_addr], ac_cv_have_struct_in6_addr, [
1663         AC_TRY_COMPILE(
1664                 [
1665 #include <sys/types.h>
1666 #include <netinet/in.h>
1667                 ],
1668                 [ struct in6_addr s; s.s6_addr[0] = 0; ],
1669                 [ ac_cv_have_struct_in6_addr="yes" ],
1670                 [ ac_cv_have_struct_in6_addr="no" ]
1671         )
1672 ])
1673 if test "x$ac_cv_have_struct_in6_addr" = "xyes" ; then
1674         AC_DEFINE(HAVE_STRUCT_IN6_ADDR)
1675 fi
1676
1677 AC_CACHE_CHECK([for struct addrinfo], ac_cv_have_struct_addrinfo, [
1678         AC_TRY_COMPILE(
1679                 [
1680 #include <sys/types.h>
1681 #include <sys/socket.h>
1682 #include <netdb.h>
1683                 ],
1684                 [ struct addrinfo s; s.ai_flags = AI_PASSIVE; ],
1685                 [ ac_cv_have_struct_addrinfo="yes" ],
1686                 [ ac_cv_have_struct_addrinfo="no" ]
1687         )
1688 ])
1689 if test "x$ac_cv_have_struct_addrinfo" = "xyes" ; then
1690         AC_DEFINE(HAVE_STRUCT_ADDRINFO)
1691 fi
1692
1693 AC_CACHE_CHECK([for struct timeval], ac_cv_have_struct_timeval, [
1694         AC_TRY_COMPILE(
1695                 [ #include <sys/time.h> ],
1696                 [ struct timeval tv; tv.tv_sec = 1;],
1697                 [ ac_cv_have_struct_timeval="yes" ],
1698                 [ ac_cv_have_struct_timeval="no" ]
1699         )
1700 ])
1701 if test "x$ac_cv_have_struct_timeval" = "xyes" ; then
1702         AC_DEFINE(HAVE_STRUCT_TIMEVAL)
1703         have_struct_timeval=1
1704 fi
1705
1706 # If we don't have int64_t then we can't compile sftp-server.  So don't
1707 # even attempt to do it.
1708 if test "x$ac_cv_have_int64_t" = "xno" -a \
1709         "x$ac_cv_sizeof_long_int" != "x8" -a \
1710         "x$ac_cv_sizeof_long_long_int" = "x0" ; then
1711         NO_SFTP='#'
1712 else
1713 dnl test snprintf (broken on SCO w/gcc)
1714         AC_TRY_RUN(
1715                 [
1716 #include <stdio.h>
1717 #include <string.h>
1718 #ifdef HAVE_SNPRINTF
1719 main()
1720 {
1721         char buf[50];
1722         char expected_out[50];
1723         int mazsize = 50 ;
1724 #if (SIZEOF_LONG_INT == 8)
1725         long int num = 0x7fffffffffffffff;
1726 #else
1727         long long num = 0x7fffffffffffffffll;
1728 #endif
1729         strcpy(expected_out, "9223372036854775807");
1730         snprintf(buf, mazsize, "%lld", num);
1731         if(strcmp(buf, expected_out) != 0)
1732                 exit(1);
1733         exit(0);
1734 }
1735 #else
1736 main() { exit(0); }
1737 #endif
1738                 ], [ true ], [ AC_DEFINE(BROKEN_SNPRINTF) ]
1739         )
1740 fi
1741 AC_SUBST(NO_SFTP)
1742
1743 dnl Checks for structure members
1744 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmp.h, HAVE_HOST_IN_UTMP)
1745 OSSH_CHECK_HEADER_FOR_FIELD(ut_host, utmpx.h, HAVE_HOST_IN_UTMPX)
1746 OSSH_CHECK_HEADER_FOR_FIELD(syslen, utmpx.h, HAVE_SYSLEN_IN_UTMPX)
1747 OSSH_CHECK_HEADER_FOR_FIELD(ut_pid, utmp.h, HAVE_PID_IN_UTMP)
1748 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmp.h, HAVE_TYPE_IN_UTMP)
1749 OSSH_CHECK_HEADER_FOR_FIELD(ut_type, utmpx.h, HAVE_TYPE_IN_UTMPX)
1750 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmp.h, HAVE_TV_IN_UTMP)
1751 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmp.h, HAVE_ID_IN_UTMP)
1752 OSSH_CHECK_HEADER_FOR_FIELD(ut_id, utmpx.h, HAVE_ID_IN_UTMPX)
1753 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmp.h, HAVE_ADDR_IN_UTMP)
1754 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr, utmpx.h, HAVE_ADDR_IN_UTMPX)
1755 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmp.h, HAVE_ADDR_V6_IN_UTMP)
1756 OSSH_CHECK_HEADER_FOR_FIELD(ut_addr_v6, utmpx.h, HAVE_ADDR_V6_IN_UTMPX)
1757 OSSH_CHECK_HEADER_FOR_FIELD(ut_exit, utmp.h, HAVE_EXIT_IN_UTMP)
1758 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmp.h, HAVE_TIME_IN_UTMP)
1759 OSSH_CHECK_HEADER_FOR_FIELD(ut_time, utmpx.h, HAVE_TIME_IN_UTMPX)
1760 OSSH_CHECK_HEADER_FOR_FIELD(ut_tv, utmpx.h, HAVE_TV_IN_UTMPX)
1761
1762 AC_CHECK_MEMBERS([struct stat.st_blksize])
1763
1764 AC_CACHE_CHECK([for ss_family field in struct sockaddr_storage],
1765                 ac_cv_have_ss_family_in_struct_ss, [
1766         AC_TRY_COMPILE(
1767                 [
1768 #include <sys/types.h>
1769 #include <sys/socket.h>
1770                 ],
1771                 [ struct sockaddr_storage s; s.ss_family = 1; ],
1772                 [ ac_cv_have_ss_family_in_struct_ss="yes" ],
1773                 [ ac_cv_have_ss_family_in_struct_ss="no" ],
1774         )
1775 ])
1776 if test "x$ac_cv_have_ss_family_in_struct_ss" = "xyes" ; then
1777         AC_DEFINE(HAVE_SS_FAMILY_IN_SS)
1778 fi
1779
1780 AC_CACHE_CHECK([for __ss_family field in struct sockaddr_storage],
1781                 ac_cv_have___ss_family_in_struct_ss, [
1782         AC_TRY_COMPILE(
1783                 [
1784 #include <sys/types.h>
1785 #include <sys/socket.h>
1786                 ],
1787                 [ struct sockaddr_storage s; s.__ss_family = 1; ],
1788                 [ ac_cv_have___ss_family_in_struct_ss="yes" ],
1789                 [ ac_cv_have___ss_family_in_struct_ss="no" ]
1790         )
1791 ])
1792 if test "x$ac_cv_have___ss_family_in_struct_ss" = "xyes" ; then
1793         AC_DEFINE(HAVE___SS_FAMILY_IN_SS)
1794 fi
1795
1796 AC_CACHE_CHECK([for pw_class field in struct passwd],
1797                 ac_cv_have_pw_class_in_struct_passwd, [
1798         AC_TRY_COMPILE(
1799                 [
1800 #include <pwd.h>
1801                 ],
1802                 [ struct passwd p; p.pw_class = 0; ],
1803                 [ ac_cv_have_pw_class_in_struct_passwd="yes" ],
1804                 [ ac_cv_have_pw_class_in_struct_passwd="no" ]
1805         )
1806 ])
1807 if test "x$ac_cv_have_pw_class_in_struct_passwd" = "xyes" ; then
1808         AC_DEFINE(HAVE_PW_CLASS_IN_PASSWD)
1809 fi
1810
1811 AC_CACHE_CHECK([for pw_expire field in struct passwd],
1812                 ac_cv_have_pw_expire_in_struct_passwd, [
1813         AC_TRY_COMPILE(
1814                 [
1815 #include <pwd.h>
1816                 ],
1817                 [ struct passwd p; p.pw_expire = 0; ],
1818                 [ ac_cv_have_pw_expire_in_struct_passwd="yes" ],
1819                 [ ac_cv_have_pw_expire_in_struct_passwd="no" ]
1820         )
1821 ])
1822 if test "x$ac_cv_have_pw_expire_in_struct_passwd" = "xyes" ; then
1823         AC_DEFINE(HAVE_PW_EXPIRE_IN_PASSWD)
1824 fi
1825
1826 AC_CACHE_CHECK([for pw_change field in struct passwd],
1827                 ac_cv_have_pw_change_in_struct_passwd, [
1828         AC_TRY_COMPILE(
1829                 [
1830 #include <pwd.h>
1831                 ],
1832                 [ struct passwd p; p.pw_change = 0; ],
1833                 [ ac_cv_have_pw_change_in_struct_passwd="yes" ],
1834                 [ ac_cv_have_pw_change_in_struct_passwd="no" ]
1835         )
1836 ])
1837 if test "x$ac_cv_have_pw_change_in_struct_passwd" = "xyes" ; then
1838         AC_DEFINE(HAVE_PW_CHANGE_IN_PASSWD)
1839 fi
1840
1841 dnl make sure we're using the real structure members and not defines
1842 AC_CACHE_CHECK([for msg_accrights field in struct msghdr],
1843                 ac_cv_have_accrights_in_msghdr, [
1844         AC_TRY_RUN(
1845                 [
1846 #include <sys/types.h>
1847 #include <sys/socket.h>
1848 #include <sys/uio.h>
1849 int main() {
1850 #ifdef msg_accrights
1851 exit(1);
1852 #endif
1853 struct msghdr m;
1854 m.msg_accrights = 0;
1855 exit(0);
1856 }
1857                 ],
1858                 [ ac_cv_have_accrights_in_msghdr="yes" ],
1859                 [ ac_cv_have_accrights_in_msghdr="no" ]
1860         )
1861 ])
1862 if test "x$ac_cv_have_accrights_in_msghdr" = "xyes" ; then
1863         AC_DEFINE(HAVE_ACCRIGHTS_IN_MSGHDR)
1864 fi
1865
1866 AC_CACHE_CHECK([for msg_control field in struct msghdr],
1867                 ac_cv_have_control_in_msghdr, [
1868         AC_TRY_RUN(
1869                 [
1870 #include <sys/types.h>
1871 #include <sys/socket.h>
1872 #include <sys/uio.h>
1873 int main() {
1874 #ifdef msg_control
1875 exit(1);
1876 #endif
1877 struct msghdr m;
1878 m.msg_control = 0;
1879 exit(0);
1880 }
1881                 ],
1882                 [ ac_cv_have_control_in_msghdr="yes" ],
1883                 [ ac_cv_have_control_in_msghdr="no" ]
1884         )
1885 ])
1886 if test "x$ac_cv_have_control_in_msghdr" = "xyes" ; then
1887         AC_DEFINE(HAVE_CONTROL_IN_MSGHDR)
1888 fi
1889
1890 AC_CACHE_CHECK([if libc defines __progname], ac_cv_libc_defines___progname, [
1891         AC_TRY_LINK([],
1892                 [ extern char *__progname; printf("%s", __progname); ],
1893                 [ ac_cv_libc_defines___progname="yes" ],
1894                 [ ac_cv_libc_defines___progname="no" ]
1895         )
1896 ])
1897 if test "x$ac_cv_libc_defines___progname" = "xyes" ; then
1898         AC_DEFINE(HAVE___PROGNAME)
1899 fi
1900
1901 AC_CACHE_CHECK([whether $CC implements __FUNCTION__], ac_cv_cc_implements___FUNCTION__, [
1902         AC_TRY_LINK([
1903 #include <stdio.h>
1904 ],
1905                 [ printf("%s", __FUNCTION__); ],
1906                 [ ac_cv_cc_implements___FUNCTION__="yes" ],
1907                 [ ac_cv_cc_implements___FUNCTION__="no" ]
1908         )
1909 ])
1910 if test "x$ac_cv_cc_implements___FUNCTION__" = "xyes" ; then
1911         AC_DEFINE(HAVE___FUNCTION__)
1912 fi
1913
1914 AC_CACHE_CHECK([whether $CC implements __func__], ac_cv_cc_implements___func__, [
1915         AC_TRY_LINK([
1916 #include <stdio.h>
1917 ],
1918                 [ printf("%s", __func__); ],
1919                 [ ac_cv_cc_implements___func__="yes" ],
1920                 [ ac_cv_cc_implements___func__="no" ]
1921         )
1922 ])
1923 if test "x$ac_cv_cc_implements___func__" = "xyes" ; then
1924         AC_DEFINE(HAVE___func__)
1925 fi
1926
1927 AC_CACHE_CHECK([whether getopt has optreset support],
1928                 ac_cv_have_getopt_optreset, [
1929         AC_TRY_LINK(
1930                 [
1931 #include <getopt.h>
1932                 ],
1933                 [ extern int optreset; optreset = 0; ],
1934                 [ ac_cv_have_getopt_optreset="yes" ],
1935                 [ ac_cv_have_getopt_optreset="no" ]
1936         )
1937 ])
1938 if test "x$ac_cv_have_getopt_optreset" = "xyes" ; then
1939         AC_DEFINE(HAVE_GETOPT_OPTRESET)
1940 fi
1941
1942 AC_CACHE_CHECK([if libc defines sys_errlist], ac_cv_libc_defines_sys_errlist, [
1943         AC_TRY_LINK([],
1944                 [ extern const char *const sys_errlist[]; printf("%s", sys_errlist[0]);],
1945                 [ ac_cv_libc_defines_sys_errlist="yes" ],
1946                 [ ac_cv_libc_defines_sys_errlist="no" ]
1947         )
1948 ])
1949 if test "x$ac_cv_libc_defines_sys_errlist" = "xyes" ; then
1950         AC_DEFINE(HAVE_SYS_ERRLIST)
1951 fi
1952
1953
1954 AC_CACHE_CHECK([if libc defines sys_nerr], ac_cv_libc_defines_sys_nerr, [
1955         AC_TRY_LINK([],
1956                 [ extern int sys_nerr; printf("%i", sys_nerr);],
1957                 [ ac_cv_libc_defines_sys_nerr="yes" ],
1958                 [ ac_cv_libc_defines_sys_nerr="no" ]
1959         )
1960 ])
1961 if test "x$ac_cv_libc_defines_sys_nerr" = "xyes" ; then
1962         AC_DEFINE(HAVE_SYS_NERR)
1963 fi
1964
1965 SCARD_MSG="no"
1966
1967 # Check whether user wants sectok support
1968 AC_ARG_WITH(sectok,
1969         [  --with-sectok           Enable smartcard support using libsectok],
1970         [
1971                 if test "x$withval" != "xno" ; then
1972                         if test "x$withval" != "xyes" ; then
1973                                 CPPFLAGS="$CPPFLAGS -I${withval}"
1974                                 LDFLAGS="$LDFLAGS -L${withval}"
1975                                 if test ! -z "$need_dash_r" ; then
1976                                         LDFLAGS="$LDFLAGS -R${withval}"
1977                                 fi
1978                                 if test ! -z "$blibpath" ; then
1979                                         blibpath="$blibpath:${withval}"
1980                                 fi
1981                         fi
1982                         AC_CHECK_HEADERS(sectok.h)
1983                         if test "$ac_cv_header_sectok_h" != yes; then
1984                                 AC_MSG_ERROR(Can't find sectok.h)
1985                         fi
1986                         AC_CHECK_LIB(sectok, sectok_open)
1987                         if test "$ac_cv_lib_sectok_sectok_open" != yes; then
1988                                 AC_MSG_ERROR(Can't find libsectok)
1989                         fi
1990                         AC_DEFINE(SMARTCARD)
1991                         AC_DEFINE(USE_SECTOK)
1992                         SCARD_MSG="yes, using sectok"
1993                 fi
1994         ]
1995 )
1996
1997 # Check whether user wants OpenSC support
1998 AC_ARG_WITH(opensc,
1999         AC_HELP_STRING([--with-opensc=PFX],
2000                        [Enable smartcard support using OpenSC]),
2001         opensc_config_prefix="$withval", opensc_config_prefix="")
2002 if test x$opensc_config_prefix != x ; then
2003   OPENSC_CONFIG=$opensc_config_prefix/bin/opensc-config
2004   AC_PATH_PROG(OPENSC_CONFIG, opensc-config, no)
2005   if test "$OPENSC_CONFIG" != "no"; then
2006     LIBOPENSC_CFLAGS=`$OPENSC_CONFIG --cflags`
2007     LIBOPENSC_LIBS=`$OPENSC_CONFIG --libs`
2008     CPPFLAGS="$CPPFLAGS $LIBOPENSC_CFLAGS"
2009     LDFLAGS="$LDFLAGS $LIBOPENSC_LIBS"
2010     AC_DEFINE(SMARTCARD)
2011     AC_DEFINE(USE_OPENSC)
2012     SCARD_MSG="yes, using OpenSC"
2013   fi
2014 fi
2015
2016 # Check whether user wants Kerberos 5 support
2017 KRB5_MSG="no"
2018 AC_ARG_WITH(kerberos5,
2019         [  --with-kerberos5=PATH   Enable Kerberos 5 support],
2020         [
2021                 if test "x$withval" != "xno" ; then
2022                         if test "x$withval" = "xyes" ; then
2023                                 KRB5ROOT="/usr/local"
2024                         else
2025                                 KRB5ROOT=${withval}
2026                         fi
2027                         CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include"
2028                         LDFLAGS="$LDFLAGS -L${KRB5ROOT}/lib"
2029                         AC_DEFINE(KRB5)
2030                         KRB5_MSG="yes"
2031                         AC_MSG_CHECKING(whether we are using Heimdal)
2032                         AC_TRY_COMPILE([ #include <krb5.h> ],
2033                                        [ char *tmp = heimdal_version; ],
2034                                        [ AC_MSG_RESULT(yes)
2035                                          AC_DEFINE(HEIMDAL)
2036                                          K5LIBS="-lkrb5 -ldes -lcom_err -lasn1 -lroken"
2037                                        ],
2038                                        [ AC_MSG_RESULT(no)
2039                                          K5LIBS="-lkrb5 -lk5crypto -lcom_err"
2040                                        ]
2041                         )
2042                         if test ! -z "$need_dash_r" ; then
2043                                 LDFLAGS="$LDFLAGS -R${KRB5ROOT}/lib"
2044                         fi
2045                         if test ! -z "$blibpath" ; then
2046                                 blibpath="$blibpath:${KRB5ROOT}/lib"
2047                         fi
2048                         AC_CHECK_LIB(resolv, dn_expand, , )
2049
2050                         # If we're using some other GSSAPI
2051                         if test "$GSSAPI" -a "$GSSAPI" != "mechglue"; then
2052                                 AC_MSG_ERROR([$GSSAPI GSSAPI library conflicts with Kerberos support.  Use mechglue instead.])
2053                         fi
2054                         AC_CHECK_LIB(gssapi,gss_init_sec_context,
2055                                 [ AC_DEFINE(GSSAPI)
2056                                   K5LIBS="-lgssapi $K5LIBS" ],
2057                                 [ AC_CHECK_LIB(gssapi_krb5,gss_init_sec_context,
2058                                         [ AC_DEFINE(GSSAPI)
2059                                           K5LIBS="-lgssapi_krb5 $K5LIBS" ],
2060                                         AC_MSG_WARN([Cannot find any suitable gss-api library - build may fail]),
2061                                         $K5LIBS)
2062                                 ],
2063                                 $K5LIBS)
2064
2065                         AC_CHECK_HEADER(gssapi.h, ,
2066                                 [ unset ac_cv_header_gssapi_h
2067                                   CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include/gssapi"
2068                                   AC_CHECK_HEADERS(gssapi.h, ,
2069                                         AC_MSG_WARN([Cannot find any suitable gss-api header - build may fail])
2070                                   )
2071                                 ]
2072                         )
2073
2074                         AC_CHECK_LIB(gssapi, gss_krb5_copy_ccache, /bin/true,
2075                                 [ K5LIBS="-lgssapi_krb5 $K5LIBS"
2076                                   AC_CHECK_LIB(gssapi_krb5, gss_krb5_copy_ccache, /bin/true,
2077                                         AC_MSG_WARN([Cannot find gss_krb5_copy_ccache -- build may fail]),
2078                                         $K5LIBS)
2079                                 ],
2080                                 $K5LIBS)
2081
2082                         oldCPP="$CPPFLAGS"
2083                         CPPFLAGS="$CPPFLAGS -I${KRB5ROOT}/include/gssapi"
2084                         AC_CHECK_HEADER(gssapi_krb5.h, ,
2085                                         [ CPPFLAGS="$oldCPP" ])
2086
2087                         if test -z "$GSSAPI"; then
2088                                 GSSAPI="KRB5";
2089                         fi
2090
2091                         KRB5=yes
2092                 fi
2093         ]
2094 )
2095 # Check whether user wants Kerberos 4 support
2096 KRB4_MSG="no"
2097 AC_ARG_WITH(kerberos4,
2098         [  --with-kerberos4=PATH   Enable Kerberos 4 support],
2099         [
2100                 if test "x$withval" != "xno" ; then
2101                         if test "x$withval" != "xyes" ; then
2102                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
2103                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
2104                                 if test ! -z "$need_dash_r" ; then
2105                                         LDFLAGS="$LDFLAGS -R${withval}/lib"
2106                                 fi
2107                                 if test ! -z "$blibpath" ; then
2108                                         blibpath="$blibpath:${withval}/lib"
2109                                 fi
2110                         else
2111                                 if test -d /usr/include/kerberosIV ; then
2112                                         CPPFLAGS="$CPPFLAGS -I/usr/include/kerberosIV"
2113                                 fi
2114                         fi
2115
2116                         AC_CHECK_HEADERS(krb.h)
2117                         if test "$ac_cv_header_krb_h" != yes; then
2118                                 AC_MSG_WARN([Cannot find krb.h, build may fail])
2119                         fi
2120                         AC_CHECK_LIB(krb, main)
2121                         if test "$ac_cv_lib_krb_main" != yes; then
2122                                 AC_CHECK_LIB(krb4, main)
2123                                 if test "$ac_cv_lib_krb4_main" != yes; then
2124                                         AC_MSG_WARN([Cannot find libkrb nor libkrb4, build may fail])
2125                                 else
2126                                         KLIBS="-lkrb4"
2127                                 fi
2128                         else
2129                                 KLIBS="-lkrb"
2130                         fi
2131                         AC_CHECK_LIB(des, des_cbc_encrypt)
2132                         if test "$ac_cv_lib_des_des_cbc_encrypt" != yes; then
2133                                 AC_CHECK_LIB(des425, des_cbc_encrypt)
2134                                 if test "$ac_cv_lib_des425_des_cbc_encrypt" != yes; then
2135                                         AC_MSG_WARN([Cannot find libdes nor libdes425, build may fail])
2136                                 else
2137                                         KLIBS="-ldes425"
2138                                 fi
2139                         else
2140                                 KLIBS="-ldes"
2141                         fi
2142                         AC_CHECK_LIB(resolv, dn_expand, , )
2143                         KRB4=yes
2144                         KRB4_MSG="yes"
2145                         AC_DEFINE(KRB4)
2146                 fi
2147         ]
2148 )
2149
2150 # Check whether user wants AFS_KRB5 support
2151 AFS_KRB5_MSG="no"
2152 AC_ARG_WITH(afs-krb5,
2153         [  --with-afs-krb5[[=AKLOG_PATH]]  Enable aklog to get token (default=/usr/bin/aklog).],
2154         [
2155                 if test "x$withval" != "xno" ; then
2156
2157                         if test "x$withval" != "xyes" ; then
2158                                 AC_DEFINE_UNQUOTED(AKLOG_PATH, "$withval")
2159                         else
2160                                 AC_DEFINE_UNQUOTED(AKLOG_PATH, "/usr/bin/aklog")
2161                         fi
2162
2163                         if test -z "$KRB5" ; then
2164                                 AC_MSG_WARN([AFS_KRB5 requires Kerberos 5 support, build may fail])
2165                         fi
2166
2167                         LIBS="-lkrbafs $LIBS"
2168                         if test ! -z "$AFS_LIBS" ; then
2169                                 LIBS="$LIBS $AFS_LIBS"
2170                         fi
2171                         AC_DEFINE(AFS_KRB5)
2172                         AFS_KRB5_MSG="yes"
2173                 fi
2174         ]
2175 )
2176
2177 # Check whether user wants AFS support
2178 AFS_MSG="no"
2179 AC_ARG_WITH(afs,
2180         [  --with-afs=PATH         Enable AFS support],
2181         [
2182                 if test "x$withval" != "xno" ; then
2183
2184                         if test "x$withval" != "xyes" ; then
2185                                 CPPFLAGS="$CPPFLAGS -I${withval}/include"
2186                                 LDFLAGS="$LDFLAGS -L${withval}/lib"
2187                         fi
2188
2189                         if test -z "$KRB4" ; then
2190                                 AC_MSG_WARN([AFS requires Kerberos IV support, build may fail])
2191                         fi
2192
2193                         LIBS="-lkafs $LIBS"
2194                         if test ! -z "$AFS_LIBS" ; then
2195                                 LIBS="$LIBS $AFS_LIBS"
2196                         fi
2197                         AC_DEFINE(AFS)
2198                         AFS_MSG="yes"
2199                 fi
2200         ]
2201 )
2202 LIBS="$LIBS $KLIBS $K5LIBS"
2203
2204 # Looking for programs, paths and files
2205
2206 PRIVSEP_PATH=/var/empty
2207 AC_ARG_WITH(privsep-path,
2208         [  --with-privsep-path=xxx Path for privilege separation chroot (default=/var/empty)],
2209         [
2210                 if test "x$withval" != "$no" ; then
2211                         PRIVSEP_PATH=$withval
2212                 fi
2213         ]
2214 )
2215 AC_SUBST(PRIVSEP_PATH)
2216
2217 AC_ARG_WITH(xauth,
2218         [  --with-xauth=PATH       Specify path to xauth program ],
2219         [
2220                 if test "x$withval" != "xno" ; then
2221                         xauth_path=$withval
2222                 fi
2223         ],
2224         [
2225                 TestPath="$PATH"
2226                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/X/bin"
2227                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/bin/X11"
2228                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/X11R6/bin"
2229                 TestPath="${TestPath}${PATH_SEPARATOR}/usr/openwin/bin"
2230                 AC_PATH_PROG(xauth_path, xauth, , $TestPath)
2231                 if (test ! -z "$xauth_path" && test -x "/usr/openwin/bin/xauth") ; then
2232                         xauth_path="/usr/openwin/bin/xauth"
2233                 fi
2234         ]
2235 )
2236
2237 if test -z "$xauth_path" ; then
2238         XAUTH_PATH="undefined"
2239         AC_SUBST(XAUTH_PATH)
2240 else
2241         AC_DEFINE_UNQUOTED(XAUTH_PATH, "$xauth_path")
2242         XAUTH_PATH=$xauth_path
2243         AC_SUBST(XAUTH_PATH)
2244 fi
2245
2246 # Check for mail directory (last resort if we cannot get it from headers)
2247 if test ! -z "$MAIL" ; then
2248         maildir=`dirname $MAIL`
2249         AC_DEFINE_UNQUOTED(MAIL_DIRECTORY, "$maildir")
2250 fi
2251
2252 if test -z "$no_dev_ptmx" ; then
2253         if test "x$disable_ptmx_check" != "xyes" ; then
2254                 AC_CHECK_FILE("/dev/ptmx",
2255                         [
2256                                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTMX)
2257                                 have_dev_ptmx=1
2258                         ]
2259                 )
2260         fi
2261 fi
2262 AC_CHECK_FILE("/dev/ptc",
2263         [
2264                 AC_DEFINE_UNQUOTED(HAVE_DEV_PTS_AND_PTC)
2265                 have_dev_ptc=1
2266         ]
2267 )
2268
2269 # Options from here on. Some of these are preset by platform above
2270 AC_ARG_WITH(mantype,
2271         [  --with-mantype=man|cat|doc  Set man page type],
2272         [
2273                 case "$withval" in
2274                 man|cat|doc)
2275                         MANTYPE=$withval
2276                         ;;
2277                 *)
2278                         AC_MSG_ERROR(invalid man type: $withval)
2279                         ;;
2280                 esac
2281         ]
2282 )
2283 if test -z "$MANTYPE"; then
2284         TestPath="/usr/bin${PATH_SEPARATOR}/usr/ucb"
2285         AC_PATH_PROGS(NROFF, nroff awf, /bin/false, $TestPath)
2286         if ${NROFF} -mdoc ${srcdir}/ssh.1 >/dev/null 2>&1; then
2287                 MANTYPE=doc
2288         elif ${NROFF} -man ${srcdir}/ssh.1 >/dev/null 2>&1; then
2289                 MANTYPE=man
2290         else
2291                 MANTYPE=cat
2292         fi
2293 fi
2294 AC_SUBST(MANTYPE)
2295 if test "$MANTYPE" = "doc"; then
2296         mansubdir=man;
2297 else
2298         mansubdir=$MANTYPE;
2299 fi
2300 AC_SUBST(mansubdir)
2301
2302 # Check whether to enable MD5 passwords
2303 MD5_MSG="no"
2304 AC_ARG_WITH(md5-passwords,
2305         [  --with-md5-passwords    Enable use of MD5 passwords],
2306         [
2307                 if test "x$withval" != "xno" ; then
2308                         AC_DEFINE(HAVE_MD5_PASSWORDS)
2309                         MD5_MSG="yes"
2310                 fi
2311         ]
2312 )
2313
2314 # Whether to disable shadow password support
2315 AC_ARG_WITH(shadow,
2316         [  --without-shadow        Disable shadow password support],
2317         [
2318                 if test "x$withval" = "xno" ; then
2319                         AC_DEFINE(DISABLE_SHADOW)
2320                         disable_shadow=yes
2321                 fi
2322         ]
2323 )
2324
2325 if test -z "$disable_shadow" ; then
2326         AC_MSG_CHECKING([if the systems has expire shadow information])
2327         AC_TRY_COMPILE(
2328         [
2329 #include <sys/types.h>
2330 #include <shadow.h>
2331         struct spwd sp;
2332         ],[ sp.sp_expire = sp.sp_lstchg = sp.sp_inact = 0; ],
2333         [ sp_expire_available=yes ], []
2334         )
2335
2336         if test "x$sp_expire_available" = "xyes" ; then
2337                 AC_MSG_RESULT(yes)
2338                 AC_DEFINE(HAS_SHADOW_EXPIRE)
2339         else
2340                 AC_MSG_RESULT(no)
2341         fi
2342 fi
2343
2344 # Use ip address instead of hostname in $DISPLAY
2345 if test ! -z "$IPADDR_IN_DISPLAY" ; then
2346         DISPLAY_HACK_MSG="yes"
2347         AC_DEFINE(IPADDR_IN_DISPLAY)
2348 else
2349         DISPLAY_HACK_MSG="no"
2350         AC_ARG_WITH(ipaddr-display,
2351                 [  --with-ipaddr-display   Use ip address instead of hostname in \$DISPLAY],
2352                 [
2353                         if test "x$withval" != "xno" ; then
2354                                 AC_DEFINE(IPADDR_IN_DISPLAY)
2355                                 DISPLAY_HACK_MSG="yes"
2356                         fi
2357                 ]
2358         )
2359 fi
2360
2361 dnl BSD systems use /etc/login.conf so --with-default-path= has no effect
2362 if test $ac_cv_func_login_getcapbool = "yes" -a \
2363         $ac_cv_header_login_cap_h = "yes" ; then
2364         USES_LOGIN_CONF=yes
2365 fi
2366 # Whether to mess with the default path
2367 SERVER_PATH_MSG="(default)"
2368 AC_ARG_WITH(default-path,
2369         [  --with-default-path=    Specify default \$PATH environment for server],
2370         [
2371                 if test "$USES_LOGIN_CONF" = "yes" ; then
2372                         AC_MSG_WARN([
2373 --with-default-path=PATH has no effect on this system.
2374 Edit /etc/login.conf instead.])
2375                 elif test "x$withval" != "xno" ; then
2376                         user_path="$withval"
2377                         SERVER_PATH_MSG="$withval"
2378                 fi
2379         ],
2380         [ if test "$USES_LOGIN_CONF" = "yes" ; then
2381         AC_MSG_WARN([Make sure the path to scp is in /etc/login.conf])
2382         else
2383         AC_TRY_RUN(
2384                 [
2385 /* find out what STDPATH is */
2386 #include <stdio.h>
2387 #ifdef HAVE_PATHS_H
2388 # include <paths.h>
2389 #endif
2390 #ifndef _PATH_STDPATH
2391 # define _PATH_STDPATH "/usr/bin:/bin:/usr/sbin:/sbin"
2392 #endif
2393 #include <sys/types.h>
2394 #include <sys/stat.h>
2395 #include <fcntl.h>
2396 #define DATA "conftest.stdpath"
2397
2398 main()
2399 {
2400         FILE *fd;
2401         int rc;
2402
2403         fd = fopen(DATA,"w");
2404         if(fd == NULL)
2405                 exit(1);
2406
2407         if ((rc = fprintf(fd,"%s", _PATH_STDPATH)) < 0)
2408                 exit(1);
2409
2410         exit(0);
2411 }
2412                 ], [ user_path=`cat conftest.stdpath` ],
2413                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ],
2414                 [ user_path="/usr/bin:/bin:/usr/sbin:/sbin" ]
2415         )
2416         fi ]
2417 )
2418 if test "$USES_LOGIN_CONF" != "yes" ; then
2419         AC_DEFINE_UNQUOTED(USER_PATH, "$user_path")
2420         AC_SUBST(user_path)
2421 fi
2422
2423 # Set superuser path separately to user path
2424 AC_ARG_WITH(superuser-path,
2425         [  --with-superuser-path=  Specify different path for super-user],
2426         [
2427                 if test "x$withval" != "xno" ; then
2428                         AC_DEFINE_UNQUOTED(SUPERUSER_PATH, "$withval")
2429                         superuser_path=$withval
2430                 fi
2431         ]
2432 )
2433
2434
2435 # Whether to force IPv4 by default (needed on broken glibc Linux)
2436 IPV4_HACK_MSG="no"
2437 AC_ARG_WITH(ipv4-default,
2438         [  --with-ipv4-default     Use IPv4 by connections unless '-6' specified],
2439         [
2440                 if test "x$withval" != "xno" ; then
2441                         AC_DEFINE(IPV4_DEFAULT)
2442                         IPV4_HACK_MSG="yes"
2443                 fi
2444         ]
2445 )
2446
2447 AC_MSG_CHECKING([if we need to convert IPv4 in IPv6-mapped addresses])
2448 IPV4_IN6_HACK_MSG="no"
2449 AC_ARG_WITH(4in6,
2450         [  --with-4in6             Check for and convert IPv4 in IPv6 mapped addresses],
2451         [
2452                 if test "x$withval" != "xno" ; then
2453                         AC_MSG_RESULT(yes)
2454                         AC_DEFINE(IPV4_IN_IPV6)
2455                         IPV4_IN6_HACK_MSG="yes"
2456                 else
2457                         AC_MSG_RESULT(no)
2458                 fi
2459         ],[
2460                 if test "x$inet6_default_4in6" = "xyes"; then
2461                         AC_MSG_RESULT([yes (default)])
2462                         AC_DEFINE(IPV4_IN_IPV6)
2463                         IPV4_IN6_HACK_MSG="yes"
2464                 else
2465                         AC_MSG_RESULT([no (default)])
2466                 fi
2467         ]
2468 )
2469
2470 # Whether to enable BSD auth support
2471 BSD_AUTH_MSG=no
2472 AC_ARG_WITH(bsd-auth,
2473         [  --with-bsd-auth         Enable BSD auth support],
2474         [
2475                 if test "x$withval" != "xno" ; then
2476                         AC_DEFINE(BSD_AUTH)
2477                         BSD_AUTH_MSG=yes
2478                 fi
2479         ]
2480 )
2481
2482 # Where to place sshd.pid
2483 piddir=/var/run
2484 # make sure the directory exists
2485 if test ! -d $piddir ; then
2486         piddir=`eval echo ${sysconfdir}`
2487         case $piddir in
2488                 NONE/*) piddir=`echo $piddir | sed "s~NONE~$ac_default_prefix~"` ;;
2489         esac
2490 fi
2491
2492 AC_ARG_WITH(pid-dir,
2493         [  --with-pid-dir=PATH     Specify location of ssh.pid file],
2494         [
2495                 if test "x$withval" != "xno" ; then
2496                         piddir=$withval
2497                         if test ! -d $piddir ; then
2498                         AC_MSG_WARN([** no $piddir directory on this system **])
2499                         fi
2500                 fi
2501         ]
2502 )
2503
2504 AC_DEFINE_UNQUOTED(_PATH_SSH_PIDDIR, "$piddir")
2505 AC_SUBST(piddir)
2506
2507 dnl allow user to disable some login recording features
2508 AC_ARG_ENABLE(lastlog,
2509         [  --disable-lastlog       disable use of lastlog even if detected [no]],
2510         [ AC_DEFINE(DISABLE_LASTLOG) ]
2511 )
2512 AC_ARG_ENABLE(utmp,
2513         [  --disable-utmp          disable use of utmp even if detected [no]],
2514         [ AC_DEFINE(DISABLE_UTMP) ]
2515 )
2516 AC_ARG_ENABLE(utmpx,
2517         [  --disable-utmpx         disable use of utmpx even if detected [no]],
2518         [ AC_DEFINE(DISABLE_UTMPX) ]
2519 )
2520 AC_ARG_ENABLE(wtmp,
2521         [  --disable-wtmp          disable use of wtmp even if detected [no]],
2522         [ AC_DEFINE(DISABLE_WTMP) ]
2523 )
2524 AC_ARG_ENABLE(wtmpx,
2525         [  --disable-wtmpx         disable use of wtmpx even if detected [no]],
2526         [ AC_DEFINE(DISABLE_WTMPX) ]
2527 )
2528 AC_ARG_ENABLE(libutil,
2529         [  --disable-libutil       disable use of libutil (login() etc.) [no]],
2530         [ AC_DEFINE(DISABLE_LOGIN) ]
2531 )
2532 AC_ARG_ENABLE(pututline,
2533         [  --disable-pututline     disable use of pututline() etc. ([uw]tmp) [no]],
2534         [ AC_DEFINE(DISABLE_PUTUTLINE) ]
2535 )
2536 AC_ARG_ENABLE(pututxline,
2537         [  --disable-pututxline    disable use of pututxline() etc. ([uw]tmpx) [no]],
2538         [ AC_DEFINE(DISABLE_PUTUTXLINE) ]
2539 )
2540 AC_ARG_WITH(lastlog,
2541   [  --with-lastlog=FILE|DIR specify lastlog location [common locations]],
2542         [
2543                 if test "x$withval" = "xno" ; then
2544                         AC_DEFINE(DISABLE_LASTLOG)
2545                 else
2546                         conf_lastlog_location=$withval
2547                 fi
2548         ]
2549 )
2550
2551 dnl lastlog, [uw]tmpx? detection
2552 dnl  NOTE: set the paths in the platform section to avoid the
2553 dnl   need for command-line parameters
2554 dnl lastlog and [uw]tmp are subject to a file search if all else fails
2555
2556 dnl lastlog detection
2557 dnl  NOTE: the code itself will detect if lastlog is a directory
2558 AC_MSG_CHECKING([if your system defines LASTLOG_FILE])
2559 AC_TRY_COMPILE([
2560 #include <sys/types.h>
2561 #include <utmp.h>
2562 #ifdef HAVE_LASTLOG_H
2563 #  include <lastlog.h>
2564 #endif
2565 #ifdef HAVE_PATHS_H
2566 #  include <paths.h>
2567 #endif
2568 #ifdef HAVE_LOGIN_H
2569 # include <login.h>
2570 #endif
2571         ],
2572         [ char *lastlog = LASTLOG_FILE; ],
2573         [ AC_MSG_RESULT(yes) ],
2574         [
2575                 AC_MSG_RESULT(no)
2576                 AC_MSG_CHECKING([if your system defines _PATH_LASTLOG])
2577                 AC_TRY_COMPILE([
2578 #include <sys/types.h>
2579 #include <utmp.h>
2580 #ifdef HAVE_LASTLOG_H
2581 #  include <lastlog.h>
2582 #endif
2583 #ifdef HAVE_PATHS_H
2584 #  include <paths.h>
2585 #endif
2586                 ],
2587                 [ char *lastlog = _PATH_LASTLOG; ],
2588                 [ AC_MSG_RESULT(yes) ],
2589                 [
2590                         AC_MSG_RESULT(no)
2591                         system_lastlog_path=no
2592                 ])
2593         ]
2594 )
2595
2596 if test -z "$conf_lastlog_location"; then
2597         if test x"$system_lastlog_path" = x"no" ; then
2598                 for f in /var/log/lastlog /usr/adm/lastlog /var/adm/lastlog /etc/security/lastlog ; do
2599                                 if (test -d "$f" || test -f "$f") ; then
2600                                         conf_lastlog_location=$f
2601                                 fi
2602                 done
2603                 if test -z "$conf_lastlog_location"; then
2604                         AC_MSG_WARN([** Cannot find lastlog **])
2605                         dnl Don't define DISABLE_LASTLOG - that means we don't try wtmp/wtmpx
2606                 fi
2607         fi
2608 fi
2609
2610 if test -n "$conf_lastlog_location"; then
2611         AC_DEFINE_UNQUOTED(CONF_LASTLOG_FILE, "$conf_lastlog_location")
2612 fi
2613
2614 dnl utmp detection
2615 AC_MSG_CHECKING([if your system defines UTMP_FILE])
2616 AC_TRY_COMPILE([
2617 #include <sys/types.h>
2618 #include <utmp.h>
2619 #ifdef HAVE_PATHS_H
2620 #  include <paths.h>
2621 #endif
2622         ],
2623         [ char *utmp = UTMP_FILE; ],
2624         [ AC_MSG_RESULT(yes) ],
2625         [ AC_MSG_RESULT(no)
2626           system_utmp_path=no ]
2627 )
2628 if test -z "$conf_utmp_location"; then
2629         if test x"$system_utmp_path" = x"no" ; then
2630                 for f in /etc/utmp /usr/adm/utmp /var/run/utmp; do
2631                         if test -f $f ; then
2632                                 conf_utmp_location=$f
2633                         fi
2634                 done
2635                 if test -z "$conf_utmp_location"; then
2636                         AC_DEFINE(DISABLE_UTMP)
2637                 fi
2638         fi
2639 fi
2640 if test -n "$conf_utmp_location"; then
2641         AC_DEFINE_UNQUOTED(CONF_UTMP_FILE, "$conf_utmp_location")
2642 fi
2643
2644 dnl wtmp detection
2645 AC_MSG_CHECKING([if your system defines WTMP_FILE])
2646 AC_TRY_COMPILE([
2647 #include <sys/types.h>
2648 #include <utmp.h>
2649 #ifdef HAVE_PATHS_H
2650 #  include <paths.h>
2651 #endif
2652         ],
2653         [ char *wtmp = WTMP_FILE; ],
2654         [ AC_MSG_RESULT(yes) ],
2655         [ AC_MSG_RESULT(no)
2656           system_wtmp_path=no ]
2657 )
2658 if test -z "$conf_wtmp_location"; then
2659         if test x"$system_wtmp_path" = x"no" ; then
2660                 for f in /usr/adm/wtmp /var/log/wtmp; do
2661                         if test -f $f ; then
2662                                 conf_wtmp_location=$f
2663                         fi
2664                 done
2665                 if test -z "$conf_wtmp_location"; then
2666                         AC_DEFINE(DISABLE_WTMP)
2667                 fi
2668         fi
2669 fi
2670 if test -n "$conf_wtmp_location"; then
2671         AC_DEFINE_UNQUOTED(CONF_WTMP_FILE, "$conf_wtmp_location")
2672 fi
2673
2674
2675 dnl utmpx detection - I don't know any system so perverse as to require
2676 dnl  utmpx, but not define UTMPX_FILE (ditto wtmpx.) No doubt it's out
2677 dnl  there, though.
2678 AC_MSG_CHECKING([if your system defines UTMPX_FILE])
2679 AC_TRY_COMPILE([
2680 #include <sys/types.h>
2681 #include <utmp.h>
2682 #ifdef HAVE_UTMPX_H
2683 #include <utmpx.h>
2684 #endif
2685 #ifdef HAVE_PATHS_H
2686 #  include <paths.h>
2687 #endif
2688         ],
2689         [ char *utmpx = UTMPX_FILE; ],
2690         [ AC_MSG_RESULT(yes) ],
2691         [ AC_MSG_RESULT(no)
2692           system_utmpx_path=no ]
2693 )
2694 if test -z "$conf_utmpx_location"; then
2695         if test x"$system_utmpx_path" = x"no" ; then
2696                 AC_DEFINE(DISABLE_UTMPX)
2697         fi
2698 else
2699         AC_DEFINE_UNQUOTED(CONF_UTMPX_FILE, "$conf_utmpx_location")
2700 fi
2701
2702 dnl wtmpx detection
2703 AC_MSG_CHECKING([if your system defines WTMPX_FILE])
2704 AC_TRY_COMPILE([
2705 #include <sys/types.h>
2706 #include <utmp.h>
2707 #ifdef HAVE_UTMPX_H
2708 #include <utmpx.h>
2709 #endif
2710 #ifdef HAVE_PATHS_H
2711 #  include <paths.h>
2712 #endif
2713         ],
2714         [ char *wtmpx = WTMPX_FILE; ],
2715         [ AC_MSG_RESULT(yes) ],
2716         [ AC_MSG_RESULT(no)
2717           system_wtmpx_path=no ]
2718 )
2719 if test -z "$conf_wtmpx_location"; then
2720         if test x"$system_wtmpx_path" = x"no" ; then
2721                 AC_DEFINE(DISABLE_WTMPX)
2722         fi
2723 else
2724         AC_DEFINE_UNQUOTED(CONF_WTMPX_FILE, "$conf_wtmpx_location")
2725 fi
2726
2727
2728 if test ! -z "$blibpath" ; then
2729         LDFLAGS="$LDFLAGS -blibpath:$blibpath"
2730         AC_MSG_WARN([Please check and edit -blibpath in LDFLAGS in Makefile])
2731 fi
2732
2733 dnl remove pam and dl because they are in $LIBPAM
2734 if test "$PAM_MSG" = yes ; then
2735         LIBS=`echo $LIBS | sed 's/-lpam //'`
2736 fi
2737 if test "$ac_cv_lib_pam_pam_set_item" = yes ; then
2738         LIBS=`echo $LIBS | sed 's/-ldl //'`
2739 fi
2740
2741 AC_EXEEXT
2742 AC_CONFIG_FILES([Makefile openbsd-compat/Makefile scard/Makefile ssh_prng_cmds])
2743 AC_OUTPUT
2744
2745 # Print summary of options
2746
2747 # Someone please show me a better way :)
2748 A=`eval echo ${prefix}` ; A=`eval echo ${A}`
2749 B=`eval echo ${bindir}` ; B=`eval echo ${B}`
2750 C=`eval echo ${sbindir}` ; C=`eval echo ${C}`
2751 D=`eval echo ${sysconfdir}` ; D=`eval echo ${D}`
2752 E=`eval echo ${libexecdir}/ssh-askpass` ; E=`eval echo ${E}`
2753 F=`eval echo ${mandir}/${mansubdir}X` ; F=`eval echo ${F}`
2754 G=`eval echo ${piddir}` ; G=`eval echo ${G}`
2755 H=`eval echo ${PRIVSEP_PATH}` ; H=`eval echo ${H}`
2756 I=`eval echo ${user_path}` ; I=`eval echo ${I}`
2757 J=`eval echo ${superuser_path}` ; J=`eval echo ${J}`
2758
2759 echo ""
2760 echo "OpenSSH has been configured with the following options:"
2761 echo "                     User binaries: $B"
2762 echo "                   System binaries: $C"
2763 echo "               Configuration files: $D"
2764 echo "                   Askpass program: $E"
2765 echo "                      Manual pages: $F"
2766 echo "                          PID file: $G"
2767 echo "  Privilege separation chroot path: $H"
2768 if test "$USES_LOGIN_CONF" = "yes" ; then
2769 echo "   At runtime, sshd will use the path defined in /etc/login.conf"
2770 else
2771 echo "            sshd default user PATH: $I"
2772 fi
2773 if test ! -z "$superuser_path" ; then
2774 echo "          sshd superuser user PATH: $J"
2775 fi
2776 echo "                    Manpage format: $MANTYPE"
2777 echo "                       PAM support: ${PAM_MSG}"
2778 echo "                KerberosIV support: $KRB4_MSG"
2779 echo "                 KerberosV support: $KRB5_MSG"
2780 echo "                 Smartcard support: $SCARD_MSG"
2781 echo "                       AFS support: $AFS_MSG"
2782 echo "                     S/KEY support: $SKEY_MSG"
2783 echo "              TCP Wrappers support: $TCPW_MSG"
2784 echo "              MD5 password support: $MD5_MSG"
2785 echo "       IP address in \$DISPLAY hack: $DISPLAY_HACK_MSG"
2786 echo "          Use IPv4 by default hack: $IPV4_HACK_MSG"
2787 echo "           Translate v4 in v6 hack: $IPV4_IN6_HACK_MSG"
2788 echo "                  BSD Auth support: $BSD_AUTH_MSG"
2789 echo "              Random number source: $RAND_MSG"
2790 if test ! -z "$USE_RAND_HELPER" ; then
2791 echo "     ssh-rand-helper collects from: $RAND_HELPER_MSG"
2792 fi
2793
2794 echo ""
2795
2796 echo "              Host: ${host}"
2797 echo "          Compiler: ${CC}"
2798 echo "    Compiler flags: ${CFLAGS}"
2799 echo "Preprocessor flags: ${CPPFLAGS}"
2800 echo "      Linker flags: ${LDFLAGS}"
2801 echo "         Libraries: ${LIBWRAP} ${LIBPAM} ${LIBS}"
2802
2803 echo ""
2804
2805 if test "x$PAM_MSG" = "xyes" ; then
2806         echo "PAM is enabled. You may need to install a PAM control file "
2807         echo "for sshd, otherwise password authentication may fail. "
2808         echo "Example PAM control files can be found in the contrib/ "
2809         echo "subdirectory"
2810         echo ""
2811 fi
2812
2813 if test ! -z "$NO_SFTP"; then
2814         echo "sftp-server will be disabled.  Your compiler does not "
2815         echo "support 64bit integers."
2816         echo ""
2817 fi
2818
2819 if test ! -z "$RAND_HELPER_CMDHASH" ; then
2820         echo "WARNING: you are using the builtin random number collection "
2821         echo "service. Please read WARNING.RNG and request that your OS "
2822         echo "vendor includes kernel-based random number collection in "
2823         echo "future versions of your OS."
2824         echo ""
2825 fi
2826