[moira.git] / configure.in

AC_INIT(patchlevel.h)

dnl On Athena at least, many of the packages (krb, zephyr, hesiod, etc)
dnl will all be in /usr/athena... this hack lets us not end up with 10
dnl copies of -I/usr/athena/include -L/usr/athena/lib in our command lines
AC_DEFUN(MR_EXTEND, [
    case $$1 in
	*$2*) ;;
	*) $1=$2\ $$1 ;;
    esac
])

AC_CANONICAL_HOST
# SO_LDFLAGS setting below is a great big ick.
# But it beats sucking in libtool for one small part of the source tree.
case $host_os in
solaris*)
	short_os=solaris
	SO_LDFLAGS="-G"
	;;
irix*)
	short_os=irix
	SO_LDFLAGS="-shared"
	;;
linux*)
	short_os=linux
	SO_LDFLAGS="-shared"
	;;
esac
AC_SUBST(SO_LDFLAGS)

dnl Define for both C and Pro*C
AC_DEFUN(MR_DEFINE, [
    AC_DEFINE($1)
    MR_EXTEND(PRO_C_DEFS, DEFINE=$1)
])

dnl Add to include path for both C and Pro*C
AC_DEFUN(MR_INCLUDE, [
    MR_EXTEND(CPPFLAGS, -I$1)
    MR_EXTEND(PRO_C_INCLUDES, INCLUDE=$1)
]) 

dnl Add to lib path
AC_DEFUN(MR_LIBS, [MR_EXTEND(LIBPATH, -L$1)])

AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_PROG_MAKE_SET

if test "$athena" = true; then
    enable_athena=yes
    prefix=/afs/.athena.mit.edu/system/moira
    bindir=$prefix/arch/$ATHENA_SYS/bin
    sbindir=$bindir
    MR_INCLUDE(/usr/athena/include)
    MR_INCLUDE(/usr/athena/include/kerberosIV)
    MR_LIBS(/usr/athena/lib)
fi

# We currently just don't support changing this
mrbindir=/moira/bin
AC_SUBST(mrbindir)

# Athena-local policy decisions
AC_MSG_CHECKING(for Athena)
AC_ARG_ENABLE(athena,
    [  --enable-athena         Enable Athena-specific policy decisions],
    , [if test "$athena" = true; then
           enableval=yes
       else
	   enableval=no
       fi])
AC_MSG_RESULT($enableval)
if test "$enableval" = yes; then
    MR_DEFINE(ATHENA)
fi

# Networking libraries
AC_CHECKING(network libraries...)
AC_CHECK_FUNC(gethostbyname, :,
	      AC_CHECK_LIB(nsl, gethostbyname, ,
			   AC_CHECK_LIB(resolv, gethostbyname)))
AC_CHECK_FUNC(socket, :,
	      AC_CHECK_LIB(socket, socket, ,
			   AC_CHECK_LIB(socket, socket,
					LIBS="-lsocket -lnsl $LIBS", :,
					-lnsl)))

# com_err (required, but can be built)
AC_MSG_CHECKING(for com_err)
AC_ARG_WITH(com_err,
    [  --with-com_err=PREFIX   Specify location of com_err],
    [AC_MSG_RESULT($withval)
     if test $withval = "no"; then
         AC_MSG_ERROR(com_err is required for Moira)
     fi
     if test $withval != "yes"; then
	 MR_INCLUDE($withval/include)
	 MR_LIBS($withval/lib)
     fi
     COMPILE_ET=compile_et],
    [AC_MSG_RESULT(util/et)
     MR_INCLUDE(`pwd`/util/et)
     MR_LIBS(`pwd`/util/et)
     COMPILE_ET=`pwd`/util/et/compile_et
     AC_CONFIG_SUBDIRS(util/et)])
AC_SUBST(COM_ERR_SUBDIR)
AC_SUBST(COMPILE_ET)

# Kerberos (Kerberos 4 required, Kerberos 5 optional for reg_svr)
AC_MSG_CHECKING(for Kerberos 4)
AC_ARG_WITH(krb4,
    [  --with-krb4=PREFIX      Specify location of krb4],
    [krb4="$withval"], [krb4=no])
AC_MSG_RESULT($krb4)
if test $krb4 = "no"; then
    AC_MSG_ERROR(Kerberos is required for Moira)
fi
if test "$krb4" != yes; then
    MR_INCLUDE($krb4/include)
    if test -d "$krb4/include/kerberosIV"; then
	MR_INCLUDE($krb4/include/kerberosIV)
    fi
    MR_LIBS($krb4/lib)
elif test -d /usr/include/kerberosIV; then
    MR_INCLUDE(/usr/include/kerberosIV)
fi
AC_CHECK_LIB(k5crypto, main, crypto="k5crypto",
             [AC_CHECK_LIB(crypto, main, crypto="crypto")])
AC_CHECK_LIB(krb4, krb_rd_req,
	     [KRB4_LIBS="-lkrb4 -ldes425 -lkrb5 -l${crypto} -lresolv"],
	     [AC_CHECK_LIB(krb, krb_rd_req,
			   [KRB4_LIBS="-lkrb -ldes"],
			   [AC_MSG_ERROR(Kerberos 4 libraries not found)],
			   $LIBPATH -ldes)],
	     $LIBPATH -ldes425 -lkrb5 -l${crypto} -lcom_err -lresolv)

AC_MSG_CHECKING(for Kerberos 5)
AC_ARG_WITH(krb5,
    [  --with-krb5=PREFIX      Specify location of krb5 (for reg_svr)],
    [krb5="$withval"], [krb5=no])
AC_MSG_RESULT($krb5)
if test "$krb5" != no; then
    REG_SVR_DEFS=-DKRB5
    if test "$krb5" != yes; then
	REG_SVR_INCLUDES=-I$krb5/include
	REG_SVR_LIBS=-L$krb5/lib
    fi
    REG_SVR_LIBS="$REG_SVR_LIBS -lkadm5clnt -lgssapi_krb5 -lgssrpc -lkrb4 -ldes425 -lkrb5 -l${crypto} -lresolv"
else
    REG_SVR_DEFS=-DKRB4
    REG_SVR_LIBS=-lkadm
fi
AC_SUBST(REG_SVR_DEFS)
AC_SUBST(REG_SVR_INCLUDES)
AC_SUBST(REG_SVR_LIBS)

# Hesiod support
AC_MSG_CHECKING(for Hesiod)
AC_ARG_WITH(hesiod,
    [  --with-hesiod=PREFIX    Specify location of Hesiod],
    [hesiod="$withval"], [hesiod=no])
AC_MSG_RESULT($hesiod)
if test "$hesiod" != no; then
    if test "$hesiod" != yes; then
	MR_INCLUDE($hesiod/include)
	MR_LIBS($hesiod/lib)
    fi
    AC_CHECK_FUNC(res_send, :,
		  AC_CHECK_LIB(resolv, res_send))
    AC_CHECK_LIB(hesiod, hes_resolve, :,
		 [AC_MSG_ERROR(Hesiod library not found)],
		 $LIBPATH $LIBS)
    MR_DEFINE(HAVE_HESIOD)
fi

# Zephyr support
AC_MSG_CHECKING(for Zephyr)
AC_ARG_WITH(zephyr,
    [  --with-zephyr=PREFIX    Specify location of Zephyr],
    [zephyr="$withval"], [zephyr=no])
AC_MSG_RESULT($zephyr)
if test "$zephyr" != no; then
    if test "$zephyr" != yes; then
	MR_INCLUDE($zephyr/include)
	MR_LIBS($zephyr/lib)
    fi
    AC_CHECK_LIB(zephyr, ZInitialize, :,
		 [AC_MSG_ERROR(Zephyr library not found)],
		 $LIBPATH $KRB4_LIBS -lcom_err)
    MR_DEFINE(HAVE_ZEPHYR)
fi

# RSAREF support (default: build util/rsaref if present)
AC_MSG_CHECKING(for RSAREF)
AC_ARG_WITH(rsaref,
    [  --with-rsaref=PREFIX      Specify location of RSAREF],
    [rsaref="$withval"
     RSAREF_CPPFLAGS="-I$rsaref/include"
     RSAREF_LIBS="$rsaref/lib/rsaref.a"],
     RSAREF_SUBDIRS=reg_svr
    [if test -d $srcdir/util/rsaref; then
         rsaref=$srcdir/util/rsaref
	 RSAREF_SUBDIRS="util/rsaref reg_svr"
	 RSAREF_OUTPUT_FILES="util/rsaref/Makefile"
	 # autoconf can't deal with creating util/rsaref if util doesn't exist
	 if test ! -d util; then
	     mkdir util
	 fi
	 RSAREF_CPPFLAGS='-I$(SRCTOP)/util/rsaref'
	 RSAREF_LIBS='$(BUILDTOP)/util/rsaref/rsaref.a'
	 RSAREF_LIBDEP='$(BUILDTOP)/util/rsaref/rsaref.a'
     else
         rsaref=no
     fi])
AC_MSG_RESULT($rsaref)
if test "$rsaref" != no; then
    MR_DEFINE(HAVE_RSAREF)
fi
AC_SUBST(RSAREF_CPPFLAGS)
AC_SUBST(RSAREF_LIBS)
AC_SUBST(RSAREF_SUBDIRS)
AC_SUBST(RSAREF_LIBDEP)

# Oracle (default: yes, if $ORACLE_HOME is set)
AC_MSG_CHECKING(for Oracle)
AC_ARG_WITH(oracle,
    [  --with-oracle=PREFIX    Specify location of Oracle (for server)],
    [oracle="$withval"],
    [if test -n "$ORACLE_HOME" -a -d "$ORACLE_HOME"; then
         oracle=$ORACLE_HOME
     else
	 oracle=no
     fi])
AC_MSG_RESULT($oracle)
if test "$oracle" != no; then
    AC_MSG_CHECKING(Pro*C version)
    ORACLE_HOME=$oracle release=`$ORACLE_HOME/bin/proc | awk '/Release/ {print $3;}'`
    AC_MSG_RESULT($release)
    case $release in
	2.0.6.0.0)
	    SQL_LIBS="-L$oracle/lib -lsql $oracle/lib/osntab.o -lsqlnet -lora -lsqlnet -lnlsrtl -lcv6 -lcore -lnlsrtl -lcore -lm"
	    ;;
	2.2.4.0.0)
	    SQL_LIBS="-L$oracle/lib -lclntsh -lxa -lsql -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric   -lepc -lnlsrtl3 -lc3v6 -lcore3 -lnlsrtl3 -lcore3 -lnlsrtl3 `cat $oracle/rdbms/lib/sysliblist` -lm -lthread"
	    ;;
	8.1.7.4.0)
	    SQL_LIBS="-L$oracle/lib -lclntsh `cat $oracle/lib/sysliblist` -R$oracle/lib -laio -lm -lthread"
	    ;;
	10.2.0.2.0)
	    SQL_LIBS="-L$oracle/lib32 -lclntsh `cat $oracle/lib32/ldflags` `cat $oracle/lib32/sysliblist` -R$oracle/lib32 -laio -lposix4 -lm -lthread"
	    ;;
	*)
	    AC_MSG_ERROR(Unsupported Oracle release)
	    ;;
    esac
    SVRSUBDIRS='$(SVRDIRS)'
    SERVER_OUTPUT_FILES="db/Makefile server/Makefile backup/Makefile dbck/Makefile dcm/Makefile gen/Makefile incremental/Makefile incremental/mailman/Makefile reg_svr/Makefile regtape/Makefile"
    PRO_C=$oracle/bin/proc
    PRO_C_OPTS=CODE=ANSI_C
    PRO_C_DEFS="DEFINE=_PROC_ DEFINE=__sparc $PRO_C_DEFS"
fi
AC_SUBST(PRO_C)
AC_SUBST(PRO_C_DEFS)
AC_SUBST(PRO_C_INCLUDES)
AC_SUBST(PRO_C_OPTS)
AC_SUBST(SQL_LIBS)
AC_SUBST(SVRSUBDIRS)

# Java support, for webmoira
AC_MSG_CHECKING(for Java)
AC_ARG_WITH(java,
    [ --with-java=PREFIX       Specify location of Java libs and headers],
    [ java="$withval"],
    [if test -n "$JAVA_HOME" -a -d "$JAVA_HOME"; then
	java=$JAVA_HOME
     else
	java=no
     fi])
AC_MSG_RESULT($java)
if test "$java" != no; then
    if test "$java" != yes; then
	JAVA_CPPFLAGS="-I$java/include -I$java/include/$short_os"
    fi
    MR_DEFINE(HAVE_JAVA)

    WEBMOIRA_SUBDIRS="webmoira"
    WEBMOIRA_OUTPUT_FILES="webmoira/Makefile"
fi
AC_SUBST(JAVA_CPPFLAGS)
AC_SUBST(WEBMOIRA_SUBDIRS)

# LDAP support
AC_MSG_CHECKING(for LDAP)
AC_ARG_WITH(ldap,
    [  --with-ldap=PREFIX      Specify location of LDAP libs (for server)],
    [ ldap="$withval"], 
    [if test -n "$LDAP_HOME" -a -d "$LDAP_HOME"; then
         ldap=$LDAP_HOME
     else
	 ldap=no
     fi])
AC_MSG_RESULT($ldap)
if test "$ldap" != no -a "$oracle" != no; then
    if test "$ldap" != yes; then
        LDAP_CPPFLAGS="-I$ldap/include"
	LDAP_LIBS="-L$ldap/lib"
    fi
    MR_DEFINE(HAVE_LDAP)

    WINAD_SUBDIRS="winad"
    WINAD_OUTPUT_FILES="incremental/winad/Makefile"
fi
AC_SUBST(LDAP_CPPFLAGS)
AC_SUBST(LDAP_LIBS)
AC_SUBST(WINAD_SUBDIRS)

# AFS support
AC_MSG_CHECKING(for AFS)
AC_ARG_WITH(afs,
    [  --with-afs=PREFIX       Specify location of AFS libs (for server)],
    [afs="$withval"], [afs=no])
AC_MSG_RESULT($afs)
if test "$afs" != no -a "$oracle" != no; then
    if test "$afs" != yes; then
	AFS_CPPFLAGS="-I$afs/include -I$afs/include/afs -I$afs/include/rx"
	AFS_PRO_C_INCLUDES="INCLUDE=$afs/include INCLUDE=$afs/include/afs INCLUDE=$afs/include/rx"
	AFS_LIBS="-L$afs/lib -L$afs/lib/afs"
	AFS_DIR=$afs
    fi
    AC_CHECK_LIB(sys, pioctl, :,
		 [AC_MSG_ERROR(AFS libraries not found)],
		 $AFS_LIBS -lrx -llwp -lsys -lafsutil)
    MR_DEFINE(HAVE_AFS)

    AFS_SUBDIRS="afs"
    AFS_OUTPUT_FILES="incremental/afs/Makefile"
    if test -d $srcdir/afssync; then
	AFS_SYNCDIR="afssync"
	AFS_OUTPUT_FILES="$AFS_OUTPUT_FILES afssync/Makefile"
    fi
fi
AC_SUBST(AFS_CPPFLAGS)
AC_SUBST(AFS_PRO_C_INCLUDES)
AC_SUBST(AFS_LIBS)
AC_SUBST(AFS_DIR)
AC_SUBST(AFS_SUBDIRS)
AC_SUBST(AFS_SYNCDIR)

# GNU readline
AC_CHECKING(for GNU readline...)
AC_ARG_WITH(readline,
    [  --with-readline=PREFIX  Specify location of GNU readline],
    [readline="$withval"; AC_MSG_RESULT($withval)],
    [AC_CHECK_LIB(readline, readline, [readline=yes],
	[if test "$athena" = true; then
	     unset ac_cv_lib_readline_readline
	     AC_CHECK_LIB(readline, readline, [readline=/mit/gnu], :,
	         -L/mit/gnu/lib -ltermcap)
	 fi],
	-ltermcap)])
if test "$readline" != no; then
    if test "$readline" != yes; then
	READLINE_CPPFLAGS="-I$readline/include"
	READLINE_LIBS="-L$readline/lib"
    fi
    READLINE_CPPFLAGS="$READLINE_CPPFLAGS -DHAVE_READLINE"
    READLINE_LIBS="$READLINE_LIBS -lreadline -ltermcap"
fi
AC_SUBST(READLINE_CPPFLAGS)
AC_SUBST(READLINE_LIBS)

# Curses
curses=curses
AC_CHECKING(for curses)
AC_CHECK_LIB(curses, main, :, AC_CHECK_LIB(ncurses, main, curses=ncurses))
if test -n "$curses"; then
    OLDLIBS=$LIBS
    LIBS=-l$curses
    AC_CHECKING(if curses needs termcap)
    dnl we need to use AC_TRY_RUN because under NetBSD, the program will
    dnl link with just -lcurses, but then fail with a runtime linker error
    dnl because you didn't use -ltermcap
    AC_TRY_RUN([#include <curses.h>
		main(int argc, char **argv)
		{
		    initscr();
		    endwin();
		    return 0;
		}], [CURSES_LIBS="-l$curses"],
		LIBS="-l$curses -ltermcap"
		AC_TRY_RUN([#include <curses.h>
			    main(int argc, char **argv)
			    {
				initscr();
				endwin();
				return 0;
			    }], [CURSES_LIBS="-l$curses -ltermcap"],
			    :, :),
		:)
    LIBS=$OLDLIBS
fi
if test -n "$CURSES_LIBS"; then
    OLDLIBS=$LIBS
    LIBS=$CURSES_LIBS
    AC_TRY_LINK([#include <curses.h>],[WINDOW *w; getmaxx(w);],
		:,
		AC_TRY_COMPILE([#include <curses.h>],[WINDOW *w; w->_maxx;],
			       [CURSES_CPPFLAGS="-D'getmaxx(w)=w->_maxx'"],
			       [CURSES_CPPFLAGS="-D'getmaxx(w)=w->maxx'"]))
    AC_TRY_LINK([#include <curses.h>],[newterm(NULL, NULL, NULL);],
		[CURSES_CPPFLAGS="$CURSES_CPPFLAGS -DCURSES_HAS_NEWTERM"])
    LIBS=$OLDLIBS
    CURSES_CPPFLAGS="-DHAVE_CURSES $CURSES_CPPFLAGS"
    CURSES_SUBDIRS='$(CURSES_SUBDIRS)'
else
    AC_MSG_WARN(Couldn't find -lcurses)
fi
AC_SUBST(CURSES_CPPFLAGS)
AC_SUBST(CURSES_LIBS)
AC_SUBST(CURSES_SUBDIRS)


AC_CHECK_FUNCS(getusershell strlcpy strlcat uname strvis)

AC_CHECK_FUNC(sigaction, AC_DEFINE(HAVE_POSIX_SIGNALS))

AC_CHECK_HEADERS(unistd.h getopt.h)

AC_CHECK_HEADER(netinet/in.h, AC_DEFINE(HAVE_NETINET_IN_H), no_netinet_in=yes)

if test "$no_netinet_in" != "yes"; then
    AC_MSG_CHECKING(for in_addr_t defined in netinet/in.h)
    AC_EGREP_HEADER(in_addr_t, netinet/in.h,
	ac_cv_type_in_addr_t=yes, ac_cv_type_in_addr_t=no)
    AC_MSG_RESULT($ac_cv_type_in_addr_t)
fi

if test "$ac_cv_type_in_addr_t" != "yes"; then
  AC_DEFINE(in_addr_t, uint32_t)
fi

MR_EXTEND(PRO_C_INCLUDES, INCLUDE='$(srcdir)')
MR_INCLUDE('$(SRCTOP)/include')
MR_INCLUDE('$(SRCTOP)/lib')
MR_INCLUDE('$(BUILDTOP)/lib')
MR_INCLUDE('$(BUILDTOP)/db')
MR_INCLUDE('$(srcdir)')
LDFLAGS="$LDFLAGS -L\$(BUILDTOP)/lib $LIBPATH"
KLIBS="-lzephyr $KRB4_LIBS -lcom_err -lhesiod $LIBS"
LIBS="-lmoira $KLIBS"
AC_SUBST(KLIBS)

MR_LIBDEP='$(BUILDTOP)/lib/libmoira.a'
AC_SUBST(MR_LIBDEP)

AC_OUTPUT(Makefile lib/Makefile include/Makefile clients/Makefile \
	  clients/lib/Makefile clients/addusr/Makefile \
	  clients/blanche/Makefile clients/chfn/Makefile \
	  clients/chpobox/Makefile clients/chsh/Makefile \
	  clients/mailmaint/Makefile clients/mitch/Makefile \
	  clients/moira/Makefile clients/mrcheck/Makefile \
	  clients/mrtest/Makefile clients/stanley/Makefile \
	  clients/stella/Makefile update/Makefile man/Makefile \
	  $WEBMOIRA_OUTPUT_FILES $SERVER_OUTPUT_FILES $WINAD_OUTPUT_FILES \
	  $AFS_OUTPUT_FILES $RSAREF_OUTPUT_FILES)
Commit	Line	Data
ea0caf4a	1	AC_INIT(patchlevel.h)
	2
	3	dnl On Athena at least, many of the packages (krb, zephyr, hesiod, etc)
	4	dnl will all be in /usr/athena... this hack lets us not end up with 10
	5	dnl copies of -I/usr/athena/include -L/usr/athena/lib in our command lines
	6	AC_DEFUN(MR_EXTEND, [
	7	case $$1 in
	8	$2) ;;
	9	*) $1=$2\ $$1 ;;
	10	esac
	11	])
	12
3595c6c0	13	AC_CANONICAL_HOST
0bec79fd	14	# SO_LDFLAGS setting below is a great big ick.
0bec79fd	15	# But it beats sucking in libtool for one small part of the source tree.
3595c6c0	16	case $host_os in
	17	solaris*)
	18	short_os=solaris
0bec79fd	19	SO_LDFLAGS="-G"
3595c6c0	20	;;
	21	irix*)
	22	short_os=irix
0bec79fd	23	SO_LDFLAGS="-shared"
3595c6c0	24	;;
	25	linux*)
	26	short_os=linux
0bec79fd	27	SO_LDFLAGS="-shared"
3595c6c0	28	;;
3595c6c0	29	esac
0bec79fd	30	AC_SUBST(SO_LDFLAGS)
3595c6c0	31
ea0caf4a	32	dnl Define for both C and Pro*C
	33	AC_DEFUN(MR_DEFINE, [
	34	AC_DEFINE($1)
	35	MR_EXTEND(PRO_C_DEFS, DEFINE=$1)
	36	])
	37
	38	dnl Add to include path for both C and Pro*C
	39	AC_DEFUN(MR_INCLUDE, [
	40	MR_EXTEND(CPPFLAGS, -I$1)
	41	MR_EXTEND(PRO_C_INCLUDES, INCLUDE=$1)
	42	])
	43
	44	dnl Add to lib path
	45	AC_DEFUN(MR_LIBS, [MR_EXTEND(LIBPATH, -L$1)])
	46
	47	AC_PROG_CC
	48	AC_PROG_INSTALL
	49	AC_PROG_RANLIB
	50	AC_PROG_MAKE_SET
	51
	52	if test "$athena" = true; then
	53	enable_athena=yes
1944209a	54	prefix=/afs/.athena.mit.edu/system/moira
ea0caf4a	55	bindir=$prefix/arch/$ATHENA_SYS/bin
ea0caf4a	56	sbindir=$bindir
618b3834	57	MR_INCLUDE(/usr/athena/include)
	58	MR_INCLUDE(/usr/athena/include/kerberosIV)
	59	MR_LIBS(/usr/athena/lib)
ea0caf4a	60	fi
	61
	62	# We currently just don't support changing this
	63	mrbindir=/moira/bin
	64	AC_SUBST(mrbindir)
	65
	66	# Athena-local policy decisions
	67	AC_MSG_CHECKING(for Athena)
	68	AC_ARG_ENABLE(athena,
	69	[ --enable-athena Enable Athena-specific policy decisions],
	70	, [if test "$athena" = true; then
	71	enableval=yes
	72	else
	73	enableval=no
	74	fi])
	75	AC_MSG_RESULT($enableval)
	76	if test "$enableval" = yes; then
	77	MR_DEFINE(ATHENA)
	78	fi
	79
	80	# Networking libraries
	81	AC_CHECKING(network libraries...)
	82	AC_CHECK_FUNC(gethostbyname, :,
	83	AC_CHECK_LIB(nsl, gethostbyname, ,
	84	AC_CHECK_LIB(resolv, gethostbyname)))
	85	AC_CHECK_FUNC(socket, :,
	86	AC_CHECK_LIB(socket, socket, ,
	87	AC_CHECK_LIB(socket, socket,
	88	LIBS="-lsocket -lnsl $LIBS", :,
	89	-lnsl)))
	90
7f7f279f	91	# com_err (required, but can be built)
	92	AC_MSG_CHECKING(for com_err)
	93	AC_ARG_WITH(com_err,
	94	[ --with-com_err=PREFIX Specify location of com_err],
	95	[AC_MSG_RESULT($withval)
	96	if test $withval = "no"; then
	97	AC_MSG_ERROR(com_err is required for Moira)
	98	fi
	99	if test $withval != "yes"; then
	100	MR_INCLUDE($withval/include)
	101	MR_LIBS($withval/lib)
	102	fi
	103	COMPILE_ET=compile_et],
	104	[AC_MSG_RESULT(util/et)
7f7f279f	105	MR_INCLUDE(`pwd`/util/et)
	106	MR_LIBS(`pwd`/util/et)
	107	COMPILE_ET=`pwd`/util/et/compile_et
00274452	108	AC_CONFIG_SUBDIRS(util/et)])
7f7f279f	109	AC_SUBST(COM_ERR_SUBDIR)
	110	AC_SUBST(COMPILE_ET)
	111
	112	# Kerberos (Kerberos 4 required, Kerberos 5 optional for reg_svr)
ea0caf4a	113	AC_MSG_CHECKING(for Kerberos 4)
	114	AC_ARG_WITH(krb4,
	115	[ --with-krb4=PREFIX Specify location of krb4],
	116	[krb4="$withval"], [krb4=no])
	117	AC_MSG_RESULT($krb4)
	118	if test $krb4 = "no"; then
	119	AC_MSG_ERROR(Kerberos is required for Moira)
	120	fi
	121	if test "$krb4" != yes; then
	122	MR_INCLUDE($krb4/include)
	123	if test -d "$krb4/include/kerberosIV"; then
	124	MR_INCLUDE($krb4/include/kerberosIV)
	125	fi
	126	MR_LIBS($krb4/lib)
	127	elif test -d /usr/include/kerberosIV; then
	128	MR_INCLUDE(/usr/include/kerberosIV)
	129	fi
88c52873	130	AC_CHECK_LIB(k5crypto, main, crypto="k5crypto",
88c52873	131	[AC_CHECK_LIB(crypto, main, crypto="crypto")])
ea0caf4a	132	AC_CHECK_LIB(krb4, krb_rd_req,
2dd418e4	133	[KRB4_LIBS="-lkrb4 -ldes425 -lkrb5 -l${crypto} -lresolv"],
ea0caf4a	134	[AC_CHECK_LIB(krb, krb_rd_req,
	135	[KRB4_LIBS="-lkrb -ldes"],
	136	[AC_MSG_ERROR(Kerberos 4 libraries not found)],
	137	$LIBPATH -ldes)],
2dd418e4	138	$LIBPATH -ldes425 -lkrb5 -l${crypto} -lcom_err -lresolv)
ea0caf4a	139
7f7f279f	140	AC_MSG_CHECKING(for Kerberos 5)
	141	AC_ARG_WITH(krb5,
	142	[ --with-krb5=PREFIX Specify location of krb5 (for reg_svr)],
	143	[krb5="$withval"], [krb5=no])
	144	AC_MSG_RESULT($krb5)
	145	if test "$krb5" != no; then
	146	REG_SVR_DEFS=-DKRB5
	147	if test "$krb5" != yes; then
	148	REG_SVR_INCLUDES=-I$krb5/include
	149	REG_SVR_LIBS=-L$krb5/lib
	150	fi
00274452	151	REG_SVR_LIBS="$REG_SVR_LIBS -lkadm5clnt -lgssapi_krb5 -lgssrpc -lkrb4 -ldes425 -lkrb5 -l${crypto} -lresolv"
7f7f279f	152	else
	153	REG_SVR_DEFS=-DKRB4
	154	REG_SVR_LIBS=-lkadm
	155	fi
	156	AC_SUBST(REG_SVR_DEFS)
	157	AC_SUBST(REG_SVR_INCLUDES)
	158	AC_SUBST(REG_SVR_LIBS)
33567bea	159
ea0caf4a	160	# Hesiod support
	161	AC_MSG_CHECKING(for Hesiod)
	162	AC_ARG_WITH(hesiod,
	163	[ --with-hesiod=PREFIX Specify location of Hesiod],
	164	[hesiod="$withval"], [hesiod=no])
	165	AC_MSG_RESULT($hesiod)
	166	if test "$hesiod" != no; then
	167	if test "$hesiod" != yes; then
	168	MR_INCLUDE($hesiod/include)
	169	MR_LIBS($hesiod/lib)
	170	fi
	171	AC_CHECK_FUNC(res_send, :,
	172	AC_CHECK_LIB(resolv, res_send))
	173	AC_CHECK_LIB(hesiod, hes_resolve, :,
	174	[AC_MSG_ERROR(Hesiod library not found)],
	175	$LIBPATH $LIBS)
	176	MR_DEFINE(HAVE_HESIOD)
	177	fi
	178
	179	# Zephyr support
	180	AC_MSG_CHECKING(for Zephyr)
	181	AC_ARG_WITH(zephyr,
	182	[ --with-zephyr=PREFIX Specify location of Zephyr],
	183	[zephyr="$withval"], [zephyr=no])
	184	AC_MSG_RESULT($zephyr)
	185	if test "$zephyr" != no; then
	186	if test "$zephyr" != yes; then
	187	MR_INCLUDE($zephyr/include)
	188	MR_LIBS($zephyr/lib)
	189	fi
	190	AC_CHECK_LIB(zephyr, ZInitialize, :,
	191	[AC_MSG_ERROR(Zephyr library not found)],
	192	$LIBPATH $KRB4_LIBS -lcom_err)
	193	MR_DEFINE(HAVE_ZEPHYR)
	194	fi
	195
33567bea	196	# RSAREF support (default: build util/rsaref if present)
	197	AC_MSG_CHECKING(for RSAREF)
	198	AC_ARG_WITH(rsaref,
	199	[ --with-rsaref=PREFIX Specify location of RSAREF],
	200	[rsaref="$withval"
	201	RSAREF_CPPFLAGS="-I$rsaref/include"
	202	RSAREF_LIBS="$rsaref/lib/rsaref.a"],
	203	RSAREF_SUBDIRS=reg_svr
	204	[if test -d $srcdir/util/rsaref; then
	205	rsaref=$srcdir/util/rsaref
	206	RSAREF_SUBDIRS="util/rsaref reg_svr"
	207	RSAREF_OUTPUT_FILES="util/rsaref/Makefile"
	208	# autoconf can't deal with creating util/rsaref if util doesn't exist
	209	if test ! -d util; then
	210	mkdir util
	211	fi
46fa38eb	212	RSAREF_CPPFLAGS='-I$(SRCTOP)/util/rsaref'
33567bea	213	RSAREF_LIBS='$(BUILDTOP)/util/rsaref/rsaref.a'
3fb6166b	214	RSAREF_LIBDEP='$(BUILDTOP)/util/rsaref/rsaref.a'
33567bea	215	else
	216	rsaref=no
	217	fi])
	218	AC_MSG_RESULT($rsaref)
	219	if test "$rsaref" != no; then
	220	MR_DEFINE(HAVE_RSAREF)
	221	fi
	222	AC_SUBST(RSAREF_CPPFLAGS)
	223	AC_SUBST(RSAREF_LIBS)
	224	AC_SUBST(RSAREF_SUBDIRS)
3fb6166b	225	AC_SUBST(RSAREF_LIBDEP)
33567bea	226
ea0caf4a	227	# Oracle (default: yes, if $ORACLE_HOME is set)
	228	AC_MSG_CHECKING(for Oracle)
	229	AC_ARG_WITH(oracle,
	230	[ --with-oracle=PREFIX Specify location of Oracle (for server)],
	231	[oracle="$withval"],
	232	[if test -n "$ORACLE_HOME" -a -d "$ORACLE_HOME"; then
	233	oracle=$ORACLE_HOME
	234	else
	235	oracle=no
	236	fi])
	237	AC_MSG_RESULT($oracle)
	238	if test "$oracle" != no; then
cd357ef5	239	AC_MSG_CHECKING(Pro*C version)
	240	ORACLE_HOME=$oracle release=`$ORACLE_HOME/bin/proc \| awk '/Release/ {print $3;}'`
	241	AC_MSG_RESULT($release)
	242	case $release in
	243	2.0.6.0.0)
	244	SQL_LIBS="-L$oracle/lib -lsql $oracle/lib/osntab.o -lsqlnet -lora -lsqlnet -lnlsrtl -lcv6 -lcore -lnlsrtl -lcore -lm"
	245	;;
7e38e77c	246	2.2.4.0.0)
cd357ef5	247	SQL_LIBS="-L$oracle/lib -lclntsh -lxa -lsql -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric -lsqlnet -lncr -lsqlnet -lclient -lcommon -lgeneric -lepc -lnlsrtl3 -lc3v6 -lcore3 -lnlsrtl3 -lcore3 -lnlsrtl3 `cat $oracle/rdbms/lib/sysliblist` -lm -lthread"
cd357ef5	248	;;
00274452	249	8.1.7.4.0)
dc02aea5	250	SQL_LIBS="-L$oracle/lib -lclntsh `cat $oracle/lib/sysliblist` -R$oracle/lib -laio -lm -lthread"
7e38e77c	251	;;
00274452	252	10.2.0.2.0)
	253	SQL_LIBS="-L$oracle/lib32 -lclntsh `cat $oracle/lib32/ldflags` `cat $oracle/lib32/sysliblist` -R$oracle/lib32 -laio -lposix4 -lm -lthread"
	254	;;
	255	*)
	256	AC_MSG_ERROR(Unsupported Oracle release)
	257	;;
cd357ef5	258	esac
ea0caf4a	259	SVRSUBDIRS='$(SVRDIRS)'
ac1784ed	260	SERVER_OUTPUT_FILES="db/Makefile server/Makefile backup/Makefile dbck/Makefile dcm/Makefile gen/Makefile incremental/Makefile incremental/mailman/Makefile reg_svr/Makefile regtape/Makefile"
ea0caf4a	261	PRO_C=$oracle/bin/proc
ea0caf4a	262	PRO_C_OPTS=CODE=ANSI_C
00274452	263	PRO_C_DEFS="DEFINE=_PROC_ DEFINE=__sparc $PRO_C_DEFS"
ea0caf4a	264	fi
	265	AC_SUBST(PRO_C)
	266	AC_SUBST(PRO_C_DEFS)
	267	AC_SUBST(PRO_C_INCLUDES)
	268	AC_SUBST(PRO_C_OPTS)
	269	AC_SUBST(SQL_LIBS)
	270	AC_SUBST(SVRSUBDIRS)
	271
3595c6c0	272	# Java support, for webmoira
	273	AC_MSG_CHECKING(for Java)
	274	AC_ARG_WITH(java,
	275	[ --with-java=PREFIX Specify location of Java libs and headers],
	276	[ java="$withval"],
	277	[if test -n "$JAVA_HOME" -a -d "$JAVA_HOME"; then
	278	java=$JAVA_HOME
	279	else
	280	java=no
	281	fi])
	282	AC_MSG_RESULT($java)
	283	if test "$java" != no; then
	284	if test "$java" != yes; then
	285	JAVA_CPPFLAGS="-I$java/include -I$java/include/$short_os"
	286	fi
	287	MR_DEFINE(HAVE_JAVA)
	288
	289	WEBMOIRA_SUBDIRS="webmoira"
	290	WEBMOIRA_OUTPUT_FILES="webmoira/Makefile"
	291	fi
	292	AC_SUBST(JAVA_CPPFLAGS)
a5a4b554	293	AC_SUBST(WEBMOIRA_SUBDIRS)
3595c6c0	294
9b1f5e48	295	# LDAP support
	296	AC_MSG_CHECKING(for LDAP)
	297	AC_ARG_WITH(ldap,
	298	[ --with-ldap=PREFIX Specify location of LDAP libs (for server)],
	299	[ ldap="$withval"],
	300	[if test -n "$LDAP_HOME" -a -d "$LDAP_HOME"; then
	301	ldap=$LDAP_HOME
	302	else
	303	ldap=no
	304	fi])
	305	AC_MSG_RESULT($ldap)
	306	if test "$ldap" != no -a "$oracle" != no; then
	307	if test "$ldap" != yes; then
	308	LDAP_CPPFLAGS="-I$ldap/include"
	309	LDAP_LIBS="-L$ldap/lib"
	310	fi
	311	MR_DEFINE(HAVE_LDAP)
	312
	313	WINAD_SUBDIRS="winad"
	314	WINAD_OUTPUT_FILES="incremental/winad/Makefile"
	315	fi
	316	AC_SUBST(LDAP_CPPFLAGS)
	317	AC_SUBST(LDAP_LIBS)
	318	AC_SUBST(WINAD_SUBDIRS)
	319
ea0caf4a	320	# AFS support
	321	AC_MSG_CHECKING(for AFS)
	322	AC_ARG_WITH(afs,
	323	[ --with-afs=PREFIX Specify location of AFS libs (for server)],
	324	[afs="$withval"], [afs=no])
	325	AC_MSG_RESULT($afs)
	326	if test "$afs" != no -a "$oracle" != no; then
	327	if test "$afs" != yes; then
	328	AFS_CPPFLAGS="-I$afs/include -I$afs/include/afs -I$afs/include/rx"
	329	AFS_PRO_C_INCLUDES="INCLUDE=$afs/include INCLUDE=$afs/include/afs INCLUDE=$afs/include/rx"
	330	AFS_LIBS="-L$afs/lib -L$afs/lib/afs"
	331	AFS_DIR=$afs
	332	fi
ea0caf4a	333	AC_CHECK_LIB(sys, pioctl, :,
ea0caf4a	334	[AC_MSG_ERROR(AFS libraries not found)],
00274452	335	$AFS_LIBS -lrx -llwp -lsys -lafsutil)
ea0caf4a	336	MR_DEFINE(HAVE_AFS)
9ed720ef	337
9b1f5e48	338	AFS_SUBDIRS="afs"
9b1f5e48	339	AFS_OUTPUT_FILES="incremental/afs/Makefile"
9ed720ef	340	if test -d $srcdir/afssync; then
9b1f5e48	341	AFS_SYNCDIR="afssync"
9ed720ef	342	AFS_OUTPUT_FILES="$AFS_OUTPUT_FILES afssync/Makefile"
9ed720ef	343	fi
ea0caf4a	344	fi
	345	AC_SUBST(AFS_CPPFLAGS)
	346	AC_SUBST(AFS_PRO_C_INCLUDES)
	347	AC_SUBST(AFS_LIBS)
ea0caf4a	348	AC_SUBST(AFS_DIR)
9ed720ef	349	AC_SUBST(AFS_SUBDIRS)
9b1f5e48	350	AC_SUBST(AFS_SYNCDIR)
ea0caf4a	351
	352	# GNU readline
	353	AC_CHECKING(for GNU readline...)
	354	AC_ARG_WITH(readline,
	355	[ --with-readline=PREFIX Specify location of GNU readline],
ee85084d	356	[readline="$withval"; AC_MSG_RESULT($withval)],
	357	[AC_CHECK_LIB(readline, readline, [readline=yes],
	358	[if test "$athena" = true; then
	359	unset ac_cv_lib_readline_readline
	360	AC_CHECK_LIB(readline, readline, [readline=/mit/gnu], :,
	361	-L/mit/gnu/lib -ltermcap)
	362	fi],
	363	-ltermcap)])
ea0caf4a	364	if test "$readline" != no; then
ea0caf4a	365	if test "$readline" != yes; then
c5c5a18d	366	READLINE_CPPFLAGS="-I$readline/include"
ee85084d	367	READLINE_LIBS="-L$readline/lib"
ea0caf4a	368	fi
ee85084d	369	READLINE_CPPFLAGS="$READLINE_CPPFLAGS -DHAVE_READLINE"
ee85084d	370	READLINE_LIBS="$READLINE_LIBS -lreadline -ltermcap"
ea0caf4a	371	fi
	372	AC_SUBST(READLINE_CPPFLAGS)
	373	AC_SUBST(READLINE_LIBS)
	374
	375	# Curses
	376	curses=curses
	377	AC_CHECKING(for curses)
	378	AC_CHECK_LIB(curses, main, :, AC_CHECK_LIB(ncurses, main, curses=ncurses))
	379	if test -n "$curses"; then
	380	OLDLIBS=$LIBS
	381	LIBS=-l$curses
	382	AC_CHECKING(if curses needs termcap)
	383	dnl we need to use AC_TRY_RUN because under NetBSD, the program will
	384	dnl link with just -lcurses, but then fail with a runtime linker error
	385	dnl because you didn't use -ltermcap
	386	AC_TRY_RUN([#include <curses.h>
	387	main(int argc, char **argv)
	388	{
	389	initscr();
	390	endwin();
	391	return 0;
	392	}], [CURSES_LIBS="-l$curses"],
	393	LIBS="-l$curses -ltermcap"
	394	AC_TRY_RUN([#include <curses.h>
	395	main(int argc, char **argv)
	396	{
	397	initscr();
	398	endwin();
	399	return 0;
	400	}], [CURSES_LIBS="-l$curses -ltermcap"],
	401	:, :),
	402	:)
	403	LIBS=$OLDLIBS
	404	fi
	405	if test -n "$CURSES_LIBS"; then
	406	OLDLIBS=$LIBS
	407	LIBS=$CURSES_LIBS
	408	AC_TRY_LINK([#include <curses.h>],[WINDOW *w; getmaxx(w);],
	409	:,
	410	AC_TRY_COMPILE([#include <curses.h>],[WINDOW *w; w->_maxx;],
	411	[CURSES_CPPFLAGS="-D'getmaxx(w)=w->_maxx'"],
	412	[CURSES_CPPFLAGS="-D'getmaxx(w)=w->maxx'"]))
4753fa79	413	AC_TRY_LINK([#include <curses.h>],[newterm(NULL, NULL, NULL);],
4753fa79	414	[CURSES_CPPFLAGS="$CURSES_CPPFLAGS -DCURSES_HAS_NEWTERM"])
ea0caf4a	415	LIBS=$OLDLIBS
	416	CURSES_CPPFLAGS="-DHAVE_CURSES $CURSES_CPPFLAGS"
	417	CURSES_SUBDIRS='$(CURSES_SUBDIRS)'
	418	else
	419	AC_MSG_WARN(Couldn't find -lcurses)
	420	fi
	421	AC_SUBST(CURSES_CPPFLAGS)
	422	AC_SUBST(CURSES_LIBS)
	423	AC_SUBST(CURSES_SUBDIRS)
	424
	425
83a0db38	426	AC_CHECK_FUNCS(getusershell strlcpy strlcat uname strvis)
533bacb3	427
	428	AC_CHECK_FUNC(sigaction, AC_DEFINE(HAVE_POSIX_SIGNALS))
	429
7674bbe4	430	AC_CHECK_HEADERS(unistd.h getopt.h)
	431
	432	AC_CHECK_HEADER(netinet/in.h, AC_DEFINE(HAVE_NETINET_IN_H), no_netinet_in=yes)
	433
	434	if test "$no_netinet_in" != "yes"; then
	435	AC_MSG_CHECKING(for in_addr_t defined in netinet/in.h)
	436	AC_EGREP_HEADER(in_addr_t, netinet/in.h,
	437	ac_cv_type_in_addr_t=yes, ac_cv_type_in_addr_t=no)
	438	AC_MSG_RESULT($ac_cv_type_in_addr_t)
	439	fi
	440
	441	if test "$ac_cv_type_in_addr_t" != "yes"; then
	442	AC_DEFINE(in_addr_t, uint32_t)
	443	fi
ea0caf4a	444
25f58600	445	MR_EXTEND(PRO_C_INCLUDES, INCLUDE='$(srcdir)')
ea0caf4a	446	MR_INCLUDE('$(SRCTOP)/include')
25f58600	447	MR_INCLUDE('$(SRCTOP)/lib')
ea0caf4a	448	MR_INCLUDE('$(BUILDTOP)/lib')
ea0caf4a	449	MR_INCLUDE('$(BUILDTOP)/db')
f4036eed	450	MR_INCLUDE('$(srcdir)')
ea0caf4a	451	LDFLAGS="$LDFLAGS -L\$(BUILDTOP)/lib $LIBPATH"
	452	KLIBS="-lzephyr $KRB4_LIBS -lcom_err -lhesiod $LIBS"
	453	LIBS="-lmoira $KLIBS"
	454	AC_SUBST(KLIBS)
	455
3fb6166b	456	MR_LIBDEP='$(BUILDTOP)/lib/libmoira.a'
	457	AC_SUBST(MR_LIBDEP)
	458
ea0caf4a	459	AC_OUTPUT(Makefile lib/Makefile include/Makefile clients/Makefile \
ee85084d	460	clients/lib/Makefile clients/addusr/Makefile \
f62cd5c0	461	clients/blanche/Makefile clients/chfn/Makefile \
	462	clients/chpobox/Makefile clients/chsh/Makefile \
	463	clients/mailmaint/Makefile clients/mitch/Makefile \
7cc696ad	464	clients/moira/Makefile clients/mrcheck/Makefile \
	465	clients/mrtest/Makefile clients/stanley/Makefile \
	466	clients/stella/Makefile update/Makefile man/Makefile \
	467	$WEBMOIRA_OUTPUT_FILES $SERVER_OUTPUT_FILES $WINAD_OUTPUT_FILES \
	468	$AFS_OUTPUT_FILES $RSAREF_OUTPUT_FILES)